nb_kernel303_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,990 行 · 第 1/4 页

;#
;# $Id: nb_kernel303_ia32_sse.intel_syntax.s,v 1.1.2.1 2006/03/01 15:18:30 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as




.globl nb_kernel303_ia32_sse
.globl _nb_kernel303_ia32_sse
nb_kernel303_ia32_sse:	
_nb_kernel303_ia32_sse:	
.equiv          nb303_p_nri,            8
.equiv          nb303_iinr,             12
.equiv          nb303_jindex,           16
.equiv          nb303_jjnr,             20
.equiv          nb303_shift,            24
.equiv          nb303_shiftvec,         28
.equiv          nb303_fshift,           32
.equiv          nb303_gid,              36
.equiv          nb303_pos,              40
.equiv          nb303_faction,          44
.equiv          nb303_charge,           48
.equiv          nb303_p_facel,          52
.equiv          nb303_argkrf,           56
.equiv          nb303_argcrf,           60
.equiv          nb303_Vc,               64
.equiv          nb303_type,             68
.equiv          nb303_p_ntype,          72
.equiv          nb303_vdwparam,         76
.equiv          nb303_Vvdw,             80
.equiv          nb303_p_tabscale,       84
.equiv          nb303_VFtab,            88
.equiv          nb303_invsqrta,         92
.equiv          nb303_dvda,             96
.equiv          nb303_p_gbtabscale,     100
.equiv          nb303_GBtab,            104
.equiv          nb303_p_nthreads,       108
.equiv          nb303_count,            112
.equiv          nb303_mtx,              116
.equiv          nb303_outeriter,        120
.equiv          nb303_inneriter,        124
.equiv          nb303_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb303_ixH1,             0
.equiv          nb303_iyH1,             16
.equiv          nb303_izH1,             32
.equiv          nb303_ixH2,             48
.equiv          nb303_iyH2,             64
.equiv          nb303_izH2,             80
.equiv          nb303_ixM,              96
.equiv          nb303_iyM,              112
.equiv          nb303_izM,              128
.equiv          nb303_iqH,              144
.equiv          nb303_iqM,              160
.equiv          nb303_dxH1,             176
.equiv          nb303_dyH1,             192
.equiv          nb303_dzH1,             208
.equiv          nb303_dxH2,             224
.equiv          nb303_dyH2,             240
.equiv          nb303_dzH2,             256
.equiv          nb303_dxM,              272
.equiv          nb303_dyM,              288
.equiv          nb303_dzM,              304
.equiv          nb303_qqH,              320
.equiv          nb303_qqM,              336
.equiv          nb303_rinvH1,           352
.equiv          nb303_rinvH2,           368
.equiv          nb303_rinvM,            384
.equiv          nb303_rH1,              400
.equiv          nb303_rH2,              416
.equiv          nb303_rM,               432
.equiv          nb303_tsc,              448
.equiv          nb303_two,              464
.equiv          nb303_vctot,            480
.equiv          nb303_fixH1,            496
.equiv          nb303_fiyH1,            512
.equiv          nb303_fizH1,            528
.equiv          nb303_fixH2,            544
.equiv          nb303_fiyH2,            560
.equiv          nb303_fizH2,            576
.equiv          nb303_fixM,             592
.equiv          nb303_fiyM,             608
.equiv          nb303_fizM,             624
.equiv          nb303_fjx,              640
.equiv          nb303_fjy,              656
.equiv          nb303_fjz,              672
.equiv          nb303_half,             688
.equiv          nb303_three,            704
.equiv          nb303_is3,              720
.equiv          nb303_ii3,              724
.equiv          nb303_innerjjnr,        728
.equiv          nb303_innerk,           732
.equiv          nb303_n,                736
.equiv          nb303_nn1,              740
.equiv          nb303_nri,              744
.equiv          nb303_nouter,           748
.equiv          nb303_ninner,           752
.equiv          nb303_salign,           756
	push ebp
	mov ebp,esp	
	push eax
	push ebx
	push ecx
	push edx
	push esi
	push edi
	sub esp, 760		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb303_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb303_p_nri]
	mov ecx, [ecx]
	mov [esp + nb303_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb303_nouter], eax
	mov [esp + nb303_ninner], eax


	mov eax, [ebp + nb303_p_tabscale]
	movss xmm3, [eax]
	shufps xmm3, xmm3, 0 
	movaps [esp + nb303_tsc], xmm3
	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb303_half], eax
	movss xmm1, [esp + nb303_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# 2.0
	addps  xmm3, xmm2	;# 3.0
	movaps [esp + nb303_half],  xmm1
	movaps [esp + nb303_two],  xmm2
	movaps [esp + nb303_three],  xmm3
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb303_iinr]   	;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]		;# ebx =ii 

	mov   edx, [ebp + nb303_charge]
	movss xmm3, [edx + ebx*4 + 4]	
	movss xmm4, [edx + ebx*4 + 12]	
	mov esi, [ebp + nb303_p_facel]
	movss xmm5, [esi]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [esp + nb303_iqH], xmm3
	movaps [esp + nb303_iqM], xmm4
		
