nb_kernel103_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,493 行 · 第 1/3 页

;#
;# $Id: nb_kernel103_ia32_sse.intel_syntax.s,v 1.1.2.1 2006/03/01 15:18:29 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as



.globl nb_kernel103_ia32_sse
.globl _nb_kernel103_ia32_sse
nb_kernel103_ia32_sse:	
_nb_kernel103_ia32_sse:	
.equiv          nb103_p_nri,            8
.equiv          nb103_iinr,             12
.equiv          nb103_jindex,           16
.equiv          nb103_jjnr,             20
.equiv          nb103_shift,            24
.equiv          nb103_shiftvec,         28
.equiv          nb103_fshift,           32
.equiv          nb103_gid,              36
.equiv          nb103_pos,              40
.equiv          nb103_faction,          44
.equiv          nb103_charge,           48
.equiv          nb103_p_facel,          52
.equiv          nb103_p_krf,            56
.equiv          nb103_p_crf,            60
.equiv          nb103_Vc,               64
.equiv          nb103_type,             68
.equiv          nb103_p_ntype,          72
.equiv          nb103_vdwparam,         76
.equiv          nb103_Vvdw,             80
.equiv          nb103_p_tabscale,       84
.equiv          nb103_VFtab,            88
.equiv          nb103_invsqrta,         92
.equiv          nb103_dvda,             96
.equiv          nb103_p_gbtabscale,     100
.equiv          nb103_GBtab,            104
.equiv          nb103_p_nthreads,       108
.equiv          nb103_count,            112
.equiv          nb103_mtx,              116
.equiv          nb103_outeriter,        120
.equiv          nb103_inneriter,        124
.equiv          nb103_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb103_ixH1,             0
.equiv          nb103_iyH1,             16
.equiv          nb103_izH1,             32
.equiv          nb103_ixH2,             48
.equiv          nb103_iyH2,             64
.equiv          nb103_izH2,             80
.equiv          nb103_ixM,              96
.equiv          nb103_iyM,              112
.equiv          nb103_izM,              128
.equiv          nb103_iqH,              144
.equiv          nb103_iqM,              160
.equiv          nb103_dxH1,             176
.equiv          nb103_dyH1,             192
.equiv          nb103_dzH1,             208
.equiv          nb103_dxH2,             224
.equiv          nb103_dyH2,             240
.equiv          nb103_dzH2,             256
.equiv          nb103_dxM,              272
.equiv          nb103_dyM,              288
.equiv          nb103_dzM,              304
.equiv          nb103_qqH,              320
.equiv          nb103_qqM,              336
.equiv          nb103_vctot,            352
.equiv          nb103_fixH1,            368
.equiv          nb103_fiyH1,            384
.equiv          nb103_fizH1,            400
.equiv          nb103_fixH2,            416
.equiv          nb103_fiyH2,            432
.equiv          nb103_fizH2,            448
.equiv          nb103_fixM,             464
.equiv          nb103_fiyM,             480
.equiv          nb103_fizM,             496
.equiv          nb103_fjx,              512
.equiv          nb103_fjy,              528
.equiv          nb103_fjz,              544
.equiv          nb103_half,             560
.equiv          nb103_three,            576
.equiv          nb103_is3,              592
.equiv          nb103_ii3,              596
.equiv          nb103_innerjjnr,        600
.equiv          nb103_innerk,           604
.equiv          nb103_n,                608
.equiv          nb103_nn1,              612
.equiv          nb103_nri,              616
.equiv          nb103_nouter,           620
.equiv          nb103_ninner,           624
.equiv          nb103_salign,           628
	push ebp
	mov ebp,esp	
	push eax
	push ebx
	push ecx
	push edx
	push esi
	push edi
	sub esp, 632		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb103_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb103_p_nri]
	mov ecx, [ecx]
	mov [esp + nb103_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb103_nouter], eax
	mov [esp + nb103_ninner], eax


	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb103_half], eax
	movss xmm1, [esp + nb103_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# constant 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# constant 2.0
	addps  xmm3, xmm2	;# constant 3.0
	movaps [esp + nb103_half],  xmm1
	movaps [esp + nb103_three],  xmm3

	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb103_iinr]   	;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]		;# ebx =ii 

	mov   edx, [ebp + nb103_charge]
	movss xmm3, [edx + ebx*4 + 4]	
	movss xmm4, [edx + ebx*4 + 12]	
	mov esi, [ebp + nb103_p_facel]
	movss xmm5, [esi]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [esp + nb103_iqH], xmm3
	movaps [esp + nb103_iqM], xmm4
	
