nb_kernel111_x86_64_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,657 行 · 第 1/3 页

;#
;# $Id: nb_kernel111_x86_64_sse.intel_syntax.s,v 1.1.2.2 2006/09/22 08:32:48 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as



.globl nb_kernel111_x86_64_sse
.globl _nb_kernel111_x86_64_sse
nb_kernel111_x86_64_sse:	
_nb_kernel111_x86_64_sse:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb111_fshift,           16
.equiv          nb111_gid,              24
.equiv          nb111_pos,              32
.equiv          nb111_faction,          40
.equiv          nb111_charge,           48
.equiv          nb111_p_facel,          56
.equiv          nb111_argkrf,           64
.equiv          nb111_argcrf,           72
.equiv          nb111_Vc,               80
.equiv          nb111_type,             88
.equiv          nb111_p_ntype,          96
.equiv          nb111_vdwparam,         104
.equiv          nb111_Vvdw,             112
.equiv          nb111_p_tabscale,       120
.equiv          nb111_VFtab,            128
.equiv          nb111_invsqrta,         136
.equiv          nb111_dvda,             144
.equiv          nb111_p_gbtabscale,     152
.equiv          nb111_GBtab,            160
.equiv          nb111_p_nthreads,       168
.equiv          nb111_count,            176
.equiv          nb111_mtx,              184
.equiv          nb111_outeriter,        192
.equiv          nb111_inneriter,        200
.equiv          nb111_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb111_ixO,              0
.equiv          nb111_iyO,              16
.equiv          nb111_izO,              32
.equiv          nb111_ixH1,             48
.equiv          nb111_iyH1,             64
.equiv          nb111_izH1,             80
.equiv          nb111_ixH2,             96
.equiv          nb111_iyH2,             112
.equiv          nb111_izH2,             128
.equiv          nb111_iqO,              144
.equiv          nb111_iqH,              160
.equiv          nb111_dxO,              176
.equiv          nb111_dyO,              192
.equiv          nb111_dzO,              208
.equiv          nb111_dxH1,             224
.equiv          nb111_dyH1,             240
.equiv          nb111_dzH1,             256
.equiv          nb111_dxH2,             272
.equiv          nb111_dyH2,             288
.equiv          nb111_dzH2,             304
.equiv          nb111_qqO,              320
.equiv          nb111_qqH,              336
.equiv          nb111_c6,               352
.equiv          nb111_c12,              368
.equiv          nb111_six,              384
.equiv          nb111_twelve,           400
.equiv          nb111_vctot,            416
.equiv          nb111_Vvdwtot,          432
.equiv          nb111_fixO,             448
.equiv          nb111_fiyO,             464
.equiv          nb111_fizO,             480
.equiv          nb111_fixH1,            496
.equiv          nb111_fiyH1,            512
.equiv          nb111_fizH1,            528
.equiv          nb111_fixH2,            544
.equiv          nb111_fiyH2,            560
.equiv          nb111_fizH2,            576
.equiv          nb111_fjx,              592
.equiv          nb111_fjy,              608
.equiv          nb111_fjz,              624
.equiv          nb111_half,             640
.equiv          nb111_three,            656
.equiv          nb111_is3,              672
.equiv          nb111_ii3,              676
.equiv          nb111_nri,              692
.equiv          nb111_iinr,             700
.equiv          nb111_jindex,           708
.equiv          nb111_jjnr,             716
.equiv          nb111_shift,            724
.equiv          nb111_shiftvec,         732
.equiv          nb111_facel,            740
.equiv          nb111_innerjjnr,        748
.equiv          nb111_ntia,             756
.equiv          nb111_innerk,           760
.equiv          nb111_n,                764
.equiv          nb111_nn1,              768
.equiv          nb111_nouter,           772
.equiv          nb111_ninner,           776


	push rbp
	mov  rbp, rsp
	push rbx

	push r12
	push r13
	push r14
	push r15
	
	sub rsp, 792
	emms

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb111_nouter], eax
	mov [rsp + nb111_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb111_nri], edi
	mov [rsp + nb111_iinr], rsi
	mov [rsp + nb111_jindex], rdx
	mov [rsp + nb111_jjnr], rcx
	mov [rsp + nb111_shift], r8
	mov [rsp + nb111_shiftvec], r9
	mov rsi, [rbp + nb111_p_facel]
	movss xmm0, [rsi]
	movss [rsp + nb111_facel], xmm0


	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb111_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb111_charge]
	movss xmm3, [rdx + rbx*4]	
	movss xmm4, [rdx + rbx*4 + 4]	
	mov rsi, [rbp + nb111_p_facel]
	movss xmm0, [rsi]
	movss xmm5, [rsp + nb111_facel]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [rsp + nb111_iqO], xmm3
	movaps [rsp + nb111_iqH], xmm4
	
	mov   rdx, [rbp + nb111_type]
	mov   ecx, [rdx + rbx*4]
	shl   ecx, 1
	mov rdi, [rbp + nb111_p_ntype]
	imul  ecx, [rdi]      ;# rcx = ntia = 2*ntype*type[ii0] 
	mov   [rsp + nb111_ntia], ecx		

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# half in IEEE (hex)
	mov [rsp + nb111_half], eax
	movss xmm1, [rsp + nb111_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# one
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# two
	addps  xmm3, xmm2	;# three
	movaps xmm4, xmm3
	addps  xmm4, xmm4	;# six
	movaps xmm5, xmm4
	addps  xmm5, xmm5	;# twelve
	movaps [rsp + nb111_half],  xmm1
	movaps [rsp + nb111_three],  xmm3
	movaps [rsp + nb111_six],  xmm4
	movaps [rsp + nb111_twelve],  xmm5

.nb111_threadloop:
        mov   rsi, [rbp + nb111_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb111_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb111_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb111_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb111_n], eax
        mov [rsp + nb111_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb111_outerstart
        jmp .nb111_end

.nb111_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb111_nouter]
	mov [rsp + nb111_nouter], ebx

.nb111_outer:
	mov   rax, [rsp + nb111_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax + rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb111_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb111_shiftvec]   ;# rax = base of shiftvec[] 

	movss xmm0, [rax + rbx*4]
	movss xmm1, [rax + rbx*4 + 4]
	movss xmm2, [rax + rbx*4 + 8] 

	mov   rcx, [rsp + nb111_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx + rsi*4]	    ;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2

	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb111_pos]    ;# rax = base of pos[]  
	mov   [rsp + nb111_ii3], ebx

	addss xmm3, [rax + rbx*4]
	addss xmm4, [rax + rbx*4 + 4]
	addss xmm5, [rax + rbx*4 + 8]		
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [rsp + nb111_ixO], xmm3
	movaps [rsp + nb111_iyO], xmm4
	movaps [rsp + nb111_izO], xmm5

	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm0, [rax + rbx*4 + 12]
	addss xmm1, [rax + rbx*4 + 16]
	addss xmm2, [rax + rbx*4 + 20]		
	addss xmm3, [rax + rbx*4 + 24]
	addss xmm4, [rax + rbx*4 + 28]
	addss xmm5, [rax + rbx*4 + 32]		

	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [rsp + nb111_ixH1], xmm0
	movaps [rsp + nb111_iyH1], xmm1
	movaps [rsp + nb111_izH1], xmm2
	movaps [rsp + nb111_ixH2], xmm3
	movaps [rsp + nb111_iyH2], xmm4
	movaps [rsp + nb111_izH2], xmm5
	
	;# clear potentials and i forces 
	xorps xmm4, xmm4
	movaps [rsp + nb111_vctot], xmm4
	movaps [rsp + nb111_Vvdwtot], xmm4
	movaps [rsp + nb111_fixO], xmm4
	movaps [rsp + nb111_fiyO], xmm4
	movaps [rsp + nb111_fizO], xmm4
	movaps [rsp + nb111_fixH1], xmm4
	movaps [rsp + nb111_fiyH1], xmm4
	movaps [rsp + nb111_fizH1], xmm4
	movaps [rsp + nb111_fixH2], xmm4
	movaps [rsp + nb111_fiyH2], xmm4
	movaps [rsp + nb111_fizH2], xmm4
	
	mov   rax, [rsp + nb111_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb111_pos]
	mov   rdi, [rbp + nb111_faction]	
	mov   rax, [rsp + nb111_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb111_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [rsp + nb111_ninner]
	mov   [rsp + nb111_ninner], ecx
	add   edx, 0
	mov   [rsp + nb111_innerk], edx    ;# number of innerloop atoms 
	jge   .nb111_unroll_loop
	jmp   .nb111_odd_inner
.nb111_unroll_loop:
	;# quad-unroll innerloop here 
	mov   rdx, [rsp + nb111_innerjjnr]     ;# pointer to jjnr[k] 
	mov   r8d, [rdx]	
	mov   r9d, [rdx + 4]              
	mov   r10d, [rdx + 8]            
	mov   r11d, [rdx + 12]         ;# eax-edx=jnr1-4 

	add qword ptr [rsp + nb111_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov rsi, [rbp + nb111_pos]       ;# base of pos[] 

	lea   rax, [r8 + r8*2]     ;# replace jnr with j3 
	lea   rbx, [r9 + r9*2]	
	lea   rcx, [r10 + r10*2]     ;# replace jnr with j3 
	lea   rdx, [r11 + r11*2]	

	;# move four j coordinates to xmm0-xmm2 	
	movlps xmm4, [rsi + rax*4]
	movlps xmm5, [rsi + rcx*4]
	movss xmm2, [rsi + rax*4 + 8]
	movss xmm6, [rsi + rcx*4 + 8]

	movhps xmm4, [rsi + rbx*4]
	movhps xmm5, [rsi + rdx*4]

	movss xmm0, [rsi + rbx*4 + 8]
	movss xmm1, [rsi + rdx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# 10001000
	
	shufps xmm0, xmm5, 136  ;# 10001000
	shufps xmm1, xmm5, 221  ;# 11011101		

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
	mov rsi, [rbp + nb111_charge]    ;# base of charge[] 
        
    movaps xmm3, xmm0
    movaps xmm4, xmm1
    movaps xmm5, xmm2
    movaps xmm6, xmm0
    movaps xmm7, xmm1
    movaps xmm8, xmm2

    subps xmm0, [rsp + nb111_ixO]
    subps xmm1, [rsp + nb111_iyO]
    subps xmm2, [rsp + nb111_izO]
    subps xmm3, [rsp + nb111_ixH1]
    subps xmm4, [rsp + nb111_iyH1]
    subps xmm5, [rsp + nb111_izH1]
    subps xmm6, [rsp + nb111_ixH2]
    subps xmm7, [rsp + nb111_iyH2]
    subps xmm8, [rsp + nb111_izH2]
    
	movaps [rsp + nb111_dxO], xmm0
	movaps [rsp + nb111_dyO], xmm1
	movaps [rsp + nb111_dzO], xmm2
	mulps  xmm0, xmm0
	mulps  xmm1, xmm1
	mulps  xmm2, xmm2
	movaps [rsp + nb111_dxH1], xmm3
	movaps [rsp + nb111_dyH1], xmm4
	movaps [rsp + nb111_dzH1], xmm5
	mulps  xmm3, xmm3
	mulps  xmm4, xmm4
	mulps  xmm5, xmm5
	movaps [rsp + nb111_dxH2], xmm6
	movaps [rsp + nb111_dyH2], xmm7
	movaps [rsp + nb111_dzH2], xmm8
	mulps  xmm6, xmm6
	mulps  xmm7, xmm7
	mulps  xmm8, xmm8
	addps  xmm0, xmm1
	addps  xmm0, xmm2
	addps  xmm3, xmm4
	addps  xmm3, xmm5
    addps  xmm6, xmm7
    addps  xmm6, xmm8

	movss xmm9, [rsi + r8*4]
	movss xmm10, [rsi + r10*4]
	movss xmm11, [rsi + r9*4]
	movss xmm12, [rsi + r11*4]

    unpcklps xmm9, xmm10
    unpcklps xmm11, xmm12
    unpcklps xmm9, xmm11
	movaps xmm7, xmm9
	mulps  xmm9, [rsp + nb111_iqO]
	mulps  xmm7, [rsp + nb111_iqH]

	movaps  [rsp + nb111_qqO], xmm9
	movaps  [rsp + nb111_qqH], xmm7

	mov rsi, [rbp + nb111_type]
	mov r8d, [rsi + r8*4]
	mov r9d, [rsi + r9*4]
	mov r10d, [rsi + r10*4]
	mov r11d, [rsi + r11*4]

	;# start doing invsqrt 
	rsqrtps xmm1, xmm0
	rsqrtps xmm4, xmm3
    rsqrtps xmm7, xmm6
	
	movaps  xmm2, xmm1
	movaps  xmm5, xmm4
    movaps  xmm8, xmm7
    
	mulps   xmm1, xmm1 ;# lu*lu
	mulps   xmm4, xmm4 ;# lu*lu
    mulps   xmm7, xmm7 ;# lu*lu
		
	mov rsi, [rbp + nb111_vdwparam]
	shl r8d, 1	
	shl r9d, 1	
	shl r10d, 1	
	shl r11d, 1	

	movaps  xmm9, [rsp + nb111_three]
	movaps  xmm10, xmm9
    movaps  xmm11, xmm9

	mulps   xmm1, xmm0 ;# rsq*lu*lu
	mulps   xmm4, xmm3 ;# rsq*lu*lu 
    mulps   xmm7, xmm6 ;# rsq*lu*lu
	
	subps   xmm9, xmm1
	subps   xmm10, xmm4
    subps   xmm11, xmm7 ;# 3-rsq*lu*lu

	mov edi, [rsp + nb111_ntia]
	add r8d, edi
	add r9d, edi
	add r10d, edi
	add r11d, edi

	mulps   xmm9, xmm2
	mulps   xmm10, xmm5
    mulps   xmm11, xmm8 ;# lu*(3-rsq*lu*lu)

	movaps  xmm0, [rsp + nb111_half]
	mulps   xmm9, xmm0  ;# rinvO 
	mulps   xmm10, xmm0 ;# rinvH1
    mulps   xmm11, xmm0 ;# rinvH2
	
    movlps xmm3, [rsi + r8*4]
	movlps xmm2, [rsi + r10*4]
	movhps xmm3, [rsi + r9*4]
	movhps xmm2, [rsi + r11*4]

	movaps xmm5, xmm3
	shufps xmm3, xmm2, 136  ;# 10001000
	shufps xmm5, xmm2, 221  ;# 11011101

	;# interactions 
    movaps xmm0, xmm9
    movaps xmm1, xmm10
    movaps xmm2, xmm11
    mulps  xmm9, xmm9    ;# rinvsq
    mulps  xmm10, xmm10
    mulps  xmm11, xmm11
    movaps xmm12, xmm9
    mulps  xmm12, xmm12 ;# rinv4
    mulps  xmm12, xmm9  ;# rinv6
    mulps  xmm0, [rsp + nb111_qqO] 
    mulps  xmm1, [rsp + nb111_qqH] 
    mulps  xmm2, [rsp + nb111_qqH] 
    movaps xmm13, xmm12 ;# rinv6
    mulps xmm12, xmm12 ;# rinv12
	mulps  xmm13, xmm3
	mulps  xmm12, xmm5
    movaps xmm14, xmm12
    subps  xmm14, xmm13
    
	addps  xmm14, [rsp + nb111_Vvdwtot]
	mulps  xmm13, [rsp + nb111_six]
	mulps  xmm12, [rsp + nb111_twelve]
	movaps [rsp + nb111_Vvdwtot], xmm14
    subps  xmm12, xmm13 ;# LJ fscal        

    addps  xmm12, xmm0
    
    mulps  xmm9, xmm12
    mulps  xmm10, xmm1
    mulps  xmm11, xmm2
    
    addps xmm0, [rsp + nb111_vctot] 
    addps xmm1, xmm2
    addps xmm0, xmm1
    movaps [rsp + nb111_vctot], xmm0
    
	mov   rdi, [rbp + nb111_faction]	
	;# move j  forces to local temp variables 
    movlps xmm0, [rdi + rax*4] ;# jxa jya  -   -
    movlps xmm1, [rdi + rcx*4] ;# jxc jyc  -   -
    movhps xmm0, [rdi + rbx*4] ;# jxa jya jxb jyb 
    movhps xmm1, [rdi + rdx*4] ;# jxc jyc jxd jyd 

    movss  xmm2, [rdi + rax*4 + 8] ;# jza  -  -  -
    movss  xmm3, [rdi + rcx*4 + 8] ;# jzc  -  -  -
    movss  xmm4, [rdi + rbx*4 + 8] ;# jzb
    movss  xmm5, [rdi + rdx*4 + 8] ;# jzd
    movlhps xmm2, xmm4 ;# jza  -  jzb  -
    movlhps xmm3, xmm5 ;# jzc  -  jzd -
    
    shufps xmm2, xmm3,  136  ;# 10001000 => jza jzb jzc jzd

    ;# xmm0: jxa jya jxb jyb 
    ;# xmm1: jxc jyc jxd jyd
    ;# xmm2: jza jzb jzc jzd