nb_kernel213_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,984 行 · 第 1/4 页

;#
;# $Id: nb_kernel213_ia32_sse.intel_syntax.s,v 1.1.2.1 2006/03/01 15:18:29 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as


	
.globl nb_kernel213_ia32_sse
.globl _nb_kernel213_ia32_sse
nb_kernel213_ia32_sse:	
_nb_kernel213_ia32_sse:	
.equiv          nb213_p_nri,            8
.equiv          nb213_iinr,             12
.equiv          nb213_jindex,           16
.equiv          nb213_jjnr,             20
.equiv          nb213_shift,            24
.equiv          nb213_shiftvec,         28
.equiv          nb213_fshift,           32
.equiv          nb213_gid,              36
.equiv          nb213_pos,              40
.equiv          nb213_faction,          44
.equiv          nb213_charge,           48
.equiv          nb213_p_facel,          52
.equiv          nb213_argkrf,           56
.equiv          nb213_argcrf,           60
.equiv          nb213_Vc,               64
.equiv          nb213_type,             68
.equiv          nb213_p_ntype,          72
.equiv          nb213_vdwparam,         76
.equiv          nb213_Vvdw,             80
.equiv          nb213_p_tabscale,       84
.equiv          nb213_VFtab,            88
.equiv          nb213_invsqrta,         92
.equiv          nb213_dvda,             96
.equiv          nb213_p_gbtabscale,     100
.equiv          nb213_GBtab,            104
.equiv          nb213_p_nthreads,       108
.equiv          nb213_count,            112
.equiv          nb213_mtx,              116
.equiv          nb213_outeriter,        120
.equiv          nb213_inneriter,        124
.equiv          nb213_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb213_ixO,              0
.equiv          nb213_iyO,              16
.equiv          nb213_izO,              32
.equiv          nb213_ixH1,             48
.equiv          nb213_iyH1,             64
.equiv          nb213_izH1,             80
.equiv          nb213_ixH2,             96
.equiv          nb213_iyH2,             112
.equiv          nb213_izH2,             128
.equiv          nb213_ixM,              144
.equiv          nb213_iyM,              160
.equiv          nb213_izM,              176
.equiv          nb213_iqM,              192
.equiv          nb213_iqH,              208
.equiv          nb213_dxO,              224
.equiv          nb213_dyO,              240
.equiv          nb213_dzO,              256
.equiv          nb213_dxH1,             272
.equiv          nb213_dyH1,             288
.equiv          nb213_dzH1,             304
.equiv          nb213_dxH2,             320
.equiv          nb213_dyH2,             336
.equiv          nb213_dzH2,             352
.equiv          nb213_dxM,              368
.equiv          nb213_dyM,              384
.equiv          nb213_dzM,              400
.equiv          nb213_qqM,              416
.equiv          nb213_qqH,              432
.equiv          nb213_rinvH1,           448
.equiv          nb213_rinvH2,           464
.equiv          nb213_rinvM,            480
.equiv          nb213_two,              496
.equiv          nb213_c6,               512
.equiv          nb213_c12,              528
.equiv          nb213_six,              544
.equiv          nb213_twelve,           560
.equiv          nb213_krf,              576
.equiv          nb213_crf,              592
.equiv          nb213_krsqH1,           608
.equiv          nb213_krsqH2,           624
.equiv          nb213_krsqM,            640
.equiv          nb213_vctot,            656
.equiv          nb213_Vvdwtot,          672
.equiv          nb213_fixO,             688
.equiv          nb213_fiyO,             704
.equiv          nb213_fizO,             720
.equiv          nb213_fixH1,            736
.equiv          nb213_fiyH1,            752
.equiv          nb213_fizH1,            768
.equiv          nb213_fixH2,            784
.equiv          nb213_fiyH2,            800
.equiv          nb213_fizH2,            816
.equiv          nb213_fixM,             832
.equiv          nb213_fiyM,             848
.equiv          nb213_fizM,             864
.equiv          nb213_fjx,              880
.equiv          nb213_fjy,              896
.equiv          nb213_fjz,              912
.equiv          nb213_half,             928
.equiv          nb213_three,            944
.equiv          nb213_is3,              960
.equiv          nb213_ii3,              964
.equiv          nb213_ntia,             968
.equiv          nb213_innerjjnr,        972
.equiv          nb213_innerk,           976
.equiv          nb213_n,                980
.equiv          nb213_nn1,              984
.equiv          nb213_nri,              988
.equiv          nb213_nouter,           992
.equiv          nb213_ninner,           996
.equiv          nb213_salign,           1000
	push ebp
	mov ebp,esp	
	push eax
	push ebx
	push ecx
	push edx
	push esi
	push edi
	sub esp, 1004		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb213_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb213_p_nri]
	mov ecx, [ecx]
	mov [esp + nb213_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb213_nouter], eax
	mov [esp + nb213_ninner], eax

	mov esi, [ebp + nb213_argkrf]
	mov edi, [ebp + nb213_argcrf]
	movss xmm5, [esi]
	movss xmm6, [edi]
	shufps xmm5, xmm5, 0
	shufps xmm6, xmm6, 0
	movaps [esp + nb213_krf], xmm5
	movaps [esp + nb213_crf], xmm6
	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb213_half], eax
	movss xmm1, [esp + nb213_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# constant 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# constant 2.0
	addps  xmm3, xmm2	;# constant 3.0
	movaps xmm4, xmm3
	addps  xmm4, xmm4	;# 6.0
	movaps xmm5, xmm4
	addps  xmm5, xmm5	;# constant 12.0
	movaps [esp + nb213_half],  xmm1
	movaps [esp + nb213_two],  xmm2
	movaps [esp + nb213_three],  xmm3
	movaps [esp + nb213_six],  xmm4
	movaps [esp + nb213_twelve],  xmm5
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb213_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb213_charge]
	movss xmm4, [edx + ebx*4 + 4]	
	movss xmm3, [edx + ebx*4 + 12]	
	mov esi, [ebp + nb213_p_facel]
	movss xmm5, [esi]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [esp + nb213_iqM], xmm3
	movaps [esp + nb213_iqH], xmm4
	
	mov   edx, [ebp + nb213_type]
	mov   ecx, [edx + ebx*4]
	shl   ecx, 1
	mov edi, [ebp + nb213_p_ntype]
	imul  ecx, [edi]      ;# ecx = ntia = 2*ntype*type[ii0] 
	mov   [esp + nb213_ntia], ecx		
