nb_kernel331_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,107 行 · 第 1/5 页

        subps  %xmm7,%xmm4

        movaps nb331_dxH2(%esp),%xmm0
        movaps nb331_dyH2(%esp),%xmm1
        movaps nb331_dzH2(%esp),%xmm2
        mulps  %xmm4,%xmm0
        mulps  %xmm4,%xmm1
        mulps  %xmm4,%xmm2

    movd %mm0,%eax
    movd %mm1,%ebx
    movd %mm2,%ecx
    movd %mm3,%edx

        ## update H2 forces 
        movaps nb331_fixH2(%esp),%xmm3
        movaps nb331_fiyH2(%esp),%xmm4
        movaps nb331_fizH2(%esp),%xmm7
        addps  %xmm0,%xmm3
        addps  %xmm1,%xmm4
        addps  %xmm2,%xmm7
        movaps %xmm3,nb331_fixH2(%esp)
        movaps %xmm4,nb331_fiyH2(%esp)
        movaps %xmm7,nb331_fizH2(%esp)

        movl nb331_faction(%ebp),%edi
        ## update j forces 
        addps nb331_fjx(%esp),%xmm0
        addps nb331_fjy(%esp),%xmm1
        addps nb331_fjz(%esp),%xmm2

        movlps (%edi,%eax,4),%xmm4
        movlps (%edi,%ecx,4),%xmm7
        movhps (%edi,%ebx,4),%xmm4
        movhps (%edi,%edx,4),%xmm7

        movaps %xmm4,%xmm3
        shufps $136,%xmm7,%xmm3 ## constant 10001000
        shufps $221,%xmm7,%xmm4 ## constant 11011101                          
        ## xmm3 has fjx, xmm4 has fjy 
        subps %xmm0,%xmm3
        subps %xmm1,%xmm4
        ## unpack them back for storing 
        movaps %xmm3,%xmm7
        unpcklps %xmm4,%xmm7
        unpckhps %xmm4,%xmm3
        movlps %xmm7,(%edi,%eax,4)
        movlps %xmm3,(%edi,%ecx,4)
        movhps %xmm7,(%edi,%ebx,4)
        movhps %xmm3,(%edi,%edx,4)
        ## finally z forces 
        movss  8(%edi,%eax,4),%xmm0
        movss  8(%edi,%ebx,4),%xmm1
        movss  8(%edi,%ecx,4),%xmm3
        movss  8(%edi,%edx,4),%xmm4
        subss  %xmm2,%xmm0
        shufps $229,%xmm2,%xmm2 ## constant 11100101
        subss  %xmm2,%xmm1
        shufps $234,%xmm2,%xmm2 ## constant 11101010
        subss  %xmm2,%xmm3
        shufps $255,%xmm2,%xmm2 ## constant 11111111
        subss  %xmm2,%xmm4
        movss  %xmm0,8(%edi,%eax,4)
        movss  %xmm1,8(%edi,%ebx,4)
        movss  %xmm3,8(%edi,%ecx,4)
        movss  %xmm4,8(%edi,%edx,4)

        ## should we do one more iteration? 
        subl $4,nb331_innerk(%esp)
        jl    _nb_kernel331_ia32_sse.nb331_odd_inner
        jmp   _nb_kernel331_ia32_sse.nb331_unroll_loop
_nb_kernel331_ia32_sse.nb331_odd_inner: 
        addl $4,nb331_innerk(%esp)
        jnz   _nb_kernel331_ia32_sse.nb331_odd_loop
        jmp   _nb_kernel331_ia32_sse.nb331_updateouterdata
