nb_kernel112_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,177 行 · 第 1/5 页

	;# H1-H2 interaction 
	movaps xmm0, [esp + nb112_rinvH1H2]
	movaps xmm1, xmm0
	mulps xmm0, xmm0
	mulps xmm1, [esp + nb112_qqHH]
	mulps xmm0, xmm1	;# fsOH2  
	addps xmm7, xmm1	;# add to local vctot 
	movaps xmm1, xmm0
	movaps xmm2, xmm0
	movaps xmm3, [esp + nb112_fjxH2]
	movaps xmm4, [esp + nb112_fjyH2]
	movaps xmm5, [esp + nb112_fjzH2]
	mulps xmm0, [esp + nb112_dxH1H2]
	mulps xmm1, [esp + nb112_dyH1H2]
	mulps xmm2, [esp + nb112_dzH1H2]
	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2
	addps xmm0, [esp + nb112_fixH1]
	addps xmm1, [esp + nb112_fiyH1]
	addps xmm2, [esp + nb112_fizH1]
	movaps [esp + nb112_fjxH2], xmm3
	movaps [esp + nb112_fjyH2], xmm4
	movaps [esp + nb112_fjzH2], xmm5
	movaps [esp + nb112_fixH1], xmm0
	movaps [esp + nb112_fiyH1], xmm1
	movaps [esp + nb112_fizH1], xmm2

	;# H2-O interaction 
	movaps xmm0, [esp + nb112_rinvH2O]
	movaps xmm1, xmm0
	mulps xmm0, xmm0
	mulps xmm1, [esp + nb112_qqOH]
	mulps xmm0, xmm1	;# fsH2O 
	addps xmm7, xmm1	;# add to local vctot 
	movaps xmm1, xmm0
	movaps xmm2, xmm0
	movaps xmm3, [esp + nb112_fjxO]
	movaps xmm4, [esp + nb112_fjyO]
	movaps xmm5, [esp + nb112_fjzO]
	mulps xmm0, [esp + nb112_dxH2O]
	mulps xmm1, [esp + nb112_dyH2O]
	mulps xmm2, [esp + nb112_dzH2O]
	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2
	addps xmm0, [esp + nb112_fixH2]
	addps xmm1, [esp + nb112_fiyH2]
	addps xmm2, [esp + nb112_fizH2]
	movaps [esp + nb112_fjxO], xmm3
	movaps [esp + nb112_fjyO], xmm4
	movaps [esp + nb112_fjzO], xmm5
	movaps [esp + nb112_fixH2], xmm0
	movaps [esp + nb112_fiyH2], xmm1
	movaps [esp + nb112_fizH2], xmm2

	;# H2-H1 interaction 
	movaps xmm0, [esp + nb112_rinvH2H1]
	movaps xmm1, xmm0
	mulps xmm0, xmm0
	mulps xmm1, [esp + nb112_qqHH]
	mulps xmm0, xmm1	;# fsH2H1 
	addps xmm7, xmm1	;# add to local vctot 
	movaps xmm1, xmm0
	movaps xmm2, xmm0
	movaps xmm3, [esp + nb112_fjxH1]
	movaps xmm4, [esp + nb112_fjyH1]
	movaps xmm5, [esp + nb112_fjzH1]
	mulps xmm0, [esp + nb112_dxH2H1]
	mulps xmm1, [esp + nb112_dyH2H1]
	mulps xmm2, [esp + nb112_dzH2H1]
	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2
	addps xmm0, [esp + nb112_fixH2]
	addps xmm1, [esp + nb112_fiyH2]
	addps xmm2, [esp + nb112_fizH2]
	movaps [esp + nb112_fjxH1], xmm3
	movaps [esp + nb112_fjyH1], xmm4
	movaps [esp + nb112_fjzH1], xmm5
	movaps [esp + nb112_fixH2], xmm0
	movaps [esp + nb112_fiyH2], xmm1
	movaps [esp + nb112_fizH2], xmm2

	;# H2-H2 interaction 
	movaps xmm0, [esp + nb112_rinvH2H2]
	movaps xmm1, xmm0
	mulps xmm0, xmm0
	mulps xmm1, [esp + nb112_qqHH]
	mulps xmm0, xmm1	;# fsH2H2 
	addps xmm7, xmm1	;# add to local vctot 
	movaps xmm1, xmm0
	movaps [esp + nb112_vctot], xmm7
	movaps xmm2, xmm0
	movaps xmm3, [esp + nb112_fjxH2]
	movaps xmm4, [esp + nb112_fjyH2]
	movaps xmm5, [esp + nb112_fjzH2]
	mulps xmm0, [esp + nb112_dxH2H2]
	mulps xmm1, [esp + nb112_dyH2H2]
	mulps xmm2, [esp + nb112_dzH2H2]
	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2
	addps xmm0, [esp + nb112_fixH2]
	addps xmm1, [esp + nb112_fiyH2]
	addps xmm2, [esp + nb112_fizH2]
	movaps [esp + nb112_fjxH2], xmm3
	movaps [esp + nb112_fjyH2], xmm4
	movaps [esp + nb112_fjzH2], xmm5
	movaps [esp + nb112_fixH2], xmm0
	movaps [esp + nb112_fiyH2], xmm1
	movaps [esp + nb112_fizH2], xmm2

	mov edi, [ebp + nb112_faction]
		
	;# Did all interactions - now update j forces 
	;# At this stage forces are still on the stack, in positions:
	;# fjxO, fjyO, fjzO, ... , fjzH2.
	;# Each position is a quadruplet of forces for the four 
	;# corresponding j waters, so we need to transpose them before
	;# adding to the memory positions.
	;# 
	;# This _used_ to be a simple transpose, but the resulting high number
	;# of unaligned 128-bit load/stores might trigger a possible hardware 
	;# bug on Athlon and Opteron chips, so I have worked around it
	;# to use 64-bit load/stores instead. The performance hit should be
	;# very modest, since the 128-bit unaligned memory instructions were
	;# slow anyway. 
	
		
	;# 4 j waters with three atoms each - first do Oxygen X & Y forces for 4 j particles 
	movaps xmm0, [esp + nb112_fjxO] ;# xmm0= fjxOa  fjxOb  fjxOc  fjxOd 
	movaps xmm2, [esp + nb112_fjyO] ;# xmm1= fjyOa  fjyOb  fjyOc  fjyOd
	movlps xmm3, [edi + eax*4]
	movlps xmm4, [edi + ecx*4]
	movaps xmm1, xmm0
	unpcklps xmm0, xmm2    	   ;# xmm0= fjxOa  fjyOa  fjxOb  fjyOb
	unpckhps xmm1, xmm2        ;# xmm1= fjxOc  fjyOc  fjxOd  fjyOd
	movhps xmm3, [edi + ebx*4]
	movhps xmm4, [edi + edx*4]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	movlps [edi + eax*4], xmm3
	movlps [edi + ecx*4], xmm4
	movhps [edi + ebx*4], xmm3
	movhps [edi + edx*4], xmm4
	
	;# Oxygen Z & first hydrogen X forces for 4 j particles 
	movaps xmm0, [esp + nb112_fjzO]  ;# xmm0= fjzOa   fjzOb   fjzOc   fjzOd 
	movaps xmm2, [esp + nb112_fjxH1] ;# xmm1= fjxH1a  fjxH1b  fjxH1c  fjxH1d
	movlps xmm3, [edi + eax*4 + 8]
	movlps xmm4, [edi + ecx*4 + 8]
	movaps xmm1, xmm0
	unpcklps xmm0, xmm2    	   ;# xmm0= fjzOa  fjxH1a  fjzOb  fjxH1b
	unpckhps xmm1, xmm2        ;# xmm1= fjzOc  fjxH1c  fjzOd  fjxH1d
	movhps xmm3, [edi + ebx*4 + 8]
	movhps xmm4, [edi + edx*4 + 8]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	movlps [edi + eax*4 + 8], xmm3
	movlps [edi + ecx*4 + 8], xmm4
	movhps [edi + ebx*4 + 8], xmm3
	movhps [edi + edx*4 + 8], xmm4

	
	;# First hydrogen Y & Z forces for 4 j particles 
	movaps xmm0, [esp + nb112_fjyH1]  ;# xmm0= fjyH1a  fjyH1b  fjyH1c  fjyH1d 
	movaps xmm2, [esp + nb112_fjzH1] ;# xmm1= fjzH1a  fjzH1b  fjzH1c  fjzH1d
	movlps xmm3, [edi + eax*4 + 16]
	movlps xmm4, [edi + ecx*4 + 16]
	movaps xmm1, xmm0
	unpcklps xmm0, xmm2		;# xmm0= fjyH1a  fjzH1a  fjyH1b  fjzH1b
	unpckhps xmm1, xmm2		;# xmm1= fjyH1c  fjzH1c  fjyH1d  fjzH1d
	movhps xmm3, [edi + ebx*4 + 16]
	movhps xmm4, [edi + edx*4 + 16]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	movlps [edi + eax*4 + 16], xmm3
	movlps [edi + ecx*4 + 16], xmm4
	movhps [edi + ebx*4 + 16], xmm3
	movhps [edi + edx*4 + 16], xmm4

	
	;# Second hydrogen X & Y forces for 4 j particles 
	movaps xmm0, [esp + nb112_fjxH2]  ;# xmm0= fjxH2a  fjxH2b  fjxH2c  fjxH2d 
	movaps xmm2, [esp + nb112_fjyH2] ;# xmm1= fjyH2a  fjyH2b  fjyH2c  fjyH2d
	movlps xmm3, [edi + eax*4 + 24]
	movlps xmm4, [edi + ecx*4 + 24]
	movaps xmm1, xmm0
	unpcklps xmm0, xmm2		;# xmm0= fjxH2a  fjyH2a  fjxH2b  fjyH2b
	unpckhps xmm1, xmm2		;# xmm1= fjxH2c  fjyH2c  fjxH2d  fjyH2d
	movhps xmm3, [edi + ebx*4 + 24]
	movhps xmm4, [edi + edx*4 + 24]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	movlps [edi + eax*4 + 24], xmm3
	movlps [edi + ecx*4 + 24], xmm4
	movhps [edi + ebx*4 + 24], xmm3
	movhps [edi + edx*4 + 24], xmm4

	
	;# Second hydrogen Z forces for 4 j particles 
	;# Just load the four Z coords into one reg. each
	movss xmm4, [edi + eax*4 + 32]
	movss xmm5, [edi + ebx*4 + 32]
	movss xmm6, [edi + ecx*4 + 32]
	movss xmm7, [edi + edx*4 + 32]
	;# add what we have on the stack
	addss xmm4, [esp + nb112_fjzH2] 
	addss xmm5, [esp + nb112_fjzH2b] 
	addss xmm6, [esp + nb112_fjzH2c] 
	addss xmm7, [esp + nb112_fjzH2d]
	;# store back
	movss [edi + eax*4 + 32], xmm4
	movss [edi + ebx*4 + 32], xmm5
	movss [edi + ecx*4 + 32], xmm6
	movss [edi + edx*4 + 32], xmm7
	
	;# should we do one more iteration? 
	sub dword ptr [esp + nb112_innerk],  4
	jl    .nb112_single_check
	jmp   .nb112_unroll_loop
