nb_kernel133_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,066 行 · 第 1/5 页

        ## increment i force 
        movss  36(%edi,%ecx,4),%xmm3
        movss  40(%edi,%ecx,4),%xmm4
        movss  44(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,36(%edi,%ecx,4)
        movss  %xmm4,40(%edi,%ecx,4)
        movss  %xmm5,44(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## constant 00001000      
        addps   %xmm0,%xmm6

        ## increment fshift force  
        movlps  (%esi,%edx,4),%xmm3
        movss  8(%esi,%edx,4),%xmm4
        addps  %xmm6,%xmm3
        addss  %xmm7,%xmm4
        movlps  %xmm3,(%esi,%edx,4)
        movss  %xmm4,8(%esi,%edx,4)

        ## get n from stack
        movl nb133_n(%esp),%esi
        ## get group index for i particle 
        movl  nb133_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb133_vctot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb133_Vc(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## accumulate total lj energy and update it 
        movaps nb133_Vvdwtot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb133_Vvdw(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## finish if last 
        movl nb133_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel133_ia32_sse.nb133_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb133_n(%esp)
        jmp _nb_kernel133_ia32_sse.nb133_outer
_nb_kernel133_ia32_sse.nb133_outerend: 
        ## check if more outer neighborlists remain
        movl  nb133_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel133_ia32_sse.nb133_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel133_ia32_sse.nb133_threadloop
_nb_kernel133_ia32_sse.nb133_end: 
        emms

        movl nb133_nouter(%esp),%eax
        movl nb133_ninner(%esp),%ebx
        movl nb133_outeriter(%ebp),%ecx
        movl nb133_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        movl nb133_salign(%esp),%eax
        addl %eax,%esp
        addl $1004,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret


.globl nb_kernel133nf_ia32_sse
.globl _nb_kernel133nf_ia32_sse
nb_kernel133nf_ia32_sse:        
_nb_kernel133nf_ia32_sse:       
.set nb133nf_p_nri, 8
.set nb133nf_iinr, 12
.set nb133nf_jindex, 16
.set nb133nf_jjnr, 20
.set nb133nf_shift, 24
.set nb133nf_shiftvec, 28
.set nb133nf_fshift, 32
.set nb133nf_gid, 36
.set nb133nf_pos, 40
.set nb133nf_faction, 44
.set nb133nf_charge, 48
.set nb133nf_p_facel, 52
.set nb133nf_argkrf, 56
.set nb133nf_argcrf, 60
.set nb133nf_Vc, 64
.set nb133nf_type, 68
.set nb133nf_p_ntype, 72
.set nb133nf_vdwparam, 76
.set nb133nf_Vvdw, 80
.set nb133nf_p_tabscale, 84
.set nb133nf_VFtab, 88
.set nb133nf_invsqrta, 92
.set nb133nf_dvda, 96
.set nb133nf_p_gbtabscale, 100
.set nb133nf_GBtab, 104
.set nb133nf_p_nthreads, 108
.set nb133nf_count, 112
.set nb133nf_mtx, 116
.set nb133nf_outeriter, 120
.set nb133nf_inneriter, 124
.set nb133nf_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb133nf_ixO, 0
.set nb133nf_iyO, 16
.set nb133nf_izO, 32
.set nb133nf_ixH1, 48
.set nb133nf_iyH1, 64
.set nb133nf_izH1, 80
.set nb133nf_ixH2, 96
.set nb133nf_iyH2, 112
.set nb133nf_izH2, 128
.set nb133nf_ixM, 144
.set nb133nf_iyM, 160
.set nb133nf_izM, 176
.set nb133nf_iqM, 192
.set nb133nf_iqH, 208
.set nb133nf_qqH, 224
.set nb133nf_rinvH1, 240
.set nb133nf_rinvH2, 256
.set nb133nf_rinvM, 272
.set nb133nf_c6, 288
.set nb133nf_c12, 304
.set nb133nf_tsc, 320
.set nb133nf_vctot, 416
.set nb133nf_Vvdwtot, 432
.set nb133nf_half, 448
.set nb133nf_three, 464
.set nb133nf_qqM, 480
.set nb133nf_is3, 496
.set nb133nf_ii3, 500
.set nb133nf_ntia, 504
.set nb133nf_innerjjnr, 508
.set nb133nf_innerk, 512
.set nb133nf_n, 516
.set nb133nf_nn1, 520
.set nb133nf_nri, 524
.set nb133nf_nouter, 528
.set nb133nf_ninner, 532
.set nb133nf_salign, 536
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $540,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb133nf_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb133nf_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb133nf_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb133nf_nouter(%esp)
        movl %eax,nb133nf_ninner(%esp)

        movl nb133nf_p_tabscale(%ebp),%eax
        movss (%eax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb133nf_tsc(%esp)


        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb133nf_half(%esp)
        movss nb133nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb133nf_half(%esp)
        movaps %xmm3,nb133nf_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb133nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb133nf_charge(%ebp),%edx
        movss 4(%edx,%ebx,4),%xmm4
        movss 12(%edx,%ebx,4),%xmm3
        movl nb133nf_p_facel(%ebp),%esi
        movss (%esi),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb133nf_iqM(%esp)
        movaps %xmm4,nb133nf_iqH(%esp)

        movl  nb133nf_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl nb133nf_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb133nf_ntia(%esp)
_nb_kernel133nf_ia32_sse.nb133nf_threadloop: 
        movl  nb133nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel133nf_ia32_sse.nb133nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel133nf_ia32_sse.nb133nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb133nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb133nf_n(%esp)
        movl %ebx,nb133nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel133nf_ia32_sse.nb133nf_outerstart
        jmp _nb_kernel133nf_ia32_sse.nb133nf_end

_nb_kernel133nf_ia32_sse.nb133nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb133nf_nouter(%esp),%ebx
        movl %ebx,nb133nf_nouter(%esp)

_nb_kernel133nf_ia32_sse.nb133nf_outer: 
        movl  nb133nf_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx        ## ebx=3*is 
        movl  %ebx,nb133nf_is3(%esp)            ## store is3 

        movl  nb133nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb133nf_iinr(%ebp),%ecx           ## ecx = pointer into iinr[]    
        movl  (%ecx,%esi,4),%ebx                ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        movaps %xmm0,%xmm6
        movaps %xmm1,%xmm7

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb133nf_pos(%ebp),%eax    ## eax = base of pos[]  
        movl  %ebx,nb133nf_ii3(%esp)

        addss (%eax,%ebx,4),%xmm3       ## ox
        addss 4(%eax,%ebx,4),%xmm4     ## oy
        addss 8(%eax,%ebx,4),%xmm5     ## oz
        addss 12(%eax,%ebx,4),%xmm6    ## h1x
        addss 16(%eax,%ebx,4),%xmm7    ## h1y
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm7,%xmm7
        movaps %xmm3,nb133nf_ixO(%esp)
        movaps %xmm4,nb133nf_iyO(%esp)
        movaps %xmm5,nb133nf_izO(%esp)
        movaps %xmm6,nb133nf_ixH1(%esp)
        movaps %xmm7,nb133nf_iyH1(%esp)

        movss %xmm2,%xmm6
        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 20(%eax,%ebx,4),%xmm6    ## h1z
        addss 24(%eax,%ebx,4),%xmm0    ## h2x
        addss 28(%eax,%ebx,4),%xmm1    ## h2y
        addss 32(%eax,%ebx,4),%xmm2    ## h2z
        addss 36(%eax,%ebx,4),%xmm3    ## mx
        addss 40(%eax,%ebx,4),%xmm4    ## my
        addss 44(%eax,%ebx,4),%xmm5    ## mz

        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm6,nb133nf_izH1(%esp)
        movaps %xmm0,nb133nf_ixH2(%esp)
        movaps %xmm1,nb133nf_iyH2(%esp)
        movaps %xmm2,nb133nf_izH2(%esp)
        movaps %xmm3,nb133nf_ixM(%esp)
        movaps %xmm4,nb133nf_iyM(%esp)
        movaps %xmm5,nb133nf_izM(%esp)

        ## clear vctot 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb133nf_vctot(%esp)
        movaps %xmm4,nb133nf_Vvdwtot(%esp)

        movl  nb133nf_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx                ## jindex[n] 
        movl  4(%eax,%esi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movl  nb133nf_pos(%ebp),%esi
        movl  nb133nf_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb133nf_innerjjnr(%esp)      ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb133nf_ninner(%esp),%ecx
        movl  %ecx,nb133nf_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb133nf_innerk(%esp)         ## number of innerloop atoms 
        jge   _nb_kernel133nf_ia32_sse.nb133nf_unroll_loop
        jmp   _nb_kernel133nf_ia32_sse.nb133nf_odd_inner
_nb_kernel133nf_ia32_sse.nb133nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb133nf_innerjjnr(%esp),%edx      ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx             ## eax-edx=jnr1-4 

        addl $16,nb133nf_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb133nf_charge(%ebp),%esi  ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        movaps %xmm3,%xmm4              ## and in xmm4 
        mulps  nb133nf_iqM(%esp),%xmm3
        mulps  nb133nf_iqH(%esp),%xmm4

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movaps  %xmm3,nb133nf_qqM(%esp)
        movaps  %xmm4,nb133nf_qqH(%esp)

        movl nb133nf_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl (%esi,%ecx,4),%ecx
        movl (%esi,%edx,4),%edx
        movl nb133nf_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb133nf_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx