nb_kernel410_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,051 行 · 第 1/4 页

	addss  xmm5, [esp + nb410_vctot]
	movss [esp + nb410_vctot], xmm5 

	;# xmm6=(vcoul+fijC*r)
	subps  xmm7, xmm6
	movaps xmm6, xmm7
	
	;# update dvdasum
	addps  xmm7, [esp + nb410_dvdasum]
	movaps [esp + nb410_dvdasum], xmm7 

	;# update j atoms dvdaj
	addss  xmm6, [esi + ebx*4]
	movss  [esi + ebx*4], xmm6
	
	;# L-J 
	movaps xmm4, xmm0
	mulss  xmm4, xmm0	;# xmm4=rinvsq 

	movaps xmm6, xmm4
	mulss  xmm6, xmm4

	mulss  xmm6, xmm4	;# xmm6=rinvsix 
	movaps xmm4, xmm6
	mulss  xmm4, xmm4	;# xmm4=rinvtwelve 
	mulss  xmm6, [esp + nb410_c6]
	mulss  xmm4, [esp + nb410_c12]
	movss xmm7, [esp + nb410_Vvdwtot]
	addss  xmm7, xmm4
	mulss  xmm4, [esp + nb410_twelve]
	subss  xmm7, xmm6
	mulss  xmm6, [esp + nb410_six]
	movss [esp + nb410_Vvdwtot], xmm7
	subss  xmm4, xmm6
	mulss  xmm4, xmm0
	subss  xmm4, xmm3
	mulss  xmm4, xmm0

	movss xmm0, [esp + nb410_dx]
	movss xmm1, [esp + nb410_dy]
	movss xmm2, [esp + nb410_dz]

	mov    edi, [ebp + nb410_faction]
	mulss  xmm0, xmm4
	mulss  xmm1, xmm4
	mulss  xmm2, xmm4
	;# xmm0-xmm2 contains tx-tz (partial force) 
	;# now update f_i 
	movss xmm3, [esp + nb410_fix]
	movss xmm4, [esp + nb410_fiy]
	movss xmm5, [esp + nb410_fiz]
	addss  xmm3, xmm0
	addss  xmm4, xmm1
	addss  xmm5, xmm2
	movss [esp + nb410_fix], xmm3
	movss [esp + nb410_fiy], xmm4
	movss [esp + nb410_fiz], xmm5
	;# update fj 
	
	movss   xmm3, [edi + eax*4]
	movss   xmm4, [edi + eax*4 + 4]
	movss   xmm5, [edi + eax*4 + 8]
	subss   xmm3, xmm0
	subss   xmm4, xmm1
	subss   xmm5, xmm2	
	movss   [edi + eax*4], xmm3
	movss   [edi + eax*4 + 4], xmm4
	movss   [edi + eax*4 + 8], xmm5	