.nb103_threadloop:
        mov   esi, [ebp + nb103_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb103_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                            ;# ebx=nn1=nn0+10
        lock 
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb103_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb103_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb103_n], eax
        mov [esp + nb103_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb103_outerstart
        jmp .nb103_end
	
.nb103_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb103_nouter]
	mov [esp + nb103_nouter], ebx

.nb103_outer:
	mov   eax, [ebp + nb103_shift]  	;# eax = pointer into shift[] 
	mov   ebx, [eax + esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]	;# ebx=3*is 
	mov   [esp + nb103_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb103_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [eax + ebx*4]
	movss xmm1, [eax + ebx*4 + 4]
	movss xmm2, [eax + ebx*4 + 8] 

	mov   ecx, [ebp + nb103_iinr]   	;# ecx = pointer into iinr[] 
	mov   ebx, [ecx + esi*4]		;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb103_pos]	;# eax = base of pos[]  
	mov   [esp + nb103_ii3], ebx

	addss xmm3, [eax + ebx*4 + 12]
	addss xmm4, [eax + ebx*4 + 16]
	addss xmm5, [eax + ebx*4 + 20]	
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb103_ixH1], xmm3
	movaps [esp + nb103_iyH1], xmm4
	movaps [esp + nb103_izH1], xmm5

	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm0, [eax + ebx*4 + 24]
	addss xmm1, [eax + ebx*4 + 28]
	addss xmm2, [eax + ebx*4 + 32]		
	addss xmm3, [eax + ebx*4 + 36]
	addss xmm4, [eax + ebx*4 + 40]
	addss xmm5, [eax + ebx*4 + 44]		

	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb103_ixH2], xmm0
	movaps [esp + nb103_iyH2], xmm1
	movaps [esp + nb103_izH2], xmm2
	movaps [esp + nb103_ixM], xmm3
	movaps [esp + nb103_iyM], xmm4
	movaps [esp + nb103_izM], xmm5
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [esp + nb103_vctot], xmm4
	movaps [esp + nb103_fixH1], xmm4
	movaps [esp + nb103_fiyH1], xmm4
	movaps [esp + nb103_fizH1], xmm4
	movaps [esp + nb103_fixH2], xmm4
	movaps [esp + nb103_fiyH2], xmm4
	movaps [esp + nb103_fizH2], xmm4
	movaps [esp + nb103_fixM], xmm4
	movaps [esp + nb103_fiyM], xmm4
	movaps [esp + nb103_fizM], xmm4
	
	mov   eax, [ebp + nb103_jindex]
	mov   ecx, [eax + esi*4]	 	;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	 	;# jindex[n+1] 
	sub   edx, ecx           	;# number of innerloop atoms 

	mov   esi, [ebp + nb103_pos]
	mov   edi, [ebp + nb103_faction]	
	mov   eax, [ebp + nb103_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb103_innerjjnr], eax 	;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [esp + nb103_ninner]
	mov   [esp + nb103_ninner], ecx
	add   edx, 0
	mov   [esp + nb103_innerk], edx	;# number of innerloop atoms 
	jge   .nb103_unroll_loop
	jmp   .nb103_odd_inner
