nb_kernel313_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,088 行 · 第 1/5 页

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  12(%edi,%ecx,4),%xmm3
        movss  16(%edi,%ecx,4),%xmm4
        movss  20(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,12(%edi,%ecx,4)
        movss  %xmm4,16(%edi,%ecx,4)
        movss  %xmm5,20(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## constant 00001000      
        addps   %xmm0,%xmm6

        ## accumulate H2i forces in xmm0, xmm1, xmm2 
        movaps nb313_fixH2(%esp),%xmm0
        movaps nb313_fiyH2(%esp),%xmm1
        movaps nb313_fizH2(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  24(%edi,%ecx,4),%xmm3
        movss  28(%edi,%ecx,4),%xmm4
        movss  32(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,24(%edi,%ecx,4)
        movss  %xmm4,28(%edi,%ecx,4)
        movss  %xmm5,32(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## constant 00001000      
        addps   %xmm0,%xmm6

        ## accumulate Mi forces in xmm0, xmm1, xmm2 
        movaps nb313_fixM(%esp),%xmm0
        movaps nb313_fiyM(%esp),%xmm1
        movaps nb313_fizM(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  36(%edi,%ecx,4),%xmm3
        movss  40(%edi,%ecx,4),%xmm4
        movss  44(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,36(%edi,%ecx,4)
        movss  %xmm4,40(%edi,%ecx,4)
        movss  %xmm5,44(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## constant 00001000      
        addps   %xmm0,%xmm6

        ## increment fshift force  
        movlps  (%esi,%edx,4),%xmm3
        movss  8(%esi,%edx,4),%xmm4
        addps  %xmm6,%xmm3
        addss  %xmm7,%xmm4
        movlps  %xmm3,(%esi,%edx,4)
        movss  %xmm4,8(%esi,%edx,4)

        ## get n from stack
        movl nb313_n(%esp),%esi
        ## get group index for i particle 
        movl  nb313_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb313_vctot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb313_Vc(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## accumulate total lj energy and update it 
        movaps nb313_Vvdwtot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb313_Vvdw(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## finish if last 
        movl nb313_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel313_ia32_sse.nb313_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb313_n(%esp)
        jmp _nb_kernel313_ia32_sse.nb313_outer
_nb_kernel313_ia32_sse.nb313_outerend: 
        ## check if more outer neighborlists remain
        movl  nb313_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel313_ia32_sse.nb313_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel313_ia32_sse.nb313_threadloop
_nb_kernel313_ia32_sse.nb313_end: 
        emms

        movl nb313_nouter(%esp),%eax
        movl nb313_ninner(%esp),%ebx
        movl nb313_outeriter(%ebp),%ecx
        movl nb313_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        movl nb313_salign(%esp),%eax
        addl %eax,%esp
        addl $988,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret







.globl nb_kernel313nf_ia32_sse
.globl _nb_kernel313nf_ia32_sse
nb_kernel313nf_ia32_sse:        
_nb_kernel313nf_ia32_sse:       
.set nb313nf_p_nri, 8
.set nb313nf_iinr, 12
.set nb313nf_jindex, 16
.set nb313nf_jjnr, 20
.set nb313nf_shift, 24
.set nb313nf_shiftvec, 28
.set nb313nf_fshift, 32
.set nb313nf_gid, 36
.set nb313nf_pos, 40
.set nb313nf_faction, 44
.set nb313nf_charge, 48
.set nb313nf_p_facel, 52
.set nb313nf_argkrf, 56
.set nb313nf_argcrf, 60
.set nb313nf_Vc, 64
.set nb313nf_type, 68
.set nb313nf_p_ntype, 72
.set nb313nf_vdwparam, 76
.set nb313nf_Vvdw, 80
.set nb313nf_p_tabscale, 84
.set nb313nf_VFtab, 88
.set nb313nf_invsqrta, 92
.set nb313nf_dvda, 96
.set nb313nf_p_gbtabscale, 100
.set nb313nf_GBtab, 104
.set nb313nf_p_nthreads, 108
.set nb313nf_count, 112
.set nb313nf_mtx, 116
.set nb313nf_outeriter, 120
.set nb313nf_inneriter, 124
.set nb313nf_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb313nf_ixO, 0
.set nb313nf_iyO, 16
.set nb313nf_izO, 32
.set nb313nf_ixH1, 48
.set nb313nf_iyH1, 64
.set nb313nf_izH1, 80
.set nb313nf_ixH2, 96
.set nb313nf_iyH2, 112
.set nb313nf_izH2, 128
.set nb313nf_ixM, 144
.set nb313nf_iyM, 160
.set nb313nf_izM, 176
.set nb313nf_iqM, 192
.set nb313nf_iqH, 208
.set nb313nf_qqM, 224
.set nb313nf_qqH, 240
.set nb313nf_rinvH1, 256
.set nb313nf_rinvH2, 272
.set nb313nf_rinvM, 288
.set nb313nf_rH1, 304
.set nb313nf_rH2, 320
.set nb313nf_rM, 336
.set nb313nf_tsc, 352
.set nb313nf_two, 368
.set nb313nf_c6, 384
.set nb313nf_c12, 400
.set nb313nf_vctot, 416
.set nb313nf_Vvdwtot, 432
.set nb313nf_half, 448
.set nb313nf_three, 464
.set nb313nf_is3, 480
.set nb313nf_ii3, 484
.set nb313nf_ntia, 488
.set nb313nf_innerjjnr, 492
.set nb313nf_innerk, 496
.set nb313nf_n, 500
.set nb313nf_nn1, 504
.set nb313nf_nri, 508
.set nb313nf_nouter, 512
.set nb313nf_ninner, 516
.set nb313nf_salign, 520
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $524,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb313nf_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb313nf_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb313nf_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb313nf_nouter(%esp)
        movl %eax,nb313nf_ninner(%esp)


        movl nb313nf_p_tabscale(%ebp),%eax
        movss (%eax),%xmm5
        shufps $0,%xmm5,%xmm5
        movaps %xmm5,nb313nf_tsc(%esp)
        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb313nf_half(%esp)
        movss nb313nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb313nf_half(%esp)
        movaps %xmm2,nb313nf_two(%esp)
        movaps %xmm3,nb313nf_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb313nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb313nf_charge(%ebp),%edx
        movss 4(%edx,%ebx,4),%xmm4
        movss 12(%edx,%ebx,4),%xmm3
        movl nb313nf_p_facel(%ebp),%esi
        movss (%esi),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb313nf_iqM(%esp)
        movaps %xmm4,nb313nf_iqH(%esp)

        movl  nb313nf_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl nb313nf_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb313nf_ntia(%esp)
_nb_kernel313nf_ia32_sse.nb313nf_threadloop: 
        movl  nb313nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel313nf_ia32_sse.nb313nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel313nf_ia32_sse.nb313nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb313nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb313nf_n(%esp)
        movl %ebx,nb313nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel313nf_ia32_sse.nb313nf_outerstart
        jmp _nb_kernel313nf_ia32_sse.nb313nf_end

_nb_kernel313nf_ia32_sse.nb313nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb313nf_nouter(%esp),%ebx
        movl %ebx,nb313nf_nouter(%esp)

_nb_kernel313nf_ia32_sse.nb313nf_outer: 
        movl  nb313nf_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx        ## ebx=3*is 
        movl  %ebx,nb313nf_is3(%esp)            ## store is3 

        movl  nb313nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb313nf_iinr(%ebp),%ecx           ## ecx = pointer into iinr[]    
        movl  (%ecx,%esi,4),%ebx                ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        movaps %xmm0,%xmm6
        movaps %xmm1,%xmm7

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb313nf_pos(%ebp),%eax    ## eax = base of pos[]  
        movl  %ebx,nb313nf_ii3(%esp)

        addss (%eax,%ebx,4),%xmm3       ## ox
        addss 4(%eax,%ebx,4),%xmm4     ## oy
        addss 8(%eax,%ebx,4),%xmm5     ## oz
        addss 12(%eax,%ebx,4),%xmm6    ## h1x
        addss 16(%eax,%ebx,4),%xmm7    ## h1y
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm7,%xmm7
        movaps %xmm3,nb313nf_ixO(%esp)
        movaps %xmm4,nb313nf_iyO(%esp)
        movaps %xmm5,nb313nf_izO(%esp)
        movaps %xmm6,nb313nf_ixH1(%esp)
        movaps %xmm7,nb313nf_iyH1(%esp)

        movss %xmm2,%xmm6
        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5