nb_kernel101_ia32_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,492 行 · 第 1/3 页

.equiv          nb101nf_izH1,           80
.equiv          nb101nf_ixH2,           96
.equiv          nb101nf_iyH2,           112
.equiv          nb101nf_izH2,           128
.equiv          nb101nf_iqO,            144
.equiv          nb101nf_iqH,            160
.equiv          nb101nf_qqO,            176
.equiv          nb101nf_qqH,            192
.equiv          nb101nf_vctot,          208
.equiv          nb101nf_half,           224
.equiv          nb101nf_three,          240
.equiv          nb101nf_is3,            256
.equiv          nb101nf_ii3,            260
.equiv          nb101nf_innerjjnr,      264
.equiv          nb101nf_innerk,         268
.equiv          nb101nf_n,              272
.equiv          nb101nf_nn1,            276
.equiv          nb101nf_nri,            280
.equiv          nb101nf_nouter,         284
.equiv          nb101nf_ninner,         288
.equiv          nb101nf_salign,         292
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 296		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb101nf_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb101nf_p_nri]
	mov ecx, [ecx]
	mov [esp + nb101nf_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb101nf_nouter], eax
	mov [esp + nb101nf_ninner], eax


	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb101nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb101nf_charge]
	movss xmm3, [edx + ebx*4]	
	movss xmm4, [edx + ebx*4 + 4]	
	mov esi, [ebp + nb101nf_p_facel]
	movss xmm5, [esi]
	mulss  xmm3, xmm5
	mulss  xmm4, xmm5

	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	movaps [esp + nb101nf_iqO], xmm3
	movaps [esp + nb101nf_iqH], xmm4	

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# constant 0.5 in IEEE (hex)
	mov [esp + nb101nf_half], eax
	movss xmm1, [esp + nb101nf_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# constant 1.0
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# constant 2.0
	addps  xmm3, xmm2	;# constant 3.0
	movaps [esp + nb101nf_half],  xmm1
	movaps [esp + nb101nf_three],  xmm3

.nb101nf_threadloop:
        mov   esi, [ebp + nb101nf_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb101nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                            ;# ebx=nn1=nn0+10
        lock 
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb101nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb101nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb101nf_n], eax
        mov [esp + nb101nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb101nf_outerstart
        jmp .nb101nf_end

.nb101nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb101nf_nouter]
	mov [esp + nb101nf_nouter], ebx

.nb101nf_outer:
	mov   eax, [ebp + nb101nf_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb101nf_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb101nf_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [eax + ebx*4]
	movss xmm1, [eax + ebx*4 + 4]
	movss xmm2, [eax + ebx*4 + 8] 

	mov   ecx, [ebp + nb101nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx + esi*4]	    ;# ebx =ii 

	movaps xmm3, xmm0
	movaps xmm4, xmm1
	movaps xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb101nf_pos]    ;# eax = base of pos[]  
	mov   [esp + nb101nf_ii3], ebx

	addss xmm3, [eax + ebx*4]
	addss xmm4, [eax + ebx*4 + 4]
	addss xmm5, [eax + ebx*4 + 8]		
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb101nf_ixO], xmm3
	movaps [esp + nb101nf_iyO], xmm4
	movaps [esp + nb101nf_izO], xmm5

	movss xmm3, xmm0
	movss xmm4, xmm1
	movss xmm5, xmm2
	addss xmm0, [eax + ebx*4 + 12]
	addss xmm1, [eax + ebx*4 + 16]
	addss xmm2, [eax + ebx*4 + 20]		
	addss xmm3, [eax + ebx*4 + 24]
	addss xmm4, [eax + ebx*4 + 28]
	addss xmm5, [eax + ebx*4 + 32]		

	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	shufps xmm3, xmm3, 0
	shufps xmm4, xmm4, 0
	shufps xmm5, xmm5, 0
	movaps [esp + nb101nf_ixH1], xmm0
	movaps [esp + nb101nf_iyH1], xmm1
	movaps [esp + nb101nf_izH1], xmm2
	movaps [esp + nb101nf_ixH2], xmm3
	movaps [esp + nb101nf_iyH2], xmm4
	movaps [esp + nb101nf_izH2], xmm5
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [esp + nb101nf_vctot], xmm4
	
	mov   eax, [ebp + nb101nf_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb101nf_pos]
	mov   eax, [ebp + nb101nf_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb101nf_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [esp + nb101nf_ninner]
	mov   [esp + nb101nf_ninner], ecx
	add   edx, 0
	mov   [esp + nb101nf_innerk], edx    ;# number of innerloop atoms 
	jge   .nb101nf_unroll_loop
	jmp   .nb101nf_odd_inner
.nb101nf_unroll_loop:
	;# quad-unroll innerloop here 
	mov   edx, [esp + nb101nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	mov   ecx, [edx + 8]            
	mov   edx, [edx + 12]         ;# eax-edx=jnr1-4 

	add dword ptr [esp + nb101nf_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	mov esi, [ebp + nb101nf_charge]    ;# base of charge[] 
	
	movss xmm3, [esi + eax*4]
	movss xmm4, [esi + ecx*4]
	movss xmm6, [esi + ebx*4]
	movss xmm7, [esi + edx*4]

	shufps xmm3, xmm6, 0
	shufps xmm4, xmm7, 0
	shufps xmm3, xmm4, 136  ;# constant 10001000 ;# all charges in xmm3  
	movaps xmm4, xmm3	     ;# and in xmm4 
	mulps  xmm3, [esp + nb101nf_iqO]
	mulps  xmm4, [esp + nb101nf_iqH]

	movaps  [esp + nb101nf_qqO], xmm3
	movaps  [esp + nb101nf_qqH], xmm4	

	mov esi, [ebp + nb101nf_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	
	lea   ecx, [ecx + ecx*2]     ;# replace jnr with j3 
	lea   edx, [edx + edx*2]	

	;# move four coordinates to xmm0-xmm2 	
	movlps xmm4, [esi + eax*4]
	movlps xmm5, [esi + ecx*4]
	movss xmm2, [esi + eax*4 + 8]
	movss xmm6, [esi + ecx*4 + 8]

	movhps xmm4, [esi + ebx*4]
	movhps xmm5, [esi + edx*4]

	movss xmm0, [esi + ebx*4 + 8]
	movss xmm1, [esi + edx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# constant 10001000
	
	shufps xmm0, xmm5, 136  ;# constant 10001000
	shufps xmm1, xmm5, 221  ;# constant 11011101		

	;# move ixO-izO to xmm4-xmm6 
	movaps xmm4, [esp + nb101nf_ixO]
	movaps xmm5, [esp + nb101nf_iyO]
	movaps xmm6, [esp + nb101nf_izO]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	movaps xmm7, xmm4
	;# rsqO in xmm7 

	;# move ixH1-izH1 to xmm4-xmm6 
	movaps xmm4, [esp + nb101nf_ixH1]
	movaps xmm5, [esp + nb101nf_iyH1]
	movaps xmm6, [esp + nb101nf_izH1]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm6, xmm5
	addps xmm6, xmm4
	;# rsqH1 in xmm6 

	;# move ixH2-izH2 to xmm3-xmm5  
	movaps xmm3, [esp + nb101nf_ixH2]
	movaps xmm4, [esp + nb101nf_iyH2]
	movaps xmm5, [esp + nb101nf_izH2]

	;# calc dr 
	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2

	;# square it 
	mulps xmm3,xmm3
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	addps xmm5, xmm4
	addps xmm5, xmm3
	;# rsqH2 in xmm5, rsqH1 in xmm6, rsqO in xmm7 

	;# start with rsqO - seed in xmm2 	
	rsqrtps xmm2, xmm7
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb101nf_three]
	mulps   xmm2, xmm7	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb101nf_half]
	movaps  xmm7, xmm4	;# rinvO in xmm7 
	;# rsqH1 - seed in xmm2 
	rsqrtps xmm2, xmm6
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb101nf_three]
	mulps   xmm2, xmm6	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb101nf_half]
	movaps  xmm6, xmm4	;# rinvH1 in xmm6 
	;# rsqH2 - seed in xmm2 
	rsqrtps xmm2, xmm5
	movaps  xmm3, xmm2
	mulps   xmm2, xmm2
	movaps  xmm4, [esp + nb101nf_three]
	mulps   xmm2, xmm5	;# rsq*lu*lu 
	subps   xmm4, xmm2	;# constant 30-rsq*lu*lu 
	mulps   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulps   xmm4, [esp + nb101nf_half]
	movaps  xmm5, xmm4	;# rinvH2 in xmm5 

	;# do O interactions 
	mulps  xmm7, [esp + nb101nf_qqO]	;# xmm7=vcoul 
	addps  xmm7, [esp + nb101nf_vctot]
	movaps [esp + nb101nf_vctot], xmm7

	;# H1 interactions 
	mulps  xmm6, [esp + nb101nf_qqH]	;# xmm6=vcoul 
	addps  xmm6, [esp + nb101nf_vctot]
	movaps [esp + nb101nf_vctot], xmm6

	;# H2 interactions 
	mulps  xmm5, [esp + nb101nf_qqH]	;# xmm5=vcoul 
	addps  xmm5, [esp + nb101nf_vctot]
	movaps [esp + nb101nf_vctot], xmm5
	
	;# should we do one more iteration? 
	sub dword ptr [esp + nb101nf_innerk],  4
	jl    .nb101nf_odd_inner
	jmp   .nb101nf_unroll_loop
.nb101nf_odd_inner:	
	add dword ptr [esp + nb101nf_innerk],  4
	jnz   .nb101nf_odd_loop
	jmp   .nb101nf_updateouterdata
.nb101nf_odd_loop:
	mov   edx, [esp + nb101nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	add dword ptr [esp + nb101nf_innerjjnr],  4	

 	xorps xmm4, xmm4
	movss xmm4, [esp + nb101nf_iqO]
	mov esi, [ebp + nb101nf_charge] 
	movhps xmm4, [esp + nb101nf_iqH]     
	movss xmm3, [esi + eax*4]	;# charge in xmm3 
	shufps xmm3, xmm3, 0
	mulps xmm3, xmm4
	movaps [esp + nb101nf_qqO], xmm3	;# use oxygen qq for storage 

	mov esi, [ebp + nb101nf_pos]
	lea   eax, [eax + eax*2]  
	
	;# move j coords to xmm0-xmm2 
	movss xmm0, [esi + eax*4]
	movss xmm1, [esi + eax*4 + 4]
	movss xmm2, [esi + eax*4 + 8]
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	
	movss xmm3, [esp + nb101nf_ixO]
	movss xmm4, [esp + nb101nf_iyO]
	movss xmm5, [esp + nb101nf_izO]
		
	movlps xmm6, [esp + nb101nf_ixH1]
	movlps xmm7, [esp + nb101nf_ixH2]
	unpcklps xmm6, xmm7
	movlhps xmm3, xmm6
	movlps xmm6, [esp + nb101nf_iyH1]
	movlps xmm7, [esp + nb101nf_iyH2]
	unpcklps xmm6, xmm7
	movlhps xmm4, xmm6
	movlps xmm6, [esp + nb101nf_izH1]
	movlps xmm7, [esp + nb101nf_izH2]
	unpcklps xmm6, xmm7
	movlhps xmm5, xmm6

	subps xmm3, xmm0
	subps xmm4, xmm1
	subps xmm5, xmm2
	
	mulps  xmm3, xmm3
	mulps  xmm4, xmm4
	mulps  xmm5, xmm5

	addps  xmm4, xmm3
	addps  xmm4, xmm5
	;# rsq in xmm4 

	rsqrtps xmm5, xmm4
	;# lookup seed in xmm5 
	movaps xmm2, xmm5
	mulps xmm5, xmm5
	movaps xmm1, [esp + nb101nf_three]
	mulps xmm5, xmm4	;# rsq*lu*lu 			
	movaps xmm0, [esp + nb101nf_half]
	subps xmm1, xmm5	;# constant 30-rsq*lu*lu 
	mulps xmm1, xmm2	
	mulps xmm0, xmm1	;# xmm0=rinv 
	;# a little trick to avoid NaNs: 
	;# positions 0,2,and 3 are valid, but not 1. 
	;# If it contains NaN it doesnt help to mult by 0, 
	;# So we shuffle it and copy pos 0 to pos1! 
	shufps xmm0, xmm0, 224 ;# constant 11100000	
	
	movaps xmm3, [esp + nb101nf_qqO]

	mulps  xmm3, xmm0	;# xmm3=vcoul 
	addps  xmm3, [esp + nb101nf_vctot]
	movaps [esp + nb101nf_vctot], xmm3

	dec   dword ptr [esp + nb101nf_innerk]
	jz    .nb101nf_updateouterdata
	jmp   .nb101nf_odd_loop
.nb101nf_updateouterdata:
	;# accumulate total potential energy and update it 
	;# get n from stack
	mov esi, [esp + nb101nf_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb101nf_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	movaps xmm7, [esp + nb101nf_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		
        
	;# add earlier value from mem 
	mov   eax, [ebp + nb101nf_Vc]
	addss xmm7, [eax + edx*4] 
	;# move back to mem 
	movss [eax + edx*4], xmm7 	
	
        ;# finish if last 
        mov ecx, [esp + nb101nf_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jecxz .nb101nf_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb101nf_n], esi
        jmp .nb101nf_outer
.nb101nf_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb101nf_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jecxz .nb101nf_end
        ;# non-zero, do one more workunit
        jmp   .nb101nf_threadloop
.nb101nf_end:
	emms

	mov eax, [esp + nb101nf_nouter]
	mov ebx, [esp + nb101nf_ninner]
	mov ecx, [ebp + nb101nf_outeriter]
	mov edx, [ebp + nb101nf_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb101nf_salign]
	add esp, eax
	add esp, 296
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret