nb_kernel213_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,957 行 · 第 1/5 页

##
## $Id: nb_kernel213_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:33 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##


.globl nb_kernel213_ia32_sse
.globl _nb_kernel213_ia32_sse
nb_kernel213_ia32_sse:  
_nb_kernel213_ia32_sse: 
.set nb213_p_nri, 8
.set nb213_iinr, 12
.set nb213_jindex, 16
.set nb213_jjnr, 20
.set nb213_shift, 24
.set nb213_shiftvec, 28
.set nb213_fshift, 32
.set nb213_gid, 36
.set nb213_pos, 40
.set nb213_faction, 44
.set nb213_charge, 48
.set nb213_p_facel, 52
.set nb213_argkrf, 56
.set nb213_argcrf, 60
.set nb213_Vc, 64
.set nb213_type, 68
.set nb213_p_ntype, 72
.set nb213_vdwparam, 76
.set nb213_Vvdw, 80
.set nb213_p_tabscale, 84
.set nb213_VFtab, 88
.set nb213_invsqrta, 92
.set nb213_dvda, 96
.set nb213_p_gbtabscale, 100
.set nb213_GBtab, 104
.set nb213_p_nthreads, 108
.set nb213_count, 112
.set nb213_mtx, 116
.set nb213_outeriter, 120
.set nb213_inneriter, 124
.set nb213_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb213_ixO, 0
.set nb213_iyO, 16
.set nb213_izO, 32
.set nb213_ixH1, 48
.set nb213_iyH1, 64
.set nb213_izH1, 80
.set nb213_ixH2, 96
.set nb213_iyH2, 112
.set nb213_izH2, 128
.set nb213_ixM, 144
.set nb213_iyM, 160
.set nb213_izM, 176
.set nb213_iqM, 192
.set nb213_iqH, 208
.set nb213_dxO, 224
.set nb213_dyO, 240
.set nb213_dzO, 256
.set nb213_dxH1, 272
.set nb213_dyH1, 288
.set nb213_dzH1, 304
.set nb213_dxH2, 320
.set nb213_dyH2, 336
.set nb213_dzH2, 352
.set nb213_dxM, 368
.set nb213_dyM, 384
.set nb213_dzM, 400
.set nb213_qqM, 416
.set nb213_qqH, 432
.set nb213_rinvH1, 448
.set nb213_rinvH2, 464
.set nb213_rinvM, 480
.set nb213_two, 496
.set nb213_c6, 512
.set nb213_c12, 528
.set nb213_six, 544
.set nb213_twelve, 560
.set nb213_krf, 576
.set nb213_crf, 592
.set nb213_krsqH1, 608
.set nb213_krsqH2, 624
.set nb213_krsqM, 640
.set nb213_vctot, 656
.set nb213_Vvdwtot, 672
.set nb213_fixO, 688
.set nb213_fiyO, 704
.set nb213_fizO, 720
.set nb213_fixH1, 736
.set nb213_fiyH1, 752
.set nb213_fizH1, 768
.set nb213_fixH2, 784
.set nb213_fiyH2, 800
.set nb213_fizH2, 816
.set nb213_fixM, 832
.set nb213_fiyM, 848
.set nb213_fizM, 864
.set nb213_fjx, 880
.set nb213_fjy, 896
.set nb213_fjz, 912
.set nb213_half, 928
.set nb213_three, 944
.set nb213_is3, 960
.set nb213_ii3, 964
.set nb213_ntia, 968
.set nb213_innerjjnr, 972
.set nb213_innerk, 976
.set nb213_n, 980
.set nb213_nn1, 984
.set nb213_nri, 988
.set nb213_nouter, 992
.set nb213_ninner, 996
.set nb213_salign, 1000
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $1004,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb213_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb213_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb213_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb213_nouter(%esp)
        movl %eax,nb213_ninner(%esp)

        movl nb213_argkrf(%ebp),%esi
        movl nb213_argcrf(%ebp),%edi
        movss (%esi),%xmm5
        movss (%edi),%xmm6
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        movaps %xmm5,nb213_krf(%esp)
        movaps %xmm6,nb213_crf(%esp)
        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb213_half(%esp)
        movss nb213_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm3,%xmm4
        addps  %xmm4,%xmm4      ## 6.0
        movaps %xmm4,%xmm5
        addps  %xmm5,%xmm5      ## constant 12.0
        movaps %xmm1,nb213_half(%esp)
        movaps %xmm2,nb213_two(%esp)
        movaps %xmm3,nb213_three(%esp)
        movaps %xmm4,nb213_six(%esp)
        movaps %xmm5,nb213_twelve(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb213_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb213_charge(%ebp),%edx
        movss 4(%edx,%ebx,4),%xmm4
        movss 12(%edx,%ebx,4),%xmm3
        movl nb213_p_facel(%ebp),%esi
        movss (%esi),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb213_iqM(%esp)
        movaps %xmm4,nb213_iqH(%esp)

        movl  nb213_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl nb213_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb213_ntia(%esp)
_nb_kernel213_ia32_sse.nb213_threadloop: 
        movl  nb213_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel213_ia32_sse.nb213_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel213_ia32_sse.nb213_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb213_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb213_n(%esp)
        movl %ebx,nb213_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel213_ia32_sse.nb213_outerstart
        jmp _nb_kernel213_ia32_sse.nb213_end

_nb_kernel213_ia32_sse.nb213_outerstart: 
        ## ebx contains number of outer iterations
        addl nb213_nouter(%esp),%ebx
        movl %ebx,nb213_nouter(%esp)

_nb_kernel213_ia32_sse.nb213_outer: 
        movl  nb213_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx        ## ebx=3*is 
        movl  %ebx,nb213_is3(%esp)      ## store is3 

        movl  nb213_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb213_iinr(%ebp),%ecx             ## ecx = pointer into iinr[]    
        movl  (%ecx,%esi,4),%ebx                ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        movaps %xmm0,%xmm6
        movaps %xmm1,%xmm7

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb213_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb213_ii3(%esp)

        addss (%eax,%ebx,4),%xmm3       ## ox
        addss 4(%eax,%ebx,4),%xmm4     ## oy
        addss 8(%eax,%ebx,4),%xmm5     ## oz
        addss 12(%eax,%ebx,4),%xmm6    ## h1x
        addss 16(%eax,%ebx,4),%xmm7    ## h1y
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm7,%xmm7
        movaps %xmm3,nb213_ixO(%esp)
        movaps %xmm4,nb213_iyO(%esp)
        movaps %xmm5,nb213_izO(%esp)
        movaps %xmm6,nb213_ixH1(%esp)
        movaps %xmm7,nb213_iyH1(%esp)

        movss %xmm2,%xmm6
        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 20(%eax,%ebx,4),%xmm6    ## h1z
        addss 24(%eax,%ebx,4),%xmm0    ## h2x
        addss 28(%eax,%ebx,4),%xmm1    ## h2y
        addss 32(%eax,%ebx,4),%xmm2    ## h2z
        addss 36(%eax,%ebx,4),%xmm3    ## mx
        addss 40(%eax,%ebx,4),%xmm4    ## my
        addss 44(%eax,%ebx,4),%xmm5    ## mz

        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm6,nb213_izH1(%esp)
        movaps %xmm0,nb213_ixH2(%esp)
        movaps %xmm1,nb213_iyH2(%esp)
        movaps %xmm2,nb213_izH2(%esp)
        movaps %xmm3,nb213_ixM(%esp)
        movaps %xmm4,nb213_iyM(%esp)
        movaps %xmm5,nb213_izM(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb213_vctot(%esp)
        movaps %xmm4,nb213_Vvdwtot(%esp)
        movaps %xmm4,nb213_fixO(%esp)
        movaps %xmm4,nb213_fiyO(%esp)
        movaps %xmm4,nb213_fizO(%esp)
        movaps %xmm4,nb213_fixH1(%esp)
        movaps %xmm4,nb213_fiyH1(%esp)
        movaps %xmm4,nb213_fizH1(%esp)
        movaps %xmm4,nb213_fixH2(%esp)
        movaps %xmm4,nb213_fiyH2(%esp)
        movaps %xmm4,nb213_fizH2(%esp)
        movaps %xmm4,nb213_fixM(%esp)
        movaps %xmm4,nb213_fiyM(%esp)
        movaps %xmm4,nb213_fizM(%esp)

        movl  nb213_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx                ## jindex[n] 
        movl  4(%eax,%esi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movl  nb213_pos(%ebp),%esi
        movl  nb213_faction(%ebp),%edi
        movl  nb213_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb213_innerjjnr(%esp)        ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb213_ninner(%esp),%ecx
        movl  %ecx,nb213_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb213_innerk(%esp)   ## number of innerloop atoms 
        jge   _nb_kernel213_ia32_sse.nb213_unroll_loop
        jmp   _nb_kernel213_ia32_sse.nb213_odd_inner
_nb_kernel213_ia32_sse.nb213_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb213_innerjjnr(%esp),%edx        ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx             ## eax-edx=jnr1-4 

        addl $16,nb213_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb213_charge(%ebp),%esi    ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        movaps %xmm3,%xmm4              ## and in xmm4 
        mulps  nb213_iqM(%esp),%xmm3
        mulps  nb213_iqH(%esp),%xmm4

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movaps  %xmm3,nb213_qqM(%esp)
        movaps  %xmm4,nb213_qqH(%esp)

        movl nb213_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl (%esi,%ecx,4),%ecx
        movl (%esi,%edx,4),%edx
        movl nb213_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb213_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%esi,%eax,4),%xmm6
        movlps (%esi,%ecx,4),%xmm7
        movhps (%esi,%ebx,4),%xmm6