nb_kernel331_x86_64_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,310 行 · 第 1/5 页

;#
;# $Id: nb_kernel331_x86_64_sse.intel_syntax.s,v 1.1.2.2 2006/09/22 08:32:51 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as




.globl nb_kernel331_x86_64_sse
.globl _nb_kernel331_x86_64_sse
nb_kernel331_x86_64_sse:	
_nb_kernel331_x86_64_sse:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb331_fshift,           16
.equiv          nb331_gid,              24
.equiv          nb331_pos,              32
.equiv          nb331_faction,          40
.equiv          nb331_charge,           48
.equiv          nb331_p_facel,          56
.equiv          nb331_argkrf,           64
.equiv          nb331_argcrf,           72
.equiv          nb331_Vc,               80
.equiv          nb331_type,             88
.equiv          nb331_p_ntype,          96
.equiv          nb331_vdwparam,         104
.equiv          nb331_Vvdw,             112
.equiv          nb331_p_tabscale,       120
.equiv          nb331_VFtab,            128
.equiv          nb331_invsqrta,         136
.equiv          nb331_dvda,             144
.equiv          nb331_p_gbtabscale,     152
.equiv          nb331_GBtab,            160
.equiv          nb331_p_nthreads,       168
.equiv          nb331_count,            176
.equiv          nb331_mtx,              184
.equiv          nb331_outeriter,        192
.equiv          nb331_inneriter,        200
.equiv          nb331_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb331_ixO,              0
.equiv          nb331_iyO,              16
.equiv          nb331_izO,              32
.equiv          nb331_ixH1,             48
.equiv          nb331_iyH1,             64
.equiv          nb331_izH1,             80
.equiv          nb331_ixH2,             96
.equiv          nb331_iyH2,             112
.equiv          nb331_izH2,             128
.equiv          nb331_iqO,              144
.equiv          nb331_iqH,              160
.equiv          nb331_dxO,              176
.equiv          nb331_dyO,              192
.equiv          nb331_dzO,              208
.equiv          nb331_dxH1,             224
.equiv          nb331_dyH1,             240
.equiv          nb331_dzH1,             256
.equiv          nb331_dxH2,             272
.equiv          nb331_dyH2,             288
.equiv          nb331_dzH2,             304
.equiv          nb331_qqO,              320
.equiv          nb331_qqH,              336
.equiv          nb331_rinvO,            352
.equiv          nb331_rinvH1,           368
.equiv          nb331_rinvH2,           384
.equiv          nb331_rO,               400
.equiv          nb331_rH1,              416
.equiv          nb331_rH2,              432
.equiv          nb331_tsc,              448
.equiv          nb331_two,              464
.equiv          nb331_c6,               480
.equiv          nb331_c12,              496
.equiv          nb331_vctot,            512
.equiv          nb331_Vvdwtot,          528
.equiv          nb331_fixO,             544
.equiv          nb331_fiyO,             560
.equiv          nb331_fizO,             576
.equiv          nb331_fixH1,            592
.equiv          nb331_fiyH1,            608
.equiv          nb331_fizH1,            624
.equiv          nb331_fixH2,            640
.equiv          nb331_fiyH2,            656
.equiv          nb331_fizH2,            672
.equiv          nb331_epsO,             688
.equiv          nb331_epsH1,            704
.equiv          nb331_epsH2,            720
.equiv          nb331_half,             736
.equiv          nb331_three,            752
.equiv          nb331_is3,              768
.equiv          nb331_ii3,              772
.equiv          nb331_nri,              776
.equiv          nb331_iinr,             784
.equiv          nb331_jindex,           792
.equiv          nb331_jjnr,             800
.equiv          nb331_shift,            808
.equiv          nb331_shiftvec,         816
.equiv          nb331_facel,            824
.equiv          nb331_innerjjnr,        832
.equiv          nb331_ntia,             840
.equiv          nb331_innerk,           844
.equiv          nb331_n,                848
.equiv          nb331_nn1,              852
.equiv          nb331_nouter,           856
.equiv          nb331_ninner,           860
	push rbp
	mov  rbp, rsp
	push rbx
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 872		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb331_nouter], eax
	mov [rsp + nb331_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb331_nri], edi
	mov [rsp + nb331_iinr], rsi
	mov [rsp + nb331_jindex], rdx
	mov [rsp + nb331_jjnr], rcx
	mov [rsp + nb331_shift], r8
	mov [rsp + nb331_shiftvec], r9
	mov rsi, [rbp + nb331_p_facel]
	movss xmm0, [rsi]
	movss [rsp + nb331_facel], xmm0

	mov rax, [rbp + nb331_p_tabscale]
	movss xmm3, [rax]
	shufps xmm3, xmm3, 0
	movaps [rsp + nb331_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# half in IEEE (hex)
	mov [rsp + nb331_half], eax
	movss xmm1, [rsp + nb331_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# one
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# two
	addps  xmm3, xmm2	;# three
	movaps [rsp + nb331_half],  xmm1
	movaps [rsp + nb331_two],  xmm2
	movaps [rsp + nb331_three],  xmm3
	
	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb331_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb331_charge]
	movss xmm3, [rdx + rbx*4]	
	movss xmm4, [rdx + rbx*4 + 4]	
	mov rsi, [rbp + nb331_p_facel]
	movss xmm0, [rsi]
	movss xmm5, [rsp + nb331_facel]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [rsp + nb331_iqO], xmm3
	movaps [rsp + nb331_iqH], xmm4
	
	mov   rdx, [rbp + nb331_type]
	mov   ecx, [rdx + rbx*4]
	shl   ecx, 1
	mov rdi, [rbp + nb331_p_ntype]
	imul  ecx, [rdi]      ;# rcx = ntia = 2*ntype*type[ii0] 
	mov   [rsp + nb331_ntia], ecx		
	
.nb331_threadloop:
        mov   rsi, [rbp + nb331_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb331_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb331_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb331_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb331_n], eax
        mov [rsp + nb331_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb331_outerstart
        jmp .nb331_end
	
.nb331_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb331_nouter]
	mov [rsp + nb331_nouter], ebx

.nb331_outer:
	mov   rax, [rsp + nb331_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax + rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb331_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb331_shiftvec]   ;# rax = base of shiftvec[] 

	movss xmm0, [rax + rbx*4]
	movss xmm1, [rax + rbx*4 + 4]
	movss xmm2, [rax + rbx*4 + 8] 

	mov   rcx, [rsp + nb331_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx + rsi*4]	    ;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2

	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb331_pos]    ;# rax = base of pos[]  
	mov   [rsp + nb331_ii3], ebx

	addss xmm3, [rax + rbx*4]
	addss xmm4, [rax + rbx*4 + 4]
	addss xmm5, [rax + rbx*4 + 8]		
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [rsp + nb331_ixO], xmm3
	movaps [rsp + nb331_iyO], xmm4
	movaps [rsp + nb331_izO], xmm5

	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm0, [rax + rbx*4 + 12]
	addss xmm1, [rax + rbx*4 + 16]
	addss xmm2, [rax + rbx*4 + 20]		
	addss xmm3, [rax + rbx*4 + 24]
	addss xmm4, [rax + rbx*4 + 28]
	addss xmm5, [rax + rbx*4 + 32]		

	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [rsp + nb331_ixH1], xmm0
	movaps [rsp + nb331_iyH1], xmm1
	movaps [rsp + nb331_izH1], xmm2
	movaps [rsp + nb331_ixH2], xmm3
	movaps [rsp + nb331_iyH2], xmm4
	movaps [rsp + nb331_izH2], xmm5
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [rsp + nb331_vctot], xmm4
	movaps [rsp + nb331_Vvdwtot], xmm4
	movaps [rsp + nb331_fixO], xmm4
	movaps [rsp + nb331_fiyO], xmm4
	movaps [rsp + nb331_fizO], xmm4
	movaps [rsp + nb331_fixH1], xmm4
	movaps [rsp + nb331_fiyH1], xmm4
	movaps [rsp + nb331_fizH1], xmm4
	movaps [rsp + nb331_fixH2], xmm4
	movaps [rsp + nb331_fiyH2], xmm4
	movaps [rsp + nb331_fizH2], xmm4
	
	mov   rax, [rsp + nb331_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb331_pos]
	mov   rdi, [rbp + nb331_faction]	
	mov   rax, [rsp + nb331_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb331_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [rsp + nb331_ninner]
	mov   [rsp + nb331_ninner], ecx
	add   edx, 0
	mov   [rsp + nb331_innerk], edx    ;# number of innerloop atoms 
	jge   .nb331_unroll_loop
	jmp   .nb331_odd_inner
.nb331_unroll_loop:
	;# quad-unroll innerloop here 
	mov   rdx, [rsp + nb331_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]              
	mov   ecx, [rdx + 8]            
	mov   edx, [rdx + 12]         ;# eax-edx=jnr1-4 

	add qword ptr [rsp + nb331_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov rsi, [rbp + nb331_charge]    ;# base of charge[] 
	
	movss xmm3, [rsi + rax*4]
	movss xmm4, [rsi + rcx*4]
	movss xmm6, [rsi + rbx*4]
	movss xmm7, [rsi + rdx*4]

	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	     ;# and in xmm4 
	mulps  xmm3, [rsp + nb331_iqO]
	mulps  xmm4, [rsp + nb331_iqH]

	movaps  [rsp + nb331_qqO], xmm3
	movaps  [rsp + nb331_qqH], xmm4
	
	mov rsi, [rbp + nb331_type]
	mov r8d, [rsi + rax*4]
	mov r9d, [rsi + rbx*4]
	mov r10d, [rsi + rcx*4]
	mov r11d, [rsi + rdx*4]
	mov rsi, [rbp + nb331_vdwparam]
	shl r8d, 1	
	shl r9d, 1	
	shl r10d, 1	
	shl r11d, 1	
	mov edi, [rsp + nb331_ntia]
	add r8d, edi
	add r9d, edi
	add r10d, edi
	add r11d, edi

	movlps xmm6, [rsi + r8*4]
	movlps xmm7, [rsi + r10*4]
	movhps xmm6, [rsi + r9*4]
	movhps xmm7, [rsi + r11*4]

	movaps xmm4, xmm6
	shufps xmm4, xmm7, 136  ;# 10001000
	shufps xmm6, xmm7, 221  ;# 11011101

	movaps [rsp + nb331_c6], xmm4
	movaps [rsp + nb331_c12], xmm6

	mov rsi, [rbp + nb331_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	
	lea   rcx, [rcx + rcx*2]     ;# replace jnr with j3 
	lea   rdx, [rdx + rdx*2]	

	;# move four coordinates to xmm0-xmm2 	
	movlps xmm4, [rsi + rax*4]
	movlps xmm5, [rsi + rcx*4]
	movss xmm2, [rsi + rax*4 + 8]
	movss xmm6, [rsi + rcx*4 + 8]

	movhps xmm4, [rsi + rbx*4]
	movhps xmm5, [rsi + rdx*4]

	movss xmm0, [rsi + rbx*4 + 8]
	movss xmm1, [rsi + rdx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# 10001000
	
	shufps xmm0, xmm5, 136  ;# 10001000
	shufps xmm1, xmm5, 221  ;# 11011101		

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
        
    movaps xmm3, xmm0
    movaps xmm4, xmm1
    movaps xmm5, xmm2
    movaps xmm6, xmm0
    movaps xmm7, xmm1
    movaps xmm8, xmm2
    
    subps xmm0, [rsp + nb331_ixO]
    subps xmm1, [rsp + nb331_iyO]
    subps xmm2, [rsp + nb331_izO]
    subps xmm3, [rsp + nb331_ixH1]
    subps xmm4, [rsp + nb331_iyH1]
    subps xmm5, [rsp + nb331_izH1]
    subps xmm6, [rsp + nb331_ixH2]
    subps xmm7, [rsp + nb331_iyH2]
    subps xmm8, [rsp + nb331_izH2]
    
    movd mm0, eax ;# save j3 in mm0-mm3
    movd mm1, ebx
    movd mm2, ecx
    movd mm3, edx

	movaps [rsp + nb331_dxO], xmm0
	movaps [rsp + nb331_dyO], xmm1
	movaps [rsp + nb331_dzO], xmm2
	mulps  xmm0, xmm0
	mulps  xmm1, xmm1
	mulps  xmm2, xmm2
	movaps [rsp + nb331_dxH1], xmm3
	movaps [rsp + nb331_dyH1], xmm4
	movaps [rsp + nb331_dzH1], xmm5
	mulps  xmm3, xmm3
	mulps  xmm4, xmm4
	mulps  xmm5, xmm5
	movaps [rsp + nb331_dxH2], xmm6