.nb103_unroll_loop:
	;# quad-unroll innerloop here 
	mov   edx, [esp + nb103_innerjjnr] 	;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	mov   ecx, [edx + 8]            
	mov   edx, [edx + 12]     	;# eax-edx=jnr1-4 

	add dword ptr [esp + nb103_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov esi, [ebp + nb103_charge]	;# base of charge[] 
	
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]

	shufps xmm3, xmm6, 0
	shufps xmm4, xmm7, 0
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	 	;# and in xmm4 
	mulps  xmm3, [esp + nb103_iqH]
	mulps  xmm4, [esp + nb103_iqM]

	movaps  [esp + nb103_qqH], xmm3
	movaps  [esp + nb103_qqM], xmm4	

	mov esi, [ebp + nb103_pos]   	;# base of pos[] 

	lea   eax, [eax + eax*2] 	;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	
	lea   ecx, [ecx + ecx*2] 	;# replace jnr with j3 
	lea   edx, [edx + edx*2]	

	;# move four coordinates to xmm0-xmm2 	
	movlps xmm4, [esi + eax*4]
	movlps xmm5, [esi + ecx*4]
	movss xmm2, [esi + eax*4 + 8]
	movss xmm6, [esi + ecx*4 + 8]

	movhps xmm4, [esi + ebx*4]
	movhps xmm5, [esi + edx*4]

	movss xmm0, [esi + ebx*4 + 8]
	movss xmm1, [esi + edx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# constant 10001000
	
	shufps xmm0, xmm5, 136  ;# constant 10001000
	shufps xmm1, xmm5, 221  ;# constant 11011101		

	;# move ixH1-izH1 to xmm4-xmm6 
	movaps xmm4, [esp + nb103_ixH1]
	movaps xmm5, [esp + nb103_iyH1]
	movaps xmm6, [esp + nb103_izH1]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb103_dxH1], xmm4
	movaps [esp + nb103_dyH1], xmm5
	movaps [esp + nb103_dzH1], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	movaps xmm7, xmm4
	;# rsqO in xmm7 

	;# move ixH2-izH2 to xmm4-xmm6 
	movaps xmm4, [esp + nb103_ixH2]
	movaps xmm5, [esp + nb103_iyH2]
	movaps xmm6, [esp + nb103_izH2]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# store dr 
	movaps [esp + nb103_dxH2], xmm4
	movaps [esp + nb103_dyH2], xmm5
	movaps [esp + nb103_dzH2], xmm6
	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm6, xmm5
	addps xmm6, xmm4
	;# rsqH1 in xmm6 

	;# move ixM-izM to xmm3-xmm5  
	movaps xmm3, [esp + nb103_ixM]
	movaps xmm4, [esp + nb103_iyM]
	movaps xmm5, [esp + nb103_izM]

	;# calc dr 
	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2

	;# store dr 
	movaps [esp + nb103_dxM], xmm3
	movaps [esp + nb103_dyM], xmm4
	movaps [esp + nb103_dzM], xmm5
	;# square it 
	mulps xmm3,xmm3
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	addps xmm5, xmm4
	addps xmm5, xmm3
	;# rsqM in xmm5, rsqH2 in xmm6, rsqH1 in xmm7 

	;# start with rsqH1 - seed in xmm2 	
	rsqrtps xmm2, xmm7
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb103_three]
	mulps   xmm2, xmm7	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb103_half]
	movaps  xmm7, xmm4	;# rinvH1 in xmm7 
	;# rsqH2 - seed in xmm2 
	rsqrtps xmm2, xmm6
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb103_three]
	mulps   xmm2, xmm6	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb103_half]
	movaps  xmm6, xmm4	;# rinvH2 in xmm6 
	;# rsqM - seed in xmm2 
	rsqrtps xmm2, xmm5
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb103_three]
	mulps   xmm2, xmm5	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb103_half]
	movaps  xmm5, xmm4	;# rinvM in xmm5 

	;# do H1 interactions 
	movaps  xmm4, xmm7	
	mulps   xmm4, xmm4	;# xmm7=rinv, xmm4=rinvsq 
	mulps  xmm7, [esp + nb103_qqH]	;# xmm7=vcoul 
	
	mulps  xmm4, xmm7	;# total fsH1 in xmm4 

	addps  xmm7, [esp + nb103_vctot]
	
	movaps [esp + nb103_vctot], xmm7

	movaps xmm0, [esp + nb103_dxH1]
	movaps xmm1, [esp + nb103_dyH1]
	movaps xmm2, [esp + nb103_dzH1]
	mulps  xmm0, xmm4
	mulps  xmm1, xmm4
	mulps  xmm2, xmm4

	;# update H1 forces 
	movaps xmm3, [esp + nb103_fixH1]
	movaps xmm4, [esp + nb103_fiyH1]
	movaps xmm7, [esp + nb103_fizH1]
	addps  xmm3, xmm0
	addps  xmm4, xmm1
	addps  xmm7, xmm2
	movaps [esp + nb103_fixH1], xmm3
	movaps [esp + nb103_fiyH1], xmm4
	movaps [esp + nb103_fizH1], xmm7
	;# update j forces with water O 
	movaps [esp + nb103_fjx], xmm0
	movaps [esp + nb103_fjy], xmm1
	movaps [esp + nb103_fjz], xmm2

	;# H2 interactions