nb_kernel102_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,099 行 · 第 1/5 页

##
## $Id: nb_kernel102_x86_64_sse.s,v 1.4.2.3 2006/09/22 08:32:48 lindahl Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl 
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##







.globl nb_kernel102_x86_64_sse
.globl _nb_kernel102_x86_64_sse
nb_kernel102_x86_64_sse:        
_nb_kernel102_x86_64_sse:       
##      Room for return address and rbp (16 bytes)
.set nb102_fshift, 16
.set nb102_gid, 24
.set nb102_pos, 32
.set nb102_faction, 40
.set nb102_charge, 48
.set nb102_p_facel, 56
.set nb102_argkrf, 64
.set nb102_argcrf, 72
.set nb102_Vc, 80
.set nb102_type, 88
.set nb102_p_ntype, 96
.set nb102_vdwparam, 104
.set nb102_Vvdw, 112
.set nb102_p_tabscale, 120
.set nb102_VFtab, 128
.set nb102_invsqrta, 136
.set nb102_dvda, 144
.set nb102_p_gbtabscale, 152
.set nb102_GBtab, 160
.set nb102_p_nthreads, 168
.set nb102_count, 176
.set nb102_mtx, 184
.set nb102_outeriter, 192
.set nb102_inneriter, 200
.set nb102_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use         
.set nb102_ixO, 0
.set nb102_iyO, 16
.set nb102_izO, 32
.set nb102_ixH1, 48
.set nb102_iyH1, 64
.set nb102_izH1, 80
.set nb102_ixH2, 96
.set nb102_iyH2, 112
.set nb102_izH2, 128
.set nb102_jxO, 144
.set nb102_jyO, 160
.set nb102_jzO, 176
.set nb102_jxH1, 192
.set nb102_jyH1, 208
.set nb102_jzH1, 224
.set nb102_jxH2, 240
.set nb102_jyH2, 256
.set nb102_jzH2, 272
.set nb102_dxOO, 288
.set nb102_dyOO, 304
.set nb102_dzOO, 320
.set nb102_dxOH1, 336
.set nb102_dyOH1, 352
.set nb102_dzOH1, 368
.set nb102_dxOH2, 384
.set nb102_dyOH2, 400
.set nb102_dzOH2, 416
.set nb102_dxH1O, 432
.set nb102_dyH1O, 448
.set nb102_dzH1O, 464
.set nb102_dxH1H1, 480
.set nb102_dyH1H1, 496
.set nb102_dzH1H1, 512
.set nb102_dxH1H2, 528
.set nb102_dyH1H2, 544
.set nb102_dzH1H2, 560
.set nb102_dxH2O, 576
.set nb102_dyH2O, 592
.set nb102_dzH2O, 608
.set nb102_dxH2H1, 624
.set nb102_dyH2H1, 640
.set nb102_dzH2H1, 656
.set nb102_dxH2H2, 672
.set nb102_dyH2H2, 688
.set nb102_dzH2H2, 704
.set nb102_qqOO, 720
.set nb102_qqOH, 736
.set nb102_qqHH, 752
.set nb102_vctot, 768
.set nb102_fixO, 784
.set nb102_fiyO, 800
.set nb102_fizO, 816
.set nb102_fixH1, 832
.set nb102_fiyH1, 848
.set nb102_fizH1, 864
.set nb102_fixH2, 880
.set nb102_fiyH2, 896
.set nb102_fizH2, 912
.set nb102_fjxO, 928
.set nb102_fjyO, 944
.set nb102_fjzO, 960
.set nb102_fjxH1, 976
.set nb102_fjyH1, 992
.set nb102_fjzH1, 1008
.set nb102_fjxH2, 1024
.set nb102_fjyH2, 1040
.set nb102_fjzH2, 1056
.set nb102_half, 1072
.set nb102_three, 1088
.set nb102_rsqOO, 1104
.set nb102_rsqOH1, 1120
.set nb102_rsqOH2, 1136
.set nb102_rsqH1O, 1152
.set nb102_rsqH1H1, 1168
.set nb102_rsqH1H2, 1184
.set nb102_rsqH2O, 1200
.set nb102_rsqH2H1, 1216
.set nb102_rsqH2H2, 1232
.set nb102_rinvOO, 1248
.set nb102_rinvOH1, 1264
.set nb102_rinvOH2, 1280
.set nb102_rinvH1O, 1296
.set nb102_rinvH1H1, 1312
.set nb102_rinvH1H2, 1328
.set nb102_rinvH2O, 1344
.set nb102_rinvH2H1, 1360
.set nb102_rinvH2H2, 1376
.set nb102_is3, 1392
.set nb102_ii3, 1396
.set nb102_innerjjnr, 1400
.set nb102_nri, 1408
.set nb102_iinr, 1416
.set nb102_jindex, 1424
.set nb102_jjnr, 1432
.set nb102_shift, 1440
.set nb102_shiftvec, 1448
.set nb102_facel, 1456
.set nb102_innerk, 1464
.set nb102_n, 1472
.set nb102_nn1, 1480
.set nb102_nouter, 1484
.set nb102_ninner, 1488
.set nb102_salign, 1492

        push %rbp
        movq %rsp,%rbp
        push %rbx

        push %r12
        push %r13
        push %r14
        push %r15

        emms
        subq $1512,%rsp
        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb102_nouter(%rsp)
        movl %eax,nb102_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb102_nri(%rsp)
        movq %rsi,nb102_iinr(%rsp)
        movq %rdx,nb102_jindex(%rsp)
        movq %rcx,nb102_jjnr(%rsp)
        movq %r8,nb102_shift(%rsp)
        movq %r9,nb102_shiftvec(%rsp)
        movq nb102_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb102_facel(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb102_iinr(%rsp),%rcx         ## ecx = pointer into iinr[]        
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb102_charge(%rbp),%rdx
        movss (%rdx,%rbx,4),%xmm3
        movss %xmm3,%xmm4
        movss 4(%rdx,%rbx,4),%xmm5
        movq nb102_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss nb102_facel(%rsp),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb102_qqOO(%rsp)
        movaps %xmm4,nb102_qqOH(%rsp)
        movaps %xmm5,nb102_qqHH(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb102_half(%rsp)
        movss nb102_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb102_half(%rsp)
        movaps %xmm3,nb102_three(%rsp)
        movq nb102_faction(%rbp),%rdi


_nb_kernel102_x86_64_sse.nb102_threadloop: 
        movq  nb102_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel102_x86_64_sse.nb102_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel102_x86_64_sse.nb102_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb102_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb102_n(%rsp)
        movl %ebx,nb102_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi

        jg  _nb_kernel102_x86_64_sse.nb102_outerstart
        jmp _nb_kernel102_x86_64_sse.nb102_end

_nb_kernel102_x86_64_sse.nb102_outerstart: 
        ## ebx contains number of outer iterations
        addl nb102_nouter(%rsp),%ebx
        movl %ebx,nb102_nouter(%rsp)

_nb_kernel102_x86_64_sse.nb102_outer: 
        movq  nb102_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## ebx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb102_is3(%rsp)      ## store is3 

        movq  nb102_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb102_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]        
        movl  (%rcx,%rsi,4),%ebx                ## ebx =ii 

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb102_pos(%rbp),%rax      ## rax = base of pos[]  
        movl  %ebx,nb102_ii3(%rsp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        addss (%rax,%rbx,4),%xmm3
        addss 4(%rax,%rbx,4),%xmm4
        addss 8(%rax,%rbx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb102_ixO(%rsp)
        movaps %xmm4,nb102_iyO(%rsp)
        movaps %xmm5,nb102_izO(%rsp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 12(%rax,%rbx,4),%xmm0
        addss 16(%rax,%rbx,4),%xmm1
        addss 20(%rax,%rbx,4),%xmm2
        addss 24(%rax,%rbx,4),%xmm3
        addss 28(%rax,%rbx,4),%xmm4
        addss 32(%rax,%rbx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb102_ixH1(%rsp)
        movaps %xmm1,nb102_iyH1(%rsp)
        movaps %xmm2,nb102_izH1(%rsp)
        movaps %xmm3,nb102_ixH2(%rsp)
        movaps %xmm4,nb102_iyH2(%rsp)
        movaps %xmm5,nb102_izH2(%rsp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb102_vctot(%rsp)
        movaps %xmm4,nb102_fixO(%rsp)
        movaps %xmm4,nb102_fiyO(%rsp)
        movaps %xmm4,nb102_fizO(%rsp)
        movaps %xmm4,nb102_fixH1(%rsp)
        movaps %xmm4,nb102_fiyH1(%rsp)
        movaps %xmm4,nb102_fizH1(%rsp)
        movaps %xmm4,nb102_fixH2(%rsp)
        movaps %xmm4,nb102_fiyH2(%rsp)
        movaps %xmm4,nb102_fizH2(%rsp)

        movq  nb102_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx                ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                         ## number of innerloop atoms 

        movq  nb102_pos(%rbp),%rsi
        movq  nb102_faction(%rbp),%rdi
        movq  nb102_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb102_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb102_ninner(%rsp),%ecx
        movl  %ecx,nb102_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb102_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel102_x86_64_sse.nb102_unroll_loop
        jmp   _nb_kernel102_x86_64_sse.nb102_single_check
_nb_kernel102_x86_64_sse.nb102_unroll_loop: 
        ## quad-unroll innerloop here 
        movq  nb102_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 

        movl  (%rdx),%eax
        movl  4(%rdx),%ebx
        movl  8(%rdx),%ecx
        movl  12(%rdx),%edx           ## eax-edx=jnr1-4 

        addq $16,nb102_innerjjnr(%rsp)             ## advance pointer (unrolled 4) 

        movq nb102_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx
        lea  (%rcx,%rcx,2),%rcx     ## replace jnr with j3 
        lea  (%rdx,%rdx,2),%rdx

        ## move j O coordinates to local temp variables 
    movlps (%rsi,%rax,4),%xmm0 ## jxOa jyOa  -   -
    movlps (%rsi,%rcx,4),%xmm1 ## jxOc jyOc  -   -
    movhps (%rsi,%rbx,4),%xmm0 ## jxOa jyOa jxOb jyOb 
    movhps (%rsi,%rdx,4),%xmm1 ## jxOc jyOc jxOd jyOd 

    movss  8(%rsi,%rax,4),%xmm2    ## jzOa  -  -  -
    movss  8(%rsi,%rcx,4),%xmm3    ## jzOc  -  -  -
    movhps 8(%rsi,%rbx,4),%xmm2    ## jzOa  -  jzOb  -
    movhps 8(%rsi,%rdx,4),%xmm3    ## jzOc  -  jzOd -

    movaps %xmm0,%xmm4
    unpcklps %xmm1,%xmm0 ## jxOa jxOc jyOa jyOc        
    unpckhps %xmm1,%xmm4 ## jxOb jxOd jyOb jyOd
    movaps %xmm0,%xmm1
    unpcklps %xmm4,%xmm0 ## x
    unpckhps %xmm4,%xmm1 ## y

    shufps $136,%xmm3,%xmm2 ## 10001000 => jzOa jzOb jzOc jzOd

    ## xmm0 = Ox
    ## xmm1 = Oy
    ## xmm2 = Oz

    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8


    subps nb102_ixO(%rsp),%xmm0
    subps nb102_iyO(%rsp),%xmm1
    subps nb102_izO(%rsp),%xmm2
    subps nb102_ixH1(%rsp),%xmm3
    subps nb102_iyH1(%rsp),%xmm4
    subps nb102_izH1(%rsp),%xmm5
    subps nb102_ixH2(%rsp),%xmm6
    subps nb102_iyH2(%rsp),%xmm7
    subps nb102_izH2(%rsp),%xmm8

        movaps %xmm0,nb102_dxOO(%rsp)
        movaps %xmm1,nb102_dyOO(%rsp)
        movaps %xmm2,nb102_dzOO(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb102_dxH1O(%rsp)
        movaps %xmm4,nb102_dyH1O(%rsp)
        movaps %xmm5,nb102_dzH1O(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb102_dxH2O(%rsp)