nb_kernel310_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,781 行 · 第 1/4 页

        movhlps %xmm15,%xmm2
        addps  %xmm13,%xmm0
        addps  %xmm14,%xmm1
        addps  %xmm15,%xmm2
    movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%rdi,%rcx,4),%xmm3
        movss  4(%rdi,%rcx,4),%xmm4
        movss  8(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rdi,%rcx,4)
        movss  %xmm4,4(%rdi,%rcx,4)
        movss  %xmm5,8(%rdi,%rcx,4)

        ## increment fshift force  
        movss  (%rsi,%rdx,4),%xmm3
        movss  4(%rsi,%rdx,4),%xmm4
        movss  8(%rsi,%rdx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rsi,%rdx,4)
        movss  %xmm4,4(%rsi,%rdx,4)
        movss  %xmm5,8(%rsi,%rdx,4)

        ## get n from stack
        movl nb310_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb310_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb310_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb310_Vc(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## accumulate total lj energy and update it 
        movaps nb310_Vvdwtot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb310_Vvdw(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb310_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel310_x86_64_sse.nb310_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb310_n(%rsp)
        jmp _nb_kernel310_x86_64_sse.nb310_outer
_nb_kernel310_x86_64_sse.nb310_outerend: 
        ## check if more outer neighborlists remain
        movl  nb310_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel310_x86_64_sse.nb310_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel310_x86_64_sse.nb310_threadloop
_nb_kernel310_x86_64_sse.nb310_end: 

        movl nb310_nouter(%rsp),%eax
        movl nb310_ninner(%rsp),%ebx
        movq nb310_outeriter(%rbp),%rcx
        movq nb310_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $472,%rsp
        emms


        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret






.globl nb_kernel310nf_x86_64_sse
.globl _nb_kernel310nf_x86_64_sse
nb_kernel310nf_x86_64_sse:      
_nb_kernel310nf_x86_64_sse:     
##      Room for return address and rbp (16 bytes)
.set nb310nf_fshift, 16
.set nb310nf_gid, 24
.set nb310nf_pos, 32
.set nb310nf_faction, 40
.set nb310nf_charge, 48
.set nb310nf_p_facel, 56
.set nb310nf_argkrf, 64
.set nb310nf_argcrf, 72
.set nb310nf_Vc, 80
.set nb310nf_type, 88
.set nb310nf_p_ntype, 96
.set nb310nf_vdwparam, 104
.set nb310nf_Vvdw, 112
.set nb310nf_p_tabscale, 120
.set nb310nf_VFtab, 128
.set nb310nf_invsqrta, 136
.set nb310nf_dvda, 144
.set nb310nf_p_gbtabscale, 152
.set nb310nf_GBtab, 160
.set nb310nf_p_nthreads, 168
.set nb310nf_count, 176
.set nb310nf_mtx, 184
.set nb310nf_outeriter, 192
.set nb310nf_inneriter, 200
.set nb310nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb310nf_ix, 0
.set nb310nf_iy, 16
.set nb310nf_iz, 32
.set nb310nf_iq, 48
.set nb310nf_tsc, 64
.set nb310nf_qq, 80
.set nb310nf_c6, 96
.set nb310nf_c12, 112
.set nb310nf_vctot, 128
.set nb310nf_Vvdwtot, 144
.set nb310nf_half, 160
.set nb310nf_three, 176
.set nb310nf_nri, 192
.set nb310nf_iinr, 200
.set nb310nf_jindex, 208
.set nb310nf_jjnr, 216
.set nb310nf_shift, 224
.set nb310nf_shiftvec, 232
.set nb310nf_facel, 240
.set nb310nf_innerjjnr, 248
.set nb310nf_is3, 256
.set nb310nf_ii3, 260
.set nb310nf_ntia, 264
.set nb310nf_innerk, 268
.set nb310nf_n, 272
.set nb310nf_nn1, 276
.set nb310nf_ntype, 280
.set nb310nf_nouter, 284
.set nb310nf_ninner, 288

        push %rbp
        movq %rsp,%rbp
        push %rbx


        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $312,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb310nf_nouter(%rsp)
        movl %eax,nb310nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb310nf_nri(%rsp)
        movq %rsi,nb310nf_iinr(%rsp)
        movq %rdx,nb310nf_jindex(%rsp)
        movq %rcx,nb310nf_jjnr(%rsp)
        movq %r8,nb310nf_shift(%rsp)
        movq %r9,nb310nf_shiftvec(%rsp)
        movq nb310nf_p_ntype(%rbp),%rdi
        movl (%rdi),%edi
        movl %edi,nb310nf_ntype(%rsp)
        movq nb310nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb310nf_facel(%rsp)

        movq nb310nf_p_tabscale(%rbp),%rax
        movss (%rax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb310nf_tsc(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb310nf_half(%rsp)
        movss nb310nf_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb310nf_half(%rsp)
        movaps %xmm3,nb310nf_three(%rsp)

_nb_kernel310nf_x86_64_sse.nb310nf_threadloop: 
        movq  nb310nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel310nf_x86_64_sse.nb310nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel310nf_x86_64_sse.nb310nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb310nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb310nf_n(%rsp)
        movl %ebx,nb310nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel310nf_x86_64_sse.nb310nf_outerstart
        jmp _nb_kernel310nf_x86_64_sse.nb310nf_end

_nb_kernel310nf_x86_64_sse.nb310nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb310nf_nouter(%rsp),%ebx
        movl %ebx,nb310nf_nouter(%rsp)

_nb_kernel310nf_x86_64_sse.nb310nf_outer: 
        movq  nb310nf_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## ebx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb310nf_is3(%rsp)            ## store is3 

        movq  nb310nf_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb310nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx,%rsi,4),%ebx            ## ebx =ii 

        movq  nb310nf_charge(%rbp),%rdx
        movss (%rdx,%rbx,4),%xmm3
        mulss nb310nf_facel(%rsp),%xmm3
        shufps $0,%xmm3,%xmm3

        movq  nb310nf_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%edx
        imull nb310nf_ntype(%rsp),%edx
        shll  %edx
        movl  %edx,nb310nf_ntia(%rsp)

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb310nf_pos(%rbp),%rax      ## rax = base of pos[]  

        addss (%rax,%rbx,4),%xmm0
        addss 4(%rax,%rbx,4),%xmm1
        addss 8(%rax,%rbx,4),%xmm2

        movaps %xmm3,nb310nf_iq(%rsp)

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2

        movaps %xmm0,nb310nf_ix(%rsp)
        movaps %xmm1,nb310nf_iy(%rsp)
        movaps %xmm2,nb310nf_iz(%rsp)

        movl  %ebx,nb310nf_ii3(%rsp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb310nf_vctot(%rsp)
        movaps %xmm4,nb310nf_Vvdwtot(%rsp)

        movq  nb310nf_jindex(%rsp),%rax
        movq  (%rax,%rsi,4),%rcx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb310nf_pos(%rbp),%rsi
        movq  nb310nf_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb310nf_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb310nf_ninner(%rsp),%ecx
        movl  %ecx,nb310nf_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb310nf_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel310nf_x86_64_sse.nb310nf_unroll_loop
        jmp   _nb_kernel310nf_x86_64_sse.nb310nf_finish_inner
_nb_kernel310nf_x86_64_sse.nb310nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movq  nb310nf_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx
        movl  8(%rdx),%ecx
        movl  12(%rdx),%edx           ## eax-edx=jnr1-4 
        addq $16,nb310nf_innerjjnr(%rsp)             ## advance pointer (unrolled 4) 

        movq nb310nf_charge(%rbp),%rsi     ## base of charge[] 

        movss (%rsi,%rax,4),%xmm3
        movss (%rsi,%rcx,4),%xmm4
        movss (%rsi,%rbx,4),%xmm6
        movss (%rsi,%rdx,4),%xmm7

        movaps nb310nf_iq(%rsp),%xmm2
        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## 10001000 ;# all charges in xmm3  
        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        mulps  %xmm2,%xmm3
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movaps %xmm3,nb310nf_qq(%rsp)

        movq nb310nf_type(%rbp),%rsi
        movl (%rsi,%rax,4),%eax
        movl (%rsi,%rbx,4),%ebx
        movl (%rsi,%rcx,4),%ecx
        movl (%rsi,%rdx,4),%edx
        movq nb310nf_vdwparam(%rbp),%rsi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb310nf_ntia(%rsp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%rsi,%rax,4),%xmm6
        movlps (%rsi,%rcx,4),%xmm7
        movhps (%rsi,%rbx,4),%xmm6
        movhps (%rsi,%rdx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## 10001000
        shufps $221,%xmm7,%xmm6 ## 11011101

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movd  %mm2,%ecx
        movd  %mm3,%edx

        movaps %xmm4,nb310nf_c6(%rsp)
        movaps %xmm6,nb310nf_c12(%rsp)

        movq nb310nf_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx

        lea  (%rcx,%rcx,2),%rcx     ## replace jnr with j3 
        lea  (%rdx,%rdx,2),%rdx

        ## move four coordinates to xmm0-xmm2   

        movlps (%rsi,%rax,4),%xmm4
        movlps (%rsi,%rcx,4),%xmm5
        movss 8(%rsi,%rax,4),%xmm2
        movss 8(%rsi,%rcx,4),%xmm6

        movhps (%rsi,%rbx,4),%xmm4
        movhps (%rsi,%rdx,4),%xmm5

        movss 8(%rsi,%rbx,4),%xmm0
        movss 8(%rsi,%rdx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## 10001000

        shufps $136,%xmm5,%xmm0 ## 10001000
        shufps $221,%xmm5,%xmm1 ## 11011101             

        ## move ix-iz to xmm4-xmm6 
        movaps nb310nf_ix(%rsp),%xmm4
        movaps nb310nf_iy(%rsp),%xmm5
        movaps nb310nf_iz(%rsp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6
        addps %xmm5,%xmm4
        addps %xmm6,%xmm4
        ## rsq in xmm4 

        rsqrtps %xmm4,%xmm5
        ## lookup seed in xmm5 
        movaps %xmm5,%xmm2
        mulps %xmm5,%xmm5