nb_kernel132_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,146 行 · 第 1/5 页

    movaps %xmm11,%xmm13
    movaps %xmm11,%xmm14
    movaps %xmm11,%xmm15
    movaps %xmm10,%xmm11
    movaps %xmm10,%xmm12

        mulps nb132_dxOH1(%rsp),%xmm7
        mulps nb132_dyOH1(%rsp),%xmm8
        mulps nb132_dzOH1(%rsp),%xmm9
        mulps nb132_dxH1H1(%rsp),%xmm10
        mulps nb132_dyH1H1(%rsp),%xmm11
        mulps nb132_dzH1H1(%rsp),%xmm12
        mulps nb132_dxH2H1(%rsp),%xmm13
        mulps nb132_dyH2H1(%rsp),%xmm14
        mulps nb132_dzH2H1(%rsp),%xmm15

    movaps %xmm7,%xmm3
    movaps %xmm8,%xmm4
    addps %xmm9,%xmm2
    addps nb132_fixO(%rsp),%xmm7
    addps nb132_fiyO(%rsp),%xmm8
    addps nb132_fizO(%rsp),%xmm9

    addps %xmm10,%xmm3
    addps %xmm11,%xmm4
    addps %xmm12,%xmm2
    addps nb132_fixH1(%rsp),%xmm10
    addps nb132_fiyH1(%rsp),%xmm11
    addps nb132_fizH1(%rsp),%xmm12

    addps %xmm13,%xmm3
    addps %xmm14,%xmm4
    addps %xmm15,%xmm2
    addps nb132_fixH2(%rsp),%xmm13
    addps nb132_fiyH2(%rsp),%xmm14
    addps nb132_fizH2(%rsp),%xmm15

    movaps %xmm7,nb132_fixO(%rsp)
    movaps %xmm8,nb132_fiyO(%rsp)
    movaps %xmm9,nb132_fizO(%rsp)
    movaps %xmm10,nb132_fixH1(%rsp)
    movaps %xmm11,nb132_fiyH1(%rsp)
    movaps %xmm12,nb132_fizH1(%rsp)
    movaps %xmm13,nb132_fixH2(%rsp)
    movaps %xmm14,nb132_fiyH2(%rsp)
    movaps %xmm15,nb132_fizH2(%rsp)

    ## xmm0 = fH1x
    ## xmm1 = fH1y
    ## xmm2 = fH1z
    movaps %xmm3,%xmm5
    unpcklps %xmm4,%xmm3
    unpckhps %xmm4,%xmm5

    addps %xmm3,%xmm0
    addps %xmm5,%xmm1

    movhlps  %xmm2,%xmm3 ## fH1zc fH1zd

    movlps %xmm0,12(%rdi,%rax,4)
    movhps %xmm0,12(%rdi,%rbx,4)
    movlps %xmm1,12(%rdi,%rcx,4)
    movhps %xmm1,12(%rdi,%rdx,4)
    movss  %xmm2,20(%rdi,%rax,4)
    movss  %xmm3,20(%rdi,%rcx,4)
    shufps $1,%xmm2,%xmm2
    shufps $1,%xmm3,%xmm3
    movss  %xmm2,20(%rdi,%rbx,4)
    movss  %xmm3,20(%rdi,%rdx,4)


        ## move j H2 coordinates to local temp variables 
        movq nb132_pos(%rbp),%rsi        ## base of pos[] 
    movlps 24(%rsi,%rax,4),%xmm0    ## jxH2a jyH2a  -   -
    movlps 24(%rsi,%rcx,4),%xmm1    ## jxH2c jyH2c  -   -
    movhps 24(%rsi,%rbx,4),%xmm0    ## jxH2a jyH2a jxH2b jyH2b 
    movhps 24(%rsi,%rdx,4),%xmm1    ## jxH2c jyH2c jxH2d jyH2d 

    movss  32(%rsi,%rax,4),%xmm2    ## jzH2a  -  -  -
    movss  32(%rsi,%rcx,4),%xmm3    ## jzH2c  -  -  -
    movss  32(%rsi,%rbx,4),%xmm5    ## jzH2b  -  -  -
    movss  32(%rsi,%rdx,4),%xmm6    ## jzH2d  -  -  -
    movlhps %xmm5,%xmm2 ## jzH2a  -  jzH2b  -
    movlhps %xmm6,%xmm3 ## jzH2c  -  jzH2d -

    movaps %xmm0,%xmm4
    unpcklps %xmm1,%xmm0 ## jxH2a jxH2c jyH2a jyH2c        
    unpckhps %xmm1,%xmm4 ## jxH2b jxH2d jyH2b jyH2d
    movaps %xmm0,%xmm1
    unpcklps %xmm4,%xmm0 ## x
    unpckhps %xmm4,%xmm1 ## y

    shufps  $136,%xmm3,%xmm2  ## 10001000 => jzH2a jzH2b jzH2c jzH2d

    ## xmm0 = H2x
    ## xmm1 = H2y
    ## xmm2 = H2z

    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8

    subps nb132_ixO(%rsp),%xmm0
    subps nb132_iyO(%rsp),%xmm1
    subps nb132_izO(%rsp),%xmm2
    subps nb132_ixH1(%rsp),%xmm3
    subps nb132_iyH1(%rsp),%xmm4
    subps nb132_izH1(%rsp),%xmm5
    subps nb132_ixH2(%rsp),%xmm6
    subps nb132_iyH2(%rsp),%xmm7
    subps nb132_izH2(%rsp),%xmm8

        movaps %xmm0,nb132_dxOH2(%rsp)
        movaps %xmm1,nb132_dyOH2(%rsp)
        movaps %xmm2,nb132_dzOH2(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb132_dxH1H2(%rsp)
        movaps %xmm4,nb132_dyH1H2(%rsp)
        movaps %xmm5,nb132_dzH1H2(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb132_dxH2H2(%rsp)
        movaps %xmm7,nb132_dyH2H2(%rsp)
        movaps %xmm8,nb132_dzH2H2(%rsp)
        mulps  %xmm6,%xmm6
        mulps  %xmm7,%xmm7
        mulps  %xmm8,%xmm8
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    addps  %xmm7,%xmm6
    addps  %xmm8,%xmm6

        ## start doing invsqrt for jH2 atoms
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm3,%xmm4
    rsqrtps %xmm6,%xmm7

        movaps  %xmm1,%xmm2
        movaps  %xmm4,%xmm5
    movaps  %xmm7,%xmm8


        mulps   %xmm1,%xmm1 ## lu*lu
        mulps   %xmm4,%xmm4 ## lu*lu
    mulps   %xmm7,%xmm7 ## lu*lu

        movaps  nb132_three(%rsp),%xmm9
        movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

        mulps   %xmm0,%xmm1 ## rsq*lu*lu
        mulps   %xmm3,%xmm4 ## rsq*lu*lu 
    mulps   %xmm6,%xmm7 ## rsq*lu*lu

        subps   %xmm1,%xmm9
        subps   %xmm4,%xmm10
    subps   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulps   %xmm2,%xmm9
        mulps   %xmm5,%xmm10
    mulps   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movaps  nb132_half(%rsp),%xmm0
        mulps   %xmm0,%xmm9 ## rinvOH2 
        mulps   %xmm0,%xmm10 ## rinvH1H2
    mulps   %xmm0,%xmm11 ## rinvH2H2

        ## H2 interactions 
    movaps %xmm9,%xmm0
    movaps %xmm10,%xmm1
    movaps %xmm11,%xmm2
    mulps  %xmm9,%xmm9
    mulps  %xmm10,%xmm10
    mulps  %xmm11,%xmm11
    mulps  nb132_qqOH(%rsp),%xmm0
    mulps  nb132_qqHH(%rsp),%xmm1
    mulps  nb132_qqHH(%rsp),%xmm2
    mulps  %xmm0,%xmm9
    mulps  %xmm1,%xmm10
    mulps  %xmm2,%xmm11

    addps nb132_vctot(%rsp),%xmm0
    addps %xmm2,%xmm1
    addps %xmm1,%xmm0
    movaps %xmm0,nb132_vctot(%rsp)

        ## move j H2 forces to local temp variables 
        movq nb132_faction(%rbp),%rdi        ## base of faction[] 
    movlps 24(%rdi,%rax,4),%xmm0    ## jxH2a jyH2a  -   -
    movlps 24(%rdi,%rcx,4),%xmm1    ## jxH2c jyH2c  -   -
    movhps 24(%rdi,%rbx,4),%xmm0    ## jxH2a jyH2a jxH2b jyH2b 
    movhps 24(%rdi,%rdx,4),%xmm1    ## jxH2c jyH2c jxH2d jyH2d 

    movss  32(%rdi,%rax,4),%xmm2    ## jzH2a  -  -  -
    movss  32(%rdi,%rcx,4),%xmm3    ## jzH2c  -  -  -
    movss  32(%rdi,%rbx,4),%xmm7    ## jzH2b  -  -  -
    movss  32(%rdi,%rdx,4),%xmm8    ## jzH2d  -  -  -
    movlhps %xmm7,%xmm2 ## jzH2a  -  jzH2b  -
    movlhps %xmm8,%xmm3 ## jzH2c  -  jzH2d -

    shufps $136,%xmm3,%xmm2 ## 10001000 => jzH2a jzH2b jzH2c jzH2d

    ## xmm0: jxH2a jyH2a jxH2b jyH2b 
    ## xmm1: jxH2c jyH2c jxH2d jyH2d
    ## xmm2: jzH2a jzH2b jzH2c jzH2d

    movaps %xmm9,%xmm7
    movaps %xmm9,%xmm8
    movaps %xmm11,%xmm13
    movaps %xmm11,%xmm14
    movaps %xmm11,%xmm15
    movaps %xmm10,%xmm11
    movaps %xmm10,%xmm12

        mulps nb132_dxOH2(%rsp),%xmm7
        mulps nb132_dyOH2(%rsp),%xmm8
        mulps nb132_dzOH2(%rsp),%xmm9
        mulps nb132_dxH1H2(%rsp),%xmm10
        mulps nb132_dyH1H2(%rsp),%xmm11
        mulps nb132_dzH1H2(%rsp),%xmm12
        mulps nb132_dxH2H2(%rsp),%xmm13
        mulps nb132_dyH2H2(%rsp),%xmm14
        mulps nb132_dzH2H2(%rsp),%xmm15

    movaps %xmm7,%xmm3
    movaps %xmm8,%xmm4
    addps %xmm9,%xmm2
    addps nb132_fixO(%rsp),%xmm7
    addps nb132_fiyO(%rsp),%xmm8
    addps nb132_fizO(%rsp),%xmm9

    addps %xmm10,%xmm3
    addps %xmm11,%xmm4
    addps %xmm12,%xmm2
    addps nb132_fixH1(%rsp),%xmm10
    addps nb132_fiyH1(%rsp),%xmm11
    addps nb132_fizH1(%rsp),%xmm12

    addps %xmm13,%xmm3
    addps %xmm14,%xmm4
    addps %xmm15,%xmm2
    addps nb132_fixH2(%rsp),%xmm13
    addps nb132_fiyH2(%rsp),%xmm14
    addps nb132_fizH2(%rsp),%xmm15

    movaps %xmm7,nb132_fixO(%rsp)
    movaps %xmm8,nb132_fiyO(%rsp)
    movaps %xmm9,nb132_fizO(%rsp)
    movaps %xmm10,nb132_fixH1(%rsp)
    movaps %xmm11,nb132_fiyH1(%rsp)
    movaps %xmm12,nb132_fizH1(%rsp)
    movaps %xmm13,nb132_fixH2(%rsp)
    movaps %xmm14,nb132_fiyH2(%rsp)
    movaps %xmm15,nb132_fizH2(%rsp)

    ## xmm0 = fH2x
    ## xmm1 = fH2y
    ## xmm2 = fH2z
    movaps %xmm3,%xmm5
    unpcklps %xmm4,%xmm3
    unpckhps %xmm4,%xmm5

    addps %xmm3,%xmm0
    addps %xmm5,%xmm1

    movhlps  %xmm2,%xmm3 ## fH2zc fH2zd

    movlps %xmm0,24(%rdi,%rax,4)
    movhps %xmm0,24(%rdi,%rbx,4)
    movlps %xmm1,24(%rdi,%rcx,4)
    movhps %xmm1,24(%rdi,%rdx,4)
    movss  %xmm2,32(%rdi,%rax,4)
    movss  %xmm3,32(%rdi,%rcx,4)
    shufps $1,%xmm2,%xmm2
    shufps $1,%xmm3,%xmm3
    movss  %xmm2,32(%rdi,%rbx,4)
    movss  %xmm3,32(%rdi,%rdx,4)

        ## should we do one more iteration? 
        subl $4,nb132_innerk(%rsp)
        jl    _nb_kernel132_x86_64_sse.nb132_single_check
        jmp   _nb_kernel132_x86_64_sse.nb132_unroll_loop
_nb_kernel132_x86_64_sse.nb132_single_check: 
        addl $4,nb132_innerk(%rsp)
        jnz   _nb_kernel132_x86_64_sse.nb132_single_loop
        jmp   _nb_kernel132_x86_64_sse.nb132_updateouterdata
_nb_kernel132_x86_64_sse.nb132_single_loop: 
        movq  nb132_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        addq $4,nb132_innerjjnr(%rsp)

        movq nb132_pos(%rbp),%rsi
        lea  (%rax,%rax,2),%rax

        ## fetch j coordinates 
        xorps %xmm0,%xmm0
        xorps %xmm1,%xmm1
        xorps %xmm2,%xmm2

        movss (%rsi,%rax,4),%xmm0               ## jxO  -  -  -
        movss 4(%rsi,%rax,4),%xmm1              ## jyO  -  -  -
        movss 8(%rsi,%rax,4),%xmm2              ## jzO  -  -  -  

        movlps 12(%rsi,%rax,4),%xmm6            ## xmm6 = jxH1 jyH1   -    -
        movss  20(%rsi,%rax,4),%xmm7            ## xmm7 = jzH1   -    -    - 
        movhps 24(%rsi,%rax,4),%xmm6            ## xmm6 = jxH1 jyH1 jxH2 jyH2
        movss  32(%rsi,%rax,4),%xmm5            ## xmm5 = jzH2   -    -    -

        ## have all coords, time for some shuffling.

        shufps $216,%xmm6,%xmm6 ## 11011000      ;# xmm6 = jxH1 jxH2 jyH1 jyH2 
        unpcklps %xmm5,%xmm7                    ## xmm7 = jzH1 jzH2   -    -
        movlhps %xmm6,%xmm0                     ## xmm0 = jxO   0   jxH1 jxH2 
        shufps $228,%xmm6,%xmm1 ## 11100100     ;# xmm1 = jyO   0   jyH1 jyH2 
        shufps $68,%xmm7,%xmm2 ## 01000100     ;# xmm2 = jzO   0   jzH1 jzH2

        ## store all j coordinates in jO  
        movaps %xmm0,nb132_jxO(%rsp)
        movaps %xmm1,nb132_jyO(%rsp)
        movaps %xmm2,nb132_jzO(%rsp)
        subps  nb132_ixO(%rsp),%xmm0
        subps  nb132_iyO(%rsp),%xmm1
        subps  nb132_izO(%rsp),%xmm2
        movaps %xmm0,nb132_dxOO(%rsp)
        movaps %xmm1,nb132_dyOO(%rsp)
        movaps %xmm2,nb132_dzOO(%rsp)
        mulps %xmm0,%xmm0
        mulps %xmm1,%xmm1
        mulps %xmm2,%xmm2
        addps %xmm1,%xmm0
        addps %xmm2,%xmm0       ## have rsq in xmm0 
        movaps  %xmm0,nb132_rsqOO(%rsp)

        ## do invsqrt 
        rsqrtps %xmm0,%xmm1
        movaps  %xmm1,%xmm2
        mulps   %xmm1,%xmm1
        movaps  nb132_three(%rsp),%xmm3
        mulps   %xmm0,%xmm1
        subps   %xmm1,%xmm3
        mulps   %xmm2,%xmm3
        mulps   nb132_half(%rsp),%xmm3   ## rinv iO - j water in xmm3
        movaps  %xmm3,nb132_rinvOO(%rsp)

        movaps  %xmm3,%xmm0 ## rinv

        xorps   %xmm4,%xmm4
        ## fetch charges to xmm4 (temporary) 
        movss   nb132_qqOO(%rsp),%xmm4
        movhps  nb132_qqOH(%rsp),%xmm4

        mulps  %xmm4,%xmm3  ## vcoul
        movaps %xmm3,%xmm6

        mulps %xmm0,%xmm3
        movaps %xmm3,nb132_fstmp(%rsp)   ## save it
        addps  nb132_vctot(%rsp),%xmm6
    movaps %xmm6,nb132_vctot(%rsp)

        movss %xmm0,%xmm1  ## rinv
        mulss  nb132_rsqOO(%rsp),%xmm1   ## xmm1=r 
        mulss  nb132_tsc(%rsp),%xmm1

    cvttps2pi %xmm1,%mm6
    cvtpi2ps %mm6,%xmm3
        subss    %xmm3,%xmm1    ## xmm1=eps 
    movss %xmm1,%xmm2
    mulss  %xmm2,%xmm2      ## xmm2=eps2 
    pslld $3,%mm6

    movq nb132_VFtab(%rbp),%rsi
    movd %mm6,%r8d

    ## dispersion 
    movlps (%rsi,%r8,4),%xmm5
    movaps %xmm5,%xmm4
    shufps $136,%xmm7,%xmm4 ## constant 10001000
    shufps $221,%xmm7,%xmm5 ## constant 11011101

    movlps 8(%rsi,%r8,4),%xmm7
    movaps %xmm7,%xmm6
    shufps $136,%xmm3,%xmm6 ## constant 10001000
    shufps $221,%xmm3,%xmm7 ## constant 11011101
    ## dispersion table ready, in xmm4-xmm7 
    mulss  %xmm1,%xmm6      ## xmm6=Geps 
    mulss  %xmm2,%xmm7      ## xmm7=Heps2 
    addss  %xmm6,%xmm5
    addss  %xmm7,%xmm5      ## xmm5=Fp 
    addss  %xmm7,%xmm7      ## two*Heps2 
    addss  %xmm6,%xmm7
    addss  %xmm5,%xmm7 ## xmm7=FF 
    mulss  %xmm1,%xmm5 ## xmm5=eps*Fp 
    addss  %xmm4,%xmm5 ## xmm5=VV 

    movss nb132_c6(%rsp),%xmm4
    mulss  %xmm4,%xmm7   ## fijD 
    mulss  %xmm4,%xmm5   ## Vvdw6 
        movss  nb132_fstmp(%rsp),%xmm3
        mulps  nb132_tsc(%rsp),%xmm7
        subss  %xmm7,%xmm3
        movss  %xmm3,nb132_fstmp(%rsp)

    addss  nb132_Vvdwtot(%rsp),%xmm5
    movss %xmm5,nb132_Vvdwtot(%rsp)

    ## repulsion 
    movlps 16(%rsi,%r8,4),%xmm5
    movaps %xmm5,%xmm4
    shufps $136,%xmm7,%xmm4 ## constant 10001000
    shufps $221,%xmm7,%xmm5 ## constant 11011101

    movlps 24(%rsi,%r8,4),%xmm7
    movaps %xmm7,%xmm6
    shufps $136,%xmm3,%xmm6 ## constant 10001000
    shufps $221,%xmm3,%xmm7 ## constant 11011101
    ## table ready, in xmm4-xmm7 
    mulss  %xmm1,%xmm6      ## xmm6=Geps 
    mulss  %xmm2,%xmm7      ## xmm7=Heps2 
    addss  %xmm6,%xmm5
    addss  %xmm7,%xmm5      ## xmm5=Fp 
    addss  %xmm7,%xmm7      ## two*Heps2 
    addss  %xmm6,%xmm7