nb_kernel130_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,895 行 · 第 1/4 页

        movaps nb130_fiz(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%rdi,%rcx,4),%xmm3
        movss  4(%rdi,%rcx,4),%xmm4
        movss  8(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rdi,%rcx,4)
        movss  %xmm4,4(%rdi,%rcx,4)
        movss  %xmm5,8(%rdi,%rcx,4)

        ## increment fshift force  
        movss  (%rsi,%rdx,4),%xmm3
        movss  4(%rsi,%rdx,4),%xmm4
        movss  8(%rsi,%rdx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rsi,%rdx,4)
        movss  %xmm4,4(%rsi,%rdx,4)
        movss  %xmm5,8(%rsi,%rdx,4)

        ## get n from stack
        movl nb130_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb130_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb130_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb130_Vc(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## accumulate total lj energy and update it 
        movaps nb130_Vvdwtot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb130_Vvdw(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb130_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel130_x86_64_sse.nb130_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb130_n(%rsp)
        jmp _nb_kernel130_x86_64_sse.nb130_outer
_nb_kernel130_x86_64_sse.nb130_outerend: 
        ## check if more outer neighborlists remain
        movl  nb130_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel130_x86_64_sse.nb130_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel130_x86_64_sse.nb130_threadloop
_nb_kernel130_x86_64_sse.nb130_end: 
        movl nb130_nouter(%rsp),%eax
        movl nb130_ninner(%rsp),%ebx
        movq nb130_outeriter(%rbp),%rcx
        movq nb130_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $440,%rsp
        emms


        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret







.globl nb_kernel130nf_x86_64_sse
.globl _nb_kernel130nf_x86_64_sse
nb_kernel130nf_x86_64_sse:      
_nb_kernel130nf_x86_64_sse:     
##      Room for return address and rbp (16 bytes)
.set nb130nf_fshift, 16
.set nb130nf_gid, 24
.set nb130nf_pos, 32
.set nb130nf_faction, 40
.set nb130nf_charge, 48
.set nb130nf_p_facel, 56
.set nb130nf_argkrf, 64
.set nb130nf_argcrf, 72
.set nb130nf_Vc, 80
.set nb130nf_type, 88
.set nb130nf_p_ntype, 96
.set nb130nf_vdwparam, 104
.set nb130nf_Vvdw, 112
.set nb130nf_p_tabscale, 120
.set nb130nf_VFtab, 128
.set nb130nf_invsqrta, 136
.set nb130nf_dvda, 144
.set nb130nf_p_gbtabscale, 152
.set nb130nf_GBtab, 160
.set nb130nf_p_nthreads, 168
.set nb130nf_count, 176
.set nb130nf_mtx, 184
.set nb130nf_outeriter, 192
.set nb130nf_inneriter, 200
.set nb130nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb130nf_ix, 0
.set nb130nf_iy, 16
.set nb130nf_iz, 32
.set nb130nf_iq, 48
.set nb130nf_c6, 64
.set nb130nf_c12, 80
.set nb130nf_vctot, 96
.set nb130nf_Vvdwtot, 112
.set nb130nf_half, 128
.set nb130nf_three, 144
.set nb130nf_krf, 160
.set nb130nf_crf, 176
.set nb130nf_tsc, 192
.set nb130nf_nri, 208
.set nb130nf_iinr, 216
.set nb130nf_jindex, 224
.set nb130nf_jjnr, 232
.set nb130nf_shift, 240
.set nb130nf_shiftvec, 248
.set nb130nf_facel, 256
.set nb130nf_innerjjnr, 264
.set nb130nf_is3, 272
.set nb130nf_ii3, 280
.set nb130nf_ntia, 284
.set nb130nf_innerk, 288
.set nb130nf_n, 292
.set nb130nf_nn1, 296
.set nb130nf_ntype, 300
.set nb130nf_nouter, 304
.set nb130nf_ninner, 308

        push %rbp
        movq %rsp,%rbp
        push %rbx

        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $328,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb130nf_nouter(%rsp)
        movl %eax,nb130nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb130nf_nri(%rsp)
        movq %rsi,nb130nf_iinr(%rsp)
        movq %rdx,nb130nf_jindex(%rsp)
        movq %rcx,nb130nf_jjnr(%rsp)
        movq %r8,nb130nf_shift(%rsp)
        movq %r9,nb130nf_shiftvec(%rsp)
        movq nb130nf_p_ntype(%rbp),%rdi
        movl (%rdi),%edi
        movl %edi,nb130nf_ntype(%rsp)
        movq nb130nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb130nf_facel(%rsp)

        movq nb130nf_p_tabscale(%rbp),%rax
        movss (%rax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb130nf_tsc(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb130nf_half(%rsp)
        movss nb130nf_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb130nf_half(%rsp)
        movaps %xmm3,nb130nf_three(%rsp)


_nb_kernel130nf_x86_64_sse.nb130nf_threadloop: 
        movq  nb130nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel130nf_x86_64_sse.nb130nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel130nf_x86_64_sse.nb130nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb130nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb130nf_n(%rsp)
        movl %ebx,nb130nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel130nf_x86_64_sse.nb130nf_outerstart
        jmp _nb_kernel130nf_x86_64_sse.nb130nf_end

_nb_kernel130nf_x86_64_sse.nb130nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb130nf_nouter(%rsp),%ebx
        movl %ebx,nb130nf_nouter(%rsp)

_nb_kernel130nf_x86_64_sse.nb130nf_outer: 
        movq  nb130nf_shift(%rsp),%rax        ## eax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## ebx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb130nf_is3(%rsp)            ## store is3 

        movq  nb130nf_shiftvec(%rsp),%rax     ## eax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb130nf_iinr(%rsp),%rcx         ## ecx = pointer into iinr[]      
        movl  (%rcx,%rsi,4),%ebx            ## ebx =ii 

        movq  nb130nf_charge(%rbp),%rdx
        movss (%rdx,%rbx,4),%xmm3
        mulss nb130nf_facel(%rsp),%xmm3
        shufps $0,%xmm3,%xmm3

        movq  nb130nf_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%edx
        imull nb130nf_ntype(%rsp),%edx
        shll  %edx
        movl  %edx,nb130nf_ntia(%rsp)

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb130nf_pos(%rbp),%rax      ## eax = base of pos[]  

        addss (%rax,%rbx,4),%xmm0
        addss 4(%rax,%rbx,4),%xmm1
        addss 8(%rax,%rbx,4),%xmm2

        movaps %xmm3,nb130nf_iq(%rsp)

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2

        movaps %xmm0,nb130nf_ix(%rsp)
        movaps %xmm1,nb130nf_iy(%rsp)
        movaps %xmm2,nb130nf_iz(%rsp)

        movl  %ebx,nb130nf_ii3(%rsp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb130nf_vctot(%rsp)
        movaps %xmm4,nb130nf_Vvdwtot(%rsp)

        movq  nb130nf_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb130nf_pos(%rbp),%rsi
        movq  nb130nf_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb130nf_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb130nf_ninner(%rsp),%ecx
        movl  %ecx,nb130nf_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb130nf_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel130nf_x86_64_sse.nb130nf_unroll_loop
        jmp   _nb_kernel130nf_x86_64_sse.nb130nf_finish_inner
_nb_kernel130nf_x86_64_sse.nb130nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movq  nb130nf_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx
        movl  8(%rdx),%ecx
        movl  12(%rdx),%edx           ## eax-edx=jnr1-4 
        addq $16,nb130nf_innerjjnr(%rsp)             ## advance pointer (unrolled 4) 

        movq nb130nf_charge(%rbp),%rsi     ## base of charge[] 

        movss (%rsi,%rax,4),%xmm3
        movss (%rsi,%rcx,4),%xmm4
        movss (%rsi,%rbx,4),%xmm6
        movss (%rsi,%rdx,4),%xmm7

        movaps nb130nf_iq(%rsp),%xmm2
        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movq nb130nf_type(%rbp),%rsi
        movl (%rsi,%rax,4),%eax
        movl (%rsi,%rbx,4),%ebx
        movl (%rsi,%rcx,4),%ecx
        movl (%rsi,%rdx,4),%edx
        movq nb130nf_vdwparam(%rbp),%rsi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb130nf_ntia(%rsp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%rsi,%rax,4),%xmm6
        movlps (%rsi,%rcx,4),%xmm7
        movhps (%rsi,%rbx,4),%xmm6
        movhps (%rsi,%rdx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## constant 10001000
        shufps $221,%xmm7,%xmm6 ## constant 11011101

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movd  %mm2,%ecx
        movd  %mm3,%edx

        movaps %xmm4,nb130nf_c6(%rsp)
        movaps %xmm6,nb130nf_c12(%rsp)

        movq nb130nf_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx

        mulps %xmm2,%xmm3
        lea  (%rcx,%rcx,2),%rcx     ## replace jnr with j3 
        lea  (%rdx,%rdx,2),%rdx

        ## move four coordinates to xmm0-xmm2   

        movlps (%rsi,%rax,4),%xmm4
        movlps (%rsi,%rcx,4),%xmm5
        movss 8(%rsi,%rax,4),%xmm2
        movss 8(%rsi,%rcx,4),%xmm6

        movhps (%rsi,%rbx,4),%xmm4
        movhps (%rsi,%rdx,4),%xmm5

        movss 8(%rsi,%rbx,4),%xmm0
        movss 8(%rsi,%rdx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## constant 10001000

        shufps $136,%xmm5,%xmm0 ## constant 10001000
        shufps $221,%xmm5,%xmm1 ## constant 11011101            

        ## move ix-iz to xmm4-xmm6 
        movaps nb130nf_ix(%rsp),%xmm4
        movaps nb130nf_iy(%rsp),%xmm5
        movaps nb130nf_iz(%rsp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6
        addps %xmm5,%xmm4
        addps %xmm6,%xmm4
        ## rsq in xmm4 

        rsqrtps %xmm4,%xmm5
        ## lookup seed in xmm5 
        movaps %xmm5,%xmm2
        mulps %xmm5,%xmm5
        movaps nb130nf_three(%rsp),%xmm1
        mulps %xmm4,%xmm5       ## rsq*lu*lu                    
        movaps nb130nf_half(%rsp),%xmm0
        subps %xmm5,%xmm1       ## constant 30-rsq*lu*lu 
        mulps %xmm2,%xmm1
        mulps %xmm1,%xmm0       ## xmm0=rinv    
        movaps %xmm0,%xmm1
        mulps %xmm0,%xmm3
        addps  nb130nf_vctot(%rsp),%xmm3
        movaps %xmm3,nb130nf_vctot(%rsp)

        ## LJ table
        mulps  %xmm1,%xmm4 ## r
        mulps  nb130nf_tsc(%rsp),%xmm4   ## rtab

        movaps %xmm1,%xmm0 ## copy of rinv
        movhlps %xmm4,%xmm5
        cvttps2pi %xmm4,%mm6
        cvttps2pi %xmm5,%mm7    ## mm6/mm7 contain lu indices 
        cvtpi2ps %mm6,%xmm6
        cvtpi2ps %mm7,%xmm5
        movlhps %xmm5,%xmm6
        subps %xmm6,%xmm4