nb_kernel101_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,416 行 · 第 1/3 页

        mulps nb101_dyO(%rsp),%xmm8
        mulps nb101_dzO(%rsp),%xmm9
        mulps nb101_dxH1(%rsp),%xmm10
        mulps nb101_dyH1(%rsp),%xmm11
        mulps nb101_dzH1(%rsp),%xmm12
        mulps nb101_dxH2(%rsp),%xmm13
        mulps nb101_dyH2(%rsp),%xmm14
        mulps nb101_dzH2(%rsp),%xmm15

    movaps %xmm7,%xmm3
    movaps %xmm8,%xmm4
    addps %xmm9,%xmm2
    addps nb101_fixO(%rsp),%xmm7
    addps nb101_fiyO(%rsp),%xmm8
    addps nb101_fizO(%rsp),%xmm9

    addps %xmm10,%xmm3
    addps %xmm11,%xmm4
    addps %xmm12,%xmm2
    addps nb101_fixH1(%rsp),%xmm10
    addps nb101_fiyH1(%rsp),%xmm11
    addps nb101_fizH1(%rsp),%xmm12

    addps %xmm13,%xmm3
    addps %xmm14,%xmm4
    addps %xmm15,%xmm2
    addps nb101_fixH2(%rsp),%xmm13
    addps nb101_fiyH2(%rsp),%xmm14
    addps nb101_fizH2(%rsp),%xmm15

    movaps %xmm7,nb101_fixO(%rsp)
    movaps %xmm8,nb101_fiyO(%rsp)
    movaps %xmm9,nb101_fizO(%rsp)
    movaps %xmm10,nb101_fixH1(%rsp)
    movaps %xmm11,nb101_fiyH1(%rsp)
    movaps %xmm12,nb101_fizH1(%rsp)
    movaps %xmm13,nb101_fixH2(%rsp)
    movaps %xmm14,nb101_fiyH2(%rsp)
    movaps %xmm15,nb101_fizH2(%rsp)

    ## xmm3 = fjx , xmm4 = fjy
    movaps %xmm3,%xmm5
    unpcklps %xmm4,%xmm3
    unpckhps %xmm4,%xmm5

    addps %xmm3,%xmm0
    addps %xmm5,%xmm1

    movhlps  %xmm2,%xmm3 ## fjzc fjzd

    movlps %xmm0,(%rdi,%rax,4)
    movhps %xmm0,(%rdi,%rbx,4)
    movlps %xmm1,(%rdi,%rcx,4)
    movhps %xmm1,(%rdi,%rdx,4)
    movss  %xmm2,8(%rdi,%rax,4)
    movss  %xmm3,8(%rdi,%rcx,4)
    shufps $1,%xmm2,%xmm2
    shufps $1,%xmm3,%xmm3
    movss  %xmm2,8(%rdi,%rbx,4)
    movss  %xmm3,8(%rdi,%rdx,4)

        ## should we do one more iteration? 
        subl $4,nb101_innerk(%rsp)
        jl    _nb_kernel101_x86_64_sse.nb101_odd_inner
        jmp   _nb_kernel101_x86_64_sse.nb101_unroll_loop
_nb_kernel101_x86_64_sse.nb101_odd_inner: 
        addl $4,nb101_innerk(%rsp)
        jnz   _nb_kernel101_x86_64_sse.nb101_odd_loop
        jmp   _nb_kernel101_x86_64_sse.nb101_updateouterdata
