nb_kernel104_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,968 行 · 第 1/5 页

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb104nf_half(%esp)
        movss nb104nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb104nf_half(%esp)
        movaps %xmm3,nb104nf_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb104nf_iinr(%ebp),%ecx           ## ecx = pointer into iinr[]    
        movl  (%ecx),%ebx               ## ebx =ii 

        movl  nb104nf_charge(%ebp),%edx
        movss 4(%edx,%ebx,4),%xmm3
        movss %xmm3,%xmm4
        movss 12(%edx,%ebx,4),%xmm5
        movl nb104nf_p_facel(%ebp),%esi
        movss (%esi),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb104nf_qqHH(%esp)
        movaps %xmm4,nb104nf_qqMH(%esp)
        movaps %xmm5,nb104nf_qqMM(%esp)

_nb_kernel104nf_ia32_sse.nb104nf_threadloop: 
        movl  nb104nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel104nf_ia32_sse.nb104nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel104nf_ia32_sse.nb104nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb104nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb104nf_n(%esp)
        movl %ebx,nb104nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel104nf_ia32_sse.nb104nf_outerstart
        jmp _nb_kernel104nf_ia32_sse.nb104nf_end

_nb_kernel104nf_ia32_sse.nb104nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb104nf_nouter(%esp),%ebx
        movl %ebx,nb104nf_nouter(%esp)

