nb_kernel210_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,596 行 · 第 1/3 页

	mov ecx, [esi + ecx*4]
	mov edx, [esi + edx*4]	
	mov esi, [ebp + nb210_vdwparam]
	shl ecx, 1	
	shl edx, 1	
	mov edi, [esp + nb210_ntia]
	add ecx, edi
	add edx, edi
	movlps xmm6, [esi + ecx*4]
	movhps xmm6, [esi + edx*4]
	mov edi, [ebp + nb210_pos]	
	xorps  xmm7,xmm7
	movaps xmm4, xmm6
	shufps xmm4, xmm4, 8 ;# constant 00001000 	
	shufps xmm6, xmm6, 13 ;# constant 00001101
	movlhps xmm4, xmm7
	movlhps xmm6, xmm7
	
	movaps [esp + nb210_c6], xmm4
	movaps [esp + nb210_c12], xmm6	
			
	lea   eax, [eax + eax*2]
	lea   ebx, [ebx + ebx*2]
	;# move coordinates to xmm0-xmm2 
	movlps xmm1, [edi + eax*4]
	movss xmm2, [edi + eax*4 + 8]	
	movhps xmm1, [edi + ebx*4]
	movss xmm0, [edi + ebx*4 + 8]	

	mulps  xmm3, [esp + nb210_iq]

	movlhps xmm3, xmm7
	
	shufps xmm2, xmm0, 0
	
	movaps xmm0, xmm1

	shufps xmm2, xmm2, 136  ;# constant 10001000
	
	shufps xmm0, xmm0, 136  ;# constant 10001000
	shufps xmm1, xmm1, 221  ;# constant 11011101
			
	mov    edi, [ebp + nb210_faction]
	;# move ix-iz to xmm4-xmm6 
	xorps   xmm7, xmm7
	
	movaps xmm4, [esp + nb210_ix]
	movaps xmm5, [esp + nb210_iy]
	movaps xmm6, [esp + nb210_iz]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb210_dx], xmm4
	movaps [esp + nb210_dy], xmm5
	movaps [esp + nb210_dz], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	;# rsq in xmm4 

	movaps xmm7, [esp + nb210_krf]
	rsqrtps xmm5, xmm4
	;# lookup seed in xmm5 
	movaps xmm2, xmm5
	mulps xmm5, xmm5
	movaps xmm1, [esp + nb210_three]
	mulps xmm5, xmm4	;# rsq*lu*lu 			
	movaps xmm0, [esp + nb210_half]
	mulps  xmm7, xmm4	;# xmm7=krsq 
	subps xmm1, xmm5	;# constant 30-rsq*lu*lu 
	mulps xmm1, xmm2	
	mulps xmm0, xmm1	;# xmm0=rinv 
	movaps xmm4, xmm0
	mulps  xmm4, xmm4	;# xmm4=rinvsq 
	movaps xmm6, xmm0
	addps  xmm6, xmm7	;# xmm6=rinv+ krsq 
	movaps xmm1, xmm4
	subps  xmm6, [esp + nb210_crf]
	mulps  xmm1, xmm4
	mulps  xmm1, xmm4	;# xmm1=rinvsix 
	movaps xmm2, xmm1
	mulps  xmm2, xmm2	;# xmm2=rinvtwelve 
	mulps  xmm6, xmm3	;# xmm6=vcoul=qq*(rinv+ krsq-crf) 
	mulps  xmm7, [esp + nb210_two]	
	mulps  xmm1, [esp + nb210_c6]
	mulps  xmm2, [esp + nb210_c12]
	movaps xmm5, xmm2
	subps  xmm5, xmm1	;# Vvdw=Vvdw12-Vvdw6 
	addps  xmm5, [esp + nb210_Vvdwtot]
	mulps  xmm1, [esp + nb210_six]
	mulps  xmm2, [esp + nb210_twelve]
	subps  xmm2, xmm1
	subps  xmm0, xmm7
	mulps  xmm3, xmm0	
	addps  xmm2, xmm3
	mulps  xmm4, xmm2	;# xmm4=total fscal 
	addps  xmm6, [esp + nb210_vctot]

	movaps xmm0, [esp + nb210_dx]
	movaps xmm1, [esp + nb210_dy]
	movaps xmm2, [esp + nb210_dz]

	movaps [esp + nb210_vctot], xmm6
	movaps [esp + nb210_Vvdwtot], xmm5

	mulps  xmm0, xmm4
	mulps  xmm1, xmm4
	mulps  xmm2, xmm4
	;# xmm0-xmm2 contains tx-tz (partial force) 
	;# now update f_i 
	movaps xmm3, [esp + nb210_fix]
	movaps xmm4, [esp + nb210_fiy]
	movaps xmm5, [esp + nb210_fiz]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	addps  xmm5, xmm2
	movaps [esp + nb210_fix], xmm3
	movaps [esp + nb210_fiy], xmm4
	movaps [esp + nb210_fiz], xmm5
	;# update the fj's 
	movss   xmm3, [edi + eax*4]
	movss   xmm4, [edi + eax*4 + 4]
	movss   xmm5, [edi + eax*4 + 8]
	subss   xmm3, xmm0
	subss   xmm4, xmm1
	subss   xmm5, xmm2	
	movss   [edi + eax*4], xmm3
	movss   [edi + eax*4 + 4], xmm4
	movss   [edi + eax*4 + 8], xmm5	

	shufps  xmm0, xmm0, 225  ;# constant 11100001
	shufps  xmm1, xmm1, 225  ;# constant 11100001
	shufps  xmm2, xmm2, 225  ;# constant 11100001

	movss   xmm3, [edi + ebx*4]
	movss   xmm4, [edi + ebx*4 + 4]
	movss   xmm5, [edi + ebx*4 + 8]
	subss   xmm3, xmm0
	subss   xmm4, xmm1
	subss   xmm5, xmm2	
	movss   [edi + ebx*4], xmm3
	movss   [edi + ebx*4 + 4], xmm4
	movss   [edi + ebx*4 + 8], xmm5	

