nb_kernel203_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,591 行 · 第 1/3 页

;#
;# $Id: nb_kernel203_ia32_sse.intel_syntax.s,v 1.1.2.1 2006/03/01 15:18:29 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as




.globl nb_kernel203_ia32_sse
.globl _nb_kernel203_ia32_sse
nb_kernel203_ia32_sse:	
_nb_kernel203_ia32_sse:	
.equiv          nb203_p_nri,            8
.equiv          nb203_iinr,             12
.equiv          nb203_jindex,           16
.equiv          nb203_jjnr,             20
.equiv          nb203_shift,            24
.equiv          nb203_shiftvec,         28
.equiv          nb203_fshift,           32
.equiv          nb203_gid,              36
.equiv          nb203_pos,              40
.equiv          nb203_faction,          44
.equiv          nb203_charge,           48
.equiv          nb203_p_facel,          52
.equiv          nb203_argkrf,           56
.equiv          nb203_argcrf,           60
.equiv          nb203_Vc,               64
.equiv          nb203_type,             68
.equiv          nb203_p_ntype,          72
.equiv          nb203_vdwparam,         76
.equiv          nb203_Vvdw,             80
.equiv          nb203_p_tabscale,       84
.equiv          nb203_VFtab,            88
.equiv          nb203_invsqrta,         92
.equiv          nb203_dvda,             96
.equiv          nb203_p_gbtabscale,     100
.equiv          nb203_GBtab,            104
.equiv          nb203_p_nthreads,       108
.equiv          nb203_count,            112
.equiv          nb203_mtx,              116
.equiv          nb203_outeriter,        120
.equiv          nb203_inneriter,        124
.equiv          nb203_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb203_ixH1,             0
.equiv          nb203_iyH1,             16
.equiv          nb203_izH1,             32
.equiv          nb203_ixH2,             48
.equiv          nb203_iyH2,             64
.equiv          nb203_izH2,             80
.equiv          nb203_ixM,              96
.equiv          nb203_iyM,              112
.equiv          nb203_izM,              128
.equiv          nb203_iqH,              144
.equiv          nb203_iqM,              160
.equiv          nb203_dxH1,             176
.equiv          nb203_dyH1,             192
.equiv          nb203_dzH1,             208
.equiv          nb203_dxH2,             224
.equiv          nb203_dyH2,             240
.equiv          nb203_dzH2,             256
.equiv          nb203_dxM,              272
.equiv          nb203_dyM,              288
.equiv          nb203_dzM,              304
.equiv          nb203_qqH,              320
.equiv          nb203_qqM,              336
.equiv          nb203_vctot,            352
.equiv          nb203_fixH1,            384
.equiv          nb203_fiyH1,            400
.equiv          nb203_fizH1,            416
.equiv          nb203_fixH2,            432
.equiv          nb203_fiyH2,            448
.equiv          nb203_fizH2,            464
.equiv          nb203_fixM,             480
.equiv          nb203_fiyM,             496
.equiv          nb203_fizM,             512
.equiv          nb203_fjx,              528
.equiv          nb203_fjy,              544
.equiv          nb203_fjz,              560
.equiv          nb203_half,             576
.equiv          nb203_three,            592
.equiv          nb203_two,              608
.equiv          nb203_krf,              624
.equiv          nb203_crf,              640
.equiv          nb203_krsqH1,           656
.equiv          nb203_krsqH2,           672
.equiv          nb203_krsqM,            688
.equiv          nb203_is3,              704
.equiv          nb203_ii3,              708
.equiv          nb203_innerjjnr,        712
.equiv          nb203_innerk,           716
.equiv          nb203_n,                720
.equiv          nb203_nn1,              724
.equiv          nb203_nri,              728
.equiv          nb203_nouter,           732
.equiv          nb203_ninner,           736
.equiv          nb203_salign,           740
	push ebp
	mov ebp,esp	
	push eax
	push ebx
	push ecx
	push edx
	push esi
	push edi
	sub esp, 744		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb203_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb203_p_nri]
	mov ecx, [ecx]
	mov [esp + nb203_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb203_nouter], eax
	mov [esp + nb203_ninner], eax


	mov esi, [ebp + nb203_argkrf]
	mov edi, [ebp + nb203_argcrf]
	movss xmm5, [esi]
	movss xmm6, [edi]
	shufps xmm5, xmm5, 0
	shufps xmm6, xmm6, 0
	movaps [esp + nb203_krf], xmm5
	movaps [esp + nb203_crf], xmm6
	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb203_half], eax
	movss xmm1, [esp + nb203_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# constant 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# constant 2.0
	addps  xmm3, xmm2	;# constant 3.0
	movaps [esp + nb203_half],  xmm1
	movaps [esp + nb203_two],  xmm2
	movaps [esp + nb203_three],  xmm3
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb203_iinr]   	;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]		;# ebx =ii 

	mov   edx, [ebp + nb203_charge]
	movss xmm3, [edx + ebx*4 + 4]	
	movss xmm4, [edx + ebx*4 + 12]	
	mov esi, [ebp + nb203_p_facel]
	movss xmm5, [esi]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [esp + nb203_iqH], xmm3
	movaps [esp + nb203_iqM], xmm4
			
