nb_kernel133_x86_64_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,156 行 · 第 1/4 页

;#
;# $Id: nb_kernel133_x86_64_sse.intel_syntax.s,v 1.1.2.2 2006/09/22 08:32:49 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as


	
.globl nb_kernel133_x86_64_sse
.globl _nb_kernel133_x86_64_sse
nb_kernel133_x86_64_sse:	
_nb_kernel133_x86_64_sse:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb133_fshift,           16
.equiv          nb133_gid,              24
.equiv          nb133_pos,              32
.equiv          nb133_faction,          40
.equiv          nb133_charge,           48
.equiv          nb133_p_facel,          56
.equiv          nb133_argkrf,           64
.equiv          nb133_argcrf,           72
.equiv          nb133_Vc,               80
.equiv          nb133_type,             88
.equiv          nb133_p_ntype,          96
.equiv          nb133_vdwparam,         104
.equiv          nb133_Vvdw,             112
.equiv          nb133_p_tabscale,       120
.equiv          nb133_VFtab,            128
.equiv          nb133_invsqrta,         136
.equiv          nb133_dvda,             144
.equiv          nb133_p_gbtabscale,     152
.equiv          nb133_GBtab,            160
.equiv          nb133_p_nthreads,       168
.equiv          nb133_count,            176
.equiv          nb133_mtx,              184
.equiv          nb133_outeriter,        192
.equiv          nb133_inneriter,        200
.equiv          nb133_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb133_ixO,              0
.equiv          nb133_iyO,              16
.equiv          nb133_izO,              32
.equiv          nb133_ixH1,             48
.equiv          nb133_iyH1,             64
.equiv          nb133_izH1,             80
.equiv          nb133_ixH2,             96
.equiv          nb133_iyH2,             112
.equiv          nb133_izH2,             128
.equiv          nb133_ixM,              144
.equiv          nb133_iyM,              160
.equiv          nb133_izM,              176
.equiv          nb133_iqM,              192
.equiv          nb133_iqH,              208
.equiv          nb133_dxO,              224
.equiv          nb133_dyO,              240
.equiv          nb133_dzO,              256
.equiv          nb133_dxH1,             272
.equiv          nb133_dyH1,             288
.equiv          nb133_dzH1,             304
.equiv          nb133_dxH2,             320
.equiv          nb133_dyH2,             336
.equiv          nb133_dzH2,             352
.equiv          nb133_dxM,              368
.equiv          nb133_dyM,              384
.equiv          nb133_dzM,              400
.equiv          nb133_qqM,              416
.equiv          nb133_qqH,              432
.equiv          nb133_rinvH1,           448
.equiv          nb133_rinvH2,           464
.equiv          nb133_rinvM,            480
.equiv          nb133_two,              496
.equiv          nb133_c6,               512
.equiv          nb133_c12,              528
.equiv          nb133_tsc,              544
.equiv          nb133_fstmp,            560
.equiv          nb133_krf,              576
.equiv          nb133_crf,              592
.equiv          nb133_krsqH1,           608
.equiv          nb133_krsqH2,           624
.equiv          nb133_krsqM,            640
.equiv          nb133_vctot,            656
.equiv          nb133_Vvdwtot,          672
.equiv          nb133_fixO,             688
.equiv          nb133_fiyO,             704
.equiv          nb133_fizO,             720
.equiv          nb133_fixH1,            736
.equiv          nb133_fiyH1,            752
.equiv          nb133_fizH1,            768
.equiv          nb133_fixH2,            784
.equiv          nb133_fiyH2,            800
.equiv          nb133_fizH2,            816
.equiv          nb133_fixM,             832
.equiv          nb133_fiyM,             848
.equiv          nb133_fizM,             864
.equiv          nb133_fjx,              880
.equiv          nb133_fjy,              896
.equiv          nb133_fjz,              912
.equiv          nb133_half,             928
.equiv          nb133_three,            944
.equiv          nb133_rsqOO,            960
.equiv          nb133_facel,            976
.equiv          nb133_iinr,             984
.equiv          nb133_jindex,           992
.equiv          nb133_jjnr,             1000
.equiv          nb133_shift,            1008
.equiv          nb133_shiftvec,         1016
.equiv          nb133_innerjjnr,        1024
.equiv          nb133_is3,              1032
.equiv          nb133_ii3,              1036
.equiv          nb133_nri,              1040
.equiv          nb133_ntia,             1044
.equiv          nb133_innerk,           1048
.equiv          nb133_n,                1052
.equiv          nb133_nn1,              1056
.equiv          nb133_nouter,           1060
.equiv          nb133_ninner,           1064
	
        push rbp
        mov  rbp, rsp
        push rbx
	
	
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 1080		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb133_nouter], eax
	mov [rsp + nb133_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb133_nri], edi
	mov [rsp + nb133_iinr], rsi
	mov [rsp + nb133_jindex], rdx
	mov [rsp + nb133_jjnr], rcx
	mov [rsp + nb133_shift], r8
	mov [rsp + nb133_shiftvec], r9
	mov rsi, [rbp + nb133_p_facel]
	movss xmm0, [rsi]
	movss [rsp + nb133_facel], xmm0

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# half in IEEE (hex)
	mov [rsp + nb133_half], eax
	movss xmm1, [rsp + nb133_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# one
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# two
	addps  xmm3, xmm2	;# three
	movaps [rsp + nb133_half],  xmm1
	movaps [rsp + nb133_two],  xmm2
	movaps [rsp + nb133_three],  xmm3
	
	mov rax, [rbp + nb133_p_tabscale]
	movss xmm3, [rax]
	shufps xmm3, xmm3, 0
	movaps [rsp + nb133_tsc], xmm3

	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb133_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb133_charge]
	movss xmm4, [rdx + rbx*4 + 4]	
	movss xmm3, [rdx + rbx*4 + 12]	
	mov rsi, [rbp + nb133_p_facel]
	movss xmm0, [rsi]
	movss xmm5, [rsp + nb133_facel]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [rsp + nb133_iqM], xmm3
	movaps [rsp + nb133_iqH], xmm4
	
	mov   rdx, [rbp + nb133_type]
	mov   ecx, [rdx + rbx*4]
	shl   ecx, 1
	mov rdi, [rbp + nb133_p_ntype]
	imul  ecx, [rdi]      ;# rcx = ntia = 2*ntype*type[ii0] 
	mov   [rsp + nb133_ntia], ecx		