.nb303_threadloop:
        mov   esi, [ebp + nb303_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb303_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb303_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb303_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb303_n], eax
        mov [esp + nb303_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb303_outerstart
        jmp .nb303_end
	
.nb303_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb303_nouter]
	mov [esp + nb303_nouter], ebx

.nb303_outer:
	mov   eax, [ebp + nb303_shift]  	;# eax = pointer into shift[] 
	mov   ebx, [eax + esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]	;# ebx=3*is 
	mov   [esp + nb303_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb303_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [eax + ebx*4]
	movss xmm1, [eax + ebx*4 + 4]
	movss xmm2, [eax + ebx*4 + 8] 

	mov   ecx, [ebp + nb303_iinr]   	;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx + esi*4]		;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb303_pos]	;# eax = base of pos[]  
	mov   [esp + nb303_ii3], ebx

	addss xmm3, [eax + ebx*4 + 12]
	addss xmm4, [eax + ebx*4 + 16]
	addss xmm5, [eax + ebx*4 + 20]		
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb303_ixH1], xmm3
	movaps [esp + nb303_iyH1], xmm4
	movaps [esp + nb303_izH1], xmm5

	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm0, [eax + ebx*4 + 24]
	addss xmm1, [eax + ebx*4 + 28]
	addss xmm2, [eax + ebx*4 + 32]		
	addss xmm3, [eax + ebx*4 + 36]
	addss xmm4, [eax + ebx*4 + 40]
	addss xmm5, [eax + ebx*4 + 44]		

	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb303_ixH2], xmm0
	movaps [esp + nb303_iyH2], xmm1
	movaps [esp + nb303_izH2], xmm2
	movaps [esp + nb303_ixM], xmm3
	movaps [esp + nb303_iyM], xmm4
	movaps [esp + nb303_izM], xmm5
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [esp + nb303_vctot], xmm4
	movaps [esp + nb303_fixH1], xmm4
	movaps [esp + nb303_fiyH1], xmm4
	movaps [esp + nb303_fizH1], xmm4
	movaps [esp + nb303_fixH2], xmm4
	movaps [esp + nb303_fiyH2], xmm4
	movaps [esp + nb303_fizH2], xmm4
	movaps [esp + nb303_fixM], xmm4
	movaps [esp + nb303_fiyM], xmm4
	movaps [esp + nb303_fizM], xmm4
	
	mov   eax, [ebp + nb303_jindex]
	mov   ecx, [eax + esi*4]	 	;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	 	;# jindex[n+1] 
	sub   edx, ecx           	;# number of innerloop atoms 

	mov   esi, [ebp + nb303_pos]
	mov   edi, [ebp + nb303_faction]	
	mov   eax, [ebp + nb303_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb303_innerjjnr], eax 	;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [esp + nb303_ninner]
	mov   [esp + nb303_ninner], ecx
	add   edx, 0
	mov   [esp + nb303_innerk], edx	;# number of innerloop atoms 
	jge   .nb303_unroll_loop
	jmp   .nb303_odd_inner