.nb112_single_check:
	add dword ptr [esp + nb112_innerk],  4
	jnz   .nb112_single_loop
	jmp   .nb112_updateouterdata
.nb112_single_loop:
	mov   edx, [esp + nb112_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	add dword ptr [esp + nb112_innerjjnr],  4	

	mov esi, [ebp + nb112_pos]
	lea   eax, [eax + eax*2]  

	;# fetch j coordinates 
	xorps xmm3, xmm3
	xorps xmm4, xmm4
	xorps xmm5, xmm5
	
	movss xmm3, [esi + eax*4]		;# jxO  -  -  -
	movss xmm4, [esi + eax*4 + 4]		;# jyO  -  -  -
	movss xmm5, [esi + eax*4 + 8]		;# jzO  -  -  -  

	movlps xmm6, [esi + eax*4 + 12]		;# xmm6 = jxH1 jyH1   -    -
	movss  xmm7, [esi + eax*4 + 20]		;# xmm7 = jzH1   -    -    - 
	movhps xmm6, [esi + eax*4 + 24]		;# xmm6 = jxH1 jyH1 jxH2 jyH2
	movss  xmm2, [esi + eax*4 + 32]		;# xmm2 = jzH2   -    -    -
	
	;# have all coords, time for some shuffling.

	shufps xmm6, xmm6, 216 ;# constant 11011000	;# xmm6 = jxH1 jxH2 jyH1 jyH2 
	unpcklps xmm7, xmm2			;# xmm7 = jzH1 jzH2   -    -
	movaps  xmm0, [esp + nb112_ixO]     
	movaps  xmm1, [esp + nb112_iyO]
	movaps  xmm2, [esp + nb112_izO]	
	movlhps xmm3, xmm6			;# xmm3 = jxO   0   jxH1 jxH2 
	shufps  xmm4, xmm6, 228 ;# constant 11100100	;# xmm4 = jyO   0   jyH1 jyH2 
	shufps  xmm5, xmm7, 68  ;# constant 01000100	;# xmm5 = jzO   0   jzH1 jzH2
	
	;# store all j coordinates in jO  
	movaps [esp + nb112_jxO], xmm3
	movaps [esp + nb112_jyO], xmm4
	movaps [esp + nb112_jzO], xmm5
	subps  xmm0, xmm3
	subps  xmm1, xmm4
	subps  xmm2, xmm5
	movaps [esp + nb112_dxOO], xmm0
	movaps [esp + nb112_dyOO], xmm1
	movaps [esp + nb112_dzOO], xmm2
	mulps xmm0, xmm0
	mulps xmm1, xmm1
	mulps xmm2, xmm2
	addps xmm0, xmm1
	addps xmm0, xmm2	;# have rsq in xmm0 
	
	;# do invsqrt 
	rsqrtps xmm1, xmm0
	movaps  xmm2, xmm1	
	mulps   xmm1, xmm1
	movaps  xmm3, [esp + nb112_three]
	mulps   xmm1, xmm0
	subps   xmm3, xmm1
	mulps   xmm3, xmm2							
	mulps   xmm3, [esp + nb112_half] ;# rinv iO - j water 

	xorps   xmm1, xmm1
	movaps  xmm0, xmm3
	xorps   xmm4, xmm4
	mulps   xmm0, xmm0	;# xmm0=rinvsq 
	;# fetch charges to xmm4 (temporary) 
	movss   xmm4, [esp + nb112_qqOO]
	movss   xmm1, xmm0
	movhps  xmm4, [esp + nb112_qqOH]
	mulss   xmm1, xmm0
	mulps   xmm3, xmm4	;# xmm3=vcoul 
	mulss   xmm1, xmm0	;# xmm1(0)=rinvsix 
	movaps  xmm2, xmm1	;# zero everything else in xmm2 
	mulss   xmm2, xmm2	;# xmm2=rinvtwelve 

	mulss   xmm1, [esp + nb112_c6]
	mulss   xmm2, [esp + nb112_c12]
	movaps  xmm4, xmm2
	subss   xmm4, xmm1	;# Vvdwtot=Vvdw12-Vvdw6 
	addps   xmm4, [esp + nb112_Vvdwtot]
	mulss   xmm1, [esp + nb112_six]
	mulss   xmm2, [esp + nb112_twelve]	
	movaps  [esp + nb112_Vvdwtot], xmm4
	subss   xmm2, xmm1	;# fsD+ fsR 
	addps   xmm2, xmm3	;# fsC+ fsD+ fsR 

	addps   xmm3, [esp + nb112_vctot]
	mulps   xmm0, xmm2	;# total fscal 
	movaps  [esp + nb112_vctot], xmm3	

	movaps  xmm1, xmm0
	movaps  xmm2, xmm0
	mulps   xmm0, [esp + nb112_dxOO]
	mulps   xmm1, [esp + nb112_dyOO]
	mulps   xmm2, [esp + nb112_dzOO]
	;# initial update for j forces 
	xorps   xmm3, xmm3
	xorps   xmm4, xmm4
	xorps   xmm5, xmm5
	subps   xmm3, xmm0
	subps   xmm4, xmm1
	subps   xmm5, xmm2
	movaps  [esp + nb112_fjxO], xmm3
	movaps  [esp + nb112_fjyO], xmm4
	movaps  [esp + nb112_fjzO], xmm5
	addps   xmm0, [esp + nb112_fixO]
	addps   xmm1, [esp + nb112_fiyO]
	addps   xmm2, [esp + nb112_fizO]
	movaps  [esp + nb112_fixO], xmm0
	movaps  [esp + nb112_fiyO], xmm1
	movaps  [esp + nb112_fizO], xmm2

	
	;# done with i O Now do i H1 & H2 simultaneously first get i particle coords: 
	movaps  xmm0, [esp + nb112_ixH1]
	movaps  xmm1, [esp + nb112_iyH1]
	movaps  xmm2, [esp + nb112_izH1]	
	movaps  xmm3, [esp + nb112_ixH2] 
	movaps  xmm4, [esp + nb112_iyH2] 
	movaps  xmm5, [esp + nb112_izH2] 
	subps   xmm0, [esp + nb112_jxO]
	subps   xmm1, [esp + nb112_jyO]
	subps   xmm2, [esp + nb112_jzO]
	subps   xmm3, [esp + nb112_jxO]
	subps   xmm4, [esp + nb112_jyO]
	subps   xmm5, [esp + nb112_jzO]
	movaps [esp + nb112_dxH1O], xmm0
	movaps [esp + nb112_dyH1O], xmm1
	movaps [esp + nb112_dzH1O], xmm2
	movaps [esp + nb112_dxH2O], xmm3
	movaps [esp + nb112_dyH2O], xmm4
	movaps [esp + nb112_dzH2O], xmm5
	mulps xmm0, xmm0
	mulps xmm1, xmm1
	mulps xmm2, xmm2
	mulps xmm3, xmm3
	mulps xmm4, xmm4
	mulps xmm5, xmm5
	addps xmm0, xmm1
	addps xmm4, xmm3
	addps xmm0, xmm2	;# have rsqH1 in xmm0 
	addps xmm4, xmm5	;# have rsqH2 in xmm4 

	;# do invsqrt 
	rsqrtps xmm1, xmm0
	rsqrtps xmm5, xmm4
	movaps  xmm2, xmm1   ;# do coulomb interaction 
	movaps  xmm6, xmm5
	mulps   xmm1, xmm1
	mulps   xmm5, xmm5
	movaps  xmm3, [esp + nb112_three]
	movaps  xmm7, xmm3
	mulps   xmm1, xmm0
	mulps   xmm5, xmm4
	subps   xmm3, xmm1
	subps   xmm7, xmm5
	mulps   xmm3, xmm2
	mulps   xmm7, xmm6
	mulps   xmm3, [esp + nb112_half] ;# rinv H1 - j water 
	mulps   xmm7, [esp + nb112_half] ;# rinv H2 - j water  

	;# assemble charges in xmm6 
	xorps   xmm6, xmm6
	;# do coulomb interaction 
	movaps  xmm0, xmm3
	movss   xmm6, [esp + nb112_qqOH]
	movaps  xmm4, xmm7
	movhps  xmm6, [esp + nb112_qqHH]
	mulps   xmm0, xmm0	;# rinvsq 
	mulps   xmm4, xmm4	;# rinvsq 
	mulps   xmm3, xmm6	;# vcoul 
	mulps   xmm7, xmm6	;# vcoul 
	movaps  xmm2, xmm3
	addps   xmm2, xmm7	;# total vcoul 
	mulps   xmm0, xmm3	;# fscal 
	
	addps   xmm2, [esp + nb112_vctot]
	mulps   xmm7, xmm4	;# fscal 
	movaps  [esp + nb112_vctot], xmm2
	movaps  xmm1, xmm0
	movaps  xmm2, xmm0
	mulps   xmm0, [esp + nb112_dxH1O]
	mulps   xmm1, [esp + nb112_dyH1O]
	mulps   xmm2, [esp + nb112_dzH1O]
	;# update forces H1 - j water 
	movaps  xmm3, [esp + nb112_fjxO]
	movaps  xmm4, [esp + nb112_fjyO]
	movaps  xmm5, [esp + nb112_fjzO]
	subps   xmm3, xmm0
	subps   xmm4, xmm1
	subps   xmm5, xmm2
	movaps  [esp + nb112_fjxO], xmm3
	movaps  [esp + nb112_fjyO], xmm4
	movaps  [esp + nb112_fjzO], xmm5
	addps   xmm0, [esp + nb112_fixH1]
	addps   xmm1, [esp + nb112_fiyH1]
	addps   xmm2, [esp + nb112_fizH1]
	movaps  [esp + nb112_fixH1], xmm0
	movaps  [esp + nb112_fiyH1], xmm1
	movaps  [esp + nb112_fizH1], xmm2
	;# do forces H2 - j water 
	movaps xmm0, xmm7
	movaps xmm1, xmm7
	movaps xmm2, xmm7
	mulps   xmm0, [esp + nb112_dxH2O]
	mulps   xmm1, [esp + nb112_dyH2O]
	mulps   xmm2, [esp + nb112_dzH2O]
	movaps  xmm3, [esp + nb112_fjxO]
	movaps  xmm4, [esp + nb112_fjyO]
	movaps  xmm5, [esp + nb112_fjzO]
	subps   xmm3, xmm0