nb_kernel231_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,071 行 · 第 1/5 页

##
## $Id: nb_kernel231_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:33 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel231_ia32_sse
.globl _nb_kernel231_ia32_sse
nb_kernel231_ia32_sse:  
_nb_kernel231_ia32_sse: 
.set nb231_p_nri, 8
.set nb231_iinr, 12
.set nb231_jindex, 16
.set nb231_jjnr, 20
.set nb231_shift, 24
.set nb231_shiftvec, 28
.set nb231_fshift, 32
.set nb231_gid, 36
.set nb231_pos, 40
.set nb231_faction, 44
.set nb231_charge, 48
.set nb231_p_facel, 52
.set nb231_argkrf, 56
.set nb231_argcrf, 60
.set nb231_Vc, 64
.set nb231_type, 68
.set nb231_p_ntype, 72
.set nb231_vdwparam, 76
.set nb231_Vvdw, 80
.set nb231_p_tabscale, 84
.set nb231_VFtab, 88
.set nb231_invsqrta, 92
.set nb231_dvda, 96
.set nb231_p_gbtabscale, 100
.set nb231_GBtab, 104
.set nb231_p_nthreads, 108
.set nb231_count, 112
.set nb231_mtx, 116
.set nb231_outeriter, 120
.set nb231_inneriter, 124
.set nb231_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb231_ixO, 0
.set nb231_iyO, 16
.set nb231_izO, 32
.set nb231_ixH1, 48
.set nb231_iyH1, 64
.set nb231_izH1, 80
.set nb231_ixH2, 96
.set nb231_iyH2, 112
.set nb231_izH2, 128
.set nb231_iqO, 144
.set nb231_iqH, 160
.set nb231_dxO, 176
.set nb231_dyO, 192
.set nb231_dzO, 208
.set nb231_dxH1, 224
.set nb231_dyH1, 240
.set nb231_dzH1, 256
.set nb231_dxH2, 272
.set nb231_dyH2, 288
.set nb231_dzH2, 304
.set nb231_qqO, 320
.set nb231_qqH, 336
.set nb231_c6, 352
.set nb231_c12, 368
.set nb231_tsc, 384
.set nb231_fstmp, 400
.set nb231_vctot, 416
.set nb231_Vvdwtot, 432
.set nb231_fixO, 448
.set nb231_fiyO, 464
.set nb231_fizO, 480
.set nb231_fixH1, 496
.set nb231_fiyH1, 512
.set nb231_fizH1, 528
.set nb231_fixH2, 544
.set nb231_fiyH2, 560
.set nb231_fizH2, 576
.set nb231_fjx, 592
.set nb231_fjy, 608
.set nb231_fjz, 624
.set nb231_half, 640
.set nb231_three, 656
.set nb231_two, 672
.set nb231_krf, 688
.set nb231_crf, 704
.set nb231_krsqO, 720
.set nb231_krsqH1, 736
.set nb231_krsqH2, 752
.set nb231_rinvO, 768
.set nb231_rinvH1, 784
.set nb231_rinvH2, 800
.set nb231_is3, 816
.set nb231_ii3, 820
.set nb231_ntia, 824
.set nb231_innerjjnr, 828
.set nb231_innerk, 832
.set nb231_n, 836
.set nb231_nn1, 840
.set nb231_nri, 844
.set nb231_nouter, 848
.set nb231_ninner, 852
.set nb231_salign, 856
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $860,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb231_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb231_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb231_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb231_nouter(%esp)
        movl %eax,nb231_ninner(%esp)

        movl nb231_p_tabscale(%ebp),%eax
        movss (%eax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb231_tsc(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb231_half(%esp)
        movss nb231_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb231_half(%esp)
        movaps %xmm2,nb231_two(%esp)
        movaps %xmm3,nb231_three(%esp)

        movl nb231_argkrf(%ebp),%esi
        movl nb231_argcrf(%ebp),%edi
        movss (%esi),%xmm5
        movss (%edi),%xmm6
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        movaps %xmm5,nb231_krf(%esp)
        movaps %xmm6,nb231_crf(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb231_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb231_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        movss 4(%edx,%ebx,4),%xmm4
        movl nb231_p_facel(%ebp),%esi
        movss (%esi),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb231_iqO(%esp)
        movaps %xmm4,nb231_iqH(%esp)

        movl  nb231_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl nb231_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb231_ntia(%esp)

_nb_kernel231_ia32_sse.nb231_threadloop: 
        movl  nb231_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel231_ia32_sse.nb231_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel231_ia32_sse.nb231_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb231_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb231_n(%esp)
        movl %ebx,nb231_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel231_ia32_sse.nb231_outerstart
        jmp _nb_kernel231_ia32_sse.nb231_end

_nb_kernel231_ia32_sse.nb231_outerstart: 
        ## ebx contains number of outer iterations
        addl nb231_nouter(%esp),%ebx
        movl %ebx,nb231_nouter(%esp)

_nb_kernel231_ia32_sse.nb231_outer: 
        movl  nb231_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb231_is3(%esp)      ## store is3 

        movl  nb231_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb231_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb231_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb231_ii3(%esp)

        addss (%eax,%ebx,4),%xmm3
        addss 4(%eax,%ebx,4),%xmm4
        addss 8(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb231_ixO(%esp)
        movaps %xmm4,nb231_iyO(%esp)
        movaps %xmm5,nb231_izO(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 12(%eax,%ebx,4),%xmm0
        addss 16(%eax,%ebx,4),%xmm1
        addss 20(%eax,%ebx,4),%xmm2
        addss 24(%eax,%ebx,4),%xmm3
        addss 28(%eax,%ebx,4),%xmm4
        addss 32(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb231_ixH1(%esp)
        movaps %xmm1,nb231_iyH1(%esp)
        movaps %xmm2,nb231_izH1(%esp)
        movaps %xmm3,nb231_ixH2(%esp)
        movaps %xmm4,nb231_iyH2(%esp)
        movaps %xmm5,nb231_izH2(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb231_vctot(%esp)
        movaps %xmm4,nb231_Vvdwtot(%esp)
        movaps %xmm4,nb231_fixO(%esp)
        movaps %xmm4,nb231_fiyO(%esp)
        movaps %xmm4,nb231_fizO(%esp)
        movaps %xmm4,nb231_fixH1(%esp)
        movaps %xmm4,nb231_fiyH1(%esp)
        movaps %xmm4,nb231_fizH1(%esp)
        movaps %xmm4,nb231_fixH2(%esp)
        movaps %xmm4,nb231_fiyH2(%esp)
        movaps %xmm4,nb231_fizH2(%esp)

        movl  nb231_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb231_pos(%ebp),%esi
        movl  nb231_faction(%ebp),%edi
        movl  nb231_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb231_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb231_ninner(%esp),%ecx
        movl  %ecx,nb231_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb231_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel231_ia32_sse.nb231_unroll_loop
        jmp   _nb_kernel231_ia32_sse.nb231_odd_inner
_nb_kernel231_ia32_sse.nb231_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb231_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 

        addl $16,nb231_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb231_charge(%ebp),%esi     ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        movaps %xmm3,%xmm4           ## and in xmm4 
        mulps  nb231_iqO(%esp),%xmm3
        mulps  nb231_iqH(%esp),%xmm4

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movaps  %xmm3,nb231_qqO(%esp)
        movaps  %xmm4,nb231_qqH(%esp)

        movl nb231_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl (%esi,%ecx,4),%ecx
        movl (%esi,%edx,4),%edx
        movl nb231_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb231_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%esi,%eax,4),%xmm6
        movlps (%esi,%ecx,4),%xmm7
        movhps (%esi,%ebx,4),%xmm6
        movhps (%esi,%edx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## constant 10001000
        shufps $221,%xmm7,%xmm6 ## constant 11011101

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movd  %mm2,%ecx
        movd  %mm3,%edx

        movaps %xmm4,nb231_c6(%esp)
        movaps %xmm6,nb231_c12(%esp)

        movl nb231_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx     ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move four coordinates to xmm0-xmm2   
        movlps (%esi,%eax,4),%xmm4
        movlps (%esi,%ecx,4),%xmm5
        movss 8(%esi,%eax,4),%xmm2
        movss 8(%esi,%ecx,4),%xmm6

        movhps (%esi,%ebx,4),%xmm4
        movhps (%esi,%edx,4),%xmm5

        movss 8(%esi,%ebx,4),%xmm0
        movss 8(%esi,%edx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## constant 10001000

        shufps $136,%xmm5,%xmm0 ## constant 10001000
        shufps $221,%xmm5,%xmm1 ## constant 11011101            

        ## move ixO-izO to xmm4-xmm6