.nb133_threadloop:
        mov   rsi, [rbp + nb133_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb133_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb133_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb133_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb133_n], eax
        mov [rsp + nb133_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb133_outerstart
        jmp .nb133_end
	
.nb133_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb133_nouter]
	mov [rsp + nb133_nouter], ebx

.nb133_outer:
	mov   rax, [rsp + nb133_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [rax + rsi*4]		;# ebx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]	;# rbx=3*is 
	mov   [rsp + nb133_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb133_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [rax + rbx*4]
	movss xmm1, [rax + rbx*4 + 4]
	movss xmm2, [rax + rbx*4 + 8] 

	mov   rcx, [rsp + nb133_iinr]   	;# ecx = pointer into iinr[] 	
	mov   ebx, [rcx + rsi*4]		;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2	
	movaps xmm6, xmm0
	movaps xmm7, xmm1
	
	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb133_pos]	;# eax = base of pos[]  
	mov   [rsp + nb133_ii3], ebx

	addss xmm3, [rax + rbx*4]  	;# ox
	addss xmm4, [rax + rbx*4 + 4]  ;# oy
	addss xmm5, [rax + rbx*4 + 8]  ;# oz
	addss xmm6, [rax + rbx*4 + 12] ;# h1x
	addss xmm7, [rax + rbx*4 + 16] ;# h1y
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	shufps xmm6, xmm6, 0
	shufps xmm7, xmm7, 0
	movaps [rsp + nb133_ixO], xmm3
	movaps [rsp + nb133_iyO], xmm4
	movaps [rsp + nb133_izO], xmm5
	movaps [rsp + nb133_ixH1], xmm6
	movaps [rsp + nb133_iyH1], xmm7

	movss xmm6, xmm2
	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm6, [rax + rbx*4 + 20] ;# h1z
	addss xmm0, [rax + rbx*4 + 24] ;# h2x
	addss xmm1, [rax + rbx*4 + 28] ;# h2y
	addss xmm2, [rax + rbx*4 + 32] ;# h2z
	addss xmm3, [rax + rbx*4 + 36] ;# mx
	addss xmm4, [rax + rbx*4 + 40] ;# my
	addss xmm5, [rax + rbx*4 + 44] ;# mz

	shufps xmm6, xmm6, 0
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [rsp + nb133_izH1], xmm6
	movaps [rsp + nb133_ixH2], xmm0
	movaps [rsp + nb133_iyH2], xmm1
	movaps [rsp + nb133_izH2], xmm2
	movaps [rsp + nb133_ixM], xmm3
	movaps [rsp + nb133_iyM], xmm4
	movaps [rsp + nb133_izM], xmm5
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [rsp + nb133_vctot], xmm4
	movaps [rsp + nb133_Vvdwtot], xmm4
	movaps [rsp + nb133_fixO], xmm4
	movaps [rsp + nb133_fiyO], xmm4
	movaps [rsp + nb133_fizO], xmm4
	movaps [rsp + nb133_fixH1], xmm4
	movaps [rsp + nb133_fiyH1], xmm4
	movaps [rsp + nb133_fizH1], xmm4
	movaps [rsp + nb133_fixH2], xmm4
	movaps [rsp + nb133_fiyH2], xmm4
	movaps [rsp + nb133_fizH2], xmm4
	movaps [rsp + nb133_fixM], xmm4
	movaps [rsp + nb133_fiyM], xmm4
	movaps [rsp + nb133_fizM], xmm4
	
	mov   rax, [rsp + nb133_jindex]
	mov   ecx, [rax + rsi*4]	 	;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	 	;# jindex[n+1] 
	sub   edx, ecx           	;# number of innerloop atoms 

	mov   rsi, [rbp + nb133_pos]
	mov   rdi, [rbp + nb133_faction]	
	mov   rax, [rsp + nb133_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb133_innerjjnr], rax 	;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [rsp + nb133_ninner]
	mov   [rsp + nb133_ninner], ecx
	add   edx, 0
	mov   [rsp + nb133_innerk], edx	;# number of innerloop atoms 
	jge   .nb133_unroll_loop
	jmp   .nb133_odd_inner
.nb133_unroll_loop:
	;# quad-unroll innerloop here 
	mov   rdx, [rsp + nb133_innerjjnr] 	;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]              
	mov   ecx, [rdx + 8]            
	mov   edx, [rdx + 12]     	;# eax-edx=jnr1-4 

	add qword ptr [rsp + nb133_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov rsi, [rbp + nb133_charge]	;# base of charge[] 
	
	movss xmm3, [rsi + rax*4]
	movss xmm4, [rsi + rcx*4]
	movss xmm6, [rsi + rbx*4]
	movss xmm7, [rsi + rdx*4]

	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	 	;# and in xmm4 
	mulps  xmm3, [rsp + nb133_iqM]
	mulps  xmm4, [rsp + nb133_iqH]

	movaps  [rsp + nb133_qqM], xmm3
	movaps  [rsp + nb133_qqH], xmm4
	
	mov rsi, [rbp + nb133_type]
	mov r8d, [rsi + rax*4]
	mov r9d, [rsi + rbx*4]
	mov r10d, [rsi + rcx*4]
	mov r11d, [rsi + rdx*4]
	mov rsi, [rbp + nb133_vdwparam]
	shl r8d, 1	
	shl r9d, 1	
	shl r10d, 1	
	shl r11d, 1	
	mov edi, [rsp + nb133_ntia]
	add r8d, edi
	add r9d, edi
	add r10d, edi
	add r11d, edi

	movlps xmm6, [rsi + r8*4]
	movlps xmm7, [rsi + r10*4]
	movhps xmm6, [rsi + r9*4]
	movhps xmm7, [rsi + r11*4]

	movaps xmm4, xmm6
	shufps xmm4, xmm7, 136  ;# constant 10001000
	shufps xmm6, xmm7, 221  ;# constant 11011101

	movaps [rsp + nb133_c6], xmm4
	movaps [rsp + nb133_c12], xmm6

	mov rsi, [rbp + nb133_pos]   	;# base of pos[] 

	lea   rax, [rax + rax*2] 	;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	
	lea   rcx, [rcx + rcx*2] 	;# replace jnr with j3 
	lea   rdx, [rdx + rdx*2]	

	;# move four coordinates to xmm0-xmm2 	
	movlps xmm4, [rsi + rax*4]
	movlps xmm5, [rsi + rcx*4]
	movss xmm2, [rsi + rax*4 + 8]
	movss xmm6, [rsi + rcx*4 + 8]

	movhps xmm4, [rsi + rbx*4]
	movhps xmm5, [rsi + rdx*4]

	movss xmm0, [rsi + rbx*4 + 8]
	movss xmm1, [rsi + rdx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# constant 10001000	
	shufps xmm0, xmm5, 136  ;# constant 10001000
	shufps xmm1, xmm5, 221  ;# constant 11011101		

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
    
    ;# O interaction
    ;# copy to xmm3-xmm5
    movaps xmm3, xmm0
    movaps xmm4, xmm1
    movaps xmm5, xmm2
    
    subps xmm3, [rsp + nb133_ixO]
    subps xmm4, [rsp + nb133_iyO]
    subps xmm5, [rsp + nb133_izO]
    
    movaps [rsp + nb133_dxO], xmm3
    movaps [rsp + nb133_dyO], xmm4
    movaps [rsp + nb133_dzO], xmm5
    
	mulps  xmm3, xmm3
	mulps  xmm4, xmm4
	mulps  xmm5, xmm5

	addps  xmm3, xmm4
	addps  xmm3, xmm5
    ;# xmm3=rsq
    
    ;# calculate rinv=1/sqrt(rsq)
	rsqrtps xmm5, xmm3
	movaps xmm15, xmm5
	mulps xmm5, xmm5
	movaps xmm4, [rsp + nb133_three]
	mulps xmm5, xmm3	;# rsq*lu*lu 	
    subps xmm4, xmm5	;# 30-rsq*lu*lu 
	mulps xmm4, xmm15	
	mulps xmm4, [rsp + nb133_half]	
	movaps xmm15, xmm4
	mulps  xmm3, xmm4	
    ;# xmm15=rinv
    ;# xmm3=r

    mulps xmm3, [rsp + nb133_tsc] ;# rtab

    ;# truncate and convert to integers
    cvttps2dq xmm5, xmm3
    
    ;# convert back to float
    cvtdq2ps  xmm4, xmm5
    
    ;# multiply by 8
    pslld   xmm5, 3

    ;# calculate eps
    subps     xmm3, xmm4    ;# xmm3=eps
    
    ;# move to integer registers
    movhlps xmm6, xmm5
    movd    r8d, xmm5
    movd    r10d, xmm6
    pshufd  xmm5, xmm5, 1
    pshufd  xmm6, xmm6, 1
    movd    r9d, xmm5
    movd    r11d, xmm6
    ;# xmm3=eps
    ;# xmm15=rinv

	mov rsi, [rbp + nb133_VFtab]
    ;# calculate LJ table
    movlps xmm5, [rsi + r8*4]
   	movlps xmm9, [rsi + r8*4 + 16]

	movlps xmm7,  [rsi + r10*4]
	movlps xmm11, [rsi + r10*4 + 16]

	movhps xmm5, [rsi + r9*4]
	movhps xmm9, [rsi + r9*4 + 16]

	movhps xmm7,  [rsi + r11*4]
	movhps xmm11, [rsi + r11*4 + 16]

    movaps xmm4, xmm5
    movaps xmm8, xmm9
	shufps xmm4, xmm7, 136  ;# 10001000
	shufps xmm8, xmm11, 136  ;# 10001000
	shufps xmm5, xmm7, 221  ;# 11011101
	shufps xmm9, xmm11, 221  ;# 11011101

	movlps xmm7,  [rsi + r8*4 + 8]
	movlps xmm11, [rsi + r8*4 + 24]