nb_kernel133_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,130 行 · 第 1/5 页

    ## xmm0 = jx
    ## xmm1 = jy
    ## xmm2 = jz

    ## O interaction
    ## copy to xmm3-xmm5
    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5

    subps nb133_ixO(%rsp),%xmm3
    subps nb133_iyO(%rsp),%xmm4
    subps nb133_izO(%rsp),%xmm5

    movaps %xmm3,nb133_dxO(%rsp)
    movaps %xmm4,nb133_dyO(%rsp)
    movaps %xmm5,nb133_dzO(%rsp)

        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5

        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    ## xmm3=rsq

    ## calculate rinv=1/sqrt(rsq)
        rsqrtps %xmm3,%xmm5
        movaps %xmm5,%xmm15
        mulps %xmm5,%xmm5
        movaps nb133_three(%rsp),%xmm4
        mulps %xmm3,%xmm5       ## rsq*lu*lu    
    subps %xmm5,%xmm4   ## 30-rsq*lu*lu 
        mulps %xmm15,%xmm4
        mulps nb133_half(%rsp),%xmm4
        movaps %xmm4,%xmm15
        mulps  %xmm4,%xmm3
    ## xmm15=rinv
    ## xmm3=r

    mulps nb133_tsc(%rsp),%xmm3   ## rtab

    ## truncate and convert to integers
    cvttps2dq %xmm3,%xmm5

    ## convert back to float
    cvtdq2ps  %xmm5,%xmm4

    ## multiply by 8
    pslld   $3,%xmm5

    ## calculate eps
    subps     %xmm4,%xmm3   ## xmm3=eps

    ## move to integer registers
    movhlps %xmm5,%xmm6
    movd    %xmm5,%r8d
    movd    %xmm6,%r10d
    pshufd $1,%xmm5,%xmm5
    pshufd $1,%xmm6,%xmm6
    movd    %xmm5,%r9d
    movd    %xmm6,%r11d
    ## xmm3=eps
    ## xmm15=rinv

        movq nb133_VFtab(%rbp),%rsi
    ## calculate LJ table
    movlps (%rsi,%r8,4),%xmm5
        movlps 16(%rsi,%r8,4),%xmm9

        movlps (%rsi,%r10,4),%xmm7
        movlps 16(%rsi,%r10,4),%xmm11

        movhps (%rsi,%r9,4),%xmm5
        movhps 16(%rsi,%r9,4),%xmm9

        movhps (%rsi,%r11,4),%xmm7
        movhps 16(%rsi,%r11,4),%xmm11

    movaps %xmm5,%xmm4
    movaps %xmm9,%xmm8
        shufps $136,%xmm7,%xmm4 ## 10001000
        shufps $136,%xmm11,%xmm8 ## 10001000
        shufps $221,%xmm7,%xmm5 ## 11011101
        shufps $221,%xmm11,%xmm9 ## 11011101

        movlps 8(%rsi,%r8,4),%xmm7
        movlps 24(%rsi,%r8,4),%xmm11

        movlps 8(%rsi,%r10,4),%xmm13
        movlps 24(%rsi,%r10,4),%xmm14

        movhps 8(%rsi,%r9,4),%xmm7
        movhps 24(%rsi,%r9,4),%xmm11

        movhps 8(%rsi,%r11,4),%xmm13
        movhps 24(%rsi,%r11,4),%xmm14

    movaps %xmm7,%xmm6
    movaps %xmm11,%xmm10

        shufps $136,%xmm13,%xmm6 ## 10001000
        shufps $136,%xmm14,%xmm10 ## 10001000
        shufps $221,%xmm13,%xmm7 ## 11011101
        shufps $221,%xmm14,%xmm11 ## 11011101
    ## dispersion table in xmm4-xmm7, repulsion table in xmm8-xmm11

    mulps  %xmm3,%xmm7   ## Heps
    mulps  %xmm3,%xmm11
    mulps  %xmm3,%xmm6  ## Geps
    mulps  %xmm3,%xmm10
    mulps  %xmm3,%xmm7  ## Heps2
    mulps  %xmm3,%xmm11
    addps  %xmm6,%xmm5 ## F+Geps
    addps  %xmm10,%xmm9
    addps  %xmm7,%xmm5  ## F+Geps+Heps2 = Fp
    addps  %xmm11,%xmm9
    addps  %xmm7,%xmm7   ## 2*Heps2
    addps  %xmm11,%xmm11
    addps  %xmm6,%xmm7  ## 2*Heps2+Geps
    addps  %xmm10,%xmm11

    addps  %xmm5,%xmm7 ## FF = Fp + 2*Heps2 + Geps
    addps  %xmm9,%xmm11
    mulps  %xmm3,%xmm5 ## eps*Fp
    mulps  %xmm3,%xmm9
    movaps nb133_c6(%rsp),%xmm12
    movaps nb133_c12(%rsp),%xmm13
    addps  %xmm4,%xmm5 ## VV
    addps  %xmm8,%xmm9

    mulps  %xmm12,%xmm5 ## VV*c6 = vnb6
    mulps  %xmm13,%xmm9 ## VV*c12 = vnb12
    addps  %xmm9,%xmm5
    addps  nb133_Vvdwtot(%rsp),%xmm5
    movaps %xmm5,nb133_Vvdwtot(%rsp)

    mulps  %xmm12,%xmm7  ## FF*c6 = fnb6
    mulps  %xmm13,%xmm11  ## FF*c12  = fnb12
    addps  %xmm11,%xmm7

    mulps  nb133_tsc(%rsp),%xmm7
    mulps  %xmm15,%xmm7  ## -fscal
    xorps  %xmm9,%xmm9

    subps  %xmm7,%xmm9    ## fscal
    movaps %xmm9,%xmm10
    movaps %xmm9,%xmm11

    mulps  nb133_dxO(%rsp),%xmm9    ## fx/fy/fz
    mulps  nb133_dyO(%rsp),%xmm10
    mulps  nb133_dzO(%rsp),%xmm11

    ## save j force temporarily
    movaps %xmm9,nb133_fjx(%rsp)
    movaps %xmm10,nb133_fjy(%rsp)
    movaps %xmm11,nb133_fjz(%rsp)

    ## increment i O force
    addps nb133_fixO(%rsp),%xmm9
    addps nb133_fiyO(%rsp),%xmm10
    addps nb133_fizO(%rsp),%xmm11
    movaps %xmm9,nb133_fixO(%rsp)
    movaps %xmm10,nb133_fiyO(%rsp)
    movaps %xmm11,nb133_fizO(%rsp)
    ## finished O LJ interaction.

    ## do H1, H2, and M interactions in parallel.
    ## xmm0-xmm2 still contain j coordinates.        
    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8

    subps nb133_ixH1(%rsp),%xmm0
    subps nb133_iyH1(%rsp),%xmm1
    subps nb133_izH1(%rsp),%xmm2
    subps nb133_ixH2(%rsp),%xmm3
    subps nb133_iyH2(%rsp),%xmm4
    subps nb133_izH2(%rsp),%xmm5
    subps nb133_ixM(%rsp),%xmm6
    subps nb133_iyM(%rsp),%xmm7
    subps nb133_izM(%rsp),%xmm8

        movaps %xmm0,nb133_dxH1(%rsp)
        movaps %xmm1,nb133_dyH1(%rsp)
        movaps %xmm2,nb133_dzH1(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb133_dxH2(%rsp)
        movaps %xmm4,nb133_dyH2(%rsp)
        movaps %xmm5,nb133_dzH2(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb133_dxM(%rsp)
        movaps %xmm7,nb133_dyM(%rsp)
        movaps %xmm8,nb133_dzM(%rsp)
        mulps  %xmm6,%xmm6
        mulps  %xmm7,%xmm7
        mulps  %xmm8,%xmm8
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    addps  %xmm7,%xmm6
    addps  %xmm8,%xmm6

        ## start doing invsqrt for j atoms
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm3,%xmm4
    rsqrtps %xmm6,%xmm7

        movaps  %xmm1,%xmm2
        movaps  %xmm4,%xmm5
    movaps  %xmm7,%xmm8

        mulps   %xmm1,%xmm1 ## lu*lu
        mulps   %xmm4,%xmm4 ## lu*lu
    mulps   %xmm7,%xmm7 ## lu*lu

        movaps  nb133_three(%rsp),%xmm9
        movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

        mulps   %xmm0,%xmm1 ## rsq*lu*lu
        mulps   %xmm3,%xmm4 ## rsq*lu*lu 
    mulps   %xmm6,%xmm7 ## rsq*lu*lu

        subps   %xmm1,%xmm9
        subps   %xmm4,%xmm10
    subps   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulps   %xmm2,%xmm9
        mulps   %xmm5,%xmm10
    mulps   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movaps  nb133_half(%rsp),%xmm0
        mulps   %xmm0,%xmm9 ## rinvH1
        mulps   %xmm0,%xmm10 ## rinvH2
    mulps   %xmm0,%xmm11 ## rinvM

        ## interactions 
    movaps %xmm9,%xmm0   ## rinv
    movaps %xmm10,%xmm1
    movaps %xmm11,%xmm2
    mulps  %xmm9,%xmm9   ## rinvsq
    mulps  %xmm10,%xmm10
    mulps  %xmm11,%xmm11
    mulps  nb133_qqH(%rsp),%xmm0
    mulps  nb133_qqH(%rsp),%xmm1
    mulps  nb133_qqM(%rsp),%xmm2
    mulps  %xmm0,%xmm9
    mulps  %xmm1,%xmm10
    mulps  %xmm2,%xmm11

    addps nb133_vctot(%rsp),%xmm0
    addps %xmm2,%xmm1
    addps %xmm1,%xmm0
    movaps %xmm0,nb133_vctot(%rsp)

        ## move j forces to local temp variables 
        movq nb133_faction(%rbp),%rdi
    movlps (%rdi,%rax,4),%xmm0 ## jxa jya  -   -
    movlps (%rdi,%rcx,4),%xmm1 ## jxc jyc  -   -
    movhps (%rdi,%rbx,4),%xmm0 ## jxa jya jxb jyb 
    movhps (%rdi,%rdx,4),%xmm1 ## jxc jyc jxd jyd 

    movss  8(%rdi,%rax,4),%xmm2    ## jza  -  -  -
    movss  8(%rdi,%rcx,4),%xmm3    ## jzc  -  -  -
    movss  8(%rdi,%rbx,4),%xmm5    ## jzb  - - -
    movss  8(%rdi,%rdx,4),%xmm6    ## jzd - - -
    movlhps %xmm5,%xmm2
    movlhps %xmm6,%xmm3

    shufps $136,%xmm3,%xmm2 ## 10001000 => jza jzb jzc jzd

    ## xmm0: jxa jya jxb jyb 
    ## xmm1: jxc jyc jxd jyd
    ## xmm2: jza jzb jzc jzd

    movaps %xmm9,%xmm7
    movaps %xmm9,%xmm8
    movaps %xmm11,%xmm13
    movaps %xmm11,%xmm14
    movaps %xmm11,%xmm15
    movaps %xmm10,%xmm11
    movaps %xmm10,%xmm12

        mulps nb133_dxH1(%rsp),%xmm7
        mulps nb133_dyH1(%rsp),%xmm8
        mulps nb133_dzH1(%rsp),%xmm9
        mulps nb133_dxH2(%rsp),%xmm10
        mulps nb133_dyH2(%rsp),%xmm11
        mulps nb133_dzH2(%rsp),%xmm12
        mulps nb133_dxM(%rsp),%xmm13
        mulps nb133_dyM(%rsp),%xmm14
        mulps nb133_dzM(%rsp),%xmm15

    ## fetch forces from O interaction
    movaps nb133_fjx(%rsp),%xmm3
    movaps nb133_fjy(%rsp),%xmm4
    addps  nb133_fjz(%rsp),%xmm2

    addps %xmm7,%xmm3
    addps %xmm8,%xmm4
    addps %xmm9,%xmm2
    addps nb133_fixH1(%rsp),%xmm7
    addps nb133_fiyH1(%rsp),%xmm8
    addps nb133_fizH1(%rsp),%xmm9

    addps %xmm10,%xmm3
    addps %xmm11,%xmm4
    addps %xmm12,%xmm2
    addps nb133_fixH2(%rsp),%xmm10
    addps nb133_fiyH2(%rsp),%xmm11
    addps nb133_fizH2(%rsp),%xmm12

    addps %xmm13,%xmm3
    addps %xmm14,%xmm4
    addps %xmm15,%xmm2
    addps nb133_fixM(%rsp),%xmm13
    addps nb133_fiyM(%rsp),%xmm14
    addps nb133_fizM(%rsp),%xmm15

    movaps %xmm7,nb133_fixH1(%rsp)
    movaps %xmm8,nb133_fiyH1(%rsp)
    movaps %xmm9,nb133_fizH1(%rsp)
    movaps %xmm10,nb133_fixH2(%rsp)
    movaps %xmm11,nb133_fiyH2(%rsp)
    movaps %xmm12,nb133_fizH2(%rsp)
    movaps %xmm13,nb133_fixM(%rsp)
    movaps %xmm14,nb133_fiyM(%rsp)
    movaps %xmm15,nb133_fizM(%rsp)

    ## xmm3 = fjx , xmm4 = fjy  , xmm2=fjz, already updated.
    movaps %xmm3,%xmm5
    unpcklps %xmm4,%xmm3  ## fjx1 fjy1 fjx2 fjy2
    unpckhps %xmm4,%xmm5  ## fjx3 fjy3 fjx4 fjy4

    addps %xmm3,%xmm0
    addps %xmm5,%xmm1
    movhlps  %xmm2,%xmm3 ## fjzc fjzd

    movlps %xmm0,(%rdi,%rax,4)
    movhps %xmm0,(%rdi,%rbx,4)
    movlps %xmm1,(%rdi,%rcx,4)
    movhps %xmm1,(%rdi,%rdx,4)
    movss  %xmm2,8(%rdi,%rax,4)
    movss  %xmm3,8(%rdi,%rcx,4)
    shufps $1,%xmm2,%xmm2
    shufps $1,%xmm3,%xmm3
    movss  %xmm2,8(%rdi,%rbx,4)
    movss  %xmm3,8(%rdi,%rdx,4)

        ## should we do one more iteration? 
        subl $4,nb133_innerk(%rsp)
        jl    _nb_kernel133_x86_64_sse.nb133_odd_inner
        jmp   _nb_kernel133_x86_64_sse.nb133_unroll_loop
_nb_kernel133_x86_64_sse.nb133_odd_inner: 
        addl $4,nb133_innerk(%rsp)
        jnz   _nb_kernel133_x86_64_sse.nb133_odd_loop
        jmp   _nb_kernel133_x86_64_sse.nb133_updateouterdata
_nb_kernel133_x86_64_sse.nb133_odd_loop: 
        movq  nb133_innerjjnr(%rsp),%rdx        ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        addq $4,nb133_innerjjnr(%rsp)

        xorps %xmm4,%xmm4       ## clear reg.
        movss nb133_iqM(%rsp),%xmm4
        movq nb133_charge(%rbp),%rsi
        movhps nb133_iqH(%rsp),%xmm4    ## [qM  0  qH  qH] 
        shufps $41,%xmm4,%xmm4 ## [0 qH qH qM]

        movss (%rsi,%rax,4),%xmm3       ## charge in xmm3 
        shufps $0,%xmm3,%xmm3
        mulps %xmm4,%xmm3
        movaps %xmm3,nb133_qqM(%rsp)    ## use dummy qq for storage 

        xorps %xmm6,%xmm6
        movq nb133_type(%rbp),%rsi
        movl (%rsi,%rax,4),%ebx
        movq nb133_vdwparam(%rbp),%rsi
        shll %ebx
        addl nb133_ntia(%rsp),%ebx
        movlps (%rsi,%rbx,4),%xmm6
        movaps %xmm6,%xmm7
        shufps $252,%xmm6,%xmm6 ## constant 11111100
        shufps $253,%xmm7,%xmm7 ## constant 11111101
        movaps %xmm6,nb133_c6(%rsp)
        movaps %xmm7,nb133_c12(%rsp)

        movq nb133_pos(%rbp),%rsi
        lea (%rax,%rax,2),%rax

        movss nb133_ixO(%rsp),%xmm0
        movss nb133_iyO(%rsp),%xmm1
        movss nb133_izO(%rsp),%xmm2
        movss nb133_ixH1(%rsp),%xmm3
        movss nb133_iyH1(%rsp),%xmm4
        movss nb133_izH1(%rsp),%xmm5
        unpcklps nb133_ixH2(%rsp),%xmm0         ## ixO ixH2 - -
        unpcklps nb133_iyH2(%rsp),%xmm1         ## iyO iyH2 - -
        unpcklps nb133_izH2(%rsp),%xmm2         ## izO izH2 - -
        unpcklps nb133_ixM(%rsp),%xmm3          ## ixH1 ixM - -
        unpcklps nb133_iyM(%rsp),%xmm4          ## iyH1 iyM - -
        unpcklps nb133_izM(%rsp),%xmm5          ## izH1 izM - -
        unpcklps %xmm3,%xmm0    ## ixO ixH1 ixH2 ixM
        unpcklps %xmm4,%xmm1    ## same for y
        unpcklps %xmm5,%xmm2    ## same for z

        ## move j coords to xmm0-xmm2 
        movss (%rsi,%rax,4),%xmm3
        movss 4(%rsi,%rax,4),%xmm4
        movss 8(%rsi,%rax,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5

        subps %xmm0,%xmm3
        subps %xmm1,%xmm4
        subps %xmm2,%xmm5