_nb_kernel101_x86_64_sse.nb101_odd_loop: 
        movq  nb101_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        addq $4,nb101_innerjjnr(%rsp)

        xorps %xmm4,%xmm4
        movss nb101_iqO(%rsp),%xmm4
        movq nb101_charge(%rbp),%rsi
        movhps nb101_iqH(%rsp),%xmm4
        movss (%rsi,%rax,4),%xmm3       ## charge in xmm3 
        shufps $0,%xmm3,%xmm3
        mulps %xmm4,%xmm3
        movaps %xmm3,nb101_qqO(%rsp)    ## use oxygen qq for storage 

        movq nb101_pos(%rbp),%rsi
        lea  (%rax,%rax,2),%rax

        ## move j coords to xmm0-xmm2 
        movss (%rsi,%rax,4),%xmm3
        movss 4(%rsi,%rax,4),%xmm4
        movss 8(%rsi,%rax,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5

        movss nb101_ixO(%rsp),%xmm0
        movss nb101_iyO(%rsp),%xmm1
        movss nb101_izO(%rsp),%xmm2

        movlps nb101_ixH1(%rsp),%xmm6
        movlps nb101_ixH2(%rsp),%xmm7
        unpcklps %xmm7,%xmm6
        movlhps %xmm6,%xmm0
        movlps nb101_iyH1(%rsp),%xmm6
        movlps nb101_iyH2(%rsp),%xmm7
        unpcklps %xmm7,%xmm6
        movlhps %xmm6,%xmm1
        movlps nb101_izH1(%rsp),%xmm6
        movlps nb101_izH2(%rsp),%xmm7
        unpcklps %xmm7,%xmm6
        movlhps %xmm6,%xmm2

        subps %xmm0,%xmm3
        subps %xmm1,%xmm4
        subps %xmm2,%xmm5

        movaps %xmm3,nb101_dxO(%rsp)
        movaps %xmm4,nb101_dyO(%rsp)
        movaps %xmm5,nb101_dzO(%rsp)

        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5

        addps  %xmm3,%xmm4
        addps  %xmm5,%xmm4
        ## rsq in xmm4 

        rsqrtps %xmm4,%xmm5
        ## lookup seed in xmm5 
        movaps %xmm5,%xmm2
        mulps %xmm5,%xmm5
        movaps nb101_three(%rsp),%xmm1
        mulps %xmm4,%xmm5       ## rsq*lu*lu                    
        movaps nb101_half(%rsp),%xmm0
        subps %xmm5,%xmm1       ## 30-rsq*lu*lu 
        mulps %xmm2,%xmm1
        mulps %xmm1,%xmm0       ## xmm0=rinv 
        ## a little trick to avoid NaNs: 
        ## positions 0,2,and 3 are valid, but not 1. 
        ## If it contains NaN it doesnt help to mult by 0, 
        ## So we shuffle it and copy pos 0 to pos1! 
        shufps $224,%xmm0,%xmm0 ## 11100000      
        movaps %xmm0,%xmm4
        mulps  %xmm4,%xmm4      ## xmm4=rinvsq 
        movaps nb101_qqO(%rsp),%xmm3

        mulps  %xmm0,%xmm3      ## xmm3=vcoul 
        mulps  %xmm3,%xmm4      ## xmm4=total fscal 
        addps  nb101_vctot(%rsp),%xmm3

        movaps nb101_dxO(%rsp),%xmm0
        movaps nb101_dyO(%rsp),%xmm1
        movaps nb101_dzO(%rsp),%xmm2

        movaps %xmm3,nb101_vctot(%rsp)

        mulps  %xmm4,%xmm0
        mulps  %xmm4,%xmm1
        mulps  %xmm4,%xmm2
        ## xmm0-xmm2 contains tx-tz (partial force) 
        movss  nb101_fixO(%rsp),%xmm3
        movss  nb101_fiyO(%rsp),%xmm4
        movss  nb101_fizO(%rsp),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,nb101_fixO(%rsp)
        movss  %xmm4,nb101_fiyO(%rsp)
        movss  %xmm5,nb101_fizO(%rsp)   ## updated the O force now do the H's 
        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        shufps $230,%xmm3,%xmm3 ## 11100110      ;# shift right 
        shufps $230,%xmm4,%xmm4 ## 11100110
        shufps $230,%xmm5,%xmm5 ## 11100110
        addss  nb101_fixH1(%rsp),%xmm3
        addss  nb101_fiyH1(%rsp),%xmm4
        addss  nb101_fizH1(%rsp),%xmm5
        movss  %xmm3,nb101_fixH1(%rsp)
        movss  %xmm4,nb101_fiyH1(%rsp)
        movss  %xmm5,nb101_fizH1(%rsp)          ## updated the H1 force 

        movq nb101_faction(%rbp),%rdi
        shufps $231,%xmm3,%xmm3 ## 11100111      ;# shift right 
        shufps $231,%xmm4,%xmm4 ## 11100111
        shufps $231,%xmm5,%xmm5 ## 11100111
        addss  nb101_fixH2(%rsp),%xmm3
        addss  nb101_fiyH2(%rsp),%xmm4
        addss  nb101_fizH2(%rsp),%xmm5
        movss  %xmm3,nb101_fixH2(%rsp)
        movss  %xmm4,nb101_fiyH2(%rsp)
        movss  %xmm5,nb101_fizH2(%rsp)          ## updated the H2 force 

        ## the fj's - start by accumulating the tx/ty/tz force in xmm0, xmm1 
        xorps  %xmm5,%xmm5
        movaps %xmm0,%xmm3
        movlps (%rdi,%rax,4),%xmm6
        movss  8(%rdi,%rax,4),%xmm7
        unpcklps %xmm1,%xmm3
        movlhps  %xmm5,%xmm3
        unpckhps %xmm1,%xmm0
        addps    %xmm3,%xmm0
        movhlps  %xmm0,%xmm3
        addps    %xmm3,%xmm0    ## x,y sum in xmm0 

        movhlps  %xmm2,%xmm1
        addss    %xmm1,%xmm2
        shufps  $1,%xmm1,%xmm1
        addss    %xmm1,%xmm2   ## z sum in xmm2 
        addps    %xmm0,%xmm6
        addss    %xmm2,%xmm7

        movlps %xmm6,(%rdi,%rax,4)
        movss  %xmm7,8(%rdi,%rax,4)

        decl  nb101_innerk(%rsp)
        jz    _nb_kernel101_x86_64_sse.nb101_updateouterdata
        jmp   _nb_kernel101_x86_64_sse.nb101_odd_loop
_nb_kernel101_x86_64_sse.nb101_updateouterdata: 
        movl  nb101_ii3(%rsp),%ecx
        movq  nb101_faction(%rbp),%rdi
        movq  nb101_fshift(%rbp),%rsi
        movl  nb101_is3(%rsp),%edx

        ## accumulate Oi forces in xmm0, xmm1, xmm2 
        movaps nb101_fixO(%rsp),%xmm0
        movaps nb101_fiyO(%rsp),%xmm1
        movaps nb101_fizO(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%rdi,%rcx,4),%xmm3
        movss  4(%rdi,%rcx,4),%xmm4
        movss  8(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rdi,%rcx,4)
        movss  %xmm4,4(%rdi,%rcx,4)
        movss  %xmm5,8(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        movaps %xmm0,%xmm6
        movss %xmm2,%xmm7
        movlhps %xmm1,%xmm6
        shufps $8,%xmm6,%xmm6 ## 00001000       

        ## accumulate H1i forces in xmm0, xmm1, xmm2 
        movaps nb101_fixH1(%rsp),%xmm0
        movaps nb101_fiyH1(%rsp),%xmm1
        movaps nb101_fizH1(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  12(%rdi,%rcx,4),%xmm3
        movss  16(%rdi,%rcx,4),%xmm4
        movss  20(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,12(%rdi,%rcx,4)
        movss  %xmm4,16(%rdi,%rcx,4)
        movss  %xmm5,20(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## accumulate H2i forces in xmm0, xmm1, xmm2 
        movaps nb101_fixH2(%rsp),%xmm0
        movaps nb101_fiyH2(%rsp),%xmm1
        movaps nb101_fizH2(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  24(%rdi,%rcx,4),%xmm3
        movss  28(%rdi,%rcx,4),%xmm4
        movss  32(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,24(%rdi,%rcx,4)
        movss  %xmm4,28(%rdi,%rcx,4)
        movss  %xmm5,32(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## increment fshift force  
        movlps  (%rsi,%rdx,4),%xmm3
        movss  8(%rsi,%rdx,4),%xmm4
        subps  %xmm6,%xmm3
        subss  %xmm7,%xmm4
        movlps  %xmm3,(%rsi,%rdx,4)
        movss  %xmm4,8(%rsi,%rdx,4)

        ## get n from stack
        movl nb101_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb101_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb101_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb101_Vc(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb101_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel101_x86_64_sse.nb101_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb101_n(%rsp)
        jmp _nb_kernel101_x86_64_sse.nb101_outer
_nb_kernel101_x86_64_sse.nb101_outerend: 
        ## check if more outer neighborlists remain
        movl  nb101_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel101_x86_64_sse.nb101_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel101_x86_64_sse.nb101_threadloop
_nb_kernel101_x86_64_sse.nb101_end: 

        movl nb101_nouter(%rsp),%eax
        movl nb101_ninner(%rsp),%ebx
        movq nb101_outeriter(%rbp),%rcx
        movq nb101_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $696,%rsp
        emms

        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret


.globl nb_kernel101nf_x86_64_sse
.globl _nb_kernel101nf_x86_64_sse
nb_kernel101nf_x86_64_sse:      
_nb_kernel101nf_x86_64_sse:     
.set nb101nf_fshift, 16
.set nb101nf_gid, 24
.set nb101nf_pos, 32
.set nb101nf_faction, 40
.set nb101nf_charge, 48
.set nb101nf_p_facel, 56
.set nb101nf_argkrf, 64
.set nb101nf_argcrf, 72
.set nb101nf_Vc, 80
.set nb101nf_type, 88
.set nb101nf_p_ntype, 96
.set nb101nf_vdwparam, 104
.set nb101nf_Vvdw, 112
.set nb101nf_p_tabscale, 120
.set nb101nf_VFtab, 128
.set nb101nf_invsqrta, 136
.set nb101nf_dvda, 144
.set nb101nf_p_gbtabscale, 152
.set nb101nf_GBtab, 160
.set nb101nf_p_nthreads, 168
.set nb101nf_count, 176
.set nb101nf_mtx, 184
.set nb101nf_outeriter, 192
.set nb101nf_inneriter, 200
.set nb101nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb101nf_ixO, 0
.set nb101nf_iyO, 16
.set nb101nf_izO, 32
.set nb101nf_ixH1, 48
.set nb101nf_iyH1, 64
.set nb101nf_izH1, 80
.set nb101nf_ixH2, 96
.set nb101nf_iyH2, 112
.set nb101nf_izH2, 128
.set nb101nf_iqO, 144
.set nb101nf_iqH, 160
.set nb101nf_qqO, 176
.set nb101nf_qqH, 192
.set nb101nf_vctot, 208
.set nb101nf_half, 224
.set nb101nf_three, 240
.set nb101nf_is3, 256
.set nb101nf_ii3, 260
.set nb101nf_nri, 264
.set nb101nf_iinr, 272
.set nb101nf_jindex, 280
.set nb101nf_jjnr, 288
.set nb101nf_shift, 296
.set nb101nf_shiftvec, 304
.set nb101nf_facel, 312
.set nb101nf_innerjjnr, 320
.set nb101nf_innerk, 328
.set nb101nf_n, 332