nb_kernel333_x86_64_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,385 行 · 第 1/5 页

	addss  xmm2, xmm5	;# xmm0-xmm2 has single force in pos0 

	;# increment i force 
	movss  xmm3, [rdi + rcx*4 + 24]
	movss  xmm4, [rdi + rcx*4 + 28]
	movss  xmm5, [rdi + rcx*4 + 32]
	subss  xmm3, xmm0
	subss  xmm4, xmm1
	subss  xmm5, xmm2
	movss  [rdi + rcx*4 + 24], xmm3
	movss  [rdi + rcx*4 + 28], xmm4
	movss  [rdi + rcx*4 + 32], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addss xmm7, xmm2
	movlhps xmm0, xmm1
	shufps  xmm0, xmm0, 8 ;# 00001000	
	addps   xmm6, xmm0

	;# accumulate Mi forces in xmm0, xmm1, xmm2 
	movaps xmm0, [rsp + nb333_fixM]
	movaps xmm1, [rsp + nb333_fiyM]
	movaps xmm2, [rsp + nb333_fizM]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addps  xmm0, xmm3
	addps  xmm1, xmm4
	addps  xmm2, xmm5 ;# sum is in 1/2 in xmm0-xmm2 

	movaps xmm3, xmm0	
	movaps xmm4, xmm1	
	movaps xmm5, xmm2	

	shufps xmm3, xmm3, 1
	shufps xmm4, xmm4, 1
	shufps xmm5, xmm5, 1
	addss  xmm0, xmm3
	addss  xmm1, xmm4
	addss  xmm2, xmm5	;# xmm0-xmm2 has single force in pos0 

	;# increment i force 
	movss  xmm3, [rdi + rcx*4 + 36]
	movss  xmm4, [rdi + rcx*4 + 40]
	movss  xmm5, [rdi + rcx*4 + 44]
	subss  xmm3, xmm0
	subss  xmm4, xmm1
	subss  xmm5, xmm2
	movss  [rdi + rcx*4 + 36], xmm3
	movss  [rdi + rcx*4 + 40], xmm4
	movss  [rdi + rcx*4 + 44], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addss xmm7, xmm2
	movlhps xmm0, xmm1
	shufps  xmm0, xmm0, 8 ;# 00001000	
	addps   xmm6, xmm0

	;# increment fshift force  
	movlps  xmm3, [rsi + rdx*4]
	movss  xmm4, [rsi + rdx*4 + 8]
	subps  xmm3, xmm6
	subss  xmm4, xmm7
	movlps  [rsi + rdx*4],    xmm3
	movss  [rsi + rdx*4 + 8], xmm4

	;# get n from stack
	mov esi, [rsp + nb333_n]
        ;# get group index for i particle 
        mov   rdx, [rbp + nb333_gid]      	;# base of gid[]
        mov   edx, [rdx + rsi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movaps xmm7, [rsp + nb333_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		
        
	;# add earlier value from mem 
	mov   rax, [rbp + nb333_Vc]
	addss xmm7, [rax + rdx*4] 
	;# move back to mem 
	movss [rax + rdx*4], xmm7 
	
	;# accumulate total lj energy and update it 
	movaps xmm7, [rsp + nb333_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		

	;# add earlier value from mem 
	mov   rax, [rbp + nb333_Vvdw]
	addss xmm7, [rax + rdx*4] 
	;# move back to mem 
	movss [rax + rdx*4], xmm7 
	
        ;# finish if last 
        mov ecx, [rsp + nb333_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb333_outerend

        ;# not last, iterate outer loop once more!  
        mov [rsp + nb333_n], esi
        jmp .nb333_outer
.nb333_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [rsp + nb333_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb333_end
        ;# non-zero, do one more workunit
        jmp   .nb333_threadloop
.nb333_end:
	mov eax, [rsp + nb333_nouter]
	mov ebx, [rsp + nb333_ninner]
	mov rcx, [rbp + nb333_outeriter]
	mov rdx, [rbp + nb333_inneriter]
	mov [rcx], eax
	mov [rdx], ebx

	add rsp, 1112
	emms


        pop r15
        pop r14
        pop r13
        pop r12

	pop rbx
	pop	rbp
	ret

	


.globl nb_kernel333nf_x86_64_sse
.globl _nb_kernel333nf_x86_64_sse
nb_kernel333nf_x86_64_sse:	
_nb_kernel333nf_x86_64_sse:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb333nf_fshift,         16
.equiv          nb333nf_gid,            24
.equiv          nb333nf_pos,            32
.equiv          nb333nf_faction,        40
.equiv          nb333nf_charge,         48
.equiv          nb333nf_p_facel,        56
.equiv          nb333nf_argkrf,         64
.equiv          nb333nf_argcrf,         72
.equiv          nb333nf_Vc,             80
.equiv          nb333nf_type,           88
.equiv          nb333nf_p_ntype,        96
.equiv          nb333nf_vdwparam,       104
.equiv          nb333nf_Vvdw,           112
.equiv          nb333nf_p_tabscale,     120
.equiv          nb333nf_VFtab,          128
.equiv          nb333nf_invsqrta,       136
.equiv          nb333nf_dvda,           144
.equiv          nb333nf_p_gbtabscale,   152
.equiv          nb333nf_GBtab,          160
.equiv          nb333nf_p_nthreads,     168
.equiv          nb333nf_count,          176
.equiv          nb333nf_mtx,            184
.equiv          nb333nf_outeriter,      192
.equiv          nb333nf_inneriter,      200
.equiv          nb333nf_work,           208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb333nf_ixO,            0
.equiv          nb333nf_iyO,            16
.equiv          nb333nf_izO,            32
.equiv          nb333nf_ixH1,           48
.equiv          nb333nf_iyH1,           64
.equiv          nb333nf_izH1,           80
.equiv          nb333nf_ixH2,           96
.equiv          nb333nf_iyH2,           112
.equiv          nb333nf_izH2,           128
.equiv          nb333nf_ixM,            144
.equiv          nb333nf_iyM,            160
.equiv          nb333nf_izM,            176
.equiv          nb333nf_iqM,            192
.equiv          nb333nf_iqH,            208
.equiv          nb333nf_qqM,            224
.equiv          nb333nf_qqH,            240
.equiv          nb333nf_rinvO,          256
.equiv          nb333nf_rinvH1,         272
.equiv          nb333nf_rinvH2,         288
.equiv          nb333nf_rinvM,          304
.equiv          nb333nf_rO,             320
.equiv          nb333nf_rH1,            336
.equiv          nb333nf_rH2,            352
.equiv          nb333nf_rM,             368
.equiv          nb333nf_tsc,            384
.equiv          nb333nf_c6,             400
.equiv          nb333nf_c12,            416
.equiv          nb333nf_vctot,          432
.equiv          nb333nf_Vvdwtot,        448
.equiv          nb333nf_half,           464
.equiv          nb333nf_three,          480
.equiv          nb333nf_is3,            496
.equiv          nb333nf_ii3,            500
.equiv          nb333nf_nri,            504
.equiv          nb333nf_iinr,           512
.equiv          nb333nf_jindex,         520
.equiv          nb333nf_jjnr,           528
.equiv          nb333nf_shift,          536
.equiv          nb333nf_shiftvec,       544
.equiv          nb333nf_facel,          552
.equiv          nb333nf_innerjjnr,      560
.equiv          nb333nf_ntia,           568
.equiv          nb333nf_innerk,         572
.equiv          nb333nf_n,              576
.equiv          nb333nf_nn1,            580
.equiv          nb333nf_nouter,         584
.equiv          nb333nf_ninner,         588
	push rbp
	mov  rbp, rsp
	push rbx

	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 600		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb333nf_nouter], eax
	mov [rsp + nb333nf_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb333nf_nri], edi
	mov [rsp + nb333nf_iinr], rsi
	mov [rsp + nb333nf_jindex], rdx
	mov [rsp + nb333nf_jjnr], rcx
	mov [rsp + nb333nf_shift], r8
	mov [rsp + nb333nf_shiftvec], r9
	mov rsi, [rbp + nb333nf_p_facel]
	movss xmm0, [rsi]
	movss [rsp + nb333nf_facel], xmm0

	mov rax, [rbp + nb333nf_p_tabscale]
	movss xmm3, [rax]
	shufps xmm3, xmm3, 0
	movaps [rsp + nb333nf_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# half in IEEE (hex)
	mov [rsp + nb333nf_half], eax
	movss xmm1, [rsp + nb333nf_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# one
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# two
	addps  xmm3, xmm2	;# three
	movaps [rsp + nb333nf_half],  xmm1
	movaps [rsp + nb333nf_three],  xmm3
	
	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb333nf_iinr]   	;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]		;# ebx =ii 

	mov   rdx, [rbp + nb333nf_charge]
	movss xmm4, [rdx + rbx*4 + 4]	
	movss xmm3, [rdx + rbx*4 + 12]	
	mov rsi, [rbp + nb333nf_p_facel]
	movss xmm0, [rsi]
	movss xmm5, [rsp + nb333nf_facel]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [rsp + nb333nf_iqM], xmm3
	movaps [rsp + nb333nf_iqH], xmm4
	
	mov   rdx, [rbp + nb333nf_type]
	mov   ecx, [rdx + rbx*4]
	shl   ecx, 1
	mov rdi, [rbp + nb333nf_p_ntype]
	imul  ecx, [rdi]  	;# rcx = ntia = 2*ntype*type[ii0] 
	mov   [rsp + nb333nf_ntia], ecx		

.nb333nf_threadloop:
        mov   rsi, [rbp + nb333nf_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb333nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb333nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb333nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb333nf_n], eax
        mov [rsp + nb333nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb333nf_outerstart
        jmp .nb333nf_end
	
.nb333nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb333nf_nouter]
	mov [rsp + nb333nf_nouter], ebx

.nb333nf_outer:
	mov   rax, [rsp + nb333nf_shift]  	;# rax = pointer into shift[] 
	mov   ebx, [rax + rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]	;# rbx=3*is 
	mov   [rsp + nb333nf_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb333nf_shiftvec]   ;# rax = base of shiftvec[] 

	movss xmm0, [rax + rbx*4]
	movss xmm1, [rax + rbx*4 + 4]
	movss xmm2, [rax + rbx*4 + 8] 

	mov   rcx, [rsp + nb333nf_iinr]   	;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx + rsi*4]		;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2	
	movaps xmm6, xmm0
	movaps xmm7, xmm1
	
	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb333nf_pos]	;# rax = base of pos[]  
	mov   [rsp + nb333nf_ii3], ebx

	addss xmm3, [rax + rbx*4]  	;# ox
	addss xmm4, [rax + rbx*4 + 4]  ;# oy
	addss xmm5, [rax + rbx*4 + 8]  ;# oz
	addss xmm6, [rax + rbx*4 + 12] ;# h1x
	addss xmm7, [rax + rbx*4 + 16] ;# h1y
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	shufps xmm6, xmm6, 0
	shufps xmm7, xmm7, 0
	movaps [rsp + nb333nf_ixO], xmm3
	movaps [rsp + nb333nf_iyO], xmm4
	movaps [rsp + nb333nf_izO], xmm5
	movaps [rsp + nb333nf_ixH1], xmm6
	movaps [rsp + nb333nf_iyH1], xmm7

	movss xmm6, xmm2
	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm6, [rax + rbx*4 + 20] ;# h1z
	addss xmm0, [rax + rbx*4 + 24] ;# h2x
	addss xmm1, [rax + rbx*4 + 28] ;# h2y
	addss xmm2, [rax + rbx*4 + 32] ;# h2z
	addss xmm3, [rax + rbx*4 + 36] ;# mx
	addss xmm4, [rax + rbx*4 + 40] ;# my
	addss xmm5, [rax + rbx*4 + 44] ;# mz

	shufps xmm6, xmm6, 0
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [rsp + nb333nf_izH1], xmm6
	movaps [rsp + nb333nf_ixH2], xmm0
	movaps [rsp + nb333nf_iyH2], xmm1
	movaps [rsp + nb333nf_izH2], xmm2
	movaps [rsp + nb333nf_ixM], xmm3
	movaps [rsp + nb333nf_iyM], xmm4
	movaps [rsp + nb333nf_izM], xmm5
	
	;# clear vctot 
	xorps xmm4, xmm4
	movaps [rsp + nb333nf_vctot], xmm4
	movaps [rsp + nb333nf_Vvdwtot], xmm4

	mov   rax, [rsp + nb333nf_jindex]
	mov   ecx, [rax + rsi*4]	 	;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	 	;# jindex[n+1] 
	sub   edx, ecx           	;# number of innerloop atoms 

	mov   rsi, [rbp + nb333nf_pos]
	mov   rdi, [rbp + nb333nf_faction]	
	mov   rax, [rsp + nb333nf_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb333nf_innerjjnr], rax 	;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [rsp + nb333nf_ninner]
	mov   [rsp + nb333nf_ninner], ecx
	add   edx, 0
	mov   [rsp + nb333nf_innerk], edx	;# number of innerloop atoms 
	jge   .nb333nf_unroll_loop
	jmp   .nb333nf_odd_inner
.nb333nf_unroll_loop:
	;# quad-unroll innerloop here 
	mov   rdx, [rsp + nb333nf_innerjjnr] 	;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]              
	mov   ecx, [rdx + 8]            
	mov   edx, [rdx + 12]     	;# eax-edx=jnr1-4
	
	add qword ptr [rsp + nb333nf_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov rsi, [rbp + nb333nf_charge]	;# base of charge[] 

	movss xmm3, [rsi + rax*4]
	movss xmm4, [rsi + rcx*4]
	movss xmm6, [rsi + rbx*4]
	movss xmm7, [rsi + rdx*4]
	
	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	 	;# and in xmm4 
	mulps  xmm3, [rsp + nb333nf_iqM]
	mulps  xmm4, [rsp + nb333nf_iqH]

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx
	movd  mm2, ecx
	movd  mm3, edx

	movaps  [rsp + nb333nf_qqM], xmm3
	movaps  [rsp + nb333nf_qqH], xmm4
	
	mov rsi, [rbp + nb333nf_type]
	mov eax, [rsi + rax*4]
	mov ebx, [rsi + rbx*4]
	mov ecx, [rsi + rcx*4]
	mov edx, [rsi + rdx*4]
	mov rsi, [rbp + nb333nf_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	shl ecx, 1	
	shl edx, 1	
	mov edi, [rsp + nb333nf_ntia]
	add eax, edi
	add ebx, edi
	add ecx, edi
	add edx, edi

	movlps xmm6, [rsi + rax*4]
	movlps xmm7, [rsi + rcx*4]
	movhps xmm6, [rsi + rbx*4]
	movhps xmm7, [rsi + rdx*4]

	movaps xmm4, xmm6
	shufps xmm4, xmm7, 136  ;# 10001000
	shufps xmm6, xmm7, 221  ;# 11011101