nb_kernel313_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,372 行 · 第 1/5 页

;#
;# $Id: nb_kernel313_ia32_sse.intel_syntax.s,v 1.1.2.1 2006/03/01 15:18:30 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as





.globl nb_kernel313_ia32_sse
.globl _nb_kernel313_ia32_sse
nb_kernel313_ia32_sse:	
_nb_kernel313_ia32_sse:	
.equiv          nb313_p_nri,            8
.equiv          nb313_iinr,             12
.equiv          nb313_jindex,           16
.equiv          nb313_jjnr,             20
.equiv          nb313_shift,            24
.equiv          nb313_shiftvec,         28
.equiv          nb313_fshift,           32
.equiv          nb313_gid,              36
.equiv          nb313_pos,              40
.equiv          nb313_faction,          44
.equiv          nb313_charge,           48
.equiv          nb313_p_facel,          52
.equiv          nb313_argkrf,           56
.equiv          nb313_argcrf,           60
.equiv          nb313_Vc,               64
.equiv          nb313_type,             68
.equiv          nb313_p_ntype,          72
.equiv          nb313_vdwparam,         76
.equiv          nb313_Vvdw,             80
.equiv          nb313_p_tabscale,       84
.equiv          nb313_VFtab,            88
.equiv          nb313_invsqrta,         92
.equiv          nb313_dvda,             96
.equiv          nb313_p_gbtabscale,     100
.equiv          nb313_GBtab,            104
.equiv          nb313_p_nthreads,       108
.equiv          nb313_count,            112
.equiv          nb313_mtx,              116
.equiv          nb313_outeriter,        120
.equiv          nb313_inneriter,        124
.equiv          nb313_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb313_ixO,              0
.equiv          nb313_iyO,              16
.equiv          nb313_izO,              32
.equiv          nb313_ixH1,             48
.equiv          nb313_iyH1,             64
.equiv          nb313_izH1,             80
.equiv          nb313_ixH2,             96
.equiv          nb313_iyH2,             112
.equiv          nb313_izH2,             128
.equiv          nb313_ixM,              144
.equiv          nb313_iyM,              160
.equiv          nb313_izM,              176
.equiv          nb313_iqM,              192
.equiv          nb313_iqH,              208
.equiv          nb313_dxO,              224
.equiv          nb313_dyO,              240
.equiv          nb313_dzO,              256
.equiv          nb313_dxH1,             272
.equiv          nb313_dyH1,             288
.equiv          nb313_dzH1,             304
.equiv          nb313_dxH2,             320
.equiv          nb313_dyH2,             336
.equiv          nb313_dzH2,             352
.equiv          nb313_dxM,              368
.equiv          nb313_dyM,              384
.equiv          nb313_dzM,              400
.equiv          nb313_qqM,              416
.equiv          nb313_qqH,              432
.equiv          nb313_rinvH1,           448
.equiv          nb313_rinvH2,           464
.equiv          nb313_rinvM,            480
.equiv          nb313_rH1,              496
.equiv          nb313_rH2,              512
.equiv          nb313_rM,               528
.equiv          nb313_tsc,              544
.equiv          nb313_two,              560
.equiv          nb313_c6,               576
.equiv          nb313_c12,              592
.equiv          nb313_six,              608
.equiv          nb313_twelve,           624
.equiv          nb313_vctot,            640
.equiv          nb313_Vvdwtot,          656
.equiv          nb313_fixO,             672
.equiv          nb313_fiyO,             688
.equiv          nb313_fizO,             704
.equiv          nb313_fixH1,            720
.equiv          nb313_fiyH1,            736
.equiv          nb313_fizH1,            752
.equiv          nb313_fixH2,            768
.equiv          nb313_fiyH2,            784
.equiv          nb313_fizH2,            800
.equiv          nb313_fixM,             816
.equiv          nb313_fiyM,             832
.equiv          nb313_fizM,             848
.equiv          nb313_fjx,              864
.equiv          nb313_fjy,              880
.equiv          nb313_fjz,              896
.equiv          nb313_half,             912
.equiv          nb313_three,            928
.equiv          nb313_is3,              944
.equiv          nb313_ii3,              948
.equiv          nb313_ntia,             952
.equiv          nb313_innerjjnr,        956
.equiv          nb313_innerk,           960
.equiv          nb313_n,                964
.equiv          nb313_nn1,              968
.equiv          nb313_nri,              972
.equiv          nb313_nouter,           976
.equiv          nb313_ninner,           980
.equiv          nb313_salign,           984
	push ebp
	mov ebp,esp	
	push eax
	push ebx
	push ecx
	push edx
	push esi
	push edi
	sub esp, 988		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb313_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb313_p_nri]
	mov ecx, [ecx]
	mov [esp + nb313_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb313_nouter], eax
	mov [esp + nb313_ninner], eax


	mov eax, [ebp + nb313_p_tabscale]
	movss xmm5, [eax]
	shufps xmm5, xmm5, 0
	movaps [esp + nb313_tsc], xmm5
	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb313_half], eax
	movss xmm1, [esp + nb313_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# constant 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# constant 2.0
	addps  xmm3, xmm2	;# constant 3.0
	movaps xmm4, xmm3
	addps  xmm4, xmm4	;# 6.0
	movaps xmm5, xmm4
	addps  xmm5, xmm5	;# constant 12.0
	movaps [esp + nb313_half],  xmm1
	movaps [esp + nb313_two],  xmm2
	movaps [esp + nb313_three],  xmm3
	movaps [esp + nb313_six],  xmm4
	movaps [esp + nb313_twelve],  xmm5
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb313_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb313_charge]
	movss xmm4, [edx + ebx*4 + 4]	
	movss xmm3, [edx + ebx*4 + 12]	
	mov esi, [ebp + nb313_p_facel]
	movss xmm5, [esi]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [esp + nb313_iqM], xmm3
	movaps [esp + nb313_iqH], xmm4
	
	mov   edx, [ebp + nb313_type]
	mov   ecx, [edx + ebx*4]
	shl   ecx, 1
	mov edi, [ebp + nb313_p_ntype]
	imul  ecx, [edi]      ;# ecx = ntia = 2*ntype*type[ii0] 
	mov   [esp + nb313_ntia], ecx		
