nb_kernel204_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,119 行 · 第 1/5 页

    movss  44(%rsi,%rax,4),%xmm2    ## jzMa  -  -  -
    movss  44(%rsi,%rcx,4),%xmm3    ## jzMc  -  -  -
    movss  44(%rsi,%rbx,4),%xmm5    ## jzMb  -  -  -
    movss  44(%rsi,%rdx,4),%xmm6    ## jzMd  -  -  -
    movlhps %xmm5,%xmm2 ## jzMa  -  jzMb  -
    movlhps %xmm6,%xmm3 ## jzMc  -  jzMd -

    movaps %xmm0,%xmm4
    unpcklps %xmm1,%xmm0 ## jxMa jxMc jyMa jyMc        
    unpckhps %xmm1,%xmm4 ## jxMb jxMd jyMb jyMd
    movaps %xmm0,%xmm1
    unpcklps %xmm4,%xmm0 ## x
    unpckhps %xmm4,%xmm1 ## y

    shufps $136,%xmm3,%xmm2 ## 10001000 => jzMa jzMb jzMc jzMd

    ## xmm0 = Mx
    ## xmm1 = My
    ## xmm2 = Mz

    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8

    subps nb204_ixH1(%rsp),%xmm0
    subps nb204_iyH1(%rsp),%xmm1
    subps nb204_izH1(%rsp),%xmm2
    subps nb204_ixH2(%rsp),%xmm3
    subps nb204_iyH2(%rsp),%xmm4
    subps nb204_izH2(%rsp),%xmm5
    subps nb204_ixM(%rsp),%xmm6
    subps nb204_iyM(%rsp),%xmm7
    subps nb204_izM(%rsp),%xmm8

        movaps %xmm0,nb204_dxH1M(%rsp)
        movaps %xmm1,nb204_dyH1M(%rsp)
        movaps %xmm2,nb204_dzH1M(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb204_dxH2M(%rsp)
        movaps %xmm4,nb204_dyH2M(%rsp)
        movaps %xmm5,nb204_dzH2M(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb204_dxMM(%rsp)
        movaps %xmm7,nb204_dyMM(%rsp)
        movaps %xmm8,nb204_dzMM(%rsp)
        mulps  %xmm6,%xmm6
        mulps  %xmm7,%xmm7
        mulps  %xmm8,%xmm8
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    addps  %xmm7,%xmm6
    addps  %xmm8,%xmm6

        ## start doing invsqrt for jM atoms
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm3,%xmm4
    rsqrtps %xmm6,%xmm7

        movaps  %xmm1,%xmm2
        movaps  %xmm4,%xmm5
    movaps  %xmm7,%xmm8

        mulps   %xmm1,%xmm1 ## lu*lu
        mulps   %xmm4,%xmm4 ## lu*lu
    mulps   %xmm7,%xmm7 ## lu*lu

        movaps  nb204_three(%rsp),%xmm9
        movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

        mulps   %xmm0,%xmm1 ## rsq*lu*lu
        mulps   %xmm3,%xmm4 ## rsq*lu*lu 
    mulps   %xmm6,%xmm7 ## rsq*lu*lu

        subps   %xmm1,%xmm9
        subps   %xmm4,%xmm10
    subps   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulps   %xmm2,%xmm9
        mulps   %xmm5,%xmm10
    mulps   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movaps  nb204_half(%rsp),%xmm4
        mulps   %xmm4,%xmm9 ## rinvH1M
        mulps   %xmm4,%xmm10 ## rinvH2M
    mulps   %xmm4,%xmm11 ## rinvMM

        ## M interactions 
    ## rsq in xmm0,xmm3,xmm6  
    ## rinv in xmm9, xmm10, xmm11

    movaps %xmm9,%xmm1 ## copy of rinv
    movaps %xmm10,%xmm4
    movaps %xmm11,%xmm7
    movaps nb204_krf(%rsp),%xmm2
    mulps  %xmm9,%xmm9  ## rinvsq
    mulps  %xmm10,%xmm10
    mulps  %xmm11,%xmm11
    mulps  %xmm2,%xmm0 ## k*rsq
    mulps  %xmm2,%xmm3
    mulps  %xmm2,%xmm6
    movaps %xmm0,%xmm2 ## copy of k*rsq
    movaps %xmm3,%xmm5
    movaps %xmm6,%xmm8
    addps  %xmm1,%xmm2 ## rinv+krsq
    addps  %xmm4,%xmm5
    addps  %xmm7,%xmm8
    movaps nb204_crf(%rsp),%xmm14
    subps  %xmm14,%xmm2  ## rinv+krsq-crf
    subps  %xmm14,%xmm5
    subps  %xmm14,%xmm8
    movaps nb204_qqMH(%rsp),%xmm12
    movaps nb204_qqMM(%rsp),%xmm13
    mulps  %xmm12,%xmm2 ## xmm6=voul=qq*(rinv+ krsq-crf)
    mulps  %xmm12,%xmm5 ## xmm6=voul=qq*(rinv+ krsq-crf)
    mulps  %xmm13,%xmm8 ## xmm6=voul=qq*(rinv+ krsq-crf)
    addps  %xmm0,%xmm0 ## 2*krsq
    addps  %xmm3,%xmm3
    addps  %xmm6,%xmm6
    subps  %xmm0,%xmm1 ## rinv-2*krsq
    subps  %xmm3,%xmm4
    subps  %xmm6,%xmm7
    mulps  %xmm12,%xmm1  ## (rinv-2*krsq)*qq
    mulps  %xmm12,%xmm4
    mulps  %xmm13,%xmm7
    addps  %xmm8,%xmm5
    addps  %xmm15,%xmm2
    addps  %xmm5,%xmm2
    movaps %xmm2,nb204_vctot(%rsp)

    mulps  %xmm9,%xmm1  ## fscal
    mulps  %xmm10,%xmm4
    mulps  %xmm11,%xmm7

        ## move j M forces to local temp variables 
    movlps 36(%rdi,%rax,4),%xmm9    ## jxMa jyMa  -   -
    movlps 36(%rdi,%rcx,4),%xmm10    ## jxMc jyMc  -   -
    movhps 36(%rdi,%rbx,4),%xmm9    ## jxMa jyMa jxMb jyMb 
    movhps 36(%rdi,%rdx,4),%xmm10    ## jxMc jyMc jxMd jyMd 

    movss  44(%rdi,%rax,4),%xmm11    ## jzMa  -  -  -
    movss  44(%rdi,%rcx,4),%xmm12    ## jzMc  -  -  -
    movss  44(%rdi,%rbx,4),%xmm2     ## jzMb  -  -  -
    movss  44(%rdi,%rdx,4),%xmm3     ## jzMd  -  -  -
    movlhps %xmm2,%xmm11 ## jzMa  -  jzMb  -
    movlhps %xmm3,%xmm12 ## jzMc  -  jzMd -

    shufps $136,%xmm12,%xmm11 ## 10001000 => jzMa jzMb jzMc jzMd

    ## xmm9: jxMa jyMa jxMb jyMb 
    ## xmm10: jxMc jyMc jxMd jyMd
    ## xmm11: jzMa jzMb jzMc jzMd

    movaps %xmm1,%xmm0
    movaps %xmm1,%xmm2
    movaps %xmm4,%xmm3
    movaps %xmm4,%xmm5
    movaps %xmm7,%xmm6
    movaps %xmm7,%xmm8

        mulps nb204_dxH1M(%rsp),%xmm0
        mulps nb204_dyH1M(%rsp),%xmm1
        mulps nb204_dzH1M(%rsp),%xmm2
        mulps nb204_dxH2M(%rsp),%xmm3
        mulps nb204_dyH2M(%rsp),%xmm4
        mulps nb204_dzH2M(%rsp),%xmm5
        mulps nb204_dxMM(%rsp),%xmm6
        mulps nb204_dyMM(%rsp),%xmm7
        mulps nb204_dzMM(%rsp),%xmm8

    movaps %xmm0,%xmm13
    movaps %xmm1,%xmm14
    addps %xmm2,%xmm11
    addps nb204_fixH1(%rsp),%xmm0
    addps nb204_fiyH1(%rsp),%xmm1
    addps nb204_fizH1(%rsp),%xmm2

    addps %xmm3,%xmm13
    addps %xmm4,%xmm14
    addps %xmm5,%xmm11
    addps nb204_fixH2(%rsp),%xmm3
    addps nb204_fiyH2(%rsp),%xmm4
    addps nb204_fizH2(%rsp),%xmm5

    addps %xmm6,%xmm13
    addps %xmm7,%xmm14
    addps %xmm8,%xmm11
    addps nb204_fixM(%rsp),%xmm6
    addps nb204_fiyM(%rsp),%xmm7
    addps nb204_fizM(%rsp),%xmm8

    movaps %xmm0,nb204_fixH1(%rsp)
    movaps %xmm1,nb204_fiyH1(%rsp)
    movaps %xmm2,nb204_fizH1(%rsp)
    movaps %xmm3,nb204_fixH2(%rsp)
    movaps %xmm4,nb204_fiyH2(%rsp)
    movaps %xmm5,nb204_fizH2(%rsp)
    movaps %xmm6,nb204_fixM(%rsp)
    movaps %xmm7,nb204_fiyM(%rsp)
    movaps %xmm8,nb204_fizM(%rsp)

    ## xmm0 = fMx
    ## xmm1 = fMy
    ## xmm2 = fMz
    movaps %xmm13,%xmm15
    unpcklps %xmm14,%xmm13
    unpckhps %xmm14,%xmm15

    addps %xmm13,%xmm9
    addps %xmm15,%xmm10

    movhlps  %xmm11,%xmm12 ## fMzc fMzd

    movlps %xmm9,36(%rdi,%rax,4)
    movhps %xmm9,36(%rdi,%rbx,4)
    movlps %xmm10,36(%rdi,%rcx,4)
    movhps %xmm10,36(%rdi,%rdx,4)
    movss  %xmm11,44(%rdi,%rax,4)
    movss  %xmm12,44(%rdi,%rcx,4)
    shufps $1,%xmm11,%xmm11
    shufps $1,%xmm12,%xmm12
    movss  %xmm11,44(%rdi,%rbx,4)
    movss  %xmm12,44(%rdi,%rdx,4)

        ## should we do one more iteration? 
        subl $4,nb204_innerk(%rsp)
        jl    _nb_kernel204_x86_64_sse.nb204_single_check
        jmp   _nb_kernel204_x86_64_sse.nb204_unroll_loop
_nb_kernel204_x86_64_sse.nb204_single_check: 
        addl $4,nb204_innerk(%rsp)
        jnz   _nb_kernel204_x86_64_sse.nb204_single_loop
        jmp   _nb_kernel204_x86_64_sse.nb204_updateouterdata
_nb_kernel204_x86_64_sse.nb204_single_loop: 
        movq  nb204_innerjjnr(%rsp),%rdx        ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        addq $4,nb204_innerjjnr(%rsp)

        movq nb204_pos(%rbp),%rsi
        lea  (%rax,%rax,2),%rax

        ## fetch j coordinates 
        xorps %xmm0,%xmm0
        xorps %xmm1,%xmm1
        xorps %xmm2,%xmm2
        movss 36(%rsi,%rax,4),%xmm0             ## jxM  -  -  -
        movss 40(%rsi,%rax,4),%xmm1             ## jyM  -  -  -
        movss 44(%rsi,%rax,4),%xmm2             ## jzM  -  -  -  

        movlps 12(%rsi,%rax,4),%xmm6            ## xmm6 = jxH1 jyH1   -    -
        movss  20(%rsi,%rax,4),%xmm7            ## xmm7 = jzH1   -    -    - 
        movhps 24(%rsi,%rax,4),%xmm6            ## xmm6 = jxH1 jyH1 jxH2 jyH2
        movss  32(%rsi,%rax,4),%xmm5            ## xmm5 = jzH2   -    -    -

        ## have all coords, time for some shuffling.

        shufps $216,%xmm6,%xmm6 ## 11011000      ;# xmm6 = jxH1 jxH2 jyH1 jyH2 
        unpcklps %xmm5,%xmm7                    ## xmm7 = jzH1 jzH2   -    -

        movlhps %xmm6,%xmm0                     ## xmm0 = jxM   0   jxH1 jxH2 
        shufps $228,%xmm6,%xmm1 ## 11100100     ;# xmm1 = jyM   0   jyH1 jyH2 
        shufps $68,%xmm7,%xmm2 ## 01000100     ;# xmm2 = jzM   0   jzH1 jzH2

        ## store all j coordinates in jM 
        movaps %xmm0,nb204_jxM(%rsp)
        movaps %xmm1,nb204_jyM(%rsp)
        movaps %xmm2,nb204_jzM(%rsp)
        subps  nb204_ixM(%rsp),%xmm0
        subps  nb204_iyM(%rsp),%xmm1
        subps  nb204_izM(%rsp),%xmm2
        movaps %xmm0,nb204_dxMM(%rsp)
        movaps %xmm1,nb204_dyMM(%rsp)
        movaps %xmm2,nb204_dzMM(%rsp)

        mulps %xmm0,%xmm0
        mulps %xmm1,%xmm1
        mulps %xmm2,%xmm2
        addps %xmm1,%xmm0
        addps %xmm2,%xmm0       ## have rsq in xmm0 

        movaps %xmm0,%xmm6

        ## do invsqrt 
        rsqrtps %xmm0,%xmm1
        mulps   nb204_krf(%rsp),%xmm6   ## xmm6=krsq 
        movaps  %xmm1,%xmm2
        movaps  %xmm6,%xmm7     ## xmm7=krsq 
        mulps   %xmm1,%xmm1
        movaps  nb204_three(%rsp),%xmm3
        mulps   %xmm0,%xmm1
        subps   %xmm1,%xmm3
        mulps   %xmm2,%xmm3
        mulps   nb204_half(%rsp),%xmm3   ## rinv iO - j water 

        addps   %xmm3,%xmm6     ## xmm6=rinv+ krsq 
        mulps   nb204_two(%rsp),%xmm7
        subps   nb204_crf(%rsp),%xmm6   ## xmm6=rinv+ krsq-crf 

        xorps   %xmm1,%xmm1
        movaps  %xmm3,%xmm0
        subps   %xmm7,%xmm3     ## xmm3=rinv-2*krsq 
        xorps   %xmm4,%xmm4
        mulps   %xmm0,%xmm0     ## xmm0=rinvsq 
        ## fetch charges to xmm4 (temporary) 
        movss   nb204_qqMM(%rsp),%xmm4
        movhps  nb204_qqMH(%rsp),%xmm4

        mulps %xmm4,%xmm6       ## vcoul  
        mulps %xmm4,%xmm3       ## coul part of fs  


        addps   nb204_vctot(%rsp),%xmm6
        mulps   %xmm3,%xmm0     ## total fscal 
        movaps  %xmm6,nb204_vctot(%rsp)

        movaps  %xmm0,%xmm1
        movaps  %xmm0,%xmm2
        mulps   nb204_dxMM(%rsp),%xmm0
        mulps   nb204_dyMM(%rsp),%xmm1
        mulps   nb204_dzMM(%rsp),%xmm2

        ## initial update for j forces 
        xorps   %xmm3,%xmm3
        xorps   %xmm4,%xmm4
        xorps   %xmm5,%xmm5
        addps   %xmm0,%xmm3
        addps   %xmm1,%xmm4
        addps   %xmm2,%xmm5
        movaps  %xmm3,nb204_fjxM(%rsp)
        movaps  %xmm4,nb204_fjyM(%rsp)
        movaps  %xmm5,nb204_fjzM(%rsp)
        addps   nb204_fixM(%rsp),%xmm0
        addps   nb204_fiyM(%rsp),%xmm1
        addps   nb204_fizM(%rsp),%xmm2
        movaps  %xmm0,nb204_fixM(%rsp)
        movaps  %xmm1,nb204_fiyM(%rsp)
        movaps  %xmm2,nb204_fizM(%rsp)


        ## done with i M Now do i H1 & H2 simultaneously first get i particle coords: 
    movaps  nb204_jxM(%rsp),%xmm0
    movaps  nb204_jyM(%rsp),%xmm1
    movaps  nb204_jzM(%rsp),%xmm2
    movaps  %xmm0,%xmm3
    movaps  %xmm1,%xmm4
    movaps  %xmm2,%xmm5

        subps   nb204_ixH1(%rsp),%xmm0
        subps   nb204_iyH1(%rsp),%xmm1
        subps   nb204_izH1(%rsp),%xmm2
        subps   nb204_ixH2(%rsp),%xmm3
        subps   nb204_iyH2(%rsp),%xmm4
        subps   nb204_izH2(%rsp),%xmm5

        movaps %xmm0,nb204_dxH1M(%rsp)
        movaps %xmm1,nb204_dyH1M(%rsp)
        movaps %xmm2,nb204_dzH1M(%rsp)
        movaps %xmm3,nb204_dxH2M(%rsp)
        movaps %xmm4,nb204_dyH2M(%rsp)
        movaps %xmm5,nb204_dzH2M(%rsp)
        mulps %xmm0,%xmm0
        mulps %xmm1,%xmm1
        mulps %xmm2,%xmm2
        mulps %xmm3,%xmm3
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        addps %xmm1,%xmm0
        addps %xmm3,%xmm4
        addps %xmm2,%xmm0       ## have rsqH1 in xmm0 
        addps %xmm5,%xmm4       ## have rsqH2 in xmm4 

        ## do invsqrt 
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm4,%xmm5
        movaps  %xmm1,%xmm2
        movaps  %xmm5,%xmm6
        mulps   %xmm1,%xmm1
        mulps   %xmm5,%xmm5
        movaps  nb204_three(%rsp),%xmm3
        movaps  %xmm3,%xmm7
        mulps   %xmm0,%xmm1
        mulps   %xmm4,%xmm5
        subps   %xmm1,%xmm3
        subps   %xmm5,%xmm7
        mulps   %xmm2,%xmm3
        mulps   %xmm6,%xmm7
        mulps   nb204_half(%rsp),%xmm3   ## rinv H1 - j water 
        mulps   nb204_half(%rsp),%xmm7   ## rinv H2 - j water  

        mulps nb204_krf(%rsp),%xmm0   ## krsq 
        mulps nb204_krf(%rsp),%xmm4   ## krsq  

        ## assemble charges in xmm6 
        xorps   %xmm6,%xmm6
        movss   nb204_qqMH(%rsp),%xmm6
        movhps  nb204_qqHH(%rsp),%xmm6
        movaps  %xmm0,%xmm1
        movaps  %xmm4,%xmm5
        addps   %xmm3,%xmm0     ## krsq+ rinv 
        addps   %xmm7,%xmm4     ## krsq+ rinv 
        subps   nb204_crf(%rsp),%xmm0
        subps   nb204_crf(%rsp),%xmm4
        mulps   nb204_two(%rsp),%xmm1
        mulps   nb204_two(%rsp),%xmm5
        mulps   %xmm6,%xmm0     ## vcoul 
        mulps   %xmm6,%xmm4     ## vcoul 
        addps   %xmm0,%xmm4
        addps   nb204_vctot(%rsp),%xmm4
        movaps  %xmm4,nb204_vctot(%rsp)
        movaps  %xmm3,%xmm0
        movaps  %xmm7,%xmm4
        mulps   %xmm3,%xmm3
        mulps   %xmm7,%xmm7
        subps   %xmm1,%xmm0
        subps   %xmm5,%xmm4
        mulps   %xmm6,%xmm0