.nb303_unroll_loop:
	;# quad-unroll innerloop here 
	mov   edx, [esp + nb303_innerjjnr] 	;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	mov   ecx, [edx + 8]            
	mov   edx, [edx + 12]     	;# eax-edx=jnr1-4 

	add dword ptr [esp + nb303_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov esi, [ebp + nb303_charge]	;# base of charge[] 
	
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]

	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	 	;# and in xmm4 
	mulps  xmm3, [esp + nb303_iqH]
	mulps  xmm4, [esp + nb303_iqM]

	movaps  [esp + nb303_qqH], xmm3
	movaps  [esp + nb303_qqM], xmm4	

	mov esi, [ebp + nb303_pos]   	;# base of pos[] 

	lea   eax, [eax + eax*2] 	;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	
	lea   ecx, [ecx + ecx*2] 	;# replace jnr with j3 
	lea   edx, [edx + edx*2]	

	;# move four coordinates to xmm0-xmm2 	
	movlps xmm4, [esi + eax*4]
	movlps xmm5, [esi + ecx*4]
	movss xmm2, [esi + eax*4 + 8]
	movss xmm6, [esi + ecx*4 + 8]

	movhps xmm4, [esi + ebx*4]
	movhps xmm5, [esi + edx*4]

	movss xmm0, [esi + ebx*4 + 8]
	movss xmm1, [esi + edx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# 10001000
	
	shufps xmm0, xmm5, 136  ;# 10001000
	shufps xmm1, xmm5, 221  ;# 11011101		

	;# move ixH1-izH1 to xmm4-xmm6 
	movaps xmm4, [esp + nb303_ixH1]
	movaps xmm5, [esp + nb303_iyH1]
	movaps xmm6, [esp + nb303_izH1]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb303_dxH1], xmm4
	movaps [esp + nb303_dyH1], xmm5
	movaps [esp + nb303_dzH1], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	movaps xmm7, xmm4
	;# rsqH1 in xmm7 

	;# move ixH2-izH2 to xmm4-xmm6 
	movaps xmm4, [esp + nb303_ixH2]
	movaps xmm5, [esp + nb303_iyH2]
	movaps xmm6, [esp + nb303_izH2]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb303_dxH2], xmm4
	movaps [esp + nb303_dyH2], xmm5
	movaps [esp + nb303_dzH2], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm6, xmm5
	addps xmm6, xmm4
	;# rsqH2 in xmm6 

	;# move ixM-izM to xmm3-xmm5  
	movaps xmm3, [esp + nb303_ixM]
	movaps xmm4, [esp + nb303_iyM]
	movaps xmm5, [esp + nb303_izM]

	;# calc dr 
	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2

	;# store dr 
	movaps [esp + nb303_dxM], xmm3
	movaps [esp + nb303_dyM], xmm4
	movaps [esp + nb303_dzM], xmm5
	;# square it 
	mulps xmm3,xmm3
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	addps xmm5, xmm4
	addps xmm5, xmm3
	;# rsqM in xmm5, rsqH2 in xmm6, rsqH1 in xmm7 

	;# start with rsqH1 - seed to xmm2 	
	rsqrtps xmm2, xmm7
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb303_three]
	mulps   xmm2, xmm7	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb303_half]
	movaps  [esp + nb303_rinvH1], xmm4	;# rinvH1 in xmm4 
	mulps   xmm7, xmm4
	movaps  [esp + nb303_rH1], xmm7	

	;# rsqH2 - seed in xmm2 
	rsqrtps xmm2, xmm6
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb303_three]
	mulps   xmm2, xmm6	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb303_half]
	movaps  [esp + nb303_rinvH2], xmm4	;# rinvH2 in xmm4 
	mulps   xmm6, xmm4
	movaps  [esp + nb303_rH2], xmm6

	;# rsqM - seed to xmm2 
	rsqrtps xmm2, xmm5
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb303_three]
	mulps   xmm2, xmm5	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb303_half]
	movaps  [esp + nb303_rinvM], xmm4	;# rinvM in xmm4 
	mulps   xmm5, xmm4
	movaps  [esp + nb303_rM], xmm5

	;# do H1 interactions 
	;# rH1 is still in xmm7 
	mulps   xmm7, [esp + nb303_tsc]
	movhlps xmm4, xmm7
	cvttps2pi mm6, xmm7
	cvttps2pi mm7, xmm4	;# mm6/mm7 contain lu indices 
	
	cvtpi2ps xmm3, mm6
	cvtpi2ps xmm4, mm7
	movlhps xmm3, xmm4
	
	subps xmm7, xmm3