.nb313_threadloop:
        mov   esi, [ebp + nb313_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb313_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb313_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb313_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb313_n], eax
        mov [esp + nb313_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb313_outerstart
        jmp .nb313_end
	
.nb313_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb313_nouter]
	mov [esp + nb313_nouter], ebx

.nb313_outer:
	mov   eax, [ebp + nb313_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax + esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]	;# ebx=3*is 
	mov   [esp + nb313_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb313_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [eax + ebx*4]
	movss xmm1, [eax + ebx*4 + 4]
	movss xmm2, [eax + ebx*4 + 8] 

	mov   ecx, [ebp + nb313_iinr]   	;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx + esi*4]		;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2	
	movaps xmm6, xmm0
	movaps xmm7, xmm1
	
	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb313_pos]	;# eax = base of pos[]  
	mov   [esp + nb313_ii3], ebx

	addss xmm3, [eax + ebx*4]  	;# ox
	addss xmm4, [eax + ebx*4 + 4]  ;# oy
	addss xmm5, [eax + ebx*4 + 8]  ;# oz
	addss xmm6, [eax + ebx*4 + 12] ;# h1x
	addss xmm7, [eax + ebx*4 + 16] ;# h1y
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	shufps xmm6, xmm6, 0
	shufps xmm7, xmm7, 0
	movaps [esp + nb313_ixO], xmm3
	movaps [esp + nb313_iyO], xmm4
	movaps [esp + nb313_izO], xmm5
	movaps [esp + nb313_ixH1], xmm6
	movaps [esp + nb313_iyH1], xmm7

	movss xmm6, xmm2
	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm6, [eax + ebx*4 + 20] ;# h1z
	addss xmm0, [eax + ebx*4 + 24] ;# h2x
	addss xmm1, [eax + ebx*4 + 28] ;# h2y
	addss xmm2, [eax + ebx*4 + 32] ;# h2z
	addss xmm3, [eax + ebx*4 + 36] ;# mx
	addss xmm4, [eax + ebx*4 + 40] ;# my
	addss xmm5, [eax + ebx*4 + 44] ;# mz

	shufps xmm6, xmm6, 0
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb313_izH1], xmm6
	movaps [esp + nb313_ixH2], xmm0
	movaps [esp + nb313_iyH2], xmm1
	movaps [esp + nb313_izH2], xmm2
	movaps [esp + nb313_ixM], xmm3
	movaps [esp + nb313_iyM], xmm4
	movaps [esp + nb313_izM], xmm5
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [esp + nb313_vctot], xmm4
	movaps [esp + nb313_Vvdwtot], xmm4
	movaps [esp + nb313_fixO], xmm4
	movaps [esp + nb313_fiyO], xmm4
	movaps [esp + nb313_fizO], xmm4
	movaps [esp + nb313_fixH1], xmm4
	movaps [esp + nb313_fiyH1], xmm4
	movaps [esp + nb313_fizH1], xmm4
	movaps [esp + nb313_fixH2], xmm4
	movaps [esp + nb313_fiyH2], xmm4
	movaps [esp + nb313_fizH2], xmm4
	movaps [esp + nb313_fixM], xmm4
	movaps [esp + nb313_fiyM], xmm4
	movaps [esp + nb313_fizM], xmm4
	
	mov   eax, [ebp + nb313_jindex]
	mov   ecx, [eax + esi*4]	 	;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	 	;# jindex[n+1] 
	sub   edx, ecx           	;# number of innerloop atoms 

	mov   esi, [ebp + nb313_pos]
	mov   edi, [ebp + nb313_faction]	
	mov   eax, [ebp + nb313_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb313_innerjjnr], eax 	;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [esp + nb313_ninner]
	mov   [esp + nb313_ninner], ecx
	add   edx, 0
	mov   [esp + nb313_innerk], edx	;# number of innerloop atoms 
	jge   .nb313_unroll_loop
	jmp   .nb313_odd_inner
