nb_kernel132_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,018 行 · 第 1/5 页

        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  24(%edi,%ecx,4),%xmm3
        movss  28(%edi,%ecx,4),%xmm4
        movss  32(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,24(%edi,%ecx,4)
        movss  %xmm4,28(%edi,%ecx,4)
        movss  %xmm5,32(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## constant 00001000      
        addps   %xmm0,%xmm6

        ## increment fshift force  
        movlps  (%esi,%edx,4),%xmm3
        movss  8(%esi,%edx,4),%xmm4
        addps  %xmm6,%xmm3
        addss  %xmm7,%xmm4
        movlps  %xmm3,(%esi,%edx,4)
        movss  %xmm4,8(%esi,%edx,4)

        ## get n from stack
        movl nb132_n(%esp),%esi
        ## get group index for i particle 
        movl  nb132_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb132_vctot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb132_Vc(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## accumulate total lj energy and update it 
        movaps nb132_Vvdwtot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb132_Vvdw(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## finish if last 
        movl nb132_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel132_ia32_sse.nb132_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb132_n(%esp)
        jmp _nb_kernel132_ia32_sse.nb132_outer
_nb_kernel132_ia32_sse.nb132_outerend: 
        ## check if more outer neighborlists remain
        movl  nb132_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel132_ia32_sse.nb132_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel132_ia32_sse.nb132_threadloop
_nb_kernel132_ia32_sse.nb132_end: 
        emms

        movl nb132_nouter(%esp),%eax
        movl nb132_ninner(%esp),%ebx
        movl nb132_outeriter(%ebp),%ecx
        movl nb132_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        movl nb132_salign(%esp),%eax
        addl %eax,%esp
        addl $1560,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret


.globl nb_kernel132nf_ia32_sse
.globl _nb_kernel132nf_ia32_sse
nb_kernel132nf_ia32_sse:        
_nb_kernel132nf_ia32_sse:       
.set nb132nf_p_nri, 8
.set nb132nf_iinr, 12
.set nb132nf_jindex, 16
.set nb132nf_jjnr, 20
.set nb132nf_shift, 24
.set nb132nf_shiftvec, 28
.set nb132nf_fshift, 32
.set nb132nf_gid, 36
.set nb132nf_pos, 40
.set nb132nf_faction, 44
.set nb132nf_charge, 48
.set nb132nf_p_facel, 52
.set nb132nf_argkrf, 56
.set nb132nf_argcrf, 60
.set nb132nf_Vc, 64
.set nb132nf_type, 68
.set nb132nf_p_ntype, 72
.set nb132nf_vdwparam, 76
.set nb132nf_Vvdw, 80
.set nb132nf_p_tabscale, 84
.set nb132nf_VFtab, 88
.set nb132nf_invsqrta, 92
.set nb132nf_dvda, 96
.set nb132nf_p_gbtabscale, 100
.set nb132nf_GBtab, 104
.set nb132nf_p_nthreads, 108
.set nb132nf_count, 112
.set nb132nf_mtx, 116
.set nb132nf_outeriter, 120
.set nb132nf_inneriter, 124
.set nb132nf_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb132nf_ixO, 0
.set nb132nf_iyO, 16
.set nb132nf_izO, 32
.set nb132nf_ixH1, 48
.set nb132nf_iyH1, 64
.set nb132nf_izH1, 80
.set nb132nf_ixH2, 96
.set nb132nf_iyH2, 112
.set nb132nf_izH2, 128
.set nb132nf_jxO, 144
.set nb132nf_jyO, 160
.set nb132nf_jzO, 176
.set nb132nf_jxH1, 192
.set nb132nf_jyH1, 208
.set nb132nf_jzH1, 224
.set nb132nf_jxH2, 240
.set nb132nf_jyH2, 256
.set nb132nf_jzH2, 272
.set nb132nf_qqOO, 288
.set nb132nf_qqOH, 304
.set nb132nf_qqHH, 320
.set nb132nf_c6, 336
.set nb132nf_c12, 352
.set nb132nf_tsc, 368
.set nb132nf_vctot, 384
.set nb132nf_Vvdwtot, 400
.set nb132nf_half, 416
.set nb132nf_three, 432
.set nb132nf_rsqOO, 448
.set nb132nf_rsqOH1, 464
.set nb132nf_rsqOH2, 480
.set nb132nf_rsqH1O, 496
.set nb132nf_rsqH1H1, 512
.set nb132nf_rsqH1H2, 528
.set nb132nf_rsqH2O, 544
.set nb132nf_rsqH2H1, 560
.set nb132nf_rsqH2H2, 576
.set nb132nf_rinvOO, 592
.set nb132nf_rinvOH1, 608
.set nb132nf_rinvOH2, 624
.set nb132nf_rinvH1O, 640
.set nb132nf_rinvH1H1, 656
.set nb132nf_rinvH1H2, 672
.set nb132nf_rinvH2O, 688
.set nb132nf_rinvH2H1, 704
.set nb132nf_rinvH2H2, 720
.set nb132nf_is3, 768
.set nb132nf_ii3, 772
.set nb132nf_innerjjnr, 776
.set nb132nf_innerk, 780
.set nb132nf_n, 784
.set nb132nf_nn1, 788
.set nb132nf_nri, 792
.set nb132nf_nouter, 796
.set nb132nf_ninner, 800
.set nb132nf_salign, 804
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $808,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb132nf_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb132nf_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb132nf_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb132nf_nouter(%esp)
        movl %eax,nb132nf_ninner(%esp)

        movl nb132nf_p_tabscale(%ebp),%eax
        movss (%eax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb132nf_tsc(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb132nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb132nf_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        movss %xmm3,%xmm4
        movss 4(%edx,%ebx,4),%xmm5
        movl nb132nf_p_facel(%ebp),%esi
        movss (%esi),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb132nf_qqOO(%esp)
        movaps %xmm4,nb132nf_qqOH(%esp)
        movaps %xmm5,nb132nf_qqHH(%esp)

        xorps %xmm0,%xmm0
        movl  nb132nf_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movl nb132nf_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movl  nb132nf_vdwparam(%ebp),%eax
        movlps (%eax,%edx,4),%xmm0
        movaps %xmm0,%xmm1
        shufps $0,%xmm0,%xmm0
        shufps $85,%xmm1,%xmm1 ## constant 01010101
        movaps %xmm0,nb132nf_c6(%esp)
        movaps %xmm1,nb132nf_c12(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb132nf_half(%esp)
        movss nb132nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb132nf_half(%esp)
        movaps %xmm3,nb132nf_three(%esp)

_nb_kernel132nf_ia32_sse.nb132nf_threadloop: 
        movl  nb132nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel132nf_ia32_sse.nb132nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel132nf_ia32_sse.nb132nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb132nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb132nf_n(%esp)
        movl %ebx,nb132nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel132nf_ia32_sse.nb132nf_outerstart
        jmp _nb_kernel132nf_ia32_sse.nb132nf_end

_nb_kernel132nf_ia32_sse.nb132nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb132nf_nouter(%esp),%ebx
        movl %ebx,nb132nf_nouter(%esp)

_nb_kernel132nf_ia32_sse.nb132nf_outer: 
        movl  nb132nf_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb132nf_is3(%esp)            ## store is3 

        movl  nb132nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb132nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb132nf_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb132nf_ii3(%esp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        addss (%eax,%ebx,4),%xmm3
        addss 4(%eax,%ebx,4),%xmm4
        addss 8(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb132nf_ixO(%esp)
        movaps %xmm4,nb132nf_iyO(%esp)
        movaps %xmm5,nb132nf_izO(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 12(%eax,%ebx,4),%xmm0
        addss 16(%eax,%ebx,4),%xmm1
        addss 20(%eax,%ebx,4),%xmm2
        addss 24(%eax,%ebx,4),%xmm3
        addss 28(%eax,%ebx,4),%xmm4
        addss 32(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb132nf_ixH1(%esp)
        movaps %xmm1,nb132nf_iyH1(%esp)
        movaps %xmm2,nb132nf_izH1(%esp)
        movaps %xmm3,nb132nf_ixH2(%esp)
        movaps %xmm4,nb132nf_iyH2(%esp)
        movaps %xmm5,nb132nf_izH2(%esp)

        ## clear vctot
        xorps %xmm4,%xmm4
        movaps %xmm4,nb132nf_vctot(%esp)
        movaps %xmm4,nb132nf_Vvdwtot(%esp)

        movl  nb132nf_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb132nf_pos(%ebp),%esi
        movl  nb132nf_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb132nf_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb132nf_ninner(%esp),%ecx
        movl  %ecx,nb132nf_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb132nf_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel132nf_ia32_sse.nb132nf_unroll_loop
        jmp   _nb_kernel132nf_ia32_sse.nb132nf_single_check
_nb_kernel132nf_ia32_sse.nb132nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb132nf_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 

        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 

        addl $16,nb132nf_innerjjnr(%esp)             ##