nb_kernel132_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,018 行 · 第 1/5 页

        movaps  nb132_iyO(%esp),%xmm1
        movaps  nb132_izO(%esp),%xmm2
        movlhps %xmm6,%xmm3                     ## xmm3 = jxO   0   jxH1 jxH2 
        shufps $228,%xmm6,%xmm4 ## constant 11100100    ;# xmm4 = jyO   0   jyH1 jyH2 
        shufps $68,%xmm7,%xmm5 ## constant 01000100    ;# xmm5 = jzO   0   jzH1 jzH2

        ## store all j coordinates in jO  
        movaps %xmm3,nb132_jxO(%esp)
        movaps %xmm4,nb132_jyO(%esp)
        movaps %xmm5,nb132_jzO(%esp)
        subps  %xmm3,%xmm0
        subps  %xmm4,%xmm1
        subps  %xmm5,%xmm2
        movaps %xmm0,nb132_dxOO(%esp)
        movaps %xmm1,nb132_dyOO(%esp)
        movaps %xmm2,nb132_dzOO(%esp)
        mulps %xmm0,%xmm0
        mulps %xmm1,%xmm1
        mulps %xmm2,%xmm2
        addps %xmm1,%xmm0
        addps %xmm2,%xmm0       ## have rsq in xmm0 
        movaps %xmm0,nb132_rsqOO(%esp)

        movaps %xmm0,%xmm6

        ## do invsqrt 
        rsqrtps %xmm0,%xmm1
        movaps  %xmm1,%xmm2
        mulps   %xmm1,%xmm1
        movaps  nb132_three(%esp),%xmm3
        mulps   %xmm0,%xmm1
        subps   %xmm1,%xmm3
        mulps   %xmm2,%xmm3
        mulps   nb132_half(%esp),%xmm3   ## rinv iO - j water in xmm3
        movaps  %xmm3,nb132_rinvOO(%esp)

        movaps  %xmm3,%xmm0 ## rinv

        xorps   %xmm4,%xmm4
        ## fetch charges to xmm4 (temporary) 
        movss   nb132_qqOO(%esp),%xmm4
        movhps  nb132_qqOH(%esp),%xmm4

        mulps  %xmm4,%xmm3  ## vcoul
        movaps %xmm3,%xmm6

        mulps %xmm0,%xmm3
        movaps %xmm3,nb132_fstmp(%esp)   ## save it
        addps  nb132_vctot(%esp),%xmm6
    movaps %xmm6,nb132_vctot(%esp)

        movaps nb132_rinvOO(%esp),%xmm0
        movss %xmm0,%xmm1
        mulss  nb132_rsqOO(%esp),%xmm1   ## xmm1=r 
        mulss  nb132_tsc(%esp),%xmm1

    cvttps2pi %xmm1,%mm6
    cvtpi2ps %mm6,%xmm3
        subss    %xmm3,%xmm1    ## xmm1=eps 
    movss %xmm1,%xmm2
    mulss  %xmm2,%xmm2      ## xmm2=eps2 
    pslld $3,%mm6

    movd %eax,%mm0

    movl nb132_VFtab(%ebp),%esi
    movd %mm6,%eax

    ## dispersion 
    movlps (%esi,%eax,4),%xmm5
    movaps %xmm5,%xmm4
    shufps $136,%xmm7,%xmm4 ## constant 10001000
    shufps $221,%xmm7,%xmm5 ## constant 11011101

    movlps 8(%esi,%eax,4),%xmm7
    movaps %xmm7,%xmm6
    shufps $136,%xmm3,%xmm6 ## constant 10001000
    shufps $221,%xmm3,%xmm7 ## constant 11011101
    ## dispersion table ready, in xmm4-xmm7 
    mulss  %xmm1,%xmm6      ## xmm6=Geps 
    mulss  %xmm2,%xmm7      ## xmm7=Heps2 
    addss  %xmm6,%xmm5
    addss  %xmm7,%xmm5      ## xmm5=Fp 
    mulss  nb132_two(%esp),%xmm7         ## two*Heps2 
    addss  %xmm6,%xmm7
    addss  %xmm5,%xmm7 ## xmm7=FF 
    mulss  %xmm1,%xmm5 ## xmm5=eps*Fp 
    addss  %xmm4,%xmm5 ## xmm5=VV 

    movss nb132_c6(%esp),%xmm4
    mulss  %xmm4,%xmm7   ## fijD 
    mulss  %xmm4,%xmm5   ## Vvdw6 
        movss  nb132_fstmp(%esp),%xmm3
        mulps  nb132_tsc(%esp),%xmm7
        subss  %xmm7,%xmm3
        movss  %xmm3,nb132_fstmp(%esp)

    addss  nb132_Vvdwtot(%esp),%xmm5
    movss %xmm5,nb132_Vvdwtot(%esp)

    ## repulsion 
    movlps 16(%esi,%eax,4),%xmm5
    movaps %xmm5,%xmm4
    shufps $136,%xmm7,%xmm4 ## constant 10001000
    shufps $221,%xmm7,%xmm5 ## constant 11011101

    movlps 24(%esi,%eax,4),%xmm7
    movaps %xmm7,%xmm6
    shufps $136,%xmm3,%xmm6 ## constant 10001000
    shufps $221,%xmm3,%xmm7 ## constant 11011101
    ## table ready, in xmm4-xmm7 
    mulss  %xmm1,%xmm6      ## xmm6=Geps 
    mulss  %xmm2,%xmm7      ## xmm7=Heps2 
    addss  %xmm6,%xmm5
    addss  %xmm7,%xmm5      ## xmm5=Fp 
    mulss  nb132_two(%esp),%xmm7         ## two*Heps2 
    addss  %xmm6,%xmm7
    addss  %xmm5,%xmm7 ## xmm7=FF 
    mulss  %xmm1,%xmm5 ## xmm5=eps*Fp 
    addss  %xmm4,%xmm5 ## xmm5=VV 

    movss nb132_c12(%esp),%xmm4
    mulss  %xmm4,%xmm7 ## fijR 
    mulss  %xmm4,%xmm5 ## Vvdw12 
        movaps nb132_fstmp(%esp),%xmm3
        mulss  nb132_tsc(%esp),%xmm7
        subss  %xmm7,%xmm3

    addss  nb132_Vvdwtot(%esp),%xmm5
    movss %xmm5,nb132_Vvdwtot(%esp)

        mulps  %xmm3,%xmm0
        movaps  %xmm0,%xmm1
        movaps  %xmm0,%xmm2

        mulps   nb132_dxOO(%esp),%xmm0
        mulps   nb132_dyOO(%esp),%xmm1
        mulps   nb132_dzOO(%esp),%xmm2

        movd %mm0,%eax

        ## initial update for j forces 
        xorps   %xmm3,%xmm3
        xorps   %xmm4,%xmm4
        xorps   %xmm5,%xmm5
        subps   %xmm0,%xmm3
        subps   %xmm1,%xmm4
        subps   %xmm2,%xmm5
        movaps  %xmm3,nb132_fjxO(%esp)
        movaps  %xmm4,nb132_fjyO(%esp)
        movaps  %xmm5,nb132_fjzO(%esp)
        addps   nb132_fixO(%esp),%xmm0
        addps   nb132_fiyO(%esp),%xmm1
        addps   nb132_fizO(%esp),%xmm2
        movaps  %xmm0,nb132_fixO(%esp)
        movaps  %xmm1,nb132_fiyO(%esp)
        movaps  %xmm2,nb132_fizO(%esp)


        ## done with i O Now do i H1 & H2 simultaneously first get i particle coords: 
        movaps  nb132_ixH1(%esp),%xmm0
        movaps  nb132_iyH1(%esp),%xmm1
        movaps  nb132_izH1(%esp),%xmm2
        movaps  nb132_ixH2(%esp),%xmm3
        movaps  nb132_iyH2(%esp),%xmm4
        movaps  nb132_izH2(%esp),%xmm5
        subps   nb132_jxO(%esp),%xmm0
        subps   nb132_jyO(%esp),%xmm1
        subps   nb132_jzO(%esp),%xmm2
        subps   nb132_jxO(%esp),%xmm3
        subps   nb132_jyO(%esp),%xmm4
        subps   nb132_jzO(%esp),%xmm5
        movaps %xmm0,nb132_dxH1O(%esp)
        movaps %xmm1,nb132_dyH1O(%esp)
        movaps %xmm2,nb132_dzH1O(%esp)
        movaps %xmm3,nb132_dxH2O(%esp)
        movaps %xmm4,nb132_dyH2O(%esp)
        movaps %xmm5,nb132_dzH2O(%esp)
        mulps %xmm0,%xmm0
        mulps %xmm1,%xmm1
        mulps %xmm2,%xmm2
        mulps %xmm3,%xmm3
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        addps %xmm1,%xmm0
        addps %xmm3,%xmm4
        addps %xmm2,%xmm0       ## have rsqH1 in xmm0 
        addps %xmm5,%xmm4       ## have rsqH2 in xmm4 

        ## do invsqrt 
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm4,%xmm5
        movaps  %xmm1,%xmm2
        movaps  %xmm5,%xmm6
        mulps   %xmm1,%xmm1
        mulps   %xmm5,%xmm5
        movaps  nb132_three(%esp),%xmm3
        movaps  %xmm3,%xmm7
        mulps   %xmm0,%xmm1
        mulps   %xmm4,%xmm5
        subps   %xmm1,%xmm3
        subps   %xmm5,%xmm7
        mulps   %xmm2,%xmm3
        mulps   %xmm6,%xmm7
        mulps   nb132_half(%esp),%xmm3   ## rinv H1 - j water 
        mulps   nb132_half(%esp),%xmm7   ## rinv H2 - j water  

        ## assemble charges in xmm6 
        xorps   %xmm6,%xmm6
        movss   nb132_qqOH(%esp),%xmm6
        movhps  nb132_qqHH(%esp),%xmm6

        movaps  %xmm3,%xmm0
        movaps  %xmm7,%xmm1
        mulps   %xmm6,%xmm3 ## vcoul
        mulps   %xmm6,%xmm7 ## vcoul
        mulps   %xmm0,%xmm0
        mulps   %xmm1,%xmm1
        mulps   %xmm3,%xmm0
        addps   %xmm7,%xmm3
        mulps   %xmm1,%xmm7
        addps   nb132_vctot(%esp),%xmm3
        movaps  %xmm3,nb132_vctot(%esp)

        movaps  %xmm0,%xmm1
        movaps  %xmm0,%xmm2
        mulps   nb132_dxH1O(%esp),%xmm0
        mulps   nb132_dyH1O(%esp),%xmm1
        mulps   nb132_dzH1O(%esp),%xmm2
        ## update forces H1 - j water 
        movaps  nb132_fjxO(%esp),%xmm3
        movaps  nb132_fjyO(%esp),%xmm4
        movaps  nb132_fjzO(%esp),%xmm5
        subps   %xmm0,%xmm3
        subps   %xmm1,%xmm4
        subps   %xmm2,%xmm5
        movaps  %xmm3,nb132_fjxO(%esp)
        movaps  %xmm4,nb132_fjyO(%esp)
        movaps  %xmm5,nb132_fjzO(%esp)
        addps   nb132_fixH1(%esp),%xmm0
        addps   nb132_fiyH1(%esp),%xmm1
        addps   nb132_fizH1(%esp),%xmm2
        movaps  %xmm0,nb132_fixH1(%esp)
        movaps  %xmm1,nb132_fiyH1(%esp)
        movaps  %xmm2,nb132_fizH1(%esp)
        ## do forces H2 - j water 
        movaps %xmm7,%xmm0
        movaps %xmm7,%xmm1
        movaps %xmm7,%xmm2
        mulps   nb132_dxH2O(%esp),%xmm0
        mulps   nb132_dyH2O(%esp),%xmm1
        mulps   nb132_dzH2O(%esp),%xmm2
        movaps  nb132_fjxO(%esp),%xmm3
        movaps  nb132_fjyO(%esp),%xmm4
        movaps  nb132_fjzO(%esp),%xmm5
        subps   %xmm0,%xmm3
        subps   %xmm1,%xmm4
        subps   %xmm2,%xmm5
        movl    nb132_faction(%ebp),%esi
        movaps  %xmm3,nb132_fjxO(%esp)
        movaps  %xmm4,nb132_fjyO(%esp)
        movaps  %xmm5,nb132_fjzO(%esp)
        addps   nb132_fixH2(%esp),%xmm0
        addps   nb132_fiyH2(%esp),%xmm1
        addps   nb132_fizH2(%esp),%xmm2
        movaps  %xmm0,nb132_fixH2(%esp)
        movaps  %xmm1,nb132_fiyH2(%esp)
        movaps  %xmm2,nb132_fizH2(%esp)

        ## update j water forces from local variables 
        movlps  (%esi,%eax,4),%xmm0
        movlps  12(%esi,%eax,4),%xmm1
        movhps  24(%esi,%eax,4),%xmm1
        movaps  nb132_fjxO(%esp),%xmm3
        movaps  nb132_fjyO(%esp),%xmm4
        movaps  nb132_fjzO(%esp),%xmm5
        movaps  %xmm5,%xmm6
        movaps  %xmm5,%xmm7
        shufps $2,%xmm6,%xmm6 ## constant 00000010
        shufps $3,%xmm7,%xmm7 ## constant 00000011
        addss   8(%esi,%eax,4),%xmm5
        addss   20(%esi,%eax,4),%xmm6
        addss   32(%esi,%eax,4),%xmm7
        movss   %xmm5,8(%esi,%eax,4)
        movss   %xmm6,20(%esi,%eax,4)
        movss   %xmm7,32(%esi,%eax,4)
        movaps   %xmm3,%xmm5
        unpcklps %xmm4,%xmm3
        unpckhps %xmm4,%xmm5
        addps    %xmm3,%xmm0
        addps    %xmm5,%xmm1
        movlps  %xmm0,(%esi,%eax,4)
        movlps  %xmm1,12(%esi,%eax,4)
        movhps  %xmm1,24(%esi,%eax,4)

        decl nb132_innerk(%esp)
        jz    _nb_kernel132_ia32_sse.nb132_updateouterdata
        jmp   _nb_kernel132_ia32_sse.nb132_single_loop