.nb210_checksingle:				
	mov   edx, [esp + nb210_innerk]
	and   edx, 1
	jnz    .nb210_dosingle
	jmp    .nb210_updateouterdata
.nb210_dosingle:			
	mov esi, [ebp + nb210_charge]
	mov edi, [ebp + nb210_pos]
	mov   ecx, [esp + nb210_innerjjnr]
	xorps xmm3, xmm3
	mov   eax, [ecx]
	movss xmm3, [esi + eax*4]	;# xmm3(0) has the charge 	

	mov esi, [ebp + nb210_type]
	mov ecx, eax
	mov ecx, [esi + ecx*4]	
	mov esi, [ebp + nb210_vdwparam]
	shl ecx, 1
	add ecx, [esp + nb210_ntia]
	xorps  xmm6, xmm6
	movlps xmm6, [esi + ecx*4]
	movaps xmm4, xmm6
	shufps xmm4, xmm4, 252  ;# constant 11111100	
	shufps xmm6, xmm6, 253  ;# constant 11111101	
			
	movaps [esp + nb210_c6], xmm4
	movaps [esp + nb210_c12], xmm6	
		
	lea   eax, [eax + eax*2]
	
	;# move coordinates to xmm0-xmm2 
	movss xmm0, [edi + eax*4]	
	movss xmm1, [edi + eax*4 + 4]	
	movss xmm2, [edi + eax*4 + 8]	
 
	mulps  xmm3, [esp + nb210_iq]
	
	xorps   xmm7, xmm7
	
	movaps xmm4, [esp + nb210_ix]
	movaps xmm5, [esp + nb210_iy]
	movaps xmm6, [esp + nb210_iz]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb210_dx], xmm4
	movaps [esp + nb210_dy], xmm5
	movaps [esp + nb210_dz], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	;# rsq in xmm4 

	movaps xmm7, [esp + nb210_krf]
	rsqrtps xmm5, xmm4
	;# lookup seed in xmm5 
	movaps xmm2, xmm5
	mulps xmm5, xmm5
	movaps xmm1, [esp + nb210_three]
	mulps xmm5, xmm4	;# rsq*lu*lu 			
	movaps xmm0, [esp + nb210_half]
	mulps  xmm7, xmm4	;# xmm7=krsq 
	subps xmm1, xmm5	;# constant 30-rsq*lu*lu 
	mulps xmm1, xmm2	
	mulps xmm0, xmm1	;# xmm0=rinv 
	movaps xmm4, xmm0
	mulps  xmm4, xmm4	;# xmm4=rinvsq 
	movaps xmm6, xmm0
	addps  xmm6, xmm7	;# xmm6=rinv+ krsq 
	movaps xmm1, xmm4
	subps  xmm6, [esp + nb210_crf]	
	mulps  xmm1, xmm4
	mulps  xmm1, xmm4	;# xmm1=rinvsix 
	movaps xmm2, xmm1
	mulps  xmm2, xmm2	;# xmm2=rinvtwelve 
	mulps  xmm6, xmm3	;# xmm6=vcoul 
	mulps  xmm7, [esp + nb210_two]
	mulps  xmm1, [esp + nb210_c6]
	mulps  xmm2, [esp + nb210_c12]
	movaps xmm5, xmm2
	subps  xmm5, xmm1	;# Vvdw=Vvdw12-Vvdw6 
	addss  xmm5, [esp + nb210_Vvdwtot]
	mulps  xmm1, [esp + nb210_six]
	mulps  xmm2, [esp + nb210_twelve]
	subps  xmm2, xmm1
	subps  xmm0, xmm7
	mulps  xmm3, xmm0
	addps  xmm2, xmm3
	mulps  xmm4, xmm2	;# xmm4=total fscal 
	addss  xmm6, [esp + nb210_vctot]
	
	mov    edi, [ebp + nb210_faction]

	movaps xmm0, [esp + nb210_dx]
	movaps xmm1, [esp + nb210_dy]
	movaps xmm2, [esp + nb210_dz]

	movss [esp + nb210_vctot], xmm6
	movss [esp + nb210_Vvdwtot], xmm5

	mulps  xmm0, xmm4
	mulps  xmm1, xmm4
	mulps  xmm2, xmm4
	;# xmm0-xmm2 contains tx-tz (partial force) 
	;# now update f_i 
	movaps xmm3, [esp + nb210_fix]
	movaps xmm4, [esp + nb210_fiy]
	movaps xmm5, [esp + nb210_fiz]
	addss  xmm3, xmm0
	addss  xmm4, xmm1
	addss  xmm5, xmm2
	movaps [esp + nb210_fix], xmm3
	movaps [esp + nb210_fiy], xmm4
	movaps [esp + nb210_fiz], xmm5
	;# update fj 
	
	movss   xmm3, [edi + eax*4]
	movss   xmm4, [edi + eax*4 + 4]
	movss   xmm5, [edi + eax*4 + 8]
	subss   xmm3, xmm0
	subss   xmm4, xmm1
	subss   xmm5, xmm2	
	movss   [edi + eax*4], xmm3
	movss   [edi + eax*4 + 4], xmm4
	movss   [edi + eax*4 + 8], xmm5	
