nb_kernel233_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,301 行 · 第 1/5 页

	shufps xmm1, xmm5, 221  ;# constant 11011101		

	;# move ixO-izO to xmm4-xmm6 
	movaps xmm4, [esp + nb233_ixO]
	movaps xmm5, [esp + nb233_iyO]
	movaps xmm6, [esp + nb233_izO]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb233_dxO], xmm4
	movaps [esp + nb233_dyO], xmm5
	movaps [esp + nb233_dzO], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	movaps xmm7, xmm4
	;# rsqO in xmm7

	;# move ixH1-izH1 to xmm4-xmm6 
	movaps xmm4, [esp + nb233_ixH1]
	movaps xmm5, [esp + nb233_iyH1]
	movaps xmm6, [esp + nb233_izH1]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb233_dxH1], xmm4
	movaps [esp + nb233_dyH1], xmm5
	movaps [esp + nb233_dzH1], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm6, xmm5
	addps xmm6, xmm4
	;# rsqH1 in xmm6 
		
	;# move ixH2-izH2 to xmm3-xmm5  
	movaps xmm3, [esp + nb233_ixH2]
	movaps xmm4, [esp + nb233_iyH2]
	movaps xmm5, [esp + nb233_izH2]

	;# calc dr 
	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2

	;# store dr 
	movaps [esp + nb233_dxH2], xmm3
	movaps [esp + nb233_dyH2], xmm4
	movaps [esp + nb233_dzH2], xmm5
	;# square it 
	mulps xmm3,xmm3
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	addps xmm5, xmm4
	addps xmm5, xmm3
	
	;# move ixM-izM to xmm2-xmm4  
	movaps xmm3, [esp + nb233_iyM]
	movaps xmm4, [esp + nb233_izM]
	subps  xmm3, xmm1
	subps  xmm4, xmm2
	movaps xmm2, [esp + nb233_ixM]
	subps  xmm2, xmm0	

	;# store dr 
	movaps [esp + nb233_dxM], xmm2
	movaps [esp + nb233_dyM], xmm3
	movaps [esp + nb233_dzM], xmm4
	;# square it 
	mulps xmm2,xmm2
	mulps xmm3,xmm3
	mulps xmm4,xmm4
	addps xmm4, xmm3
	addps xmm4, xmm2	
	;# rsqM in xmm4, rsqH2 in xmm5, rsqH1 in xmm6, rsqO in xmm7 
	movaps xmm0, xmm4
	movaps xmm1, xmm5
	movaps xmm2, xmm6
	mulps  xmm0, [esp + nb233_krf]	
	mulps  xmm1, [esp + nb233_krf]	
	mulps  xmm2, [esp + nb233_krf]	
	movaps [esp + nb233_krsqM], xmm0
	movaps [esp + nb233_krsqH2], xmm1
	movaps [esp + nb233_krsqH1], xmm2

	;# rsqH1 - seed in xmm2 
	rsqrtps xmm2, xmm6
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm0, [esp + nb233_three]
	mulps   xmm2, xmm6	;# rsq*lu*lu 
	subps   xmm0, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm0, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm0, [esp + nb233_half]
	movaps  [esp + nb233_rinvH1], xmm0	;# rinvH1 

	;# rsqH2 - seed to xmm2 
	rsqrtps xmm2, xmm5
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm0, [esp + nb233_three]
	mulps   xmm2, xmm5	;# rsq*lu*lu 
	subps   xmm0, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm0, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm0, [esp + nb233_half]
	movaps  [esp + nb233_rinvH2], xmm0	;# rinvH2 

	;# rsqM - seed to xmm2 
	rsqrtps xmm2, xmm4
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm0, [esp + nb233_three]
	mulps   xmm2, xmm4	;# rsq*lu*lu 
	subps   xmm0, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm0, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm0, [esp + nb233_half]
	movaps  [esp + nb233_rinvM], xmm0
	
	;# Do the O LJ-only interaction directly.	
	;# rsqO is in xmm7
	rsqrtps xmm2, xmm7
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb233_three]
	mulps   xmm2, xmm7	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb233_half]
	movaps  xmm0, xmm4
	;# xmm0=rinvO
	
	mulps xmm7, xmm0
	mulps xmm7, [esp + nb233_tsc] ;# rtab
	
	movhlps xmm5, xmm7
	cvttps2pi mm6, xmm7
	cvttps2pi mm7, xmm5	;# mm6/mm7 contain lu indices 
	cvtpi2ps xmm6, mm6
	cvtpi2ps xmm5, mm7
	movlhps xmm6, xmm5
	subps  xmm7, xmm6	
	movaps xmm1, xmm7	;# xmm1=eps 
	movaps xmm2, xmm1	
	mulps  xmm2, xmm2	;# xmm2=eps2 
	pslld mm6, 3
	pslld mm7, 3

	movd mm0, eax	
	movd mm1, ebx
	movd mm2, ecx
	movd mm3, edx	

	mov  esi, [ebp + nb233_VFtab]
	movd eax, mm6
	psrlq mm6, 32
	movd ecx, mm7
	psrlq mm7, 32
	movd ebx, mm6
	movd edx, mm7
	
	;# dispersion 
	movlps xmm5, [esi + eax*4]
	movlps xmm7, [esi + ecx*4]
	movhps xmm5, [esi + ebx*4]
	movhps xmm7, [esi + edx*4] ;# got half dispersion table 
	movaps xmm4, xmm5
	shufps xmm4, xmm7, 136  ;# constant 10001000
	shufps xmm5, xmm7, 221  ;# constant 11011101
	
	movlps xmm7, [esi + eax*4 + 8]
	movlps xmm3, [esi + ecx*4 + 8]
	movhps xmm7, [esi + ebx*4 + 8]
	movhps xmm3, [esi + edx*4 + 8] ;# other half of dispersion table 
	movaps xmm6, xmm7
	shufps xmm6, xmm3, 136  ;# constant 10001000
	shufps xmm7, xmm3, 221  ;# constant 11011101
	;# dispersion table ready, in xmm4-xmm7 	

	mulps  xmm6, xmm1	;# xmm6=Geps 
	mulps  xmm7, xmm2	;# xmm7=Heps2 
	addps  xmm5, xmm6
	addps  xmm5, xmm7	;# xmm5=Fp 	
	mulps  xmm7, [esp + nb233_two]	;# two*Heps2 
	addps  xmm7, xmm6
	addps  xmm7, xmm5 ;# xmm7=FF 
	mulps  xmm5, xmm1 ;# xmm5=eps*Fp 
	addps  xmm5, xmm4 ;# xmm5=VV 

	movaps xmm4, [esp + nb233_c6]
	mulps  xmm7, xmm4	 ;# fijD 
	mulps  xmm5, xmm4	 ;# Vvdw6 
	mulps  xmm7, [esp + nb233_tsc]
	;# put scalar force on stack Update Vvdwtot directly 
	addps  xmm5, [esp + nb233_Vvdwtot]
	movaps [esp + nb233_fstmp], xmm7
	movaps [esp + nb233_Vvdwtot], xmm5

	;# repulsion 
	movlps xmm5, [esi + eax*4 + 16]
	movlps xmm7, [esi + ecx*4 + 16]
	movhps xmm5, [esi + ebx*4 + 16]
	movhps xmm7, [esi + edx*4 + 16] ;# got half repulsion table 
	movaps xmm4, xmm5
	shufps xmm4, xmm7, 136  ;# constant 10001000
	shufps xmm5, xmm7, 221  ;# constant 11011101

	movlps xmm7, [esi + eax*4 + 24]
	movlps xmm3, [esi + ecx*4 + 24]
	movhps xmm7, [esi + ebx*4 + 24]
	movhps xmm3, [esi + edx*4 + 24] ;# other half of repulsion table 
	movaps xmm6, xmm7
	shufps xmm6, xmm3, 136  ;# constant 10001000
	shufps xmm7, xmm3, 221  ;# constant 11011101
	;# table ready, in xmm4-xmm7 	
	mulps  xmm6, xmm1	;# xmm6=Geps 
	mulps  xmm7, xmm2	;# xmm7=Heps2 
	addps  xmm5, xmm6
	addps  xmm5, xmm7	;# xmm5=Fp 	
	mulps  xmm7, [esp + nb233_two]	;# two*Heps2 
	addps  xmm7, xmm6
	addps  xmm7, xmm5 ;# xmm7=FF 
	mulps  xmm5, xmm1 ;# xmm5=eps*Fp 
	addps  xmm5, xmm4 ;# xmm5=VV 
 	
	movaps xmm4, [esp + nb233_c12]
	mulps  xmm7, xmm4 ;# fijR 
	mulps  xmm5, xmm4 ;# Vvdw12 
	mulps  xmm7, [esp + nb233_tsc]
	addps  xmm7, [esp + nb233_fstmp]

	addps  xmm5, [esp + nb233_Vvdwtot]
	movaps [esp + nb233_Vvdwtot], xmm5

	movd  eax, mm0
	movd  ebx, mm1
	movd  ecx, mm2
	movd  edx, mm3

	xorps  xmm1, xmm1
	mulps  xmm7, xmm0
	subps  xmm1, xmm7
	
	movaps xmm3, [esp + nb233_dxO]
	movaps xmm4, [esp + nb233_dyO]
	movaps xmm5, [esp + nb233_dzO]
	mulps  xmm3, xmm1
	mulps  xmm4, xmm1
	mulps  xmm5, xmm1	;# tx in xmm3-xmm5

	;# update O forces 
	movaps xmm0, [esp + nb233_fixO]
	movaps xmm1, [esp + nb233_fiyO]
	movaps xmm2, [esp + nb233_fizO]
	addps  xmm0, xmm3
	addps  xmm1, xmm4
	addps  xmm2, xmm5
	movaps [esp + nb233_fixO], xmm0
	movaps [esp + nb233_fiyO], xmm1
	movaps [esp + nb233_fizO], xmm2
	;# update j forces with water O 
	movaps [esp + nb233_fjx], xmm3
	movaps [esp + nb233_fjy], xmm4
	movaps [esp + nb233_fjz], xmm5

	;# Do H1 interaction
	movaps  xmm7, [esp + nb233_rinvH1]
	movaps  xmm4, xmm7	
	mulps   xmm4, xmm4	;# xmm7=rinv, xmm4=rinvsq
	movaps xmm0, xmm7
	movaps xmm1, [esp + nb233_krsqH1]
	addps  xmm0, xmm1
	subps  xmm0, [esp + nb233_crf] ;# xmm0=rinv+ krsq-crf 
	mulps  xmm1, [esp + nb233_two]
	subps  xmm7, xmm1
	mulps  xmm0, [esp + nb233_qqH]
	mulps  xmm7, [esp + nb233_qqH]

	mulps  xmm4, xmm7	;# total fs H1 in xmm4 

	addps  xmm0, [esp + nb233_vctot]	
	movaps [esp + nb233_vctot], xmm0

	movaps xmm0, [esp + nb233_dxH1]
	movaps xmm1, [esp + nb233_dyH1]
	movaps xmm2, [esp + nb233_dzH1]
	mulps  xmm0, xmm4
	mulps  xmm1, xmm4
	mulps  xmm2, xmm4

	;# update H1 forces 
	movaps xmm3, [esp + nb233_fixH1]
	movaps xmm4, [esp + nb233_fiyH1]
	movaps xmm7, [esp + nb233_fizH1]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	addps  xmm7, xmm2
	movaps [esp + nb233_fixH1], xmm3
	movaps [esp + nb233_fiyH1], xmm4
	movaps [esp + nb233_fizH1], xmm7
	;# update j forces with water H1 
	addps  xmm0, [esp + nb233_fjx]
	addps  xmm1, [esp + nb233_fjy]
	addps  xmm2, [esp + nb233_fjz]
	movaps [esp + nb233_fjx], xmm0
	movaps [esp + nb233_fjy], xmm1
	movaps [esp + nb233_fjz], xmm2

	;# Done with H1, do H2 interactions
	movaps  xmm7, [esp + nb233_rinvH2]
	movaps  xmm4, xmm7	
	mulps   xmm4, xmm4	;# xmm7=rinv, xmm4=rinvsq
	movaps xmm0, xmm7
	movaps xmm1, [esp + nb233_krsqH2]
	addps  xmm0, xmm1
	subps  xmm0, [esp + nb233_crf] ;# xmm0=rinv+ krsq-crf 
	mulps  xmm1, [esp + nb233_two]
	subps  xmm7, xmm1
	mulps  xmm0, [esp + nb233_qqH]
	mulps  xmm7, [esp + nb233_qqH]

	mulps  xmm4, xmm7	;# total fs H2 in xmm4 

	addps  xmm0, [esp + nb233_vctot]	
	movaps [esp + nb233_vctot], xmm0

	movaps xmm0, [esp + nb233_dxH2]
	movaps xmm1, [esp + nb233_dyH2]
	movaps xmm2, [esp + nb233_dzH2]
	mulps  xmm0, xmm4
	mulps  xmm1, xmm4
	mulps  xmm2, xmm4

	;# update H2 forces 
	movaps xmm3, [esp + nb233_fixH2]
	movaps xmm4, [esp + nb233_fiyH2]
	movaps xmm7, [esp + nb233_fizH2]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	addps  xmm7, xmm2
	movaps [esp + nb233_fixH2], xmm3
	movaps [esp + nb233_fiyH2], xmm4
	movaps [esp + nb233_fizH2], xmm7
	addps xmm0, [esp + nb233_fjx]
        addps xmm1, [esp + nb233_fjy]
        addps xmm2, [esp + nb233_fjz]
	movaps [esp + nb233_fjx], xmm0
	movaps [esp + nb233_fjy], xmm1
	movaps [esp + nb233_fjz], xmm2

	;# Done with H2, do M interactions
	movaps  xmm7, [esp + nb233_rinvM]
	movaps  xmm4, xmm7	
	mulps   xmm4, xmm4	;# xmm7=rinv, xmm4=rinvsq
	movaps xmm0, xmm7
	movaps xmm1, [esp + nb233_krsqM]
	addps  xmm0, xmm1
	subps  xmm0, [esp + nb233_crf] ;# xmm0=rinv+ krsq-crf 
	mulps  xmm1, [esp + nb233_two]
	subps  xmm7, xmm1
	mulps  xmm0, [esp + nb233_qqM]
	mulps  xmm7, [esp + nb233_qqM]

	mulps  xmm4, xmm7	;# total fs M in xmm4 

	addps  xmm0, [esp + nb233_vctot]	
	movaps [esp + nb233_vctot], xmm0

	movaps xmm0, [esp + nb233_dxM]
	movaps xmm1, [esp + nb233_dyM]
	movaps xmm2, [esp + nb233_dzM]
	mulps  xmm0, xmm4
	mulps  xmm1, xmm4
	mulps  xmm2, xmm4
	
	;# update M forces 
	movaps xmm3, [esp + nb233_fixM]
	movaps xmm4, [esp + nb233_fiyM]
	movaps xmm7, [esp + nb233_fizM]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	addps  xmm7, xmm2
	movaps [esp + nb233_fixM], xmm3
	movaps [esp + nb233_fiyM], xmm4
	movaps [esp + nb233_fizM], xmm7

	mov edi, [ebp + nb233_faction]
	;# update j forces from stored values
	addps xmm0, [esp + nb233_fjx]
	addps xmm1, [esp + nb233_fjy]
	addps xmm2, [esp + nb233_fjz]

	movlps xmm4, [edi + eax*4]
	movlps xmm7, [edi + ecx*4]
	movhps xmm4, [edi + ebx*4]
	movhps xmm7, [edi + edx*4]

	movaps xmm3, xmm4
	shufps xmm3, xmm7, 136  ;# constant 10001000
	shufps xmm4, xmm7, 221  ;# constant 11011101
	
	;# xmm3 has fjx, xmm4 has fjy 
	subps xmm3, xmm0
	subps xmm4, xmm1
	;# unpack them back for storing 
	movaps xmm7, xmm3
	unpcklps xmm7, xmm4
	unpckhps xmm3, xmm4	
	movlps [edi + eax*4], xmm7
	movlps [edi + ecx*4], xmm3
	movhps [edi + ebx*4], xmm7
	movhps [edi + edx*4], xmm3
	;# finally z forces 
	movss  xmm0, [edi + eax*4 + 8]
	movss  xmm1, [edi + ebx*4 + 8]
	movss  xmm3, [edi + ecx*4 + 8]
	movss  xmm4, [edi + edx*4 + 8]
	subss  xmm0, xmm2
	shufps xmm2, xmm2, 229  ;# constant 11100101
	subss  xmm1, xmm2
	shufps xmm2, xmm2, 234  ;# constant 11101010
	subss  xmm3, xmm2
	shufps xmm2, xmm2, 255  ;# constant 11111111
	subss  xmm4, xmm2
	movss  [edi + eax*4 + 8], xmm0
	movss  [edi + ebx*4 + 8], xmm1
	movss  [edi + ecx*4 + 8], xmm3
	movss  [edi + edx*4 + 8], xmm4
	
	;# should we do one more iteration? 
	sub dword ptr [esp + nb233_innerk],  4
	jl    .nb233_odd_inner
	jmp   .nb233_unroll_loop
.nb233_odd_inner:	
	add dword ptr [esp + nb233_innerk],  4
	jnz   .nb233_odd_loop
	jmp   .nb233_updateouterdata
.nb233_odd_loop:
	mov   edx, [esp + nb233_innerjjnr] 	;# pointer to jjnr[k] 
	mov   eax, [edx]	
	add dword ptr [esp + nb233_innerjjnr],  4	

 	xorps xmm4, xmm4  	;# clear reg.
	movss xmm4, [esp + nb233_iqM]
	mov esi, [ebp + nb233_charge] 
	movhps xmm4, [esp + nb233_iqH]  ;# [qM  0  qH  qH] 
	shufps xmm4, xmm4, 41	;# [0 qH qH qM]

	movss xmm3, [esi + eax*4]	;# charge in xmm3 
	shufps xmm3, xmm3, 0