.nb213_threadloop:
        mov   esi, [ebp + nb213_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb213_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb213_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb213_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb213_n], eax
        mov [esp + nb213_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb213_outerstart
        jmp .nb213_end
	
.nb213_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb213_nouter]
	mov [esp + nb213_nouter], ebx

.nb213_outer:
	mov   eax, [ebp + nb213_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax + esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]	;# ebx=3*is 
	mov   [esp + nb213_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb213_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [eax + ebx*4]
	movss xmm1, [eax + ebx*4 + 4]
	movss xmm2, [eax + ebx*4 + 8] 

	mov   ecx, [ebp + nb213_iinr]   	;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx + esi*4]		;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2	
	movaps xmm6, xmm0
	movaps xmm7, xmm1
	
	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb213_pos]	;# eax = base of pos[]  
	mov   [esp + nb213_ii3], ebx

	addss xmm3, [eax + ebx*4]  	;# ox
	addss xmm4, [eax + ebx*4 + 4]  ;# oy
	addss xmm5, [eax + ebx*4 + 8]  ;# oz
	addss xmm6, [eax + ebx*4 + 12] ;# h1x
	addss xmm7, [eax + ebx*4 + 16] ;# h1y
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	shufps xmm6, xmm6, 0
	shufps xmm7, xmm7, 0
	movaps [esp + nb213_ixO], xmm3
	movaps [esp + nb213_iyO], xmm4
	movaps [esp + nb213_izO], xmm5
	movaps [esp + nb213_ixH1], xmm6
	movaps [esp + nb213_iyH1], xmm7

	movss xmm6, xmm2
	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm6, [eax + ebx*4 + 20] ;# h1z
	addss xmm0, [eax + ebx*4 + 24] ;# h2x
	addss xmm1, [eax + ebx*4 + 28] ;# h2y
	addss xmm2, [eax + ebx*4 + 32] ;# h2z
	addss xmm3, [eax + ebx*4 + 36] ;# mx
	addss xmm4, [eax + ebx*4 + 40] ;# my
	addss xmm5, [eax + ebx*4 + 44] ;# mz

	shufps xmm6, xmm6, 0
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb213_izH1], xmm6
	movaps [esp + nb213_ixH2], xmm0
	movaps [esp + nb213_iyH2], xmm1
	movaps [esp + nb213_izH2], xmm2
	movaps [esp + nb213_ixM], xmm3
	movaps [esp + nb213_iyM], xmm4
	movaps [esp + nb213_izM], xmm5
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [esp + nb213_vctot], xmm4
	movaps [esp + nb213_Vvdwtot], xmm4
	movaps [esp + nb213_fixO], xmm4
	movaps [esp + nb213_fiyO], xmm4
	movaps [esp + nb213_fizO], xmm4
	movaps [esp + nb213_fixH1], xmm4
	movaps [esp + nb213_fiyH1], xmm4
	movaps [esp + nb213_fizH1], xmm4
	movaps [esp + nb213_fixH2], xmm4
	movaps [esp + nb213_fiyH2], xmm4
	movaps [esp + nb213_fizH2], xmm4
	movaps [esp + nb213_fixM], xmm4
	movaps [esp + nb213_fiyM], xmm4
	movaps [esp + nb213_fizM], xmm4
	
	mov   eax, [ebp + nb213_jindex]
	mov   ecx, [eax + esi*4]	 	;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	 	;# jindex[n+1] 
	sub   edx, ecx           	;# number of innerloop atoms 

	mov   esi, [ebp + nb213_pos]
	mov   edi, [ebp + nb213_faction]	
	mov   eax, [ebp + nb213_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb213_innerjjnr], eax 	;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [esp + nb213_ninner]
	mov   [esp + nb213_ninner], ecx
	add   edx, 0
	mov   [esp + nb213_innerk], edx	;# number of innerloop atoms 
	jge   .nb213_unroll_loop
	jmp   .nb213_odd_inner
