nb_kernel210_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,569 行 · 第 1/4 页

##
## $Id: nb_kernel210_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:33 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel210_ia32_sse
.globl _nb_kernel210_ia32_sse
nb_kernel210_ia32_sse:  
_nb_kernel210_ia32_sse: 
.set nb210_p_nri, 8
.set nb210_iinr, 12
.set nb210_jindex, 16
.set nb210_jjnr, 20
.set nb210_shift, 24
.set nb210_shiftvec, 28
.set nb210_fshift, 32
.set nb210_gid, 36
.set nb210_pos, 40
.set nb210_faction, 44
.set nb210_charge, 48
.set nb210_p_facel, 52
.set nb210_argkrf, 56
.set nb210_argcrf, 60
.set nb210_Vc, 64
.set nb210_type, 68
.set nb210_p_ntype, 72
.set nb210_vdwparam, 76
.set nb210_Vvdw, 80
.set nb210_p_tabscale, 84
.set nb210_VFtab, 88
.set nb210_invsqrta, 92
.set nb210_dvda, 96
.set nb210_p_gbtabscale, 100
.set nb210_GBtab, 104
.set nb210_p_nthreads, 108
.set nb210_count, 112
.set nb210_mtx, 116
.set nb210_outeriter, 120
.set nb210_inneriter, 124
.set nb210_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb210_ix, 0
.set nb210_iy, 16
.set nb210_iz, 32
.set nb210_iq, 48
.set nb210_dx, 64
.set nb210_dy, 80
.set nb210_dz, 96
.set nb210_c6, 112
.set nb210_c12, 128
.set nb210_six, 144
.set nb210_twelve, 160
.set nb210_vctot, 176
.set nb210_Vvdwtot, 192
.set nb210_fix, 208
.set nb210_fiy, 224
.set nb210_fiz, 240
.set nb210_half, 256
.set nb210_three, 272
.set nb210_two, 288
.set nb210_krf, 304
.set nb210_crf, 320
.set nb210_is3, 336
.set nb210_ii3, 340
.set nb210_ntia, 344
.set nb210_innerjjnr, 348
.set nb210_innerk, 352
.set nb210_n, 356
.set nb210_nn1, 360
.set nb210_nri, 364
.set nb210_facel, 368
.set nb210_ntype, 372
.set nb210_nouter, 376
.set nb210_ninner, 380
.set nb210_salign, 384
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $400,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb210_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb210_p_nri(%ebp),%ecx
        movl nb210_p_facel(%ebp),%esi
        movl nb210_p_ntype(%ebp),%edi
        movl (%ecx),%ecx
        movl (%esi),%esi
        movl (%edi),%edi
        movl %ecx,nb210_nri(%esp)
        movl %esi,nb210_facel(%esp)
        movl %edi,nb210_ntype(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb210_nouter(%esp)
        movl %eax,nb210_ninner(%esp)


        movl nb210_argkrf(%ebp),%esi
        movl nb210_argcrf(%ebp),%edi
        movss (%esi),%xmm5
        movss (%edi),%xmm6
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        movaps %xmm5,nb210_krf(%esp)
        movaps %xmm6,nb210_crf(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb210_half(%esp)
        movss nb210_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm3,%xmm4
        addps  %xmm4,%xmm4      ## 6.0
        movaps %xmm4,%xmm5
        addps  %xmm5,%xmm5      ## constant 12.0
        movaps %xmm1,nb210_half(%esp)
        movaps %xmm2,nb210_two(%esp)
        movaps %xmm3,nb210_three(%esp)
        movaps %xmm4,nb210_six(%esp)
        movaps %xmm5,nb210_twelve(%esp)

_nb_kernel210_ia32_sse.nb210_threadloop: 
        movl  nb210_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel210_ia32_sse.nb210_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel210_ia32_sse.nb210_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb210_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb210_n(%esp)
        movl %ebx,nb210_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel210_ia32_sse.nb210_outerstart
        jmp _nb_kernel210_ia32_sse.nb210_end

_nb_kernel210_ia32_sse.nb210_outerstart: 
        ## ebx contains number of outer iterations
        addl nb210_nouter(%esp),%ebx
        movl %ebx,nb210_nouter(%esp)

_nb_kernel210_ia32_sse.nb210_outer: 
        movl  nb210_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb210_is3(%esp)      ## store is3 

        movl  nb210_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb210_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        movl  nb210_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        mulss nb210_facel(%esp),%xmm3
        shufps $0,%xmm3,%xmm3

        movl  nb210_type(%ebp),%edx
        movl  (%edx,%ebx,4),%edx
        imull nb210_ntype(%esp),%edx
        shll  %edx
        movl  %edx,nb210_ntia(%esp)

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb210_pos(%ebp),%eax      ## eax = base of pos[]  

        addss (%eax,%ebx,4),%xmm0
        addss 4(%eax,%ebx,4),%xmm1
        addss 8(%eax,%ebx,4),%xmm2

        movaps %xmm3,nb210_iq(%esp)

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2

        movaps %xmm0,nb210_ix(%esp)
        movaps %xmm1,nb210_iy(%esp)
        movaps %xmm2,nb210_iz(%esp)

        movl  %ebx,nb210_ii3(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb210_vctot(%esp)
        movaps %xmm4,nb210_Vvdwtot(%esp)
        movaps %xmm4,nb210_fix(%esp)
        movaps %xmm4,nb210_fiy(%esp)
        movaps %xmm4,nb210_fiz(%esp)

        movl  nb210_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb210_pos(%ebp),%esi
        movl  nb210_faction(%ebp),%edi
        movl  nb210_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb210_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb210_ninner(%esp),%ecx
        movl  %ecx,nb210_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb210_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel210_ia32_sse.nb210_unroll_loop
        jmp   _nb_kernel210_ia32_sse.nb210_finish_inner
_nb_kernel210_ia32_sse.nb210_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb210_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 
        addl $16,nb210_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb210_charge(%ebp),%esi     ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        movaps nb210_iq(%esp),%xmm2
        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movl nb210_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl (%esi,%ecx,4),%ecx
        movl (%esi,%edx,4),%edx
        movl nb210_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb210_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%esi,%eax,4),%xmm6
        movlps (%esi,%ecx,4),%xmm7
        movhps (%esi,%ebx,4),%xmm6
        movhps (%esi,%edx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## constant 10001000
        shufps $221,%xmm7,%xmm6 ## constant 11011101

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movd  %mm2,%ecx
        movd  %mm3,%edx

        movaps %xmm4,nb210_c6(%esp)
        movaps %xmm6,nb210_c12(%esp)

        movl nb210_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        mulps %xmm2,%xmm3
        leal  (%ecx,%ecx,2),%ecx     ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move four coordinates to xmm0-xmm2   

        movlps (%esi,%eax,4),%xmm4
        movlps (%esi,%ecx,4),%xmm5
        movss 8(%esi,%eax,4),%xmm2
        movss 8(%esi,%ecx,4),%xmm6

        movhps (%esi,%ebx,4),%xmm4
        movhps (%esi,%edx,4),%xmm5

        movss 8(%esi,%ebx,4),%xmm0
        movss 8(%esi,%edx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## constant 10001000

        shufps $136,%xmm5,%xmm0 ## constant 10001000
        shufps $221,%xmm5,%xmm1 ## constant 11011101            

        ## move ix-iz to xmm4-xmm6 
        movaps nb210_ix(%esp),%xmm4
        movaps nb210_iy(%esp),%xmm5
        movaps nb210_iz(%esp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## store dr 
        movaps %xmm4,nb210_dx(%esp)
        movaps %xmm5,nb210_dy(%esp)
        movaps %xmm6,nb210_dz(%esp)
        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6
        addps %xmm5,%xmm4
        addps %xmm6,%xmm4
        ## rsq in xmm4 

        movaps nb210_krf(%esp),%xmm7
        rsqrtps %xmm4,%xmm5
        ## lookup seed in xmm5 
        movaps %xmm5,%xmm2
        mulps %xmm5,%xmm5
        movaps nb210_three(%esp),%xmm1
        mulps %xmm4,%xmm5       ## rsq*lu*lu                    
        movaps nb210_half(%esp),%xmm0
        mulps  %xmm4,%xmm7      ## xmm7=krsq 
        subps %xmm5,%xmm1       ## constant 30-rsq*lu*lu 
        mulps %xmm2,%xmm1
        mulps %xmm1,%xmm0       ## xmm0=rinv 
        movaps %xmm0,%xmm4
        mulps  %xmm4,%xmm4      ## xmm4=rinvsq 
        movaps %xmm0,%xmm6
        addps  %xmm7,%xmm6      ## xmm6=rinv+ krsq 
        movaps %xmm4,%xmm1
        subps  nb210_crf(%esp),%xmm6
        mulps  %xmm4,%xmm1
        mulps  %xmm4,%xmm1      ## xmm1=rinvsix 
        movaps %xmm1,%xmm2
        mulps  %xmm2,%xmm2      ## xmm2=rinvtwelve