nb_kernel334_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,248 行 · 第 1/5 页

##
## $Id: nb_kernel334_x86_64_sse.s,v 1.4.2.3 2006/09/22 08:32:51 lindahl Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##





.globl nb_kernel334_x86_64_sse
.globl _nb_kernel334_x86_64_sse
nb_kernel334_x86_64_sse:        
_nb_kernel334_x86_64_sse:       
##      Room for return address and rbp (16 bytes)
.set nb334_fshift, 16
.set nb334_gid, 24
.set nb334_pos, 32
.set nb334_faction, 40
.set nb334_charge, 48
.set nb334_p_facel, 56
.set nb334_argkrf, 64
.set nb334_argcrf, 72
.set nb334_Vc, 80
.set nb334_type, 88
.set nb334_p_ntype, 96
.set nb334_vdwparam, 104
.set nb334_Vvdw, 112
.set nb334_p_tabscale, 120
.set nb334_VFtab, 128
.set nb334_invsqrta, 136
.set nb334_dvda, 144
.set nb334_p_gbtabscale, 152
.set nb334_GBtab, 160
.set nb334_p_nthreads, 168
.set nb334_count, 176
.set nb334_mtx, 184
.set nb334_outeriter, 192
.set nb334_inneriter, 200
.set nb334_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb334_ixO, 0
.set nb334_iyO, 16
.set nb334_izO, 32
.set nb334_ixH1, 48
.set nb334_iyH1, 64
.set nb334_izH1, 80
.set nb334_ixH2, 96
.set nb334_iyH2, 112
.set nb334_izH2, 128
.set nb334_ixM, 144
.set nb334_iyM, 160
.set nb334_izM, 176
.set nb334_jxO, 192
.set nb334_jyO, 208
.set nb334_jzO, 224
.set nb334_jxH1, 240
.set nb334_jyH1, 256
.set nb334_jzH1, 272
.set nb334_jxH2, 288
.set nb334_jyH2, 304
.set nb334_jzH2, 320
.set nb334_jxM, 336
.set nb334_jyM, 352
.set nb334_jzM, 368
.set nb334_dxOO, 384
.set nb334_dyOO, 400
.set nb334_dzOO, 416
.set nb334_dxH1H1, 432
.set nb334_dyH1H1, 448
.set nb334_dzH1H1, 464
.set nb334_dxH1H2, 480
.set nb334_dyH1H2, 496
.set nb334_dzH1H2, 512
.set nb334_dxH1M, 528
.set nb334_dyH1M, 544
.set nb334_dzH1M, 560
.set nb334_dxH2H1, 576
.set nb334_dyH2H1, 592
.set nb334_dzH2H1, 608
.set nb334_dxH2H2, 624
.set nb334_dyH2H2, 640
.set nb334_dzH2H2, 656
.set nb334_dxH2M, 672
.set nb334_dyH2M, 688
.set nb334_dzH2M, 704
.set nb334_dxMH1, 720
.set nb334_dyMH1, 736
.set nb334_dzMH1, 752
.set nb334_dxMH2, 768
.set nb334_dyMH2, 784
.set nb334_dzMH2, 800
.set nb334_dxMM, 816
.set nb334_dyMM, 832
.set nb334_dzMM, 848
.set nb334_qqMM, 864
.set nb334_qqMH, 880
.set nb334_qqHH, 896
.set nb334_two, 912
.set nb334_tsc, 928
.set nb334_c6, 944
.set nb334_c12, 960
.set nb334_vctot, 976
.set nb334_Vvdwtot, 992
.set nb334_fixO, 1008
.set nb334_fiyO, 1024
.set nb334_fizO, 1040
.set nb334_fixH1, 1056
.set nb334_fiyH1, 1072
.set nb334_fizH1, 1088
.set nb334_fixH2, 1104
.set nb334_fiyH2, 1120
.set nb334_fizH2, 1136
.set nb334_fixM, 1152
.set nb334_fiyM, 1168
.set nb334_fizM, 1184
.set nb334_fjxO, 1200
.set nb334_fjyO, 1216
.set nb334_fjzO, 1232
.set nb334_epsH1, 1248
.set nb334_epsH2, 1264
.set nb334_epsM, 1280
.set nb334_fjxH2, 1296
.set nb334_fjyH2, 1312
.set nb334_fjzH2, 1328
.set nb334_fjxM, 1344
.set nb334_fjyM, 1360
.set nb334_fjzM, 1376
.set nb334_half, 1392
.set nb334_three, 1408
.set nb334_rsqOO, 1424
.set nb334_rsqH1H1, 1440
.set nb334_rsqH1H2, 1456
.set nb334_rsqH1M, 1472
.set nb334_rsqH2H1, 1488
.set nb334_rsqH2H2, 1504
.set nb334_rsqH2M, 1520
.set nb334_rsqMH1, 1536
.set nb334_rsqMH2, 1552
.set nb334_rsqMM, 1568
.set nb334_rinvOO, 1584
.set nb334_rinvH1H1, 1600
.set nb334_rinvH1H2, 1616
.set nb334_rinvH1M, 1632
.set nb334_rinvH2H1, 1648
.set nb334_rinvH2H2, 1664
.set nb334_rinvH2M, 1680
.set nb334_rinvMH1, 1696
.set nb334_rinvMH2, 1712
.set nb334_rinvMM, 1728
.set nb334_fstmp, 1744
.set nb334_is3, 1760
.set nb334_ii3, 1764
.set nb334_nri, 1768
.set nb334_iinr, 1776
.set nb334_jindex, 1784
.set nb334_jjnr, 1792
.set nb334_shift, 1800
.set nb334_shiftvec, 1808
.set nb334_facel, 1816
.set nb334_innerjjnr, 1824
.set nb334_innerk, 1832
.set nb334_n, 1836
.set nb334_nn1, 1840
.set nb334_nouter, 1844
.set nb334_ninner, 1848
        push %rbp
        movq %rsp,%rbp
        push %rbx

        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $1864,%rsp         ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb334_nouter(%rsp)
        movl %eax,nb334_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb334_nri(%rsp)
        movq %rsi,nb334_iinr(%rsp)
        movq %rdx,nb334_jindex(%rsp)
        movq %rcx,nb334_jjnr(%rsp)
        movq %r8,nb334_shift(%rsp)
        movq %r9,nb334_shiftvec(%rsp)
        movq nb334_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb334_facel(%rsp)

        movq nb334_p_tabscale(%rbp),%rax
        movss (%rax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb334_tsc(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb334_half(%rsp)
        movss nb334_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb334_half(%rsp)
        movaps %xmm2,nb334_two(%rsp)
        movaps %xmm3,nb334_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb334_iinr(%rsp),%rcx             ## rcx = pointer into iinr[]    
        movl  (%rcx),%ebx               ## ebx =ii 

        movq  nb334_charge(%rbp),%rdx
        movss 4(%rdx,%rbx,4),%xmm5
        movss 12(%rdx,%rbx,4),%xmm3
        movss %xmm3,%xmm4
        movq nb334_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss nb334_facel(%rsp),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb334_qqMM(%rsp)
        movaps %xmm4,nb334_qqMH(%rsp)
        movaps %xmm5,nb334_qqHH(%rsp)

        xorps %xmm0,%xmm0
        movq  nb334_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movq nb334_p_ntype(%rbp),%rdi
        imull (%rdi),%ecx       ## rcx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movq  nb334_vdwparam(%rbp),%rax
        movlps (%rax,%rdx,4),%xmm0
        movaps %xmm0,%xmm1
        shufps $0,%xmm0,%xmm0
        shufps $0x55,%xmm1,%xmm1
        movaps %xmm0,nb334_c6(%rsp)
        movaps %xmm1,nb334_c12(%rsp)

_nb_kernel334_x86_64_sse.nb334_threadloop: 
        movq  nb334_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel334_x86_64_sse.nb334_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel334_x86_64_sse.nb334_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb334_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb334_n(%rsp)
        movl %ebx,nb334_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel334_x86_64_sse.nb334_outerstart
        jmp _nb_kernel334_x86_64_sse.nb334_end

_nb_kernel334_x86_64_sse.nb334_outerstart: 
        ## ebx contains number of outer iterations
        addl nb334_nouter(%rsp),%ebx
        movl %ebx,nb334_nouter(%rsp)

_nb_kernel334_x86_64_sse.nb334_outer: 
        movq  nb334_shift(%rsp),%rax            ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx        ## rbx=3*is 
        movl  %ebx,nb334_is3(%rsp)      ## store is3 

        movq  nb334_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb334_iinr(%rsp),%rcx             ## rcx = pointer into iinr[]    
        movl  (%rcx,%rsi,4),%ebx                ## ebx =ii 

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb334_pos(%rbp),%rax      ## rax = base of pos[]  
        movl  %ebx,nb334_ii3(%rsp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        movaps %xmm0,%xmm6
        movaps %xmm1,%xmm7

        addss (%rax,%rbx,4),%xmm3       ## ox
        addss 4(%rax,%rbx,4),%xmm4     ## oy
        addss 8(%rax,%rbx,4),%xmm5     ## oz
        addss 12(%rax,%rbx,4),%xmm6    ## h1x
        addss 16(%rax,%rbx,4),%xmm7    ## h1y
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm7,%xmm7
        movaps %xmm3,nb334_ixO(%rsp)
        movaps %xmm4,nb334_iyO(%rsp)
        movaps %xmm5,nb334_izO(%rsp)
        movaps %xmm6,nb334_ixH1(%rsp)
        movaps %xmm7,nb334_iyH1(%rsp)

        movss %xmm2,%xmm6
        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 20(%rax,%rbx,4),%xmm6    ## h1z
        addss 24(%rax,%rbx,4),%xmm0    ## h2x
        addss 28(%rax,%rbx,4),%xmm1    ## h2y
        addss 32(%rax,%rbx,4),%xmm2    ## h2z
        addss 36(%rax,%rbx,4),%xmm3    ## mx
        addss 40(%rax,%rbx,4),%xmm4    ## my
        addss 44(%rax,%rbx,4),%xmm5    ## mz

        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm6,nb334_izH1(%rsp)
        movaps %xmm0,nb334_ixH2(%rsp)
        movaps %xmm1,nb334_iyH2(%rsp)
        movaps %xmm2,nb334_izH2(%rsp)
        movaps %xmm3,nb334_ixM(%rsp)
        movaps %xmm4,nb334_iyM(%rsp)
        movaps %xmm5,nb334_izM(%rsp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb334_vctot(%rsp)
        movaps %xmm4,nb334_Vvdwtot(%rsp)
        movaps %xmm4,nb334_fixO(%rsp)
        movaps %xmm4,nb334_fiyO(%rsp)
        movaps %xmm4,nb334_fizO(%rsp)
        movaps %xmm4,nb334_fixH1(%rsp)
        movaps %xmm4,nb334_fiyH1(%rsp)
        movaps %xmm4,nb334_fizH1(%rsp)
        movaps %xmm4,nb334_fixH2(%rsp)
        movaps %xmm4,nb334_fiyH2(%rsp)
        movaps %xmm4,nb334_fizH2(%rsp)
        movaps %xmm4,nb334_fixM(%rsp)
        movaps %xmm4,nb334_fiyM(%rsp)
        movaps %xmm4,nb334_fizM(%rsp)

        movq  nb334_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx                ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movq  nb334_pos(%rbp),%rsi
        movq  nb334_faction(%rbp),%rdi
        movq  nb334_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb334_innerjjnr(%rsp)        ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb334_ninner(%rsp),%ecx
        movl  %ecx,nb334_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb334_innerk(%rsp)   ## number of innerloop atoms 
        jge   _nb_kernel334_x86_64_sse.nb334_unroll_loop
        jmp   _nb_kernel334_x86_64_sse.nb334_single_check
_nb_kernel334_x86_64_sse.nb334_unroll_loop: 
        ## quad-unroll innerloop here 
        movq  nb334_innerjjnr(%rsp),%rdx        ## pointer to jjnr[k] 

        movl  (%rdx),%eax
        movl  4(%rdx),%ebx
        movl  8(%rdx),%ecx
        movl  12(%rdx),%edx             ## eax-edx=jnr1-4 

        addq $16,nb334_innerjjnr(%rsp)             ## advance pointer (unroll 4) 

        movq nb334_pos(%rbp),%rsi       ## base of pos[] 

        lea  (%rax,%rax,2),%rax        ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx
        lea  (%rcx,%rcx,2),%rcx        ## replace jnr with j3 
        lea  (%rdx,%rdx,2),%rdx

        ## load j O coordinates 
    movlps (%rsi,%rax,4),%xmm0 ## jxOa jyOa  -   -
    movlps (%rsi,%rcx,4),%xmm1 ## jxOc jyOc  -   -
    movhps (%rsi,%rbx,4),%xmm0 ## jxOa jyOa jxOb jyOb 
    movhps (%rsi,%rdx,4),%xmm1 ## jxOc jyOc jxOd jyOd 

    movss  8(%rsi,%rax,4),%xmm2    ## jzOa  -  -  -
    movss  8(%rsi,%rcx,4),%xmm3    ## jzOc  -  -  -
    movhps 8(%rsi,%rbx,4),%xmm2    ## jzOa  -  jzOb  -
    movhps 8(%rsi,%rdx,4),%xmm3    ## jzOc  -  jzOd -

    movaps %xmm0,%xmm4
    unpcklps %xmm1,%xmm0 ## jxOa jxOc jyOa jyOc        
    unpckhps %xmm1,%xmm4 ## jxOb jxOd jyOb jyOd
    movaps %xmm0,%xmm1
    unpcklps %xmm4,%xmm0 ## x
    unpckhps %xmm4,%xmm1 ## y

    shufps $136,%xmm3,%xmm2 ## 10001000 => jzOa jzOb jzOc jzOd

    ## xmm0 = Ox
    ## xmm1 = Oy
    ## xmm2 = Oz

    subps nb334_ixO(%rsp),%xmm0
    subps nb334_iyO(%rsp),%xmm1
    subps nb334_izO(%rsp),%xmm2