nb_kernel211_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,822 行 · 第 1/4 页

;#
;# $Id: nb_kernel211_ia32_sse.intel_syntax.s,v 1.1.2.1 2006/03/01 15:18:29 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as




.globl nb_kernel211_ia32_sse
.globl _nb_kernel211_ia32_sse
nb_kernel211_ia32_sse:	
_nb_kernel211_ia32_sse:	
.equiv          nb211_p_nri,            8
.equiv          nb211_iinr,             12
.equiv          nb211_jindex,           16
.equiv          nb211_jjnr,             20
.equiv          nb211_shift,            24
.equiv          nb211_shiftvec,         28
.equiv          nb211_fshift,           32
.equiv          nb211_gid,              36
.equiv          nb211_pos,              40
.equiv          nb211_faction,          44
.equiv          nb211_charge,           48
.equiv          nb211_p_facel,          52
.equiv          nb211_argkrf,           56
.equiv          nb211_argcrf,           60
.equiv          nb211_Vc,               64
.equiv          nb211_type,             68
.equiv          nb211_p_ntype,          72
.equiv          nb211_vdwparam,         76
.equiv          nb211_Vvdw,             80
.equiv          nb211_p_tabscale,       84
.equiv          nb211_VFtab,            88
.equiv          nb211_invsqrta,         92
.equiv          nb211_dvda,             96
.equiv          nb211_p_gbtabscale,     100
.equiv          nb211_GBtab,            104
.equiv          nb211_p_nthreads,       108
.equiv          nb211_count,            112
.equiv          nb211_mtx,              116
.equiv          nb211_outeriter,        120
.equiv          nb211_inneriter,        124
.equiv          nb211_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb211_ixO,              0
.equiv          nb211_iyO,              16
.equiv          nb211_izO,              32
.equiv          nb211_ixH1,             48
.equiv          nb211_iyH1,             64
.equiv          nb211_izH1,             80
.equiv          nb211_ixH2,             96
.equiv          nb211_iyH2,             112
.equiv          nb211_izH2,             128
.equiv          nb211_iqO,              144
.equiv          nb211_iqH,              160
.equiv          nb211_dxO,              176
.equiv          nb211_dyO,              192
.equiv          nb211_dzO,              208
.equiv          nb211_dxH1,             224
.equiv          nb211_dyH1,             240
.equiv          nb211_dzH1,             256
.equiv          nb211_dxH2,             272
.equiv          nb211_dyH2,             288
.equiv          nb211_dzH2,             304
.equiv          nb211_qqO,              320
.equiv          nb211_qqH,              336
.equiv          nb211_c6,               352
.equiv          nb211_c12,              368
.equiv          nb211_six,              384
.equiv          nb211_twelve,           400
.equiv          nb211_vctot,            416
.equiv          nb211_Vvdwtot,          432
.equiv          nb211_fixO,             448
.equiv          nb211_fiyO,             464
.equiv          nb211_fizO,             480
.equiv          nb211_fixH1,            496
.equiv          nb211_fiyH1,            512
.equiv          nb211_fizH1,            528
.equiv          nb211_fixH2,            544
.equiv          nb211_fiyH2,            560
.equiv          nb211_fizH2,            576
.equiv          nb211_fjx,              592
.equiv          nb211_fjy,              608
.equiv          nb211_fjz,              624
.equiv          nb211_half,             640
.equiv          nb211_three,            656
.equiv          nb211_two,              672
.equiv          nb211_krf,              688
.equiv          nb211_crf,              704
.equiv          nb211_krsqO,            720
.equiv          nb211_krsqH1,           736
.equiv          nb211_krsqH2,           752
.equiv          nb211_is3,              768
.equiv          nb211_ii3,              772
.equiv          nb211_ntia,             776
.equiv          nb211_innerjjnr,        780
.equiv          nb211_innerk,           784
.equiv          nb211_n,                788
.equiv          nb211_nn1,              792
.equiv          nb211_nri,              796
.equiv          nb211_nouter,           800
.equiv          nb211_ninner,           804
.equiv          nb211_salign,           808
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 812		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb211_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb211_p_nri]
	mov ecx, [ecx]
	mov [esp + nb211_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb211_nouter], eax
	mov [esp + nb211_ninner], eax


	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb211_half], eax
	movss xmm1, [esp + nb211_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# constant 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# constant 2.0
	addps  xmm3, xmm2	;# constant 3.0
	movaps xmm4, xmm3
	addps  xmm4, xmm4	;# 6.0
	movaps xmm5, xmm4
	addps  xmm5, xmm5	;# constant 12.0
	movaps [esp + nb211_half],  xmm1
	movaps [esp + nb211_two],  xmm2
	movaps [esp + nb211_three],  xmm3
	movaps [esp + nb211_six],  xmm4
	movaps [esp + nb211_twelve],  xmm5

	mov esi, [ebp + nb211_argkrf]
	mov edi, [ebp + nb211_argcrf]
	movss xmm5, [esi]
	movss xmm6, [edi]
	shufps xmm5, xmm5, 0
	shufps xmm6, xmm6, 0
	movaps [esp + nb211_krf], xmm5
	movaps [esp + nb211_crf], xmm6
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb211_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb211_charge]
	movss xmm3, [edx + ebx*4]	
	movss xmm4, [edx + ebx*4 + 4]	
	mov esi, [ebp + nb211_p_facel]
	movss xmm5, [esi]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [esp + nb211_iqO], xmm3
	movaps [esp + nb211_iqH], xmm4
	
	mov   edx, [ebp + nb211_type]
	mov   ecx, [edx + ebx*4]
	shl   ecx, 1
	mov edi, [ebp + nb211_p_ntype]
	imul  ecx, [edi]      ;# ecx = ntia = 2*ntype*type[ii0] 
	mov   [esp + nb211_ntia], ecx		