_nb_kernel132_ia32_sse.nb132_updateouterdata: 
        movl  nb132_ii3(%esp),%ecx
        movl  nb132_faction(%ebp),%edi
        movl  nb132_fshift(%ebp),%esi
        movl  nb132_is3(%esp),%edx

        ## accumulate  Oi forces in xmm0, xmm1, xmm2 
        movaps nb132_fixO(%esp),%xmm0
        movaps nb132_fiyO(%esp),%xmm1
        movaps nb132_fizO(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%edi,%ecx,4),%xmm3
        movss  4(%edi,%ecx,4),%xmm4
        movss  8(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,(%edi,%ecx,4)
        movss  %xmm4,4(%edi,%ecx,4)
        movss  %xmm5,8(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        movaps %xmm0,%xmm6
        movss %xmm2,%xmm7
        movlhps %xmm1,%xmm6
        shufps $8,%xmm6,%xmm6 ## constant 00001000      

        ## accumulate H1i forces in xmm0, xmm1, xmm2 
        movaps nb132_fixH1(%esp),%xmm0
        movaps nb132_fiyH1(%esp),%xmm1
        movaps nb132_fizH1(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  12(%edi,%ecx,4),%xmm3
        movss  16(%edi,%ecx,4),%xmm4
        movss  20(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,12(%edi,%ecx,4)
        movss  %xmm4,16(%edi,%ecx,4)
        movss  %xmm5,20(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## constant 00001000      
        addps   %xmm0,%xmm6

        ## accumulate H2i forces in xmm0, xmm1, xmm2 
        movaps nb132_fixH2(%esp),%xmm0
        movaps nb132_fiyH2(%esp),%xmm1
        movaps nb132_fizH2(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0