nb_kernel130_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,015 行 · 第 1/4 页

			
	addss  xmm5, [esp + nb130_Vvdwtot]
	movss [esp + nb130_Vvdwtot], xmm5

	mulss xmm3, xmm0    

	movd eax, mm0	

	movaps xmm0, [esp + nb130_dx]
	movaps xmm1, [esp + nb130_dy]
	movaps xmm2, [esp + nb130_dz]

	mulss  xmm0, xmm3
	mulss  xmm1, xmm3
	mulss  xmm2, xmm3
	;# xmm0-xmm2 contains tx-tz (partial force) 
	;# now update f_i 
	movaps xmm3, [esp + nb130_fix]
	movaps xmm4, [esp + nb130_fiy]
	movaps xmm5, [esp + nb130_fiz]
	addss  xmm3, xmm0
	addss  xmm4, xmm1
	addss  xmm5, xmm2
	movaps [esp + nb130_fix], xmm3
	movaps [esp + nb130_fiy], xmm4
	movaps [esp + nb130_fiz], xmm5
	;# update fj 
	mov edi, [ebp + nb130_faction]
	
	movss   xmm3, [edi + eax*4]
	movss   xmm4, [edi + eax*4 + 4]
	movss   xmm5, [edi + eax*4 + 8]
	subss   xmm3, xmm0
	subss   xmm4, xmm1
	subss   xmm5, xmm2	
	movss   [edi + eax*4], xmm3
	movss   [edi + eax*4 + 4], xmm4
	movss   [edi + eax*4 + 8], xmm5	
