nb_kernel214_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,140 行 · 第 1/5 页

        addq $16,nb214_innerjjnr(%rsp)             ## advance pointer (unroll 4) 

        movq nb214_pos(%rbp),%rsi       ## base of pos[] 

        lea  (%rax,%rax,2),%rax        ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx
        lea  (%rcx,%rcx,2),%rcx        ## replace jnr with j3 
        lea  (%rdx,%rdx,2),%rdx

        ## load j O coordinates 
    movlps (%rsi,%rax,4),%xmm0 ## jxOa jyOa  -   -
    movlps (%rsi,%rcx,4),%xmm1 ## jxOc jyOc  -   -
    movhps (%rsi,%rbx,4),%xmm0 ## jxOa jyOa jxOb jyOb 
    movhps (%rsi,%rdx,4),%xmm1 ## jxOc jyOc jxOd jyOd 

    movss  8(%rsi,%rax,4),%xmm2    ## jzOa  -  -  -
    movss  8(%rsi,%rcx,4),%xmm3    ## jzOc  -  -  -
    movhps 8(%rsi,%rbx,4),%xmm2    ## jzOa  -  jzOb  -
    movhps 8(%rsi,%rdx,4),%xmm3    ## jzOc  -  jzOd -

    movaps %xmm0,%xmm4
    unpcklps %xmm1,%xmm0 ## jxOa jxOc jyOa jyOc        
    unpckhps %xmm1,%xmm4 ## jxOb jxOd jyOb jyOd
    movaps %xmm0,%xmm1
    unpcklps %xmm4,%xmm0 ## x
    unpckhps %xmm4,%xmm1 ## y

    shufps $136,%xmm3,%xmm2 ## 10001000 => jzOa jzOb jzOc jzOd

    ## xmm0 = Ox
    ## xmm1 = Oy
    ## xmm2 = Oz

    subps nb214_ixO(%rsp),%xmm0
    subps nb214_iyO(%rsp),%xmm1
    subps nb214_izO(%rsp),%xmm2

    movaps %xmm0,%xmm4
    movaps %xmm1,%xmm5
    movaps %xmm2,%xmm6

    ## square it
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2

        addps  %xmm0,%xmm1
        addps  %xmm2,%xmm1
    ## rsq in xmm1

        ## move j O forces to local temp variables 
    movlps (%rdi,%rax,4),%xmm10 ## jxOa jyOa  -   -
    movlps (%rdi,%rcx,4),%xmm11 ## jxOc jyOc  -   -
    movhps (%rdi,%rbx,4),%xmm10 ## jxOa jyOa jxOb jyOb 
    movhps (%rdi,%rdx,4),%xmm11 ## jxOc jyOc jxOd jyOd 

    movss  8(%rdi,%rax,4),%xmm12    ## jzOa  -  -  -
    movss  8(%rdi,%rcx,4),%xmm13    ## jzOc  -  -  -
    movss  8(%rdi,%rbx,4),%xmm0     ## jzb
    movss  8(%rdi,%rdx,4),%xmm8     ## jzd
    movlhps %xmm0,%xmm12 ## jza  -  jzb  -
    movlhps %xmm8,%xmm13 ## jzc  -  jzd -

    shufps $136,%xmm13,%xmm12 ## 10001000 => jzOa jzOb jzOc jzOd

    ## xmm10: jxOa jyOa jxOb jyOb 
    ## xmm11: jxOc jyOc jxOd jyOd
    ## xmm12: jzOa jzOb jzOc jzOd

    ## calc rinvsq=1/rsq
        rcpps %xmm1,%xmm2
        movaps nb214_two(%rsp),%xmm0
        mulps %xmm2,%xmm1
        subps %xmm1,%xmm0
        mulps %xmm2,%xmm0       ## xmm0=rinvsq

        movaps %xmm0,%xmm1  ## rinvsq

        mulps  %xmm0,%xmm0  ## rinv4
        mulps  %xmm1,%xmm0      ## rinv6
        movaps %xmm0,%xmm2
        mulps  %xmm2,%xmm2      ## xmm2=rinv12

        mulps  nb214_c6(%rsp),%xmm0
        mulps  nb214_c12(%rsp),%xmm2
        movaps %xmm2,%xmm8
    subps  %xmm0,%xmm2  ## Vvdw=Vvdw12-Vvdw6 
        mulps  nb214_six(%rsp),%xmm0
        mulps  nb214_twelve(%rsp),%xmm8
        subps  %xmm0,%xmm8
        mulps  %xmm1,%xmm8      ## xmm8=total fscal 

    ## add potential to Vvdwtot
        addps  nb214_Vvdwtot(%rsp),%xmm2
    movaps %xmm2,nb214_Vvdwtot(%rsp)

    ## calculate scalar force by multiplying dx/dy/dz with fscal
        mulps  %xmm8,%xmm4
        mulps  %xmm8,%xmm5
        mulps  %xmm8,%xmm6

    ## increment i force
    movaps nb214_fixO(%rsp),%xmm0
    movaps nb214_fiyO(%rsp),%xmm1
    movaps nb214_fizO(%rsp),%xmm2
    addps  %xmm4,%xmm0
    addps  %xmm5,%xmm1
    addps  %xmm6,%xmm2
    movaps %xmm0,nb214_fixO(%rsp)
    movaps %xmm1,nb214_fiyO(%rsp)
    movaps %xmm2,nb214_fizO(%rsp)

    ## update O forces
    ## xmm3 = fH1x , xmm4 = fH1y
    movaps %xmm4,%xmm3
    unpcklps %xmm5,%xmm4  ## fjx1 fjx1 fjy1 fjy2
    unpckhps %xmm5,%xmm3  ## fjx3 fjx4 fjy3 fjy4

    addps %xmm4,%xmm10
    addps %xmm3,%xmm11
    addps %xmm6,%xmm12

    movhlps  %xmm12,%xmm13 ## fH1zc fH1zd

    movlps %xmm10,(%rdi,%rax,4)
    movhps %xmm10,(%rdi,%rbx,4)
    movlps %xmm11,(%rdi,%rcx,4)
    movhps %xmm11,(%rdi,%rdx,4)
    movss  %xmm12,8(%rdi,%rax,4)
    movss  %xmm13,8(%rdi,%rcx,4)
    shufps $1,%xmm12,%xmm12
    shufps $1,%xmm13,%xmm13
    movss  %xmm12,8(%rdi,%rbx,4)
    movss  %xmm13,8(%rdi,%rdx,4)
    ## done with OO interaction.

        ## move j H1 coordinates to local temp variables 
    movlps 12(%rsi,%rax,4),%xmm0    ## jxH1a jyH1a  -   -
    movlps 12(%rsi,%rcx,4),%xmm1    ## jxH1c jyH1c  -   -
    movhps 12(%rsi,%rbx,4),%xmm0    ## jxH1a jyH1a jxH1b jyH1b 
    movhps 12(%rsi,%rdx,4),%xmm1    ## jxH1c jyH1c jxH1d jyH1d 

    movss  20(%rsi,%rax,4),%xmm2    ## jzH1a  -  -  -
    movss  20(%rsi,%rcx,4),%xmm3    ## jzH1c  -  -  -
    movhps 20(%rsi,%rbx,4),%xmm2    ## jzH1a  -  jzH1b  -
    movhps 20(%rsi,%rdx,4),%xmm3    ## jzH1c  -  jzH1d -

    movaps %xmm0,%xmm4
    unpcklps %xmm1,%xmm0 ## jxH1a jxH1c jyH1a jyH1c        
    unpckhps %xmm1,%xmm4 ## jxH1b jxH1d jyH1b jyH1d
    movaps %xmm0,%xmm1
    unpcklps %xmm4,%xmm0 ## x
    unpckhps %xmm4,%xmm1 ## y

    shufps $136,%xmm3,%xmm2 ## 10001000 => jzH1a jzH1b jzH1c jzH1d

    ## xmm0 = H1x
    ## xmm1 = H1y
    ## xmm2 = H1z

    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8

    subps nb214_ixH1(%rsp),%xmm0
    subps nb214_iyH1(%rsp),%xmm1
    subps nb214_izH1(%rsp),%xmm2
    subps nb214_ixH2(%rsp),%xmm3
    subps nb214_iyH2(%rsp),%xmm4
    subps nb214_izH2(%rsp),%xmm5
    subps nb214_ixM(%rsp),%xmm6
    subps nb214_iyM(%rsp),%xmm7
    subps nb214_izM(%rsp),%xmm8

        movaps %xmm0,nb214_dxH1H1(%rsp)
        movaps %xmm1,nb214_dyH1H1(%rsp)
        movaps %xmm2,nb214_dzH1H1(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb214_dxH2H1(%rsp)
        movaps %xmm4,nb214_dyH2H1(%rsp)
        movaps %xmm5,nb214_dzH2H1(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb214_dxMH1(%rsp)
        movaps %xmm7,nb214_dyMH1(%rsp)
        movaps %xmm8,nb214_dzMH1(%rsp)
        mulps  %xmm6,%xmm6
        mulps  %xmm7,%xmm7
        mulps  %xmm8,%xmm8
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    addps  %xmm7,%xmm6
    addps  %xmm8,%xmm6

        ## start doing invsqrt for jH1 atoms
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm3,%xmm4
    rsqrtps %xmm6,%xmm7

        movaps  %xmm1,%xmm2
        movaps  %xmm4,%xmm5
    movaps  %xmm7,%xmm8

        mulps   %xmm1,%xmm1 ## lu*lu
        mulps   %xmm4,%xmm4 ## lu*lu
    mulps   %xmm7,%xmm7 ## lu*lu

        movaps  nb214_three(%rsp),%xmm9
        movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

        mulps   %xmm0,%xmm1 ## rsq*lu*lu
        mulps   %xmm3,%xmm4 ## rsq*lu*lu 
    mulps   %xmm6,%xmm7 ## rsq*lu*lu

        subps   %xmm1,%xmm9
        subps   %xmm4,%xmm10
    subps   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulps   %xmm2,%xmm9
        mulps   %xmm5,%xmm10
    mulps   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movaps  nb214_half(%rsp),%xmm4
        mulps   %xmm4,%xmm9 ## rinvH1H1 
        mulps   %xmm4,%xmm10 ## rinvH2H1
    mulps   %xmm4,%xmm11 ## rinvMH1

        ## H1 interactions 
    ## rsq in xmm0,xmm3,xmm6  
    ## rinv in xmm9, xmm10, xmm11

    movaps %xmm9,%xmm1 ## copy of rinv
    movaps %xmm10,%xmm4
    movaps %xmm11,%xmm7
    movaps nb214_krf(%rsp),%xmm2
    mulps  %xmm9,%xmm9  ## rinvsq
    mulps  %xmm10,%xmm10
    mulps  %xmm11,%xmm11
    mulps  %xmm2,%xmm0 ## k*rsq
    mulps  %xmm2,%xmm3
    mulps  %xmm2,%xmm6
    movaps %xmm0,%xmm2 ## copy of k*rsq
    movaps %xmm3,%xmm5
    movaps %xmm6,%xmm8
    addps  %xmm1,%xmm2 ## rinv+krsq
    addps  %xmm4,%xmm5
    addps  %xmm7,%xmm8
    movaps nb214_crf(%rsp),%xmm14
    subps  %xmm14,%xmm2  ## rinv+krsq-crf
    subps  %xmm14,%xmm5
    subps  %xmm14,%xmm8
    movaps nb214_qqHH(%rsp),%xmm12
    movaps nb214_qqMH(%rsp),%xmm13
    mulps  %xmm12,%xmm2 ## voul=qq*(rinv+ krsq-crf)
    mulps  %xmm12,%xmm5 ## voul=qq*(rinv+ krsq-crf)
    mulps  %xmm13,%xmm8 ## voul=qq*(rinv+ krsq-crf)
    addps  %xmm0,%xmm0 ## 2*krsq
    addps  %xmm3,%xmm3
    addps  %xmm6,%xmm6
    subps  %xmm0,%xmm1 ## rinv-2*krsq
    subps  %xmm3,%xmm4
    subps  %xmm6,%xmm7
    mulps  %xmm12,%xmm1  ## (rinv-2*krsq)*qq
    mulps  %xmm12,%xmm4
    mulps  %xmm13,%xmm7
    addps  nb214_vctot(%rsp),%xmm2
    addps  %xmm8,%xmm5
    addps  %xmm5,%xmm2
    movaps %xmm2,%xmm15

    mulps  %xmm9,%xmm1  ## fscal
    mulps  %xmm10,%xmm4
    mulps  %xmm11,%xmm7

        ## move j H1 forces to local temp variables 
    movlps 12(%rdi,%rax,4),%xmm9    ## jxH1a jyH1a  -   -
    movlps 12(%rdi,%rcx,4),%xmm10    ## jxH1c jyH1c  -   -
    movhps 12(%rdi,%rbx,4),%xmm9    ## jxH1a jyH1a jxH1b jyH1b 
    movhps 12(%rdi,%rdx,4),%xmm10    ## jxH1c jyH1c jxH1d jyH1d 

    movss  20(%rdi,%rax,4),%xmm11    ## jzH1a  -  -  -
    movss  20(%rdi,%rcx,4),%xmm12    ## jzH1c  -  -  -
    movhps 20(%rdi,%rbx,4),%xmm11    ## jzH1a  -  jzH1b  -
    movhps 20(%rdi,%rdx,4),%xmm12    ## jzH1c  -  jzH1d -

    shufps $136,%xmm12,%xmm11 ## 10001000 => jzH1a jzH1b jzH1c jzH1d

    ## xmm9: jxH1a jyH1a jxH1b jyH1b 
    ## xmm10: jxH1c jyH1c jxH1d jyH1d
    ## xmm11: jzH1a jzH1b jzH1c jzH1d

    movaps %xmm1,%xmm0
    movaps %xmm1,%xmm2
    movaps %xmm4,%xmm3
    movaps %xmm4,%xmm5
    movaps %xmm7,%xmm6
    movaps %xmm7,%xmm8

        mulps nb214_dxH1H1(%rsp),%xmm0
        mulps nb214_dyH1H1(%rsp),%xmm1
        mulps nb214_dzH1H1(%rsp),%xmm2
        mulps nb214_dxH2H1(%rsp),%xmm3
        mulps nb214_dyH2H1(%rsp),%xmm4
        mulps nb214_dzH2H1(%rsp),%xmm5
        mulps nb214_dxMH1(%rsp),%xmm6
        mulps nb214_dyMH1(%rsp),%xmm7
        mulps nb214_dzMH1(%rsp),%xmm8

    movaps %xmm0,%xmm13
    movaps %xmm1,%xmm14
    addps %xmm2,%xmm11
    addps nb214_fixH1(%rsp),%xmm0
    addps nb214_fiyH1(%rsp),%xmm1
    addps nb214_fizH1(%rsp),%xmm2

    addps %xmm3,%xmm13
    addps %xmm4,%xmm14
    addps %xmm5,%xmm11
    addps nb214_fixH2(%rsp),%xmm3
    addps nb214_fiyH2(%rsp),%xmm4
    addps nb214_fizH2(%rsp),%xmm5

    addps %xmm6,%xmm13
    addps %xmm7,%xmm14
    addps %xmm8,%xmm11
    addps nb214_fixM(%rsp),%xmm6
    addps nb214_fiyM(%rsp),%xmm7
    addps nb214_fizM(%rsp),%xmm8

    movaps %xmm0,nb214_fixH1(%rsp)
    movaps %xmm1,nb214_fiyH1(%rsp)
    movaps %xmm2,nb214_fizH1(%rsp)
    movaps %xmm3,nb214_fixH2(%rsp)
    movaps %xmm4,nb214_fiyH2(%rsp)
    movaps %xmm5,nb214_fizH2(%rsp)
    movaps %xmm6,nb214_fixM(%rsp)
    movaps %xmm7,nb214_fiyM(%rsp)
    movaps %xmm8,nb214_fizM(%rsp)

    ## xmm9 = fH1x
    ## xmm10 = fH1y
    ## xmm11 = fH1z
    movaps %xmm13,%xmm0
    unpcklps %xmm14,%xmm13
    unpckhps %xmm14,%xmm0

    addps %xmm13,%xmm9
    addps %xmm0,%xmm10

    movhlps  %xmm11,%xmm12 ## fH1zc fH1zd

    movlps %xmm9,12(%rdi,%rax,4)
    movhps %xmm9,12(%rdi,%rbx,4)
    movlps %xmm10,12(%rdi,%rcx,4)
    movhps %xmm10,12(%rdi,%rdx,4)
    movss  %xmm11,20(%rdi,%rax,4)
    movss  %xmm12,20(%rdi,%rcx,4)
    shufps $1,%xmm11,%xmm11
    shufps $1,%xmm12,%xmm12
    movss  %xmm11,20(%rdi,%rbx,4)
    movss  %xmm12,20(%rdi,%rdx,4)

        ## move j H2 coordinates to local temp variables 
    movlps 24(%rsi,%rax,4),%xmm0    ## jxH2a jyH2a  -   -
    movlps 24(%rsi,%rcx,4),%xmm1    ## jxH2c jyH2c  -   -
    movhps 24(%rsi,%rbx,4),%xmm0    ## jxH2a jyH2a jxH2b jyH2b 
    movhps 24(%rsi,%rdx,4),%xmm1    ## jxH2c jyH2c jxH2d jyH2d 

    movss  32(%rsi,%rax,4),%xmm2    ## jzH2a  -  -  -
    movss  32(%rsi,%rcx,4),%xmm3    ## jzH2c  -  -  -
    movhps 32(%rsi,%rbx,4),%xmm2    ## jzH2a  -  jzH2b  -
    movhps 32(%rsi,%rdx,4),%xmm3    ## jzH2c  -  jzH2d -

    movaps %xmm0,%xmm4
    unpcklps %xmm1,%xmm0 ## jxH2a jxH2c jyH2a jyH2c        
    unpckhps %xmm1,%xmm4 ## jxH2b jxH2d jyH2b jyH2d
    movaps %xmm0,%xmm1
    unpcklps %xmm4,%xmm0 ## x
    unpckhps %xmm4,%xmm1 ## y

    shufps  $136,%xmm3,%xmm2  ## 10001000 => jzH2a jzH2b jzH2c jzH2d

    ## xmm0 = H2x
    ## xmm1 = H2y
    ## xmm2 = H2z

    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8


    subps nb214_ixH1(%rsp),%xmm0
    subps nb214_iyH1(%rsp),%xmm1
    subps nb214_izH1(%rsp),%xmm2
    subps nb214_ixH2(%rsp),%xmm3
    subps nb214_iyH2(%rsp),%xmm4
    subps nb214_izH2(%rsp),%xmm5
    subps nb214_ixM(%rsp),%xmm6
    subps nb214_iyM(%rsp),%xmm7
    subps nb214_izM(%rsp),%xmm8

        movaps %xmm0,nb214_dxH1H2(%rsp)
        movaps %xmm1,nb214_dyH1H2(%rsp)
        movaps %xmm2,nb214_dzH1H2(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb214_dxH2H2(%rsp)
        movaps %xmm4,nb214_dyH2H2(%rsp)
        movaps %xmm5,nb214_dzH2H2(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb214_dxMH2(%rsp)
        movaps %xmm7,nb214_dyMH2(%rsp)