.nb213_unroll_loop:
	;# quad-unroll innerloop here 
	mov   edx, [esp + nb213_innerjjnr] 	;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	mov   ecx, [edx + 8]            
	mov   edx, [edx + 12]     	;# eax-edx=jnr1-4 

	add dword ptr [esp + nb213_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov esi, [ebp + nb213_charge]	;# base of charge[] 
	
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]

	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	 	;# and in xmm4 
	mulps  xmm3, [esp + nb213_iqM]
	mulps  xmm4, [esp + nb213_iqH]

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx
	movd  mm2, ecx
	movd  mm3, edx

	movaps  [esp + nb213_qqM], xmm3
	movaps  [esp + nb213_qqH], xmm4
	
	mov esi, [ebp + nb213_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov ecx, [esi + ecx*4]
	mov edx, [esi + edx*4]
	mov esi, [ebp + nb213_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	shl ecx, 1	
	shl edx, 1	
	mov edi, [esp + nb213_ntia]
	add eax, edi
	add ebx, edi
	add ecx, edi
	add edx, edi

	movlps xmm6, [esi + eax*4]
	movlps xmm7, [esi + ecx*4]
	movhps xmm6, [esi + ebx*4]
	movhps xmm7, [esi + edx*4]

	movaps xmm4, xmm6
	shufps xmm4, xmm7, 136  ;# constant 10001000
	shufps xmm6, xmm7, 221  ;# constant 11011101
	
	movd  eax, mm0		
	movd  ebx, mm1
	movd  ecx, mm2
	movd  edx, mm3

	movaps [esp + nb213_c6], xmm4
	movaps [esp + nb213_c12], xmm6

	mov esi, [ebp + nb213_pos]   	;# base of pos[] 

	lea   eax, [eax + eax*2] 	;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	
	lea   ecx, [ecx + ecx*2] 	;# replace jnr with j3 
	lea   edx, [edx + edx*2]	

	;# move four coordinates to xmm0-xmm2 	
	movlps xmm4, [esi + eax*4]
	movlps xmm5, [esi + ecx*4]
	movss xmm2, [esi + eax*4 + 8]
	movss xmm6, [esi + ecx*4 + 8]

	movhps xmm4, [esi + ebx*4]
	movhps xmm5, [esi + edx*4]

	movss xmm0, [esi + ebx*4 + 8]
	movss xmm1, [esi + edx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# constant 10001000
	
	shufps xmm0, xmm5, 136  ;# constant 10001000
	shufps xmm1, xmm5, 221  ;# constant 11011101		

	;# move ixO-izO to xmm4-xmm6 
	movaps xmm4, [esp + nb213_ixO]
	movaps xmm5, [esp + nb213_iyO]
	movaps xmm6, [esp + nb213_izO]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb213_dxO], xmm4
	movaps [esp + nb213_dyO], xmm5
	movaps [esp + nb213_dzO], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	movaps xmm7, xmm4
	;# rsqO in xmm7

	;# move ixH1-izH1 to xmm4-xmm6 
	movaps xmm4, [esp + nb213_ixH1]
	movaps xmm5, [esp + nb213_iyH1]
	movaps xmm6, [esp + nb213_izH1]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2