.nb203_threadloop:
        mov   esi, [ebp + nb203_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb203_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb203_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb203_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb203_n], eax
        mov [esp + nb203_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb203_outerstart
        jmp .nb203_end
	
.nb203_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb203_nouter]
	mov [esp + nb203_nouter], ebx

.nb203_outer:
	mov   eax, [ebp + nb203_shift]  	;# eax = pointer into shift[] 
	mov   ebx, [eax + esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]	;# ebx=3*is 
	mov   [esp + nb203_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb203_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [eax + ebx*4]
	movss xmm1, [eax + ebx*4 + 4]
	movss xmm2, [eax + ebx*4 + 8] 

	mov   ecx, [ebp + nb203_iinr]   	;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx + esi*4]		;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb203_pos]	;# eax = base of pos[]  
	mov   [esp + nb203_ii3], ebx

	addss xmm3, [eax + ebx*4 + 12]
	addss xmm4, [eax + ebx*4 + 16]
	addss xmm5, [eax + ebx*4 + 20]		
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb203_ixH1], xmm3
	movaps [esp + nb203_iyH1], xmm4
	movaps [esp + nb203_izH1], xmm5

	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm0, [eax + ebx*4 + 24]
	addss xmm1, [eax + ebx*4 + 28]
	addss xmm2, [eax + ebx*4 + 32]		
	addss xmm3, [eax + ebx*4 + 36]
	addss xmm4, [eax + ebx*4 + 40]
	addss xmm5, [eax + ebx*4 + 44]		

	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb203_ixH2], xmm0
	movaps [esp + nb203_iyH2], xmm1
	movaps [esp + nb203_izH2], xmm2
	movaps [esp + nb203_ixM], xmm3
	movaps [esp + nb203_iyM], xmm4
	movaps [esp + nb203_izM], xmm5
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [esp + nb203_vctot], xmm4
	movaps [esp + nb203_fixH1], xmm4
	movaps [esp + nb203_fiyH1], xmm4
	movaps [esp + nb203_fizH1], xmm4
	movaps [esp + nb203_fixH2], xmm4
	movaps [esp + nb203_fiyH2], xmm4
	movaps [esp + nb203_fizH2], xmm4
	movaps [esp + nb203_fixM], xmm4
	movaps [esp + nb203_fiyM], xmm4
	movaps [esp + nb203_fizM], xmm4
	
	mov   eax, [ebp + nb203_jindex]
	mov   ecx, [eax + esi*4]	 	;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	 	;# jindex[n+1] 
	sub   edx, ecx           	;# number of innerloop atoms 

	mov   esi, [ebp + nb203_pos]
	mov   edi, [ebp + nb203_faction]	
	mov   eax, [ebp + nb203_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb203_innerjjnr], eax 	;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [esp + nb203_ninner]
	mov   [esp + nb203_ninner], ecx
	add   edx, 0
	mov   [esp + nb203_innerk], edx	;# number of innerloop atoms 
	jge   .nb203_unroll_loop
	jmp   .nb203_odd_inner