_nb_kernel104nf_ia32_sse.nb104nf_outer: 
        movl  nb104nf_shift(%ebp),%eax          ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx        ## ebx=3*is 
        movl  %ebx,nb104nf_is3(%esp)            ## store is3 

        movl  nb104nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb104nf_iinr(%ebp),%ecx           ## ecx = pointer into iinr[]    
        movl  (%ecx,%esi,4),%ebx                ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb104nf_pos(%ebp),%eax    ## eax = base of pos[]  
        movl  %ebx,nb104nf_ii3(%esp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        addss 12(%eax,%ebx,4),%xmm3
        addss 16(%eax,%ebx,4),%xmm4
        addss 20(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb104nf_ixH1(%esp)
        movaps %xmm4,nb104nf_iyH1(%esp)
        movaps %xmm5,nb104nf_izH1(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 24(%eax,%ebx,4),%xmm0
        addss 28(%eax,%ebx,4),%xmm1
        addss 32(%eax,%ebx,4),%xmm2
        addss 36(%eax,%ebx,4),%xmm3
        addss 40(%eax,%ebx,4),%xmm4
        addss 44(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb104nf_ixH2(%esp)
        movaps %xmm1,nb104nf_iyH2(%esp)
        movaps %xmm2,nb104nf_izH2(%esp)
        movaps %xmm3,nb104nf_ixM(%esp)
        movaps %xmm4,nb104nf_iyM(%esp)
        movaps %xmm5,nb104nf_izM(%esp)

        ## clear vctot
        xorps %xmm4,%xmm4
        movaps %xmm4,nb104nf_vctot(%esp)

        movl  nb104nf_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx                ## jindex[n] 
        movl  4(%eax,%esi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movl  nb104nf_pos(%ebp),%esi
        movl  nb104nf_faction(%ebp),%edi
        movl  nb104nf_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb104nf_innerjjnr(%esp)      ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb104nf_ninner(%esp),%ecx
        movl  %ecx,nb104nf_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb104nf_innerk(%esp)         ## number of innerloop atoms 
        jge   _nb_kernel104nf_ia32_sse.nb104nf_unroll_loop
        jmp   _nb_kernel104nf_ia32_sse.nb104nf_single_check
_nb_kernel104nf_ia32_sse.nb104nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb104nf_innerjjnr(%esp),%edx      ## pointer to jjnr[k] 

        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx             ## eax-edx=jnr1-4 

        addl $16,nb104nf_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb104nf_pos(%ebp),%esi     ## base of pos[] 

        leal  (%eax,%eax,2),%eax        ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx        ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move j coordinates to local temp variables 
        movlps 12(%esi,%eax,4),%xmm2
        movlps 24(%esi,%eax,4),%xmm3
        movlps 36(%esi,%eax,4),%xmm4

        movlps 12(%esi,%ebx,4),%xmm5
        movlps 24(%esi,%ebx,4),%xmm6
        movlps 36(%esi,%ebx,4),%xmm7

        movhps 12(%esi,%ecx,4),%xmm2
        movhps 24(%esi,%ecx,4),%xmm3
        movhps 36(%esi,%ecx,4),%xmm4

        movhps 12(%esi,%edx,4),%xmm5
        movhps 24(%esi,%edx,4),%xmm6
        movhps 36(%esi,%edx,4),%xmm7

        ## current state:       
        ## xmm2= jxh1a  jyH1a  jxH1c  jyH1c 
        ## xmm3= jxH2a jyH2a jxH2c jyH2c 
        ## xmm4= jxMa jyMa jxMc jyMc 
        ## xmm5= jxH1b  jyH1b  jxH1d  jyH1d 
        ## xmm6= jxH2b jyH2b jxH2d jyH2d 
        ## xmm7= jxMb jyMb jxMd jyMd 

        movaps %xmm2,%xmm0
        movaps %xmm3,%xmm1
        unpcklps %xmm5,%xmm0    ## xmm0= jxH1a  jxH1b  jyH1a  jyH1b 
        unpcklps %xmm6,%xmm1    ## xmm1= jxH2a jxH2b jyH2a jyH2b 
        unpckhps %xmm5,%xmm2    ## xmm2= jxH1c  jxH1d  jyH1c  jyH1d 
        unpckhps %xmm6,%xmm3    ## xmm3= jxH2c jxH2d jyH2c jyH2d  
        movaps %xmm4,%xmm5
        movaps   %xmm0,%xmm6
        unpcklps %xmm7,%xmm4    ## xmm4= jxMa jxMb jyMa jyMb            
        unpckhps %xmm7,%xmm5    ## xmm5= jxMc jxMd jyMc jyMd     
        movaps   %xmm1,%xmm7
        movlhps  %xmm2,%xmm0    ## xmm0= jxH1a  jxH1b  jxH1c  jxH1d  
        movaps %xmm0,nb104nf_jxH1(%esp)
        movhlps  %xmm6,%xmm2    ## xmm2= jyH1a  jyH1b  jyH1c  jyH1d 
        movaps %xmm2,nb104nf_jyH1(%esp)
        movlhps  %xmm3,%xmm1
        movaps %xmm1,nb104nf_jxH2(%esp)
        movhlps  %xmm7,%xmm3
        movaps   %xmm4,%xmm6
        movaps %xmm3,nb104nf_jyH2(%esp)
        movlhps  %xmm5,%xmm4
        movaps %xmm4,nb104nf_jxM(%esp)
        movhlps  %xmm6,%xmm5
        movaps %xmm5,nb104nf_jyM(%esp)

        movss  20(%esi,%eax,4),%xmm0
        movss  32(%esi,%eax,4),%xmm1
        movss  44(%esi,%eax,4),%xmm2

        movss  20(%esi,%ecx,4),%xmm3
        movss  32(%esi,%ecx,4),%xmm4
        movss  44(%esi,%ecx,4),%xmm5

        movhps 16(%esi,%ebx,4),%xmm0
        movhps 28(%esi,%ebx,4),%xmm1
        movhps 40(%esi,%ebx,4),%xmm2

        movhps 16(%esi,%edx,4),%xmm3
        movhps 28(%esi,%edx,4),%xmm4
        movhps 40(%esi,%edx,4),%xmm5

        shufps $204,%xmm3,%xmm0 ## constant 11001100
        shufps $204,%xmm4,%xmm1 ## constant 11001100
        shufps $204,%xmm5,%xmm2 ## constant 11001100
        movaps %xmm0,nb104nf_jzH1(%esp)
        movaps %xmm1,nb104nf_jzH2(%esp)
        movaps %xmm2,nb104nf_jzM(%esp)

        movaps nb104nf_ixH1(%esp),%xmm0
        movaps nb104nf_iyH1(%esp),%xmm1
        movaps nb104nf_izH1(%esp),%xmm2
        movaps nb104nf_ixH1(%esp),%xmm3
        movaps nb104nf_iyH1(%esp),%xmm4
        movaps nb104nf_izH1(%esp),%xmm5
        subps  nb104nf_jxH1(%esp),%xmm0
        subps  nb104nf_jyH1(%esp),%xmm1
        subps  nb104nf_jzH1(%esp),%xmm2
        subps  nb104nf_jxH2(%esp),%xmm3
        subps  nb104nf_jyH2(%esp),%xmm4
        subps  nb104nf_jzH2(%esp),%xmm5
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
        movaps %xmm0,nb104nf_rsqH1H1(%esp)
        movaps %xmm3,nb104nf_rsqH1H2(%esp)

        movaps nb104nf_ixH1(%esp),%xmm0
        movaps nb104nf_iyH1(%esp),%xmm1
        movaps nb104nf_izH1(%esp),%xmm2
        movaps nb104nf_ixH2(%esp),%xmm3
        movaps nb104nf_iyH2(%esp),%xmm4
        movaps nb104nf_izH2(%esp),%xmm5
        subps  nb104nf_jxM(%esp),%xmm0
        subps  nb104nf_jyM(%esp),%xmm1
        subps  nb104nf_jzM(%esp),%xmm2
        subps  nb104nf_jxH1(%esp),%xmm3
        subps  nb104nf_jyH1(%esp),%xmm4
        subps  nb104nf_jzH1(%esp),%xmm5
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
        movaps %xmm0,nb104nf_rsqH1M(%esp)
        movaps %xmm3,nb104nf_rsqH2H1(%esp)

        movaps nb104nf_ixH2(%esp),%xmm0
        movaps nb104nf_iyH2(%esp),%xmm1
        movaps nb104nf_izH2(%esp),%xmm2
        movaps nb104nf_ixH2(%esp),%xmm3
        movaps nb104nf_iyH2(%esp),%xmm4
        movaps nb104nf_izH2(%esp),%xmm5
        subps  nb104nf_jxH2(%esp),%xmm0
        subps  nb104nf_jyH2(%esp),%xmm1
        subps  nb104nf_jzH2(%esp),%xmm2
        subps  nb104nf_jxM(%esp),%xmm3
        subps  nb104nf_jyM(%esp),%xmm4
        subps  nb104nf_jzM(%esp),%xmm5
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
        movaps %xmm0,nb104nf_rsqH2H2(%esp)
        movaps %xmm3,nb104nf_rsqH2M(%esp)

        movaps nb104nf_ixM(%esp),%xmm0
        movaps nb104nf_iyM(%esp),%xmm1
        movaps nb104nf_izM(%esp),%xmm2
        movaps nb104nf_ixM(%esp),%xmm3
        movaps nb104nf_iyM(%esp),%xmm4
        movaps nb104nf_izM(%esp),%xmm5
        subps  nb104nf_jxH1(%esp),%xmm0
        subps  nb104nf_jyH1(%esp),%xmm1
        subps  nb104nf_jzH1(%esp),%xmm2
        subps  nb104nf_jxH2(%esp),%xmm3
        subps  nb104nf_jyH2(%esp),%xmm4
        subps  nb104nf_jzH2(%esp),%xmm5
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm3,%xmm4
        addps  %xmm5,%xmm4
        movaps %xmm0,nb104nf_rsqMH1(%esp)
        movaps %xmm4,nb104nf_rsqMH2(%esp)

        movaps nb104nf_ixM(%esp),%xmm0
        movaps nb104nf_iyM(%esp),%xmm1
        movaps nb104nf_izM(%esp),%xmm2
        subps  nb104nf_jxM(%esp),%xmm0
        subps  nb104nf_jyM(%esp),%xmm1
        subps  nb104nf_jzM(%esp),%xmm2
        mulps %xmm0,%xmm0
        mulps %xmm1,%xmm1
        mulps %xmm2,%xmm2
        addps %xmm1,%xmm0
        addps %xmm2,%xmm0
        movaps %xmm0,nb104nf_rsqMM(%esp)

        ## start doing invsqrt use rsq values in xmm0, xmm4 
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm4,%xmm5
        movaps  %xmm1,%xmm2
        movaps  %xmm5,%xmm6
        mulps   %xmm1,%xmm1
        mulps   %xmm5,%xmm5
        movaps  nb104nf_three(%esp),%xmm3
        movaps  %xmm3,%xmm7
        mulps   %xmm0,%xmm1
        mulps   %xmm4,%xmm5
        subps   %xmm1,%xmm3
        subps   %xmm5,%xmm7
        mulps   %xmm2,%xmm3
        mulps   %xmm6,%xmm7
        mulps   nb104nf_half(%esp),%xmm3   ## rinvMM 
        mulps   nb104nf_half(%esp),%xmm7   ## rinvMH2 
        movaps  %xmm3,nb104nf_rinvMM(%esp)
        movaps  %xmm7,nb104nf_rinvMH2(%esp)

        rsqrtps nb104nf_rsqH1H1(%esp),%xmm1
        rsqrtps nb104nf_rsqH1H2(%esp),%xmm5
        movaps  %xmm1,%xmm2
        movaps  %xmm5,%xmm6
        mulps   %xmm1,%xmm1
        mulps   %xmm5,%xmm5
        movaps  nb104nf_three(%esp),%xmm3
        movaps  %xmm3,%xmm7
        mulps   nb104nf_rsqH1H1(%esp),%xmm1
        mulps   nb104nf_rsqH1H2(%esp),%xmm5
        subps   %xmm1,%xmm3
        subps   %xmm5,%xmm7
        mulps   %xmm2,%xmm3
        mulps   %xmm6,%xmm7
        mulps   nb104nf_half(%esp),%xmm3
        mulps   nb104nf_half(%esp),%xmm7
        movaps  %xmm3,nb104nf_rinvH1H1(%esp)
        movaps  %xmm7,nb104nf_rinvH1H2(%esp)

        rsqrtps nb104nf_rsqH1M(%esp),%xmm1
        rsqrtps nb104nf_rsqH2H1(%esp),%