.nb313_unroll_loop:
	;# quad-unroll innerloop here 
	mov   edx, [esp + nb313_innerjjnr] 	;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	mov   ecx, [edx + 8]            
	mov   edx, [edx + 12]     	;# eax-edx=jnr1-4 

	add dword ptr [esp + nb313_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov esi, [ebp + nb313_charge]	;# base of charge[] 
	
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]

	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	 	;# and in xmm4 
	mulps  xmm3, [esp + nb313_iqM]
	mulps  xmm4, [esp + nb313_iqH]

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx
	movd  mm2, ecx
	movd  mm3, edx

	movaps  [esp + nb313_qqM], xmm3
	movaps  [esp + nb313_qqH], xmm4
	
	mov esi, [ebp + nb313_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov ecx, [esi + ecx*4]
	mov edx, [esi + edx*4]
	mov esi, [ebp + nb313_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	shl ecx, 1	
	shl edx, 1	
	mov edi, [esp + nb313_ntia]
	add eax, edi
	add ebx, edi
	add ecx, edi
	add edx, edi

	movlps xmm6, [esi + eax*4]
	movlps xmm7, [esi + ecx*4]
	movhps xmm6, [esi + ebx*4]
	movhps xmm7, [esi + edx*4]

	movaps xmm4, xmm6
	shufps xmm4, xmm7, 136  ;# constant 10001000
	shufps xmm6, xmm7, 221  ;# constant 11011101
	
	movd  eax, mm0		
	movd  ebx, mm1
	movd  ecx, mm2
	movd  edx, mm3

	movaps [esp + nb313_c6], xmm4
	movaps [esp + nb313_c12], xmm6

	mov esi, [ebp + nb313_pos]   	;# base of pos[] 

	lea   eax, [eax + eax*2] 	;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	
	lea   ecx, [ecx + ecx*2] 	;# replace jnr with j3 
	lea   edx, [edx + edx*2]	

	;# move four coordinates to xmm0-xmm2 	
	movlps xmm4, [esi + eax*4]
	movlps xmm5, [esi + ecx*4]
	movss xmm2, [esi + eax*4 + 8]
	movss xmm6, [esi + ecx*4 + 8]

	movhps xmm4, [esi + ebx*4]
	movhps xmm5, [esi + edx*4]

	movss xmm0, [esi + ebx*4 + 8]
	movss xmm1, [esi + edx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# constant 10001000
	
	shufps xmm0, xmm5, 136  ;# constant 10001000
	shufps xmm1, xmm5, 221  ;# constant 11011101		

	;# move ixO-izO to xmm4-xmm6 
	movaps xmm4, [esp + nb313_ixO]
	movaps xmm5, [esp + nb313_iyO]
	movaps xmm6, [esp + nb313_izO]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb313_dxO], xmm4
	movaps [esp + nb313_dyO], xmm5