_nb_kernel331_ia32_sse.nb331_odd_loop: 
        movl  nb331_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        addl $4,nb331_innerjjnr(%esp)

        xorps %xmm4,%xmm4
        movss nb331_iqO(%esp),%xmm4
        movl nb331_charge(%ebp),%esi
        movhps nb331_iqH(%esp),%xmm4
        movss (%esi,%eax,4),%xmm3       ## charge in xmm3 
        shufps $0,%xmm3,%xmm3
        mulps %xmm4,%xmm3
        movaps %xmm3,nb331_qqO(%esp)    ## use oxygen qq for storage 

        xorps %xmm6,%xmm6
        movl nb331_type(%ebp),%esi
        movl (%esi,%eax,4),%ebx
        movl nb331_vdwparam(%ebp),%esi
        shll %ebx
        addl nb331_ntia(%esp),%ebx
        movlps (%esi,%ebx,4),%xmm6
        movaps %xmm6,%xmm7
        shufps $252,%xmm6,%xmm6 ## constant 11111100
        shufps $253,%xmm7,%xmm7 ## constant 11111101
        movaps %xmm6,nb331_c6(%esp)
        movaps %xmm7,nb331_c12(%esp)

        movl nb331_pos(%ebp),%esi
        leal  (%eax,%eax,2),%eax

        ## move j coords to xmm0-xmm2 
        movss (%esi,%eax,4),%xmm0
        movss 4(%esi,%eax,4),%xmm1
        movss 8(%esi,%eax,4),%xmm2
        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2

        movss nb331_ixO(%esp),%xmm3
        movss nb331_iyO(%esp),%xmm4
        movss nb331_izO(%esp),%xmm5

        movlps nb331_ixH1(%esp),%xmm6
        movlps nb331_ixH2(%esp),%xmm7
        unpcklps %xmm7,%xmm6
        movlhps %xmm6,%xmm3
        movlps nb331_iyH1(%esp),%xmm6
        movlps nb331_iyH2(%esp),%xmm7
        unpcklps %xmm7,%xmm6
        movlhps %xmm6,%xmm4
        movlps nb331_izH1(%esp),%xmm6
        movlps nb331_izH2(%esp),%xmm7
        unpcklps %xmm7,%xmm6
        movlhps %xmm6,%xmm5

        subps %xmm0,%xmm3
        subps %xmm1,%xmm4
        subps %xmm2,%xmm5

        movaps %xmm3,nb331_dxO(%esp)
        movaps %xmm4,nb331_dyO(%esp)
        movaps %xmm5,nb331_dzO(%esp)

        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5

        addps  %xmm3,%xmm4
        addps  %xmm5,%xmm4
        ## rsq in xmm4 

        rsqrtps %xmm4,%xmm5
        ## lookup seed in xmm5 
        movaps %xmm5,%xmm2
        mulps %xmm5,%xmm5
        movaps nb331_three(%esp),%xmm1
        mulps %xmm4,%xmm5       ## rsq*lu*lu                    
        movaps nb331_half(%esp),%xmm0
        subps %xmm5,%xmm1       ## constant 30-rsq*lu*lu 
        mulps %xmm2,%xmm1
        mulps %xmm1,%xmm0       ## xmm0=rinv 

        ## a little trick to avoid NaNs: 
        ## positions 0,2,and 3 are valid, but not 1. 
        ## If it contains NaN it doesnt help to mult by 0, 
        ## So we shuffle it and copy pos 0 to pos1! 
        shufps $224,%xmm0,%xmm0 ## constant 11100000     

        mulps %xmm0,%xmm4       ## xmm4=r 
        movaps %xmm0,nb331_rinvO(%esp)

        mulps nb331_tsc(%esp),%xmm4
        movhlps %xmm4,%xmm7
        cvttps2pi %xmm4,%mm6
        cvttps2pi %xmm7,%mm7   ## mm6/mm7 contain lu indices 
    cvtpi2ps %mm6,%xmm3
    cvtpi2ps %mm7,%xmm7
    movlhps %xmm7,%xmm3

        subps   %xmm3,%xmm4
        movaps %xmm4,%xmm1      ## xmm1=eps 
        movaps %xmm1,%xmm2
        mulps  %xmm2,%xmm2      ## xmm2=eps2 
    pslld $2,%mm6
    pslld $2,%mm7

    movd %eax,%mm0
    movd %ecx,%mm1
    movd %edx,%mm2

    movl nb331_VFtab(%ebp),%esi
    movd %mm6,%eax
    movd %mm7,%ecx
    psrlq $32,%mm7
    movd %mm7,%edx

    leal  (%eax,%eax,2),%eax
    leal  (%ecx,%ecx,2),%ecx
    leal  (%edx,%edx,2),%edx

    movlps (%esi,%eax,4),%xmm5
    movlps (%esi,%ecx,4),%xmm7
    movhps (%esi,%edx,4),%xmm7 ## got half coulomb table 

    movaps %xmm5,%xmm4
    shufps $136,%xmm7,%xmm4 ## constant 10001000
    shufps $221,%xmm7,%xmm5 ## constant 11011101

    movlps 8(%esi,%eax,4),%xmm7
    movlps 8(%esi,%ecx,4),%xmm3
    movhps 8(%esi,%edx,4),%xmm3    ## other half of coulomb table  
    movaps %xmm7,%xmm6
    shufps $136,%xmm3,%xmm6 ## constant 10001000
    shufps $221,%xmm3,%xmm7 ## constant 11011101
    ## coulomb table ready, in xmm4-xmm7      
    mulps  %xmm1,%xmm6      ## xmm6=Geps 
    mulps  %xmm2,%xmm7      ## xmm7=Heps2 
    addps  %xmm6,%xmm5
    addps  %xmm7,%xmm5      ## xmm5=Fp        
    mulps  nb331_two(%esp),%xmm7         ## two*Heps2 
    movaps nb331_qqO(%esp),%xmm0
    addps  %xmm6,%xmm7
    addps  %xmm5,%xmm7 ## xmm7=FF 
    mulps  %xmm1,%xmm5 ## xmm5=eps*Fp 
    addps  %xmm4,%xmm5 ## xmm5=VV 
    mulps  %xmm0,%xmm5 ## vcoul=qq*VV  
    mulps  %xmm7,%xmm0 ## fijC=FF*qq 
    ## at this point mm5 contains vcoul and xmm0 fijC 
    ## increment vcoul - then we can get rid of mm5 
    addps  nb331_vctot(%esp),%xmm5
    movaps %xmm5,nb331_vctot(%esp)

    ## dispersion 
    movlps 16(%esi,%eax,4),%xmm5        ## half table 
    movaps %xmm5,%xmm4
    shufps $252,%xmm4,%xmm4 ## constant 11111100
    shufps $253,%xmm5,%xmm5 ## constant 11111101

    movlps 24(%esi,%eax,4),%xmm7    ## other half of dispersion table 
    movaps %xmm7,%xmm6
    shufps $252,%xmm6,%xmm6 ## constant 11111100
    shufps $253,%xmm7,%xmm7 ## constant 11111101
    ## dispersion table ready, in xmm4-xmm7  
    mulss  %xmm1,%xmm6      ## xmm6=Geps 
    mulss  %xmm2,%xmm7      ## xmm7=Heps2 
    addss  %xmm6,%xmm5  ## Update Vvdwtot directly 
    addss  %xmm7,%xmm5      ## xmm5=Fp        
    mulss  nb331_two(%esp),%xmm7         ## two*Heps2 
    addss  %xmm6,%xmm7
    addss  %xmm5,%xmm7 ## xmm7=FF 
    mulss  %xmm1,%xmm5 ## xmm5=eps*Fp 
    addss  %xmm4,%xmm5 ## xmm5=VV 

    movaps nb331_c6(%esp),%xmm4
    mulps  %xmm4,%xmm7   ## fijD 
    mulps  %xmm4,%xmm5   ## Vvdw6 
    addps  %xmm7,%xmm0 ## add to fscal 

    ## Update Vvdwtot directly 
    addps  nb331_Vvdwtot(%esp),%xmm5
    movaps %xmm5,nb331_Vvdwtot(%esp)

    ## repulsion 
    movlps 32(%esi,%eax,4),%xmm5    ## got half repulsion table 
    movaps %xmm5,%xmm4
    shufps $136,%xmm4,%xmm4 ## constant 10001000
    shufps $221,%xmm5,%xmm5 ## constant 11011101

    movlps 40(%esi,%eax,4),%xmm7    ## other half of repulsion table 
    movaps %xmm7,%xmm6
    shufps $136,%xmm6,%xmm6 ## constant 10001000
    shufps $221,%xmm7,%xmm7 ## constant 11011101
    ## repulsion table ready, in xmm4-xmm7      
    mulss  %xmm1,%xmm6      ## xmm6=Geps 
    mulss  %xmm2,%xmm7      ## xmm7=Heps2 
    addss  %xmm6,%xmm5
    addss  %xmm7,%xmm5      ## xmm5=Fp        
    mulss  nb331_two(%esp),%xmm7         ## two*Heps2 
    addss  %xmm6,%xmm7
    addss  %xmm5,%xmm7 ## xmm7=FF 
    mulss  %xmm1,%xmm5 ## xmm5=eps*Fp 
    addss  %xmm4,%xmm5 ## xmm5=VV 

    movaps nb331_c12(%esp),%xmm4
    mulps  %xmm4,%xmm7   ## fijD 
    mulps  %xmm4,%xmm5   ## Vvdw12 
    addps  %xmm0,%xmm7 ## add to fscal 
    addps  nb331_Vvdwtot(%esp),%xmm5   ## total nonbonded potential in xmm5 

        xorps  %xmm4,%xmm4
    movd %mm0,%eax
    movd %mm1,%ecx
    movd %mm2,%edx

        mulps  nb331_rinvO(%esp),%xmm7   ## total fscal now in xmm7 
    movaps %xmm5,nb331_Vvdwtot(%esp)
        mulps  nb331_tsc(%esp),%xmm7
        subps %xmm7,%xmm4

        movaps nb331_dxO(%esp),%xmm0
        movaps nb331_dyO(%esp),%xmm1
        movaps nb331_dzO(%esp),%xmm2

        mulps  %xmm4,%xmm0
        mulps  %xmm4,%xmm1
        mulps  %xmm4,%xmm2 ## xmm0-xmm2 now contains tx-tz (partial force) 
        movss  nb331_fixO(%esp),%xmm3
        movss  nb331_fiyO(%esp),%xmm4
        movss  nb331_fizO(%esp),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,nb331_fixO(%esp)
        movss  %xmm4,nb331_fiyO(%esp)
        movss  %xmm5,nb331_fizO(%esp)   ## updated the O force now do the H's 
        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        shufps $230,%xmm3,%xmm3 ## constant 11100110     ;# shift right 
        shufps $230,%xmm4,%xmm4 ## constant 11100110
        shufps $230,%xmm5,%xmm5 ## constant 11100110
        addss  nb331_fixH1(%esp),%xmm3
        addss  nb331_fiyH1(%esp),%xmm4
        addss  nb331_fizH1(%esp),%xmm5
        movss  %xmm3,nb331_fixH1(%esp)
        movss  %xmm4,nb331_fiyH1(%esp)
        movss  %xmm5,nb331_fizH1(%esp)          ## updated the H1 force 

        movl nb331_faction(%ebp),%edi
        shufps $231,%xmm3,%xmm3 ## constant 11100111     ;# shift right 
        shufps $231,%xmm4,%xmm4 ## constant 11100111
        shufps $231,%xmm5,%xmm5 ## constant 11100111
        addss  nb331_fixH2(%esp),%xmm3
        addss  nb331_fiyH2(%esp),%xmm4
        addss  nb331_fizH2(%esp),%xmm5
        movss  %xmm3,nb331_fixH2(%esp)
        movss  %xmm4,nb331_fiyH2(%esp)
        movss  %xmm5,nb331_fizH2(%esp)          ## updated the H2 force 

        ## the fj's - start by accumulating the tx/ty/tz force in xmm0, xmm1 
        xorps  %xmm5,%xmm5
        movaps %xmm0,%xmm3
        movlps (%edi,%eax,4),%xmm6
        movss  8(%edi,%eax,4),%xmm7
        unpcklps %xmm1,%xmm3
        movlhps  %xmm5,%xmm3
        unpckhps %xmm1,%xmm0
        addps    %xmm3,%xmm0
        movhlps  %xmm0,%xmm3
        addps    %xmm3,%xmm0    ## x,y sum in xmm0 

        movhlps  %xmm2,%xmm1
        addss    %xmm1,%xmm2
        shufps  $1,%xmm1,%xmm1
        addss    %xmm1,%xmm2   ## z sum in xmm2 
        subps    %xmm0,%xmm6
        subss    %xmm2,%xmm7

        movlps %xmm6,(%edi,%eax,4)
        movss  %xmm7,8(%edi,%eax,4)

        decl nb331_innerk(%esp)
        jz    _nb_kernel331_ia32_sse.nb331_updateouterdata
        jmp   _nb_kernel331_ia32_sse.nb331_odd_loop
_nb_kernel331_ia32_sse.nb331_updateouterdata: 
        movl  nb331_ii3(%esp),%ecx
        movl  nb331_faction(%ebp),%edi
        movl  nb331_fshift(%ebp),%esi
        movl  nb331_is3(%esp),%edx

        ## accumulate  Oi forces in xmm0, xmm1, xmm2 
        movaps nb331_fixO(%esp),%xmm0
        movaps nb331_fiyO(%esp),%xmm1
        movaps nb331_fizO(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%edi,%ecx,4),%xmm3
        movss  4(%edi,%ecx,4),%xmm4
        movss  8(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,(%edi,%ecx,4)
        movss  %xmm4,4(%edi,%ecx,4)
        movss  %xmm5,8(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        movaps %xmm0,%xmm6
        movss %xmm2,%xmm7
        movlhps %xmm1,%xmm6
        shufps $8,%xmm6,%xmm6 ## constant 00001000      

        ## accumulate H1i forces in xmm0, xmm1, xmm2 
        movaps nb331_fixH1(%esp),%xmm0
        movaps nb331_fiyH1(%esp),%xmm1
        movaps nb331_fizH1(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3