nb_kernel131_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,004 行 · 第 1/5 页

##
## $Id: nb_kernel131_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:33 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel131_ia32_sse
.globl _nb_kernel131_ia32_sse
nb_kernel131_ia32_sse:  
_nb_kernel131_ia32_sse: 
.set nb131_p_nri, 8
.set nb131_iinr, 12
.set nb131_jindex, 16
.set nb131_jjnr, 20
.set nb131_shift, 24
.set nb131_shiftvec, 28
.set nb131_fshift, 32
.set nb131_gid, 36
.set nb131_pos, 40
.set nb131_faction, 44
.set nb131_charge, 48
.set nb131_p_facel, 52
.set nb131_argkrf, 56
.set nb131_argcrf, 60
.set nb131_Vc, 64
.set nb131_type, 68
.set nb131_p_ntype, 72
.set nb131_vdwparam, 76
.set nb131_Vvdw, 80
.set nb131_p_tabscale, 84
.set nb131_VFtab, 88
.set nb131_invsqrta, 92
.set nb131_dvda, 96
.set nb131_p_gbtabscale, 100
.set nb131_GBtab, 104
.set nb131_p_nthreads, 108
.set nb131_count, 112
.set nb131_mtx, 116
.set nb131_outeriter, 120
.set nb131_inneriter, 124
.set nb131_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb131_ixO, 0
.set nb131_iyO, 16
.set nb131_izO, 32
.set nb131_ixH1, 48
.set nb131_iyH1, 64
.set nb131_izH1, 80
.set nb131_ixH2, 96
.set nb131_iyH2, 112
.set nb131_izH2, 128
.set nb131_iqO, 144
.set nb131_iqH, 160
.set nb131_dxO, 176
.set nb131_dyO, 192
.set nb131_dzO, 208
.set nb131_dxH1, 224
.set nb131_dyH1, 240
.set nb131_dzH1, 256
.set nb131_dxH2, 272
.set nb131_dyH2, 288
.set nb131_dzH2, 304
.set nb131_qqO, 320
.set nb131_qqH, 336
.set nb131_c6, 352
.set nb131_c12, 368
.set nb131_tsc, 384
.set nb131_fstmp, 400
.set nb131_vctot, 416
.set nb131_Vvdwtot, 432
.set nb131_fixO, 448
.set nb131_fiyO, 464
.set nb131_fizO, 480
.set nb131_fixH1, 496
.set nb131_fiyH1, 512
.set nb131_fizH1, 528
.set nb131_fixH2, 544
.set nb131_fiyH2, 560
.set nb131_fizH2, 576
.set nb131_fjx, 592
.set nb131_fjy, 608
.set nb131_fjz, 624
.set nb131_half, 640
.set nb131_three, 656
.set nb131_two, 672
.set nb131_krf, 688
.set nb131_crf, 704
.set nb131_rinvO, 768
.set nb131_rinvH1, 784
.set nb131_rinvH2, 800
.set nb131_is3, 816
.set nb131_ii3, 820
.set nb131_ntia, 824
.set nb131_innerjjnr, 828
.set nb131_innerk, 832
.set nb131_n, 836
.set nb131_nn1, 840
.set nb131_nri, 844
.set nb131_nouter, 848
.set nb131_ninner, 852
.set nb131_salign, 856
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $860,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb131_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb131_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb131_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb131_nouter(%esp)
        movl %eax,nb131_ninner(%esp)

        movl nb131_p_tabscale(%ebp),%eax
        movss (%eax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb131_tsc(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb131_half(%esp)
        movss nb131_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb131_half(%esp)
        movaps %xmm2,nb131_two(%esp)
        movaps %xmm3,nb131_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb131_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb131_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        movss 4(%edx,%ebx,4),%xmm4
        movl nb131_p_facel(%ebp),%esi
        movss (%esi),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb131_iqO(%esp)
        movaps %xmm4,nb131_iqH(%esp)

        movl  nb131_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl nb131_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb131_ntia(%esp)

_nb_kernel131_ia32_sse.nb131_threadloop: 
        movl  nb131_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel131_ia32_sse.nb131_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel131_ia32_sse.nb131_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb131_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb131_n(%esp)
        movl %ebx,nb131_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel131_ia32_sse.nb131_outerstart
        jmp _nb_kernel131_ia32_sse.nb131_end

_nb_kernel131_ia32_sse.nb131_outerstart: 
        ## ebx contains number of outer iterations
        addl nb131_nouter(%esp),%ebx
        movl %ebx,nb131_nouter(%esp)

_nb_kernel131_ia32_sse.nb131_outer: 
        movl  nb131_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb131_is3(%esp)      ## store is3 

        movl  nb131_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb131_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb131_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb131_ii3(%esp)

        addss (%eax,%ebx,4),%xmm3
        addss 4(%eax,%ebx,4),%xmm4
        addss 8(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb131_ixO(%esp)
        movaps %xmm4,nb131_iyO(%esp)
        movaps %xmm5,nb131_izO(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 12(%eax,%ebx,4),%xmm0
        addss 16(%eax,%ebx,4),%xmm1
        addss 20(%eax,%ebx,4),%xmm2
        addss 24(%eax,%ebx,4),%xmm3
        addss 28(%eax,%ebx,4),%xmm4
        addss 32(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb131_ixH1(%esp)
        movaps %xmm1,nb131_iyH1(%esp)
        movaps %xmm2,nb131_izH1(%esp)
        movaps %xmm3,nb131_ixH2(%esp)
        movaps %xmm4,nb131_iyH2(%esp)
        movaps %xmm5,nb131_izH2(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb131_vctot(%esp)
        movaps %xmm4,nb131_Vvdwtot(%esp)
        movaps %xmm4,nb131_fixO(%esp)
        movaps %xmm4,nb131_fiyO(%esp)
        movaps %xmm4,nb131_fizO(%esp)
        movaps %xmm4,nb131_fixH1(%esp)
        movaps %xmm4,nb131_fiyH1(%esp)
        movaps %xmm4,nb131_fizH1(%esp)
        movaps %xmm4,nb131_fixH2(%esp)
        movaps %xmm4,nb131_fiyH2(%esp)
        movaps %xmm4,nb131_fizH2(%esp)

        movl  nb131_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb131_pos(%ebp),%esi
        movl  nb131_faction(%ebp),%edi
        movl  nb131_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb131_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb131_ninner(%esp),%ecx
        movl  %ecx,nb131_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb131_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel131_ia32_sse.nb131_unroll_loop
        jmp   _nb_kernel131_ia32_sse.nb131_odd_inner
_nb_kernel131_ia32_sse.nb131_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb131_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 

        addl $16,nb131_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb131_charge(%ebp),%esi     ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        movaps %xmm3,%xmm4           ## and in xmm4 
        mulps  nb131_iqO(%esp),%xmm3
        mulps  nb131_iqH(%esp),%xmm4

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movaps  %xmm3,nb131_qqO(%esp)
        movaps  %xmm4,nb131_qqH(%esp)

        movl nb131_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl (%esi,%ecx,4),%ecx
        movl (%esi,%edx,4),%edx
        movl nb131_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb131_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%esi,%eax,4),%xmm6
        movlps (%esi,%ecx,4),%xmm7
        movhps (%esi,%ebx,4),%xmm6
        movhps (%esi,%edx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## constant 10001000
        shufps $221,%xmm7,%xmm6 ## constant 11011101

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movd  %mm2,%ecx
        movd  %mm3,%edx

        movaps %xmm4,nb131_c6(%esp)
        movaps %xmm6,nb131_c12(%esp)

        movl nb131_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx     ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move four coordinates to xmm0-xmm2   
        movlps (%esi,%eax,4),%xmm4
        movlps (%esi,%ecx,4),%xmm5
        movss 8(%esi,%eax,4),%xmm2
        movss 8(%esi,%ecx,4),%xmm6

        movhps (%esi,%ebx,4),%xmm4
        movhps (%esi,%edx,4),%xmm5

        movss 8(%esi,%ebx,4),%xmm0
        movss 8(%esi,%edx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## constant 10001000

        shufps $136,%xmm5,%xmm0 ## constant 10001000
        shufps $221,%xmm5,%xmm1 ## constant 11011101