.nb203_unroll_loop:
	;# quad-unroll innerloop here 
	mov   edx, [esp + nb203_innerjjnr] 	;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	mov   ecx, [edx + 8]            
	mov   edx, [edx + 12]     	;# eax-edx=jnr1-4 

	add dword ptr [esp + nb203_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov esi, [ebp + nb203_charge]	;# base of charge[] 
	
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]

	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	 	;# and in xmm4 
	mulps  xmm3, [esp + nb203_iqH]
	mulps  xmm4, [esp + nb203_iqM]

	movaps  [esp + nb203_qqH], xmm3
	movaps  [esp + nb203_qqM], xmm4

	mov esi, [ebp + nb203_pos]   	;# base of pos[] 

	lea   eax, [eax + eax*2] 	;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	
	lea   ecx, [ecx + ecx*2] 	;# replace jnr with j3 
	lea   edx, [edx + edx*2]	

	;# move four coordinates to xmm0-xmm2 	
	movlps xmm4, [esi + eax*4]
	movlps xmm5, [esi + ecx*4]
	movss xmm2, [esi + eax*4 + 8]
	movss xmm6, [esi + ecx*4 + 8]

	movhps xmm4, [esi + ebx*4]
	movhps xmm5, [esi + edx*4]

	movss xmm0, [esi + ebx*4 + 8]
	movss xmm1, [esi + edx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# constant 10001000
	
	shufps xmm0, xmm5, 136  ;# constant 10001000
	shufps xmm1, xmm5, 221  ;# constant 11011101		

	;# move ixH1-izH1 to xmm4-xmm6 
	movaps xmm4, [esp + nb203_ixH1]
	movaps xmm5, [esp + nb203_iyH1]
	movaps xmm6, [esp + nb203_izH1]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb203_dxH1], xmm4
	movaps [esp + nb203_dyH1], xmm5
	movaps [esp + nb203_dzH1], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	movaps xmm7, xmm4
	;# rsqH1 in xmm7 

	;# move ixH2-izH2 to xmm4-xmm6 
	movaps xmm4, [esp + nb203_ixH2]
	movaps xmm5, [esp + nb203_iyH2]
	movaps xmm6, [esp + nb203_izH2]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb203_dxH2], xmm4
	movaps [esp + nb203_dyH2], xmm5
	movaps [esp + nb203_dzH2], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm6, xmm5
	addps xmm6, xmm4
	;# rsqH2 in xmm6 

	;# move ixM-izM to xmm3-xmm5  
	movaps xmm3, [esp + nb203_ixM]
	movaps xmm4, [esp + nb203_iyM]
	movaps xmm5, [esp + nb203_izM]

	;# calc dr 
	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2

	;# store dr 
	movaps [esp + nb203_dxM], xmm3
	movaps [esp + nb203_dyM], xmm4
	movaps [esp + nb203_dzM], xmm5
	;# square it 
	mulps xmm3,xmm3
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	addps xmm5, xmm4
	addps xmm5, xmm3
	;# rsqM in xmm5, rsqH2 in xmm6, rsqH1 in xmm7 

	movaps xmm0, xmm5
	movaps xmm1, xmm6
	movaps xmm2, xmm7

	mulps  xmm0, [esp + nb203_krf]	
	mulps  xmm1, [esp + nb203_krf]	
	mulps  xmm2, [esp + nb203_krf]	

	movaps [esp + nb203_krsqM], xmm0
	movaps [esp + nb203_krsqH2], xmm1
	movaps [esp + nb203_krsqH1], xmm2
	
	;# start with rsqH1 - seed in xmm2 	
	rsqrtps xmm2, xmm7
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb203_three]
	mulps   xmm2, xmm7	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb203_half]
	movaps  xmm7, xmm4	;# rinvH1 in xmm7 
	;# rsqH2 - seed in xmm2 
	rsqrtps xmm2, xmm6
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb203_three]
	mulps   xmm2, xmm6	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb203_half]
	movaps  xmm6, xmm4	;# rinvH2 in xmm6 
	;# rsqM - seed in xmm2 
	rsqrtps xmm2, xmm5
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb203_three]
	mulps   xmm2, xmm5	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb203_half]
	movaps  xmm5, xmm4	;# rinvM in xmm5 

	;# do H1 interactions 
	movaps  xmm4, xmm7	
	mulps   xmm4, xmm4	;# xmm7=rinv, xmm4=rinvsq 

	movaps xmm0, xmm7
	movaps xmm1, [esp + nb203_krsqH1]
	addps  xmm0, xmm1
	subps  xmm0, [esp + nb203_crf] ;# xmm0=rinv+ krsq-crf 
	mulps  xmm1, [esp + nb203_two]
	subps  xmm7, xmm1
	mulps  xmm0, [esp + nb203_qqH]
	mulps  xmm7, [esp + nb203_qqH]

	mulps  xmm4, xmm7	;# total fs H1 in xmm4 

	addps  xmm0, [esp + nb203_vctot]
	movaps [esp + nb203_vctot], xmm0

	movaps xmm0, [esp + nb203_dxH1]
	movaps xmm1, [esp + nb203_dyH1]
	movaps xmm2, [esp + nb203_dzH1]
	mulps  xmm0, xmm4
	mulps  xmm1, xmm4
	mulps  xmm2, xmm4

	;# update H1 forces 
	movaps xmm3, [esp + nb203_fixH1]
	movaps xmm4, [esp + nb203_fiyH1]
	movaps xmm7, [esp + nb203_fizH1]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	addps  xmm7, xmm2
	movaps [esp + nb203_fixH1], xmm3
	movaps [esp + nb203_fiyH1], xmm4
	movaps [esp + nb203_fizH1], xmm7
	;# update j forces with water O 
	movaps [esp + nb203_fjx], xmm0
	movaps [esp + nb203_fjy], xmm1
	movaps [esp + nb203_fjz], xmm2