.nb130_updateouterdata:
	mov   ecx, [esp + nb130_ii3]
	mov   edi, [ebp + nb130_faction]
	mov   esi, [ebp + nb130_fshift]
	mov   edx, [esp + nb130_is3]

	;# accumulate i forces in xmm0, xmm1, xmm2 
	movaps xmm0, [esp + nb130_fix]
	movaps xmm1, [esp + nb130_fiy]
	movaps xmm2, [esp + nb130_fiz]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addps  xmm0, xmm3
	addps  xmm1, xmm4
	addps  xmm2, xmm5 ;# sum is in 1/2 in xmm0-xmm2 

	movaps xmm3, xmm0	
	movaps xmm4, xmm1	
	movaps xmm5, xmm2	

	shufps xmm3, xmm3, 1
	shufps xmm4, xmm4, 1
	shufps xmm5, xmm5, 1
	addss  xmm0, xmm3
	addss  xmm1, xmm4
	addss  xmm2, xmm5	;# xmm0-xmm2 has single force in pos0 

	;# increment i force 
	movss  xmm3, [edi + ecx*4]
	movss  xmm4, [edi + ecx*4 + 4]
	movss  xmm5, [edi + ecx*4 + 8]
	addss  xmm3, xmm0
	addss  xmm4, xmm1
	addss  xmm5, xmm2
	movss  [edi + ecx*4],     xmm3
	movss  [edi + ecx*4 + 4], xmm4
	movss  [edi + ecx*4 + 8], xmm5

	;# increment fshift force  
	movss  xmm3, [esi + edx*4]
	movss  xmm4, [esi + edx*4 + 4]
	movss  xmm5, [esi + edx*4 + 8]
	addss  xmm3, xmm0
	addss  xmm4, xmm1
	addss  xmm5, xmm2
	movss  [esi + edx*4],     xmm3
	movss  [esi + edx*4 + 4], xmm4
	movss  [esi + edx*4 + 8], xmm5

	;# get n from stack
	mov esi, [esp + nb130_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb130_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movaps xmm7, [esp + nb130_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		

	;# add earlier value from mem 
	mov   eax, [ebp + nb130_Vc]
	addss xmm7, [eax + edx*4] 
	;# move back to mem 
	movss [eax + edx*4], xmm7 
	
	;# accumulate total lj energy and update it 
	movaps xmm7, [esp + nb130_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		

	;# add earlier value from mem 
	mov   eax, [ebp + nb130_Vvdw]
	addss xmm7, [eax + edx*4] 
	;# move back to mem 
	movss [eax + edx*4], xmm7 
	
        ;# finish if last 
        mov ecx, [esp + nb130_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jecxz .nb130_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb130_n], esi
        jmp .nb130_outer
.nb130_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb130_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jecxz .nb130_end
        ;# non-zero, do one more workunit
        jmp   .nb130_threadloop
.nb130_end:
	emms

	mov eax, [esp + nb130_nouter]
	mov ebx, [esp + nb130_ninner]
	mov ecx, [ebp + nb130_outeriter]
	mov edx, [ebp + nb130_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb130_salign]
	add esp, eax
	add esp,  400
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret







.globl nb_kernel130nf_ia32_sse
.globl _nb_kernel130nf_ia32_sse
nb_kernel130nf_ia32_sse:	
_nb_kernel130nf_ia32_sse:	
.equiv          nb130nf_p_nri,            8
.equiv          nb130nf_iinr,             12
.equiv          nb130nf_jindex,           16
.equiv          nb130nf_jjnr,             20
.equiv          nb130nf_shift,            24
.equiv          nb130nf_shiftvec,         28
.equiv          nb130nf_fshift,           32
.equiv          nb130nf_gid,              36
.equiv          nb130nf_pos,              40
.equiv          nb130nf_faction,          44
.equiv          nb130nf_charge,           48
.equiv          nb130nf_p_facel,          52
.equiv          nb130nf_argkrf,           56
.equiv          nb130nf_argcrf,           60
.equiv          nb130nf_Vc,               64
.equiv          nb130nf_type,             68
.equiv          nb130nf_p_ntype,          72
.equiv          nb130nf_vdwparam,         76
.equiv          nb130nf_Vvdw,             80
.equiv          nb130nf_p_tabscale,       84
.equiv          nb130nf_VFtab,            88
.equiv          nb130nf_invsqrta,         92
.equiv          nb130nf_dvda,             96
.equiv          nb130nf_p_gbtabscale,     100
.equiv          nb130nf_GBtab,            104
.equiv          nb130nf_p_nthreads,       108
.equiv          nb130nf_count,            112
.equiv          nb130nf_mtx,              116
.equiv          nb130nf_outeriter,        120
.equiv          nb130nf_inneriter,        124
.equiv          nb130nf_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb130nf_ix,               0
.equiv          nb130nf_iy,               16
.equiv          nb130nf_iz,               32
.equiv          nb130nf_iq,               48
.equiv          nb130nf_dx,               64
.equiv          nb130nf_dy,               80
.equiv          nb130nf_dz,               96
.equiv          nb130nf_c6,               112
.equiv          nb130nf_c12,              128
.equiv          nb130nf_tsc,              144
.equiv          nb130nf_vctot,            160
.equiv          nb130nf_Vvdwtot,          176
.equiv          nb130nf_half,             192
.equiv          nb130nf_three,            208
.equiv          nb130nf_krf,              224
.equiv          nb130nf_crf,              240
.equiv          nb130nf_is3,              256
.equiv          nb130nf_ii3,              260
.equiv          nb130nf_ntia,             264
.equiv          nb130nf_innerjjnr,        268
.equiv          nb130nf_innerk,           272
.equiv          nb130nf_n,                276
.equiv          nb130nf_nn1,              280
.equiv          nb130nf_nri,              284
.equiv          nb130nf_facel,            288
.equiv          nb130nf_ntype,            292
.equiv          nb130nf_nouter,           296
.equiv          nb130nf_ninner,           300
.equiv          nb130nf_salign,           304
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp,  304		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb130nf_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb130nf_p_nri]
	mov esi, [ebp + nb130nf_p_facel]
	mov edi, [ebp + nb130nf_p_ntype]
	mov ecx, [ecx]
	mov esi, [esi]
	mov edi, [edi]
	mov [esp + nb130nf_nri], ecx
	mov [esp + nb130nf_facel], esi
	mov [esp + nb130nf_ntype], edi

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb130nf_nouter], eax
	mov [esp + nb130nf_ninner], eax
	
	mov eax, [ebp + nb130nf_p_tabscale]
	movss xmm3, [eax]
	shufps xmm3, xmm3, 0
	movaps [esp + nb130nf_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb130nf_half], eax
	movss xmm1, [esp + nb130nf_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# constant 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# constant 2.0
	addps  xmm3, xmm2	;# constant 3.0
	movaps [esp + nb130nf_half],  xmm1
	movaps [esp + nb130nf_three],  xmm3

.nb130nf_threadloop:
        mov   esi, [ebp + nb130nf_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb130nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb130nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb130nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb130nf_n], eax
        mov [esp + nb130nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb130nf_outerstart
        jmp .nb130nf_end

.nb130nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb130nf_nouter]
	mov [esp + nb130nf_nouter], ebx

.nb130nf_outer:
	mov   eax, [ebp + nb130nf_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax + esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb130nf_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb130nf_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [eax + ebx*4]
	movss xmm1, [eax + ebx*4 + 4]
	movss xmm2, [eax + ebx*4 + 8] 

	mov   ecx, [ebp + nb130nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx + esi*4]	    ;# ebx =ii 

	mov   edx, [ebp + nb130nf_charge]
	movss xmm3, [edx + ebx*4]	
	mulss xmm3, [esp + nb130nf_facel]
	shufps xmm3, xmm3, 0

    	mov   edx, [ebp + nb130nf_type] 
    	mov   edx, [edx + ebx*4]
    	imul  edx, [esp + nb130nf_ntype]
    	shl   edx, 1
    	mov   [esp + nb130nf_ntia], edx
		
	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb130nf_pos]    ;# eax = base of pos[]  

	addss xmm0, [eax + ebx*4]
	addss xmm1, [eax + ebx*4 + 4]
	addss xmm2, [eax + ebx*4 + 8]

	movaps [esp + nb130nf_iq], xmm3
	
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0

	movaps [esp + nb130nf_ix], xmm0
	movaps [esp + nb130nf_iy], xmm1
	movaps [esp + nb130nf_iz], xmm2

	mov   [esp + nb130nf_ii3], ebx
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [esp + nb130nf_vctot], xmm4
	movaps [esp + nb130nf_Vvdwtot], xmm4
		
	mov   eax, [ebp + nb130nf_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb130nf_pos]
	mov   eax, [ebp + nb130nf_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb130nf_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [esp + nb130nf_ninner]
	mov   [esp + nb130nf_ninner], ecx
	add   edx, 0
	mov   [esp + nb130nf_innerk], edx    ;# number of innerloop atoms 
	jge   .nb130nf_unroll_loop
	jmp   .nb130nf_finish_inner
.nb130nf_unroll_loop:	
	;# quad-unroll innerloop here 
	mov   edx, [esp + nb130nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	mov   ecx, [edx + 8]            
	mov   edx, [edx + 12]         ;# eax-edx=jnr1-4 
	add dword ptr [esp + nb130nf_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov esi, [ebp + nb130nf_charge]    ;# base of charge[] 
	
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]

	movaps xmm2, [esp + nb130nf_iq]
	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx
	movd  mm2, ecx
	movd  mm3, edx
	
	mov esi, [ebp + nb130nf_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov ecx, [esi + ecx*4]
	mov edx, [esi + edx*4]
	mov esi, [ebp + nb130nf_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	shl ecx, 1	
	shl edx, 1	
	mov edi, [esp + nb130nf_ntia]
	add eax, edi
	add ebx, edi
	add ecx, edi
	add edx, edi

	movlps xmm6, [esi + eax*4]
	movlps xmm7, [esi + ecx*4]
	movhps xmm6, [esi + ebx*4]
	movhps xmm7, [esi + edx*4]

	movaps xmm4, xmm6
	shufps xmm4, xmm7, 136  ;# constant 10001000
	shufps xmm6, xmm7, 221  ;# constant 11011101
	
	movd  eax, mm0		
	movd  ebx, mm1
	movd  ecx, mm2
	movd  edx, mm3

	movaps [esp + nb130nf_c6], xmm4
	movaps [esp + nb130nf_c12], xmm6
	
	mov esi, [ebp + nb130nf_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	

	mulps xmm3, xmm2
	lea   ecx, [ecx + ecx*2]     ;# replace jnr with j3 
	lea   edx, [edx + edx*2]	

	;# move four coordinates to xmm0-xmm2 	

	movlps xmm4, [esi + eax*4]
	movlps xmm5, [esi + ecx*4]
	movss xmm2, [esi + eax*4 + 8]
	movss xmm6, [esi + ecx*4 + 8]

	movhps xmm4, [esi + ebx*4]
	movhps xmm5, [esi + edx*4]

	movss xmm0, [esi + ebx*4 + 8]
	movss xmm1, [esi + edx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# constant 10001000
	
	shufps xmm0, xmm5, 136  ;# constant 10001000
	shufps xmm1, xmm5, 221  ;# constant 11011101		

	;# move ix-iz to xmm4-xmm6 
	movaps xmm4, [esp + nb130nf_ix]
	movaps xmm5, [esp + nb130nf_iy]
	movaps xmm6, [esp + nb130nf_iz]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	;# rsq in xmm4 
	
	movaps xmm7, [esp + nb130nf_krf]
	rsqrtps xmm5, xmm4
	;# lookup seed in xmm5 
	movaps xmm2, xmm5
	mulps xmm5, xmm5
	movaps xmm1, [esp + nb130nf_three]
	mulps xmm5, xmm4	;# rsq*lu*lu