.nb210_updateouterdata:
	mov   ecx, [esp + nb210_ii3]
	mov   edi, [ebp + nb210_faction]
	mov   esi, [ebp + nb210_fshift]
	mov   edx, [esp + nb210_is3]

	;# accumulate i forces in xmm0, xmm1, xmm2 
	movaps xmm0, [esp + nb210_fix]
	movaps xmm1, [esp + nb210_fiy]
	movaps xmm2, [esp + nb210_fiz]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addps  xmm0, xmm3
	addps  xmm1, xmm4
	addps  xmm2, xmm5 ;# sum is in 1/2 in xmm0-xmm2 

	movaps xmm3, xmm0	
	movaps xmm4, xmm1	
	movaps xmm5, xmm2	

	shufps xmm3, xmm3, 1
	shufps xmm4, xmm4, 1
	shufps xmm5, xmm5, 1
	addss  xmm0, xmm3
	addss  xmm1, xmm4
	addss  xmm2, xmm5	;# xmm0-xmm2 has single force in pos0 

	;# increment i force 
	movss  xmm3, [edi + ecx*4]
	movss  xmm4, [edi + ecx*4 + 4]
	movss  xmm5, [edi + ecx*4 + 8]
	addss  xmm3, xmm0
	addss  xmm4, xmm1
	addss  xmm5, xmm2
	movss  [edi + ecx*4],     xmm3
	movss  [edi + ecx*4 + 4], xmm4
	movss  [edi + ecx*4 + 8], xmm5

	;# increment fshift force  
	movss  xmm3, [esi + edx*4]
	movss  xmm4, [esi + edx*4 + 4]
	movss  xmm5, [esi + edx*4 + 8]
	addss  xmm3, xmm0
	addss  xmm4, xmm1
	addss  xmm5, xmm2
	movss  [esi + edx*4],     xmm3
	movss  [esi + edx*4 + 4], xmm4
	movss  [esi + edx*4 + 8], xmm5

	;# get n from stack
	mov esi, [esp + nb210_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb210_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movaps xmm7, [esp + nb210_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		

	;# add earlier value from mem 
	mov   eax, [ebp + nb210_Vc]
	addss xmm7, [eax + edx*4] 
	;# move back to mem 
	movss [eax + edx*4], xmm7 
	
	;# accumulate total lj energy and update it 
	movaps xmm7, [esp + nb210_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		

	;# add earlier value from mem 
	mov   eax, [ebp + nb210_Vvdw]
	addss xmm7, [eax + edx*4] 
	;# move back to mem 
	movss [eax + edx*4], xmm7 
	
        ;# finish if last 
        mov ecx, [esp + nb210_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jecxz .nb210_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb210_n], esi
        jmp .nb210_outer
.nb210_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb210_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jecxz .nb210_end
        ;# non-zero, do one more workunit
        jmp   .nb210_threadloop
.nb210_end:
	emms

	mov eax, [esp + nb210_nouter]
	mov ebx, [esp + nb210_ninner]
	mov ecx, [ebp + nb210_outeriter]
	mov edx, [ebp + nb210_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb210_salign]
	add esp, eax
	add esp,  400
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret







.globl nb_kernel210nf_ia32_sse
.globl _nb_kernel210nf_ia32_sse
nb_kernel210nf_ia32_sse:	
_nb_kernel210nf_ia32_sse:	
.equiv          nb210nf_p_nri,          8
.equiv          nb210nf_iinr,           12
.equiv          nb210nf_jindex,         16
.equiv          nb210nf_jjnr,           20
.equiv          nb210nf_shift,          24
.equiv          nb210nf_shiftvec,       28
.equiv          nb210nf_fshift,         32
.equiv          nb210nf_gid,            36
.equiv          nb210nf_pos,            40
.equiv          nb210nf_faction,        44
.equiv          nb210nf_charge,         48
.equiv          nb210nf_p_facel,        52
.equiv          nb210nf_argkrf,         56
.equiv          nb210nf_argcrf,         60
.equiv          nb210nf_Vc,             64
.equiv          nb210nf_type,           68
.equiv          nb210nf_p_ntype,        72
.equiv          nb210nf_vdwparam,       76
.equiv          nb210nf_Vvdw,           80
.equiv          nb210nf_p_tabscale,     84
.equiv          nb210nf_VFtab,          88
.equiv          nb210nf_invsqrta,       92
.equiv          nb210nf_dvda,           96
.equiv          nb210nf_p_gbtabscale,   100
.equiv          nb210nf_GBtab,          104
.equiv          nb210nf_p_nthreads,     108
.equiv          nb210nf_count,          112
.equiv          nb210nf_mtx,            116
.equiv          nb210nf_outeriter,      120
.equiv          nb210nf_inneriter,      124
.equiv          nb210nf_work,           128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb210nf_ix,             0
.equiv          nb210nf_iy,             16
.equiv          nb210nf_iz,             32
.equiv          nb210nf_iq,             48
.equiv          nb210nf_c6,             64
.equiv          nb210nf_c12,            80
.equiv          nb210nf_vctot,          96
.equiv          nb210nf_Vvdwtot,        112
.equiv          nb210nf_half,           128
.equiv          nb210nf_three,          144
.equiv          nb210nf_krf,            160
.equiv          nb210nf_crf,            176
.equiv          nb210nf_is3,            192
.equiv          nb210nf_ii3,            196
.equiv          nb210nf_ntia,           200
.equiv          nb210nf_innerjjnr,      204
.equiv          nb210nf_innerk,         208
.equiv          nb210nf_n,              212
.equiv          nb210nf_nn1,            216
.equiv          nb210nf_nri,            220
.equiv          nb210nf_facel,          224
.equiv          nb210nf_ntype,          228
.equiv          nb210nf_nouter,         232
.equiv          nb210nf_ninner,         236
.equiv          nb210nf_salign,         240
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp,  256		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb210nf_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb210nf_p_nri]
	mov esi, [ebp + nb210nf_p_facel]
	mov edi, [ebp + nb210nf_p_ntype]
	mov ecx, [ecx]
	mov esi, [esi]
	mov edi, [edi]
	mov [esp + nb210nf_nri], ecx
	mov [esp + nb210nf_facel], esi
	mov [esp + nb210nf_ntype], edi

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb210nf_nouter], eax
	mov [esp + nb210nf_ninner], eax


	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb210nf_half], eax
	movss xmm1, [esp + nb210nf_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# constant 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# constant 2.0
	addps  xmm3, xmm2	;# constant 3.0
	movaps [esp + nb210nf_half],  xmm1
	movaps [esp + nb210nf_three],  xmm3
	mov esi, [ebp + nb210nf_argkrf]
	mov edi, [ebp + nb210nf_argcrf]
	movss xmm5, [esi]
	movss xmm6, [edi]
	shufps xmm5, xmm5, 0
	shufps xmm6, xmm6, 0
	movaps [esp + nb210nf_krf], xmm5
	movaps [esp + nb210nf_crf], xmm6