nb_kernel130_x86_64_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,919 行 · 第 1/4 页

;#
;# $Id: nb_kernel130_x86_64_sse.intel_syntax.s,v 1.1.2.2 2006/09/22 08:32:49 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as




.globl nb_kernel130_x86_64_sse
.globl _nb_kernel130_x86_64_sse
nb_kernel130_x86_64_sse:	
_nb_kernel130_x86_64_sse:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb130_fshift,           16
.equiv          nb130_gid,              24
.equiv          nb130_pos,              32
.equiv          nb130_faction,          40
.equiv          nb130_charge,           48
.equiv          nb130_p_facel,          56
.equiv          nb130_argkrf,           64
.equiv          nb130_argcrf,           72
.equiv          nb130_Vc,               80
.equiv          nb130_type,             88
.equiv          nb130_p_ntype,          96
.equiv          nb130_vdwparam,         104
.equiv          nb130_Vvdw,             112
.equiv          nb130_p_tabscale,       120
.equiv          nb130_VFtab,            128
.equiv          nb130_invsqrta,         136
.equiv          nb130_dvda,             144
.equiv          nb130_p_gbtabscale,     152
.equiv          nb130_GBtab,            160
.equiv          nb130_p_nthreads,       168
.equiv          nb130_count,            176
.equiv          nb130_mtx,              184
.equiv          nb130_outeriter,        192
.equiv          nb130_inneriter,        200
.equiv          nb130_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb130_ix,               0
.equiv          nb130_iy,               16
.equiv          nb130_iz,               32
.equiv          nb130_iq,               48
.equiv          nb130_dx,               64
.equiv          nb130_dy,               80
.equiv          nb130_dz,               96
.equiv          nb130_c6,               112
.equiv          nb130_c12,              128
.equiv          nb130_tsc,              144
.equiv          nb130_qq,               160
.equiv          nb130_vctot,            176
.equiv          nb130_Vvdwtot,          192
.equiv          nb130_fix,              208
.equiv          nb130_fiy,              224
.equiv          nb130_fiz,              240
.equiv          nb130_half,             256
.equiv          nb130_three,            272
.equiv          nb130_two,              288
.equiv          nb130_nri,              336
.equiv          nb130_iinr,             344
.equiv          nb130_jindex,           352
.equiv          nb130_jjnr,             360
.equiv          nb130_shift,            368
.equiv          nb130_shiftvec,         376
.equiv          nb130_facel,            384
.equiv          nb130_innerjjnr,        392
.equiv          nb130_is3,              400
.equiv          nb130_ii3,              404
.equiv          nb130_ntia,             408
.equiv          nb130_innerk,           412
.equiv          nb130_n,                416
.equiv          nb130_nn1,              420
.equiv          nb130_ntype,            424
.equiv          nb130_nouter,           428
.equiv          nb130_ninner,           432


	push rbp
	mov  rbp, rsp
	push rbx

	
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 440		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb130_nouter], eax
	mov [rsp + nb130_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb130_nri], edi
	mov [rsp + nb130_iinr], rsi
	mov [rsp + nb130_jindex], rdx
	mov [rsp + nb130_jjnr], rcx
	mov [rsp + nb130_shift], r8
	mov [rsp + nb130_shiftvec], r9
	mov rdi, [rbp + nb130_p_ntype]
	mov edi, [rdi]
	mov [rsp + nb130_ntype], edi
	mov rsi, [rbp + nb130_p_facel]
	movss xmm0, [rsi]
	movss [rsp + nb130_facel], xmm0

	mov rax, [rbp + nb130_p_tabscale]
	movss xmm3, [rax]
	shufps xmm3, xmm3, 0
	movaps [rsp + nb130_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# half in IEEE (hex)
	mov [rsp + nb130_half], eax
	movss xmm1, [rsp + nb130_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# one
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# two
	addps  xmm3, xmm2	;# three
	movaps [rsp + nb130_half],  xmm1
	movaps [rsp + nb130_two],  xmm2
	movaps [rsp + nb130_three],  xmm3

.nb130_threadloop:
        mov   rsi, [rbp + nb130_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb130_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb130_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb130_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb130_n], eax
        mov [rsp + nb130_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb130_outerstart
        jmp .nb130_end

.nb130_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb130_nouter]
	mov [rsp + nb130_nouter], ebx

.nb130_outer:
	mov   rax, [rsp + nb130_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [rax + rsi*4]		;# ebx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb130_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb130_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [rax + rbx*4]
	movss xmm1, [rax + rbx*4 + 4]
	movss xmm2, [rax + rbx*4 + 8] 

	mov   rcx, [rsp + nb130_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [rcx + rsi*4]	    ;# ebx =ii 

	mov   rdx, [rbp + nb130_charge]
	movss xmm3, [rdx + rbx*4]	
	mulss xmm3, [rsp + nb130_facel]
	shufps xmm3, xmm3, 0

    	mov   rdx, [rbp + nb130_type] 
    	mov   edx, [rdx + rbx*4]
    	imul  edx, [rsp + nb130_ntype]
    	shl   edx, 1
    	mov   [rsp + nb130_ntia], edx
		
	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb130_pos]    ;# eax = base of pos[]  

	addss xmm0, [rax + rbx*4]
	addss xmm1, [rax + rbx*4 + 4]
	addss xmm2, [rax + rbx*4 + 8]

	movaps [rsp + nb130_iq], xmm3
	
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0

	movaps [rsp + nb130_ix], xmm0
	movaps [rsp + nb130_iy], xmm1
	movaps [rsp + nb130_iz], xmm2

	mov   [rsp + nb130_ii3], ebx
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [rsp + nb130_vctot], xmm4
	movaps [rsp + nb130_Vvdwtot], xmm4
	movaps [rsp + nb130_fix], xmm4
	movaps [rsp + nb130_fiy], xmm4
	movaps [rsp + nb130_fiz], xmm4
	
	mov   rax, [rsp + nb130_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rax, [rsp + nb130_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb130_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [rsp + nb130_ninner]
	mov   [rsp + nb130_ninner], ecx
	add   edx, 0
	mov   [rsp + nb130_innerk], edx    ;# number of innerloop atoms 
	jge   .nb130_unroll_loop
	jmp   .nb130_finish_inner
.nb130_unroll_loop:	
	;# quad-unroll innerloop here 
	mov   rdx, [rsp + nb130_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]              
	mov   ecx, [rdx + 8]            
	mov   edx, [rdx + 12]         ;# eax-edx=jnr1-4 
	add qword ptr [rsp + nb130_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov rsi, [rbp + nb130_charge]
	movss xmm0, [rsi + rax*4]
	movss xmm1, [rsi + rcx*4]
	movss xmm2, [rsi + rbx*4]
	movss xmm3, [rsi + rdx*4]

    unpcklps xmm0, xmm1  ;# jqa jqc - -
    unpcklps xmm2, xmm3  ;# jqb jqd - -
    unpcklps xmm0, xmm2  ;# jqa jqb jqc jqd
	mulps xmm0, [rsp + nb130_iq] 
    movaps [rsp + nb130_qq], xmm0

    ;# vdw parameters
	mov rsi, [rbp + nb130_type]
	mov r12d, [rsi + rax*4]
	mov r13d, [rsi + rbx*4]
	mov r14d, [rsi + rcx*4]
	mov r15d, [rsi + rdx*4]
	shl r12d, 1	
	shl r13d, 1	
	shl r14d, 1	
	shl r15d, 1	
    mov edi, [rsp + nb130_ntia]
	add r12d, edi
	add r13d, edi
	add r14d, edi
	add r15d, edi

	mov rsi, [rbp + nb130_vdwparam]
	movlps xmm3, [rsi + r12*4]
	movlps xmm7, [rsi + r14*4]
	movhps xmm3, [rsi + r13*4]
	movhps xmm7, [rsi + r15*4]

	movaps xmm0, xmm3
	shufps xmm0, xmm7, 136  ;# 10001000
	shufps xmm3, xmm7, 221  ;# 11011101

    movaps [rsp + nb130_c6], xmm0
    movaps [rsp + nb130_c12], xmm3
    
	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	
	lea   rcx, [rcx + rcx*2]    
	lea   rdx, [rdx + rdx*2]	

	mov rdi, [rbp + nb130_pos]
	;# load coordinates
	movlps xmm1, [rdi + rax*4]	;# x1 y1 - - 
	movlps xmm2, [rdi + rcx*4]	;# x3 y3 - - 
	movhps xmm1, [rdi + rbx*4]	;# x2 y2 - -
	movhps xmm2, [rdi + rdx*4]	;# x4 y4 - -

	movss xmm5, [rdi + rax*4 + 8]	;# z1 - - - 
	movss xmm6, [rdi + rcx*4 + 8]	;# z2 - - - 
	movss xmm7, [rdi + rbx*4 + 8]	;# z3 - - - 
	movss xmm8, [rdi + rdx*4 + 8]	;# z4 - - - 
    movlhps xmm5, xmm7 ;# jzOa  -  jzOb  -
    movlhps xmm6, xmm8 ;# jzOc  -  jzOd -

    movaps xmm4, xmm1
    unpcklps xmm1, xmm2  ;# jxa jxc jya jyc        
    unpckhps xmm4, xmm2  ;# jxb jxd jyb jyd
    movaps xmm2, xmm1
    unpcklps xmm1, xmm4 ;# x
    unpckhps xmm2, xmm4 ;# y
    shufps   xmm5, xmm6,  136  ;# 10001000 => jzH2a jzH2b jzH2c jzH2d

	;# calc dr  
	subps xmm1, [rsp + nb130_ix]
	subps xmm2, [rsp + nb130_iy]
	subps xmm5, [rsp + nb130_iz]

	;# store dr
    movaps [rsp + nb130_dx], xmm1
    movaps [rsp + nb130_dy], xmm2
    movaps [rsp + nb130_dz], xmm5
    
	;# square it 
	mulps xmm1,xmm1
	mulps xmm2,xmm2
	mulps xmm5,xmm5
	addps xmm1, xmm2
	addps xmm1, xmm5

	;# rsq in xmm1
    
    ;# calculate rinv=1/sqrt(rsq)
	rsqrtps xmm5, xmm1
	movaps xmm2, xmm5
	mulps xmm5, xmm5
	movaps xmm4, [rsp + nb130_three]
	mulps xmm5, xmm1	;# rsq*lu*lu 	
    subps xmm4, xmm5	;# 30-rsq*lu*lu 
	mulps xmm4, xmm2	
	mulps xmm4, [rsp + nb130_half]	
	movaps xmm2, xmm4
	mulps  xmm1, xmm4	
    ;# xmm2=rinv
    ;# xmm1=r

    mulps xmm1, [rsp + nb130_tsc] ;# rtab

    ;# truncate and convert to integers
    cvttps2dq xmm5, xmm1
    
    ;# convert back to float
    cvtdq2ps  xmm4, xmm5
    
    ;# multiply by 8
    pslld   xmm5, 3

    ;# calculate eps
    subps     xmm1, xmm4

    ;# move to integer registers
    movhlps xmm6, xmm5
    movd    r8d, xmm5
    movd    r10d, xmm6
    pshufd  xmm5, xmm5, 1
    pshufd  xmm6, xmm6, 1
    movd    r9d, xmm5
    movd    r11d, xmm6

    ;# xmm1=eps
    ;# xmm2=rinv
    
	mov rsi, [rbp + nb130_VFtab]
    ;# calculate LJ table
    movlps xmm5, [rsi + r8*4]
   	movlps xmm9, [rsi + r8*4 + 16]
    
	movlps xmm7,  [rsi + r10*4]
	movlps xmm11, [rsi + r10*4 + 16]

    movaps  xmm0, xmm2             ;# rinv
    mulps   xmm2, [rsp + nb130_qq] ;# vcoul=rinv*qq
    movaps  xmm3, xmm2             ;# copy of vcoul (to calc fscal)
    mulps   xmm3, xmm0             ;# vcoul*rinv
    
	movhps xmm5, [rsi + r9*4]
	movhps xmm9, [rsi + r9*4 + 16]

    addps   xmm2, [rsp + nb130_vctot]
    movaps  [rsp + nb130_vctot], xmm2
    
	movhps xmm7,  [rsi + r11*4]
	movhps xmm11, [rsi + r11*4 + 16]
    
    movaps xmm4, xmm5
    movaps xmm8, xmm9
	shufps xmm4, xmm7, 136  ;# 10001000
	shufps xmm8, xmm11, 136  ;# 10001000
	shufps xmm5, xmm7, 221  ;# 11011101
	shufps xmm9, xmm11, 221  ;# 11011101

	movlps xmm7,  [rsi + r8*4 + 8]
	movlps xmm11, [rsi + r8*4 + 24]
    
	movlps xmm13, [rsi + r10*4 + 8]
	movlps xmm14, [rsi + r10*4 + 24]

	movhps xmm7,  [rsi + r9*4 + 8]
	movhps xmm11, [rsi + r9*4 + 24]
    
	movhps xmm13, [rsi + r11*4 + 8]
	movhps xmm14, [rsi + r11*4 + 24]

    movaps xmm6, xmm7
    movaps xmm10, xmm11
    
	shufps xmm6, xmm13, 136  ;# 10001000
	shufps xmm10, xmm14, 136  ;# 10001000
	shufps xmm7, xmm13, 221  ;# 11011101
	shufps xmm11, xmm14, 221  ;# 11011101
    ;# dispersion table in xmm4-xmm7, repulsion table in xmm8-xmm11
    
    mulps  xmm7, xmm1    ;# Heps
    mulps  xmm11, xmm1 
    mulps  xmm6, xmm1   ;# Geps
    mulps  xmm10, xmm1 
    mulps  xmm7, xmm1   ;# Heps2
    mulps  xmm11, xmm1 
    addps  xmm5, xmm6  ;# F+Geps
    addps  xmm9, xmm10 
    addps  xmm5, xmm7   ;# F+Geps+Heps2 = Fp
    addps  xmm9, xmm11 
    addps  xmm7, xmm7    ;# 2*Heps2
    addps  xmm11, xmm11
    addps  xmm7, xmm6   ;# 2*Heps2+Geps
    addps  xmm11, xmm10
    
    addps  xmm7, xmm5  ;# FF = Fp + 2*Heps2 + Geps
    addps  xmm11, xmm9
    mulps  xmm5, xmm1  ;# eps*Fp
    mulps  xmm9, xmm1
    movaps xmm12, [rsp + nb130_c6]
    movaps xmm13, [rsp + nb130_c12]