nb_kernel234_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,980 行 · 第 1/5 页

##
## $Id: nb_kernel234_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:33 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##


.globl nb_kernel234_ia32_sse
.globl _nb_kernel234_ia32_sse
nb_kernel234_ia32_sse:  
_nb_kernel234_ia32_sse: 
.set nb234_p_nri, 8
.set nb234_iinr, 12
.set nb234_jindex, 16
.set nb234_jjnr, 20
.set nb234_shift, 24
.set nb234_shiftvec, 28
.set nb234_fshift, 32
.set nb234_gid, 36
.set nb234_pos, 40
.set nb234_faction, 44
.set nb234_charge, 48
.set nb234_p_facel, 52
.set nb234_argkrf, 56
.set nb234_argcrf, 60
.set nb234_Vc, 64
.set nb234_type, 68
.set nb234_p_ntype, 72
.set nb234_vdwparam, 76
.set nb234_Vvdw, 80
.set nb234_p_tabscale, 84
.set nb234_VFtab, 88
.set nb234_invsqrta, 92
.set nb234_dvda, 96
.set nb234_p_gbtabscale, 100
.set nb234_GBtab, 104
.set nb234_p_nthreads, 108
.set nb234_count, 112
.set nb234_mtx, 116
.set nb234_outeriter, 120
.set nb234_inneriter, 124
.set nb234_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb234_ixO, 0
.set nb234_iyO, 16
.set nb234_izO, 32
.set nb234_ixH1, 48
.set nb234_iyH1, 64
.set nb234_izH1, 80
.set nb234_ixH2, 96
.set nb234_iyH2, 112
.set nb234_izH2, 128
.set nb234_ixM, 144
.set nb234_iyM, 160
.set nb234_izM, 176
.set nb234_jxO, 192
.set nb234_jyO, 208
.set nb234_jzO, 224
.set nb234_jxH1, 240
.set nb234_jyH1, 256
.set nb234_jzH1, 272
.set nb234_jxH2, 288
.set nb234_jyH2, 304
.set nb234_jzH2, 320
.set nb234_jxM, 336
.set nb234_jyM, 352
.set nb234_jzM, 368
.set nb234_dxOO, 384
.set nb234_dyOO, 400
.set nb234_dzOO, 416
.set nb234_dxH1H1, 432
.set nb234_dyH1H1, 448
.set nb234_dzH1H1, 464
.set nb234_dxH1H2, 480
.set nb234_dyH1H2, 496
.set nb234_dzH1H2, 512
.set nb234_dxH1M, 528
.set nb234_dyH1M, 544
.set nb234_dzH1M, 560
.set nb234_dxH2H1, 576
.set nb234_dyH2H1, 592
.set nb234_dzH2H1, 608
.set nb234_dxH2H2, 624
.set nb234_dyH2H2, 640
.set nb234_dzH2H2, 656
.set nb234_dxH2M, 672
.set nb234_dyH2M, 688
.set nb234_dzH2M, 704
.set nb234_dxMH1, 720
.set nb234_dyMH1, 736
.set nb234_dzMH1, 752
.set nb234_dxMH2, 768
.set nb234_dyMH2, 784
.set nb234_dzMH2, 800
.set nb234_dxMM, 816
.set nb234_dyMM, 832
.set nb234_dzMM, 848
.set nb234_qqMM, 864
.set nb234_qqMH, 880
.set nb234_qqHH, 896
.set nb234_two, 912
.set nb234_c6, 928
.set nb234_c12, 944
.set nb234_tsc, 960
.set nb234_fscal, 976
.set nb234_vctot, 992
.set nb234_Vvdwtot, 1008
.set nb234_fixO, 1024
.set nb234_fiyO, 1040
.set nb234_fizO, 1056
.set nb234_fixH1, 1072
.set nb234_fiyH1, 1088
.set nb234_fizH1, 1104
.set nb234_fixH2, 1120
.set nb234_fiyH2, 1136
.set nb234_fizH2, 1152
.set nb234_fixM, 1168
.set nb234_fiyM, 1184
.set nb234_fizM, 1200
.set nb234_fjxO, 1216
.set nb234_fjyO, 1232
.set nb234_fjzO, 1248
.set nb234_fjxH1, 1264
.set nb234_fjyH1, 1280
.set nb234_fjzH1, 1296
.set nb234_fjxH2, 1312
.set nb234_fjyH2, 1328
.set nb234_fjzH2, 1344
.set nb234_fjxM, 1360
.set nb234_fjyM, 1376
.set nb234_fjzM, 1392
.set nb234_half, 1408
.set nb234_three, 1424
.set nb234_rsqOO, 1440
.set nb234_rsqH1H1, 1456
.set nb234_rsqH1H2, 1472
.set nb234_rsqH1M, 1488
.set nb234_rsqH2H1, 1504
.set nb234_rsqH2H2, 1520
.set nb234_rsqH2M, 1536
.set nb234_rsqMH1, 1552
.set nb234_rsqMH2, 1568
.set nb234_rsqMM, 1584
.set nb234_rinvOO, 1600
.set nb234_rinvH1H1, 1616
.set nb234_rinvH1H2, 1632
.set nb234_rinvH1M, 1648
.set nb234_rinvH2H1, 1664
.set nb234_rinvH2H2, 1680
.set nb234_rinvH2M, 1696
.set nb234_rinvMH1, 1712
.set nb234_rinvMH2, 1728
.set nb234_rinvMM, 1744
.set nb234_fstmp, 1760
.set nb234_krf, 1776
.set nb234_crf, 1792
.set nb234_is3, 1808
.set nb234_ii3, 1812
.set nb234_innerjjnr, 1816
.set nb234_innerk, 1820
.set nb234_n, 1824
.set nb234_nn1, 1828
.set nb234_nri, 1832
.set nb234_nouter, 1836
.set nb234_ninner, 1840
.set nb234_salign, 1844
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $1848,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb234_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb234_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb234_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb234_nouter(%esp)
        movl %eax,nb234_ninner(%esp)

        movl nb234_p_tabscale(%ebp),%eax
        movss (%eax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb234_tsc(%esp)

        movl nb234_argkrf(%ebp),%esi
        movl nb234_argcrf(%ebp),%edi
        movss (%esi),%xmm5
        movss (%edi),%xmm6
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        movaps %xmm5,nb234_krf(%esp)
        movaps %xmm6,nb234_crf(%esp)
        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb234_half(%esp)
        movss nb234_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb234_half(%esp)
        movaps %xmm2,nb234_two(%esp)
        movaps %xmm3,nb234_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb234_iinr(%ebp),%ecx     ## ecx = pointer into iinr[]
        movl  (%ecx),%ebx               ## ebx =ii 

        movl  nb234_charge(%ebp),%edx
        movss 4(%edx,%ebx,4),%xmm5
        movss 12(%edx,%ebx,4),%xmm3
        movss %xmm3,%xmm4
        movl nb234_p_facel(%ebp),%esi
        movss (%esi),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb234_qqMM(%esp)
        movaps %xmm4,nb234_qqMH(%esp)
        movaps %xmm5,nb234_qqHH(%esp)

        xorps %xmm0,%xmm0
        movl  nb234_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movl nb234_p_ntype(%ebp),%edi
        imull (%edi),%ecx ## ecx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movl  nb234_vdwparam(%ebp),%eax
        movlps (%eax,%edx,4),%xmm0
        movaps %xmm0,%xmm1
        shufps $0,%xmm0,%xmm0
        shufps $0x55,%xmm1,%xmm1
        movaps %xmm0,nb234_c6(%esp)
        movaps %xmm1,nb234_c12(%esp)

_nb_kernel234_ia32_sse.nb234_threadloop: 
        movl  nb234_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel234_ia32_sse.nb234_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel234_ia32_sse.nb234_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb234_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb234_n(%esp)
        movl %ebx,nb234_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel234_ia32_sse.nb234_outerstart
        jmp _nb_kernel234_ia32_sse.nb234_end

_nb_kernel234_ia32_sse.nb234_outerstart: 
        ## ebx contains number of outer iterations
        addl nb234_nouter(%esp),%ebx
        movl %ebx,nb234_nouter(%esp)

_nb_kernel234_ia32_sse.nb234_outer: 
        movl  nb234_shift(%ebp),%eax            ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx        ## ebx=3*is 
        movl  %ebx,nb234_is3(%esp)      ## store is3 

        movl  nb234_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb234_iinr(%ebp),%ecx             ## ecx = pointer into iinr[]    
        movl  (%ecx,%esi,4),%ebx                ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb234_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb234_ii3(%esp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        movaps %xmm0,%xmm6
        movaps %xmm1,%xmm7

        addss (%eax,%ebx,4),%xmm3       ## ox
        addss 4(%eax,%ebx,4),%xmm4     ## oy
        addss 8(%eax,%ebx,4),%xmm5     ## oz
        addss 12(%eax,%ebx,4),%xmm6    ## h1x
        addss 16(%eax,%ebx,4),%xmm7    ## h1y
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm7,%xmm7
        movaps %xmm3,nb234_ixO(%esp)
        movaps %xmm4,nb234_iyO(%esp)
        movaps %xmm5,nb234_izO(%esp)
        movaps %xmm6,nb234_ixH1(%esp)
        movaps %xmm7,nb234_iyH1(%esp)

        movss %xmm2,%xmm6
        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 20(%eax,%ebx,4),%xmm6    ## h1z
        addss 24(%eax,%ebx,4),%xmm0    ## h2x
        addss 28(%eax,%ebx,4),%xmm1    ## h2y
        addss 32(%eax,%ebx,4),%xmm2    ## h2z
        addss 36(%eax,%ebx,4),%xmm3    ## mx
        addss 40(%eax,%ebx,4),%xmm4    ## my
        addss 44(%eax,%ebx,4),%xmm5    ## mz

        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm6,nb234_izH1(%esp)
        movaps %xmm0,nb234_ixH2(%esp)
        movaps %xmm1,nb234_iyH2(%esp)
        movaps %xmm2,nb234_izH2(%esp)
        movaps %xmm3,nb234_ixM(%esp)
        movaps %xmm4,nb234_iyM(%esp)
        movaps %xmm5,nb234_izM(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb234_vctot(%esp)
        movaps %xmm4,nb234_Vvdwtot(%esp)
        movaps %xmm4,nb234_fixO(%esp)
        movaps %xmm4,nb234_fiyO(%esp)
        movaps %xmm4,nb234_fizO(%esp)
        movaps %xmm4,nb234_fixH1(%esp)
        movaps %xmm4,nb234_fiyH1(%esp)
        movaps %xmm4,nb234_fizH1(%esp)
        movaps %xmm4,nb234_fixH2(%esp)
        movaps %xmm4,nb234_fiyH2(%esp)
        movaps %xmm4,nb234_fizH2(%esp)
        movaps %xmm4,nb234_fixM(%esp)
        movaps %xmm4,nb234_fiyM(%esp)
        movaps %xmm4,nb234_fizM(%esp)

        movl  nb234_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx                ## jindex[n] 
        movl  4(%eax,%esi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movl  nb234_pos(%ebp),%esi
        movl  nb234_faction(%ebp),%edi