nb_kernel330_x86_64_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,051 行 · 第 1/4 页

;#
;# $Id: nb_kernel330_x86_64_sse.intel_syntax.s,v 1.1.2.2 2006/09/22 08:32:51 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		ddq
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as





.globl nb_kernel330_x86_64_sse
.globl _nb_kernel330_x86_64_sse
nb_kernel330_x86_64_sse:	
_nb_kernel330_x86_64_sse:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb330_fshift,           16
.equiv          nb330_gid,              24
.equiv          nb330_pos,              32
.equiv          nb330_faction,          40
.equiv          nb330_charge,           48
.equiv          nb330_p_facel,          56
.equiv          nb330_argkrf,           64
.equiv          nb330_argcrf,           72
.equiv          nb330_Vc,               80
.equiv          nb330_type,             88
.equiv          nb330_p_ntype,          96
.equiv          nb330_vdwparam,         104
.equiv          nb330_Vvdw,             112
.equiv          nb330_p_tabscale,       120
.equiv          nb330_VFtab,            128
.equiv          nb330_invsqrta,         136
.equiv          nb330_dvda,             144
.equiv          nb330_p_gbtabscale,     152
.equiv          nb330_GBtab,            160
.equiv          nb330_p_nthreads,       168
.equiv          nb330_count,            176
.equiv          nb330_mtx,              184
.equiv          nb330_outeriter,        192
.equiv          nb330_inneriter,        200
.equiv          nb330_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb330_ix,               0
.equiv          nb330_iy,               16
.equiv          nb330_iz,               32
.equiv          nb330_iq,               48
.equiv          nb330_dx,               64
.equiv          nb330_dy,               80
.equiv          nb330_dz,               96
.equiv          nb330_rinv,             112
.equiv          nb330_tsc,              128
.equiv          nb330_qq,               144
.equiv          nb330_c6,               160
.equiv          nb330_c12,              176
.equiv          nb330_eps,              192
.equiv          nb330_vctot,            208
.equiv          nb330_Vvdwtot,          224
.equiv          nb330_fix,              240
.equiv          nb330_fiy,              256
.equiv          nb330_fiz,              272
.equiv          nb330_half,             288
.equiv          nb330_three,            304
.equiv          nb330_nri,              320
.equiv          nb330_iinr,             328
.equiv          nb330_jindex,           336
.equiv          nb330_jjnr,             344
.equiv          nb330_shift,            352
.equiv          nb330_shiftvec,         360
.equiv          nb330_facel,            368
.equiv          nb330_innerjjnr,        376
.equiv          nb330_is3,              384
.equiv          nb330_ii3,              388
.equiv          nb330_ntia,             392
.equiv          nb330_innerk,           396
.equiv          nb330_n,                400
.equiv          nb330_nn1,              404
.equiv          nb330_ntype,            408
.equiv          nb330_nouter,           412
.equiv          nb330_ninner,           416

	push rbp
	mov  rbp, rsp
	push rbx

	
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 440		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb330_nouter], eax
	mov [rsp + nb330_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb330_nri], edi
	mov [rsp + nb330_iinr], rsi
	mov [rsp + nb330_jindex], rdx
	mov [rsp + nb330_jjnr], rcx
	mov [rsp + nb330_shift], r8
	mov [rsp + nb330_shiftvec], r9
	mov rdi, [rbp + nb330_p_ntype]
	mov edi, [rdi]
	mov [rsp + nb330_ntype], edi
	mov rsi, [rbp + nb330_p_facel]
	movss xmm0, [rsi]
	movss [rsp + nb330_facel], xmm0

	mov rax, [rbp + nb330_p_tabscale]
	movss xmm3, [rax]
	shufps xmm3, xmm3, 0
	movaps [rsp + nb330_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# half in IEEE (hex)
	mov [rsp + nb330_half], eax
	movss xmm1, [rsp + nb330_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# one
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# two
	addps  xmm3, xmm2	;# three
	movaps [rsp + nb330_half],  xmm1
	movaps [rsp + nb330_three],  xmm3

.nb330_threadloop:
        mov   rsi, [rbp + nb330_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb330_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb330_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb330_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb330_n], eax
        mov [rsp + nb330_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb330_outerstart
        jmp .nb330_end

.nb330_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb330_nouter]
	mov [rsp + nb330_nouter], ebx

.nb330_outer:
	mov   rax, [rsp + nb330_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax + rsi*4]		;# ebx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb330_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb330_shiftvec]   ;# rax = base of shiftvec[] 

	movss xmm0, [rax + rbx*4]
	movss xmm1, [rax + rbx*4 + 4]
	movss xmm2, [rax + rbx*4 + 8] 

	mov   rcx, [rsp + nb330_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx + rsi*4]	    ;# ebx =ii 

	mov   rdx, [rbp + nb330_charge]
	movss xmm3, [rdx + rbx*4]	
	mulss xmm3, [rsp + nb330_facel]
	shufps xmm3, xmm3, 0

    	mov   rdx, [rbp + nb330_type] 
    	mov   edx, [rdx + rbx*4]
    	imul  edx, [rsp + nb330_ntype]
    	shl   edx, 1
    	mov   [rsp + nb330_ntia], edx
	
	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb330_pos]    ;# rax = base of pos[]  

	addss xmm0, [rax + rbx*4]
	addss xmm1, [rax + rbx*4 + 4]
	addss xmm2, [rax + rbx*4 + 8]

	movaps [rsp + nb330_iq], xmm3
	
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0

	movaps [rsp + nb330_ix], xmm0
	movaps [rsp + nb330_iy], xmm1
	movaps [rsp + nb330_iz], xmm2

	mov   [rsp + nb330_ii3], ebx
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [rsp + nb330_vctot], xmm4
	movaps [rsp + nb330_Vvdwtot], xmm4
	movaps [rsp + nb330_fix], xmm4
	movaps [rsp + nb330_fiy], xmm4
	movaps [rsp + nb330_fiz], xmm4
	
	mov   rax, [rsp + nb330_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

        mov esi, [rsp + nb330_charge]
        mov edi, [rsp + nb330_ntia]

	mov   rsi, [rbp + nb330_pos]
	mov   rdi, [rbp + nb330_faction]	
	mov   rax, [rsp + nb330_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb330_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [rsp + nb330_ninner]
	mov   [rsp + nb330_ninner], ecx
	add   edx, 0
	mov   [rsp + nb330_innerk], edx    ;# number of innerloop atoms 
	jge   .nb330_unroll_loop
	jmp   .nb330_finish_inner
.nb330_unroll_loop:	
	;# quad-unroll innerloop here 
	mov   rdx, [rsp + nb330_innerjjnr]     ;# pointer to jjnr[k] 
	mov   r12d, [rdx]	
	mov   r13d, [rdx + 4]              
	mov   r14d, [rdx + 8]            
	mov   r15d, [rdx + 12]         ;# eax-edx=jnr1-4 
	add qword ptr [rsp + nb330_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	lea   rax, [r12 + r12*2]     ;# replace jnr with j3 
	lea   rbx, [r13 + r13*2]	
	lea   rcx, [r14 + r14*2]    
	lea   rdx, [r15 + r15*2]	

	mov rdi, [rbp + nb330_pos]
	;# load coordinates
	movlps xmm1, [rdi + rax*4]	;# x1 y1 - - 
	movlps xmm2, [rdi + rcx*4]	;# x3 y3 - - 
	movhps xmm1, [rdi + rbx*4]	;# x2 y2 - -
	movhps xmm2, [rdi + rdx*4]	;# x4 y4 - -

	movss xmm5, [rdi + rax*4 + 8]	;# z1 - - - 
	movss xmm6, [rdi + rcx*4 + 8]	;# z2 - - - 
	movss xmm7, [rdi + rbx*4 + 8]	;# z3 - - - 
	movss xmm8, [rdi + rdx*4 + 8]	;# z4 - - - 
    movlhps xmm5, xmm7 ;# jzOa  -  jzOb  -
    movlhps xmm6, xmm8 ;# jzOc  -  jzOd -

    movaps xmm4, xmm1
    unpcklps xmm1, xmm2  ;# jxa jxc jya jyc        
    unpckhps xmm4, xmm2  ;# jxb jxd jyb jyd
    movaps xmm2, xmm1
    unpcklps xmm1, xmm4 ;# x
    unpckhps xmm2, xmm4 ;# y
    shufps   xmm5, xmm6,  136  ;# 10001000 => jzH2a jzH2b jzH2c jzH2d
	mov rsi, [rbp + nb330_charge]

	;# calc dr  
	subps xmm1, [rsp + nb330_ix]
	subps xmm2, [rsp + nb330_iy]
	subps xmm5, [rsp + nb330_iz]

	;# store dr
    movaps [rsp + nb330_dx], xmm1
    movaps [rsp + nb330_dy], xmm2
    movaps [rsp + nb330_dz], xmm5
    
	movss xmm0, [rsi + r12*4]
	movss xmm3, [rsi + r14*4]
	movss xmm4, [rsi + r13*4]
	movss xmm6, [rsi + r15*4]
    
	;# square it 
	mulps xmm1,xmm1
	mulps xmm2,xmm2
	mulps xmm5,xmm5
	addps xmm1, xmm2
	addps xmm1, xmm5
	;# rsq in xmm1

    unpcklps xmm0, xmm3  ;# jqa jqc - -
    unpcklps xmm4, xmm6  ;# jqb jqd - -
    unpcklps xmm0, xmm4  ;# jqa jqb jqc jqd
	mulps xmm0, [rsp + nb330_iq] 
    movaps [rsp + nb330_qq], xmm0

	mov rsi, [rbp + nb330_type]
    ;# calculate rinv=1/sqrt(rsq)
	rsqrtps xmm5, xmm1
	movaps xmm12, xmm5
	mulps xmm5, xmm5
	movaps xmm4, [rsp + nb330_three]
	mulps xmm5, xmm1	;# rsq*lu*lu 	
    subps xmm4, xmm5	;# 30-rsq*lu*lu 
	mulps xmm4, xmm12	
	mulps xmm4, [rsp + nb330_half]	
	movaps xmm15, xmm4
	mulps  xmm1, xmm4	
    ;# xmm15=rinv
    ;# xmm1=r

    ;# vdw parameters
	mov r12d, [rsi + r12*4]
	mov r13d, [rsi + r13*4]
	mov r14d, [rsi + r14*4]
	mov r15d, [rsi + r15*4]
 
    mulps xmm1, [rsp + nb330_tsc] ;# rtab

    ;# truncate and convert to integers
    cvttps2dq xmm5, xmm1
    
	shl r12d, 1	
	shl r13d, 1	
	shl r14d, 1	
	shl r15d, 1	
    mov edi, [rsp + nb330_ntia]

    ;# convert back to float
    cvtdq2ps  xmm4, xmm5
    
    ;# multiply by 4
    pslld   xmm5, 2

    ;# multiply by three (copy, mult. by two, add back)
    movaps  xmm6, xmm5
    pslld   xmm5, 1
    paddd   xmm5, xmm6

    ;# calculate eps
    subps     xmm1, xmm4

	add r12d, edi
	add r13d, edi
	add r14d, edi
	add r15d, edi

    ;# move to integer registers
    movhlps xmm6, xmm5
    movd    r8d, xmm5
    movd    r10d, xmm6
    pshufd  xmm5, xmm5, 1
    pshufd  xmm6, xmm6, 1
    movd    r9d, xmm5
    movd    r11d, xmm6

	mov rsi, [rbp + nb330_vdwparam]
	movlps xmm3, [rsi + r12*4]
	movlps xmm7, [rsi + r14*4]
	movhps xmm3, [rsi + r13*4]
	movhps xmm7, [rsi + r15*4]

	movaps xmm0, xmm3
	shufps xmm0, xmm7, 136  ;# 10001000
	shufps xmm3, xmm7, 221  ;# 11011101

    movaps [rsp + nb330_c6], xmm0
    movaps [rsp + nb330_c12], xmm3

    movaps [rsp + nb330_eps], xmm1
    ;# xmm15=rinv
    
	mov rsi, [rbp + nb330_VFtab]
    ;# load Coulomb and LJ table data in parallel
   	movlps xmm1, [rsi + r8*4]        ;# Y1c F1c 
   	movlps xmm5, [rsi + r8*4 + 16]   ;# Y1d F1d 
   	movlps xmm9, [rsi + r8*4 + 32]   ;# Y1r F1r 

	movlps xmm3, [rsi + r10*4]       ;# Y3c F3c 
	movlps xmm7, [rsi + r10*4 + 16]  ;# Y3d F3d 
	movlps xmm11, [rsi + r10*4 + 32] ;# Y3r F3r 

	movhps xmm1, [rsi + r9*4]        ;# Y1c F1c Y2c F2c
	movhps xmm5, [rsi + r9*4 + 16]   ;# Y1d F1d Y2d F2d
	movhps xmm9, [rsi + r9*4 + 32]   ;# Y1r F1r Y2r F2r

	movhps xmm3, [rsi + r11*4]       ;# Y3c F3c Y4c F4c
	movhps xmm7, [rsi + r11*4 + 16]  ;# Y3d F3d Y4d F4d
	movhps xmm11, [rsi + r11*4 + 32] ;# Y3r F3r Y4r F4r

    movaps xmm0, xmm1
    movaps xmm4, xmm5
    movaps xmm8, xmm9
	shufps xmm0, xmm3, 136  ;# 10001000   => Y1c Y2c Y3c Y4c
	shufps xmm4, xmm7, 136  ;# 10001000   => Y1d Y2d Y3d Y4d
	shufps xmm8, xmm11, 136  ;# 10001000  => Y1r Y2r Y3r Y4r
	shufps xmm1, xmm3, 221  ;# 11011101   => F1c F2c F3c F4c
	shufps xmm5, xmm7, 221  ;# 11011101   => F1d F2d F3d F4d
	shufps xmm9, xmm11, 221  ;# 11011101  => F1r F2r F3r F4r
    
   	movlps xmm3, [rsi + r8*4 + 8]     ;# G1c H1c 
   	movlps xmm7, [rsi + r8*4 + 24]    ;# G1d H1d 
   	movlps xmm11, [rsi + r8*4 + 40]   ;# G1r H1r 

	movlps xmm12, [rsi + r10*4 + 8]   ;# G3c H3c 
	movlps xmm13, [rsi + r10*4 + 24]  ;# G3d H3d 
	movlps xmm14, [rsi + r10*4 + 40]  ;# G3r H3r 

	movhps xmm3, [rsi + r9*4 + 8]     ;# G1c H1c G2c H2c
	movhps xmm7, [rsi + r9*4 + 24]    ;# G1d H1d G2d H2d
	movhps xmm11, [rsi + r9*4 + 40]   ;# G1r H1r G2r H2r

	movhps xmm12, [rsi + r11*4 + 8]   ;# G3c H3c G4c H4c
	movhps xmm13, [rsi + r11*4 + 24]  ;# G3d H3d G4d H4d
	movhps xmm14, [rsi + r11*4 + 40]  ;# G3r H3r G4r H4r


    movaps xmm2, xmm3
    movaps xmm6, xmm7
    movaps xmm10, xmm11
    
	shufps xmm2, xmm12, 136  ;# 10001000  => G1c G2c G3c G4c
	shufps xmm6, xmm13, 136  ;# 10001000  => G1d G2d G3d G4d
	shufps xmm10, xmm14, 136  ;# 10001000 => G1r G2r G3r G4r
	shufps xmm3, xmm12, 221  ;# 11011101  => H1c H2c H3c H4c
	shufps xmm7, xmm13, 221  ;# 11011101  => H1d H2d H3d H4d
	shufps xmm11, xmm14, 221  ;# 11011101 => H1r H2r H3r H4r
    ;# table data ready. Coul in xmm0-xmm3 , disp in xmm4-xmm7 , rep. in xmm8-xmm11

    movaps xmm12, [rsp + nb330_eps]
    
    mulps  xmm3, xmm12   ;# Heps
    mulps  xmm7, xmm12
    mulps  xmm11, xmm12
    mulps  xmm2, xmm12     ;# Geps
    mulps  xmm6, xmm12
    mulps  xmm10, xmm12
    mulps  xmm3, xmm12   ;# Heps2
    mulps  xmm7, xmm12
    mulps  xmm11, xmm12

    addps  xmm1, xmm2   ;# F+Geps
    addps  xmm5, xmm6
    addps  xmm9, xmm10 
    addps  xmm1, xmm3   ;# F+Geps+Heps2 = Fp
    addps  xmm5, xmm7
    addps  xmm9, xmm11 
    addps  xmm3, xmm3    ;# 2*Heps2
    addps  xmm7, xmm7
    addps  xmm11, xmm11
    addps  xmm3, xmm2    ;# 2*Heps2+Geps
    addps  xmm7, xmm6  
    addps  xmm11, xmm10
    addps  xmm3, xmm1   ;# FF = Fp + 2*Heps2 + Geps
    addps  xmm7, xmm5
    addps  xmm11, xmm9
    mulps  xmm1, xmm12   ;# eps*Fp
    mulps  xmm5, xmm12
    mulps  xmm9, xmm12
    addps  xmm1, xmm0     ;# VV
    addps  xmm5, xmm4
    addps  xmm9, xmm8
    mulps  xmm1, [rsp + nb330_qq]   ;# VV*qq = vcoul
    mulps  xmm5, [rsp + nb330_c6]   ;# vnb6
    mulps  xmm9, [rsp + nb330_c12]   ;# vnb12