nb_kernel204_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,959 行 · 第 1/5 页

        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret




.globl nb_kernel204nf_ia32_sse
.globl _nb_kernel204nf_ia32_sse
nb_kernel204nf_ia32_sse:        
_nb_kernel204nf_ia32_sse:       
.set nb204nf_p_nri, 8
.set nb204nf_iinr, 12
.set nb204nf_jindex, 16
.set nb204nf_jjnr, 20
.set nb204nf_shift, 24
.set nb204nf_shiftvec, 28
.set nb204nf_fshift, 32
.set nb204nf_gid, 36
.set nb204nf_pos, 40
.set nb204nf_faction, 44
.set nb204nf_charge, 48
.set nb204nf_p_facel, 52
.set nb204nf_argkrf, 56
.set nb204nf_argcrf, 60
.set nb204nf_Vc, 64
.set nb204nf_type, 68
.set nb204nf_p_ntype, 72
.set nb204nf_vdwparam, 76
.set nb204nf_Vvdw, 80
.set nb204nf_p_tabscale, 84
.set nb204nf_VFtab, 88
.set nb204nf_invsqrta, 92
.set nb204nf_dvda, 96
.set nb204nf_p_gbtabscale, 100
.set nb204nf_GBtab, 104
.set nb204nf_p_nthreads, 108
.set nb204nf_count, 112
.set nb204nf_mtx, 116
.set nb204nf_outeriter, 120
.set nb204nf_inneriter, 124
.set nb204nf_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb204nf_ixH1, 0
.set nb204nf_iyH1, 16
.set nb204nf_izH1, 32
.set nb204nf_ixH2, 48
.set nb204nf_iyH2, 64
.set nb204nf_izH2, 80
.set nb204nf_ixM, 96
.set nb204nf_iyM, 112
.set nb204nf_izM, 128
.set nb204nf_jxH1, 144
.set nb204nf_jyH1, 160
.set nb204nf_jzH1, 176
.set nb204nf_jxH2, 192
.set nb204nf_jyH2, 208
.set nb204nf_jzH2, 224
.set nb204nf_jxM, 240
.set nb204nf_jyM, 256
.set nb204nf_jzM, 272
.set nb204nf_qqHH, 288
.set nb204nf_qqMH, 304
.set nb204nf_qqMM, 320
.set nb204nf_vctot, 336
.set nb204nf_half, 352
.set nb204nf_three, 368
.set nb204nf_rsqH1H1, 384
.set nb204nf_rsqH1H2, 400
.set nb204nf_rsqH1M, 416
.set nb204nf_rsqH2H1, 432
.set nb204nf_rsqH2H2, 448
.set nb204nf_rsqH2M, 464
.set nb204nf_rsqMH1, 480
.set nb204nf_rsqMH2, 496
.set nb204nf_rsqMM, 512
.set nb204nf_rinvH1H1, 528
.set nb204nf_rinvH1H2, 544
.set nb204nf_rinvH1M, 560
.set nb204nf_rinvH2H1, 576
.set nb204nf_rinvH2H2, 592
.set nb204nf_rinvH2M, 608
.set nb204nf_rinvMH1, 624
.set nb204nf_rinvMH2, 640
.set nb204nf_rinvMM, 656
.set nb204nf_krf, 672
.set nb204nf_crf, 688
.set nb204nf_is3, 704
.set nb204nf_ii3, 708
.set nb204nf_innerjjnr, 712
.set nb204nf_innerk, 716
.set nb204nf_n, 720
.set nb204nf_nn1, 724
.set nb204nf_nri, 728
.set nb204nf_nouter, 732
.set nb204nf_ninner, 736
.set nb204nf_salign, 740
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $744,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb204nf_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb204nf_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb204nf_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb204nf_nouter(%esp)
        movl %eax,nb204nf_ninner(%esp)


        movl nb204nf_argkrf(%ebp),%esi
        movl nb204nf_argcrf(%ebp),%edi
        movss (%esi),%xmm5
        movss (%edi),%xmm6
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        movaps %xmm5,nb204nf_krf(%esp)
        movaps %xmm6,nb204nf_crf(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb204nf_half(%esp)
        movss nb204nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb204nf_half(%esp)
        movaps %xmm3,nb204nf_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb204nf_iinr(%ebp),%ecx           ## ecx = pointer into iinr[]    
        movl  (%ecx),%ebx               ## ebx =ii 

        movl  nb204nf_charge(%ebp),%edx
        movss 4(%edx,%ebx,4),%xmm3
        movss %xmm3,%xmm4
        movss 12(%edx,%ebx,4),%xmm5
        movl nb204nf_p_facel(%ebp),%esi
        movss (%esi),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb204nf_qqHH(%esp)
        movaps %xmm4,nb204nf_qqMH(%esp)
        movaps %xmm5,nb204nf_qqMM(%esp)

_nb_kernel204nf_ia32_sse.nb204nf_threadloop: 
        movl  nb204nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel204nf_ia32_sse.nb204nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel204nf_ia32_sse.nb204nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb204nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb204nf_n(%esp)
        movl %ebx,nb204nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel204nf_ia32_sse.nb204nf_outerstart
        jmp _nb_kernel204nf_ia32_sse.nb204nf_end

_nb_kernel204nf_ia32_sse.nb204nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb204nf_nouter(%esp),%ebx
        movl %ebx,nb204nf_nouter(%esp)

_nb_kernel204nf_ia32_sse.nb204nf_outer: 
        movl  nb204nf_shift(%ebp),%eax          ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx        ## ebx=3*is 
        movl  %ebx,nb204nf_is3(%esp)            ## store is3 

        movl  nb204nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb204nf_iinr(%ebp),%ecx           ## ecx = pointer into iinr[]    
        movl  (%ecx,%esi,4),%ebx                ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb204nf_pos(%ebp),%eax    ## eax = base of pos[]  
        movl  %ebx,nb204nf_ii3(%esp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        addss 12(%eax,%ebx,4),%xmm3
        addss 16(%eax,%ebx,4),%xmm4
        addss 20(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb204nf_ixH1(%esp)
        movaps %xmm4,nb204nf_iyH1(%esp)
        movaps %xmm5,nb204nf_izH1(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 24(%eax,%ebx,4),%xmm0
        addss 28(%eax,%ebx,4),%xmm1
        addss 32(%eax,%ebx,4),%xmm2
        addss 36(%eax,%ebx,4),%xmm3
        addss 40(%eax,%ebx,4),%xmm4
        addss 44(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb204nf_ixH2(%esp)
        movaps %xmm1,nb204nf_iyH2(%esp)
        movaps %xmm2,nb204nf_izH2(%esp)
        movaps %xmm3,nb204nf_ixM(%esp)
        movaps %xmm4,nb204nf_iyM(%esp)
        movaps %xmm5,nb204nf_izM(%esp)

        ## clear vctot 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb204nf_vctot(%esp)

        movl  nb204nf_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx                ## jindex[n] 
        movl  4(%eax,%esi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movl  nb204nf_pos(%ebp),%esi
        movl  nb204nf_faction(%ebp),%edi
        movl  nb204nf_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb204nf_innerjjnr(%esp)      ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb204nf_ninner(%esp),%ecx
        movl  %ecx,nb204nf_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb204nf_innerk(%esp)         ## number of innerloop atoms 
        jge   _nb_kernel204nf_ia32_sse.nb204nf_unroll_loop
        jmp   _nb_kernel204nf_ia32_sse.nb204nf_single_check
_nb_kernel204nf_ia32_sse.nb204nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb204nf_innerjjnr(%esp),%edx      ## pointer to jjnr[k] 

        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx             ## eax-edx=jnr1-4 

        addl $16,nb204nf_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb204nf_pos(%ebp),%esi     ## base of pos[] 

        leal  (%eax,%eax,2),%eax        ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx        ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move j coordinates to local temp variables 
        movlps 12(%esi,%eax,4),%xmm2
        movlps 24(%esi,%eax,4),%xmm3
        movlps 36(%esi,%eax,4),%xmm4

        movlps 12(%esi,%ebx,4),%xmm5
        movlps 24(%esi,%ebx,4),%xmm6
        movlps 36(%esi,%ebx,4),%xmm7

        movhps 12(%esi,%ecx,4),%xmm2
        movhps 24(%esi,%ecx,4),%xmm3
        movhps 36(%esi,%ecx,4),%xmm4

        movhps 12(%esi,%edx,4),%xmm5
        movhps 24(%esi,%edx,4),%xmm6
        movhps 36(%esi,%edx,4),%xmm7

        movaps %xmm2,%xmm0
        movaps %xmm3,%xmm1
        unpcklps %xmm5,%xmm0
        unpcklps %xmm6,%xmm1
        unpckhps %xmm5,%xmm2
        unpckhps %xmm6,%xmm3
        movaps %xmm4,%xmm5
        movaps   %xmm0,%xmm6
        unpcklps %xmm7,%xmm4
        unpckhps %xmm7,%xmm5
        movaps   %xmm1,%xmm7
        movlhps  %xmm2,%xmm0
        movaps %xmm0,nb204nf_jxH1(%esp)
        movhlps  %xmm6,%xmm2
        movaps %xmm2,nb204nf_jyH1(%esp)
        movlhps  %xmm3,%xmm1
        movaps %xmm1,nb204nf_jxH2(%esp)
        movhlps  %xmm7,%xmm3
        movaps   %xmm4,%xmm6
        movaps %xmm3,nb204nf_jyH2(%esp)
        movlhps  %xmm5,%xmm4
        movaps %xmm4,nb204nf_jxM(%esp)
        movhlps  %xmm6,%xmm5
        movaps %xmm5,nb204nf_jyM(%esp)

        movss  20(%esi,%eax,4),%xmm0
        movss  32(%esi,%eax,4),%xmm1
        movss  44(%esi,%eax,4),%xmm2

        movss  20(%esi,%ecx,4),%xmm3
        movss  32(%esi,%ecx,4),%xmm4
        movss  44(%esi,%ecx,4),%xmm5

        movhps 16(%esi,%ebx,4),%xmm0
        movhps 28(%esi,%ebx,4),%xmm1
        movhps 40(%esi,%ebx,4),%xmm2

        movhps 16(%esi,%edx,4),%xmm3
        movhps 28(%esi,%edx,4),%xmm4
        movhps 40(%esi,%edx,4),%xmm5

        shufps $204,%xmm3,%xmm0 ## constant 11001100
        shufps $204,%xmm4,%xmm1 ## constant 11001100
        shufps $204,%xmm5,%xmm2 ## constant 11001100
        movaps %xmm0,nb204nf_jzH1(%esp)
        movaps %xmm1,nb204nf_jzH2(%esp)
        movaps %xmm2,nb204nf_jzM(%esp)

        movaps nb204nf_ixH1(%esp),%xmm0
        movaps nb204nf_iyH1(%esp),%xmm1
        movaps nb204nf_izH1(%esp),%xmm2
        movaps nb204nf_ixH1(%esp),%xmm3
        movaps nb204nf_iyH1(%esp),%xmm4
        movaps nb204nf_izH1(%esp),%xmm5
        subps  nb204nf_jxH1(%esp),%xmm0
        subps  nb204nf_jyH1(%esp),%xmm1
        subps  nb204nf_jzH1(%esp),%xmm2
        subps  nb204nf_jxH2(%esp),%xmm3
        subps  nb204nf_jyH2(%esp),%xmm4
        subps  nb204nf_jzH2(%esp),%xmm5
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
        movaps %xmm0,nb2