.nb410_updateouterdata:
	mov   ecx, [esp + nb410_ii3]
	mov   edi, [ebp + nb410_faction]
	mov   esi, [ebp + nb410_fshift]
	mov   edx, [esp + nb410_is3]

	;# accumulate i forces in xmm0, xmm1, xmm2 
	movaps xmm0, [esp + nb410_fix]
	movaps xmm1, [esp + nb410_fiy]
	movaps xmm2, [esp + nb410_fiz]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addps  xmm0, xmm3
	addps  xmm1, xmm4
	addps  xmm2, xmm5 ;# sum is in 1/2 in xmm0-xmm2 

	movaps xmm3, xmm0	
	movaps xmm4, xmm1	
	movaps xmm5, xmm2	

	shufps xmm3, xmm3, 1
	shufps xmm4, xmm4, 1
	shufps xmm5, xmm5, 1
	addss  xmm0, xmm3
	addss  xmm1, xmm4
	addss  xmm2, xmm5	;# xmm0-xmm2 has single force in pos0 

	;# increment i force 
	movss  xmm3, [edi + ecx*4]
	movss  xmm4, [edi + ecx*4 + 4]
	movss  xmm5, [edi + ecx*4 + 8]
	addss  xmm3, xmm0
	addss  xmm4, xmm1
	addss  xmm5, xmm2
	movss  [edi + ecx*4],     xmm3
	movss  [edi + ecx*4 + 4], xmm4
	movss  [edi + ecx*4 + 8], xmm5

	;# increment fshift force  
	movss  xmm3, [esi + edx*4]
	movss  xmm4, [esi + edx*4 + 4]
	movss  xmm5, [esi + edx*4 + 8]
	addss  xmm3, xmm0
	addss  xmm4, xmm1
	addss  xmm5, xmm2
	movss  [esi + edx*4],     xmm3
	movss  [esi + edx*4 + 4], xmm4
	movss  [esi + edx*4 + 8], xmm5

	;# get n from stack
	mov esi, [esp + nb410_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb410_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movaps xmm7, [esp + nb410_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		

	;# add earlier value from mem 
	mov   eax, [ebp + nb410_Vc]
	addss xmm7, [eax + edx*4] 
	;# move back to mem 
	movss [eax + edx*4], xmm7 
	
	;# accumulate total lj energy and update it 
	movaps xmm7, [esp + nb410_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		

	;# add earlier value from mem 
	mov   eax, [ebp + nb410_Vvdw]
	addss xmm7, [eax + edx*4] 
	;# move back to mem 
	movss [eax + edx*4], xmm7 
	
	;# accumulate dVda and update it 
	movaps xmm7, [esp + nb410_dvdasum]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		
	
	mov edx, [esp + nb410_ii]
	mov eax, [ebp + nb410_dvda]
	addss xmm7, [eax + edx*4]
	movss [eax + edx*4], xmm7
	
        ;# finish if last 
        mov ecx, [esp + nb410_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jecxz .nb410_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb410_n], esi
        jmp .nb410_outer
.nb410_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb410_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jecxz .nb410_end
        ;# non-zero, do one more workunit
        jmp   .nb410_threadloop
.nb410_end:
	emms

	mov eax, [esp + nb410_nouter]
	mov ebx, [esp + nb410_ninner]
	mov ecx, [ebp + nb410_outeriter]
	mov edx, [ebp + nb410_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb410_salign]
	add esp, eax
	add esp, 504
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret



.globl nb_kernel410nf_ia32_sse
.globl _nb_kernel410nf_ia32_sse
nb_kernel410nf_ia32_sse:	
_nb_kernel410nf_ia32_sse:	
.equiv          nb410nf_p_nri,          8
.equiv          nb410nf_iinr,           12
.equiv          nb410nf_jindex,         16
.equiv          nb410nf_jjnr,           20
.equiv          nb410nf_shift,          24
.equiv          nb410nf_shiftvec,       28
.equiv          nb410nf_fshift,         32
.equiv          nb410nf_gid,            36
.equiv          nb410nf_pos,            40
.equiv          nb410nf_faction,        44
.equiv          nb410nf_charge,         48
.equiv          nb410nf_p_facel,        52
.equiv          nb410nf_argkrf,         56
.equiv          nb410nf_argcrf,         60
.equiv          nb410nf_Vc,             64
.equiv          nb410nf_type,           68
.equiv          nb410nf_p_ntype,        72
.equiv          nb410nf_vdwparam,       76
.equiv          nb410nf_Vvdw,           80
.equiv          nb410nf_p_tabscale,     84
.equiv          nb410nf_VFtab,          88
.equiv          nb410nf_invsqrta,       92
.equiv          nb410nf_dvda,           96
.equiv          nb410nf_p_gbtabscale,   100
.equiv          nb410nf_GBtab,          104
.equiv          nb410nf_p_nthreads,     108
.equiv          nb410nf_count,          112
.equiv          nb410nf_mtx,            116
.equiv          nb410nf_outeriter,      120
.equiv          nb410nf_inneriter,      124
.equiv          nb410nf_work,           128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb410nf_ix,             0
.equiv          nb410nf_iy,             16
.equiv          nb410nf_iz,             32
.equiv          nb410nf_iq,             48
.equiv          nb410nf_gbtsc,          64
.equiv          nb410nf_qq,             80
.equiv          nb410nf_c6,             96
.equiv          nb410nf_c12,            112
.equiv          nb410nf_vctot,          128
.equiv          nb410nf_Vvdwtot,        144
.equiv          nb410nf_half,           160
.equiv          nb410nf_three,          176
.equiv          nb410nf_isai,           192
.equiv          nb410nf_isaprod,        208
.equiv          nb410nf_gbscale,        224
.equiv          nb410nf_is3,            240
.equiv          nb410nf_ii3,            244
.equiv          nb410nf_ntia,           248
.equiv          nb410nf_innerjjnr,      252
.equiv          nb410nf_innerk,         256
.equiv          nb410nf_n,              260
.equiv          nb410nf_nn1,            264
.equiv          nb410nf_nri,            268
.equiv          nb410nf_facel,          272
.equiv          nb410nf_ntype,          276
.equiv          nb410nf_nouter,         280
.equiv          nb410nf_ninner,         284
.equiv          nb410nf_salign,         288
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 292		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb410nf_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb410nf_p_nri]
	mov esi, [ebp + nb410nf_p_facel]
	mov edi, [ebp + nb410nf_p_ntype]
	mov ecx, [ecx]
	mov esi, [esi]
	mov edi, [edi]
	mov [esp + nb410nf_nri], ecx
	mov [esp + nb410nf_facel], esi
	mov [esp + nb410nf_ntype], edi

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb410nf_nouter], eax
	mov [esp + nb410nf_ninner], eax


	mov eax, [ebp + nb410nf_p_gbtabscale]
	movss xmm5, [eax]	
	shufps xmm5, xmm5, 0
	movaps [esp + nb410nf_gbtsc], xmm5

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb410nf_half], eax
	movss xmm1, [esp + nb410nf_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# constant 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# constant 2.0
	addps  xmm3, xmm2	;# constant 3.0
	movaps [esp + nb410nf_half],  xmm1
	movaps [esp + nb410nf_three],  xmm3

.nb410nf_threadloop:
        mov   esi, [ebp + nb410nf_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb410nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb410nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb410nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb410nf_n], eax
        mov [esp + nb410nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb410nf_outerstart
        jmp .nb410nf_end

.nb410nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb410nf_nouter]
	mov [esp + nb410nf_nouter], ebx

.nb410nf_outer:
	mov   eax, [ebp + nb410nf_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb410nf_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb410nf_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [eax + ebx*4]
	movss xmm1, [eax + ebx*4 + 4]
	movss xmm2, [eax + ebx*4 + 8] 

	mov   ecx, [ebp + nb410nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx + esi*4]	    ;# ebx =ii
	
	mov   edx, [ebp + nb410nf_charge]
	movss xmm3, [edx + ebx*4]	
	mulss xmm3, [esp + nb410nf_facel]
	shufps xmm3, xmm3, 0

	mov   edx, [ebp + nb410nf_invsqrta]	;# load invsqrta[ii]
	movss xmm4, [edx + ebx*4]
	shufps xmm4, xmm4, 0

    	mov   edx, [ebp + nb410nf_type] 
    	mov   edx, [edx + ebx*4]
    	imul  edx, [esp + nb410nf_ntype]
    	shl   edx, 1
    	mov   [esp + nb410nf_ntia], edx
		
	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb410nf_pos]    ;# eax = base of pos[]  

	addss xmm0, [eax + ebx*4]
	addss xmm1, [eax + ebx*4 + 4]
	addss xmm2, [eax + ebx*4 + 8]

	movaps [esp + nb410nf_iq], xmm3
	movaps [esp + nb410nf_isai], xmm4
	
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0

	movaps [esp + nb410nf_ix], xmm0
	movaps [esp + nb410nf_iy], xmm1
	movaps [esp + nb410nf_iz], xmm2

	mov   [esp + nb410nf_ii3], ebx
	
	;# clear vctot
	xorps xmm4, xmm4
	movaps [esp + nb410nf_vctot], xmm4
	movaps [esp + nb410nf_Vvdwtot], xmm4
	
	mov   eax, [ebp + nb410nf_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb410nf_pos]
	mov   edi, [ebp + nb410nf_faction]	
	mov   eax, [ebp + nb410nf_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb410nf_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [esp + nb410nf_ninner]
	mov   [esp + nb410nf_ninner], ecx
	add   edx, 0
	mov   [esp + nb410nf_innerk], edx    ;# number of innerloop atoms 
	jge   .nb410nf_unroll_loop
	jmp   .nb410nf_finish_inner
.nb410nf_unroll_loop:	
	;# quad-unroll innerloop here 
	mov   edx, [esp + nb410nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	mov   ecx, [edx + 8]            
	mov   edx, [edx + 12]         ;# eax-edx=jnr1-4 
	add dword ptr [esp + nb410nf_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	;# load isa2
	mov esi, [ebp + nb410nf_invsqrta]
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]
	movaps xmm2, [esp + nb410nf_isai]
	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	mulps  xmm2, xmm3
		
	movaps [esp + nb410nf_isaprod], xmm2
	movaps xmm1, xmm2
	mulps xmm1, [esp + nb410nf_gbtsc]
	movaps [esp + nb410nf_gbscale], xmm1
	
	mov esi, [ebp + nb410nf_charge]    ;# base of charge[] 
	
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]

	mulps xmm2, [esp + nb410nf_iq]
	shufps xmm3, xmm6, 0 
	shufps xmm4, xmm7, 0 
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	mulps  xmm3, xmm2
	movaps [esp + nb410nf_qq], xmm3	

	movd mm0, eax
	movd mm1, ebx
	movd mm2, ecx
	movd mm3, edx
	
	mov esi, [ebp + nb410nf_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov ecx, [esi + ecx*4]
	mov edx, [esi + edx*4]
	mov esi, [ebp + nb410nf_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	shl ecx, 1	
	shl edx, 1	
	mov edi, [esp + nb410nf_ntia]
	add eax, edi
	add ebx, edi
	add ecx, edi
	add edx, edi

	movlps xmm6, [esi + eax*4]
	movlps xmm7, [esi + ecx*4]
	movhps xmm6, [esi + ebx*4]
	movhps xmm7, [esi + edx*4]

	movaps xmm4, xmm6
	shufps xmm4, xmm7, 136  ;# constant 10001000
	shufps xmm6, xmm7, 221  ;# constant 11011101
	
	movd  eax, mm0		
	movd  ebx, mm1
	movd  ecx, mm2
	movd  edx, mm3

	movaps [esp + nb410nf_c6], xmm4
	movaps [esp + nb410nf_c12], xmm6
	
	mov esi, [ebp + nb410nf_pos]       ;# base of pos[]