.nb211_threadloop:
        mov   esi, [ebp + nb211_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb211_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb211_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb211_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb211_n], eax
        mov [esp + nb211_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb211_outerstart
        jmp .nb211_end

.nb211_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb211_nouter]
	mov [esp + nb211_nouter], ebx

.nb211_outer:
	mov   eax, [ebp + nb211_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax +esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb211_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb211_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [eax + ebx*4]
	movss xmm1, [eax + ebx*4 + 4]
	movss xmm2, [eax + ebx*4 + 8] 

	mov   ecx, [ebp + nb211_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx + esi*4]	    ;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb211_pos]    ;# eax = base of pos[]  
	mov   [esp + nb211_ii3], ebx

	addss xmm3, [eax + ebx*4]
	addss xmm4, [eax + ebx*4 + 4]
	addss xmm5, [eax + ebx*4 + 8]		
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb211_ixO], xmm3
	movaps [esp + nb211_iyO], xmm4
	movaps [esp + nb211_izO], xmm5

	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm0, [eax + ebx*4 + 12]
	addss xmm1, [eax + ebx*4 + 16]
	addss xmm2, [eax + ebx*4 + 20]		
	addss xmm3, [eax + ebx*4 + 24]
	addss xmm4, [eax + ebx*4 + 28]
	addss xmm5, [eax + ebx*4 + 32]		

	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb211_ixH1], xmm0
	movaps [esp + nb211_iyH1], xmm1
	movaps [esp + nb211_izH1], xmm2
	movaps [esp + nb211_ixH2], xmm3
	movaps [esp + nb211_iyH2], xmm4
	movaps [esp + nb211_izH2], xmm5
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [esp + nb211_vctot], xmm4
	movaps [esp + nb211_Vvdwtot], xmm4
	movaps [esp + nb211_fixO], xmm4
	movaps [esp + nb211_fiyO], xmm4
	movaps [esp + nb211_fizO], xmm4
	movaps [esp + nb211_fixH1], xmm4
	movaps [esp + nb211_fiyH1], xmm4
	movaps [esp + nb211_fizH1], xmm4
	movaps [esp + nb211_fixH2], xmm4
	movaps [esp + nb211_fiyH2], xmm4
	movaps [esp + nb211_fizH2], xmm4
	
	mov   eax, [ebp + nb211_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb211_pos]
	mov   edi, [ebp + nb211_faction]	
	mov   eax, [ebp + nb211_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb211_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [esp + nb211_ninner]
	mov   [esp + nb211_ninner], ecx
	add   edx, 0
	mov   [esp + nb211_innerk], edx    ;# number of innerloop atoms 
	jge   .nb211_unroll_loop
	jmp   .nb211_odd_inner
.nb211_unroll_loop:
	;# quad-unroll innerloop here 
	mov   edx, [esp + nb211_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	mov   ecx, [edx + 8]            
	mov   edx, [edx + 12]         ;# eax-edx=jnr1-4 

	add dword ptr [esp + nb211_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov esi, [ebp + nb211_charge]    ;# base of charge[] 
	
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]

	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	     ;# and in xmm4 
	mulps  xmm3, [esp + nb211_iqO]
	mulps  xmm4, [esp + nb211_iqH]

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx
	movd  mm2, ecx
	movd  mm3, edx

	movaps  [esp + nb211_qqO], xmm3
	movaps  [esp + nb211_qqH], xmm4
	
	mov esi, [ebp + nb211_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov ecx, [esi + ecx*4]
	mov edx, [esi + edx*4]
	mov esi, [ebp + nb211_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	shl ecx, 1	
	shl edx, 1	
	mov edi, [esp + nb211_ntia]
	add eax, edi
	add ebx, edi
	add ecx, edi
	add edx, edi

	movlps xmm6, [esi + eax*4]
	movlps xmm7, [esi + ecx*4]
	movhps xmm6, [esi + ebx*4]
	movhps xmm7, [esi + edx*4]

	movaps xmm4, xmm6
	shufps xmm4, xmm7, 136  ;# constant 10001000
	shufps xmm6, xmm7, 221  ;# constant 11011101
	
	movd  eax, mm0		
	movd  ebx, mm1
	movd  ecx, mm2
	movd  edx, mm3

	movaps [esp + nb211_c6], xmm4
	movaps [esp + nb211_c12], xmm6

	mov esi, [ebp + nb211_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	
	lea   ecx, [ecx + ecx*2]     ;# replace jnr with j3 
	lea   edx, [edx + edx*2]	

	;# move four coordinates to xmm0-xmm2 	
	movlps xmm4, [esi + eax*4]
	movlps xmm5, [esi + ecx*4]
	movss xmm2, [esi + eax*4 + 8]
	movss xmm6, [esi + ecx*4 + 8]

	movhps xmm4, [esi + ebx*4]
	movhps xmm5, [esi + edx*4]

	movss xmm0, [esi + ebx*4 + 8]
	movss xmm1, [esi + edx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# constant 10001000
	
	shufps xmm0, xmm5, 136  ;# constant 10001000
	shufps xmm1, xmm5, 221  ;# constant 11011101		

	;# move ixO-izO to xmm4-xmm6 
	movaps xmm4, [esp + nb211_ixO]
	movaps xmm5, [esp + nb211_iyO]
	movaps xmm6, [esp + nb211_izO]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb211_dxO], xmm4
	movaps [esp + nb211_dyO], xmm5
	movaps [esp + nb211_dzO], xmm6
	;# square it