nb_kernel232_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,002 行 · 第 1/5 页

        movlps %xmm3,8(%edi,%eax,4)
        movlps %xmm4,8(%edi,%ecx,4)
        movhps %xmm3,8(%edi,%ebx,4)
        movhps %xmm4,8(%edi,%edx,4)


        ## First hydrogen Y & Z forces for 4 j particles 
        movaps nb232_fjyH1(%esp),%xmm0    ## xmm0= fjyH1a  fjyH1b  fjyH1c  fjyH1d 
        movaps nb232_fjzH1(%esp),%xmm2   ## xmm1= fjzH1a  fjzH1b  fjzH1c  fjzH1d
        movlps 16(%edi,%eax,4),%xmm3
        movlps 16(%edi,%ecx,4),%xmm4
        movaps %xmm0,%xmm1
        unpcklps %xmm2,%xmm0            ## xmm0= fjyH1a  fjzH1a  fjyH1b  fjzH1b
        unpckhps %xmm2,%xmm1            ## xmm1= fjyH1c  fjzH1c  fjyH1d  fjzH1d
        movhps 16(%edi,%ebx,4),%xmm3
        movhps 16(%edi,%edx,4),%xmm4
        addps  %xmm0,%xmm3
        addps  %xmm1,%xmm4
        movlps %xmm3,16(%edi,%eax,4)
        movlps %xmm4,16(%edi,%ecx,4)
        movhps %xmm3,16(%edi,%ebx,4)
        movhps %xmm4,16(%edi,%edx,4)


        ## Second hydrogen X & Y forces for 4 j particles 
        movaps nb232_fjxH2(%esp),%xmm0    ## xmm0= fjxH2a  fjxH2b  fjxH2c  fjxH2d 
        movaps nb232_fjyH2(%esp),%xmm2   ## xmm1= fjyH2a  fjyH2b  fjyH2c  fjyH2d
        movlps 24(%edi,%eax,4),%xmm3
        movlps 24(%edi,%ecx,4),%xmm4
        movaps %xmm0,%xmm1
        unpcklps %xmm2,%xmm0            ## xmm0= fjxH2a  fjyH2a  fjxH2b  fjyH2b
        unpckhps %xmm2,%xmm1            ## xmm1= fjxH2c  fjyH2c  fjxH2d  fjyH2d
        movhps 24(%edi,%ebx,4),%xmm3
        movhps 24(%edi,%edx,4),%xmm4
        addps  %xmm0,%xmm3
        addps  %xmm1,%xmm4
        movlps %xmm3,24(%edi,%eax,4)
        movlps %xmm4,24(%edi,%ecx,4)
        movhps %xmm3,24(%edi,%ebx,4)
        movhps %xmm4,24(%edi,%edx,4)


        ## Second hydrogen Z forces for 4 j particles 
        ## Just load the four Z coords into one reg. each
        movss 32(%edi,%eax,4),%xmm4
        movss 32(%edi,%ebx,4),%xmm5
        movss 32(%edi,%ecx,4),%xmm6
        movss 32(%edi,%edx,4),%xmm7
        ## add what we have on the stack
        addss nb232_fjzH2(%esp),%xmm4
        addss nb232_fjzH2b(%esp),%xmm5
        addss nb232_fjzH2c(%esp),%xmm6
        addss nb232_fjzH2d(%esp),%xmm7
        ## store back
        movss %xmm4,32(%edi,%eax,4)
        movss %xmm5,32(%edi,%ebx,4)
        movss %xmm6,32(%edi,%ecx,4)
        movss %xmm7,32(%edi,%edx,4)

        ## should we do one more iteration? 
        subl $4,nb232_innerk(%esp)
        jl    _nb_kernel232_ia32_sse.nb232_single_check
        jmp   _nb_kernel232_ia32_sse.nb232_unroll_loop
_nb_kernel232_ia32_sse.nb232_single_check: 
        addl $4,nb232_innerk(%esp)
        jnz   _nb_kernel232_ia32_sse.nb232_single_loop
        jmp   _nb_kernel232_ia32_sse.nb232_updateouterdata
_nb_kernel232_ia32_sse.nb232_single_loop: 
        movl  nb232_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        addl $4,nb232_innerjjnr(%esp)

        movl nb232_pos(%ebp),%esi
        leal  (%eax,%eax,2),%eax

        ## fetch j coordinates 
        xorps %xmm3,%xmm3
        xorps %xmm4,%xmm4
        xorps %xmm5,%xmm5

        movss (%esi,%eax,4),%xmm3               ## jxO  -  -  -
        movss 4(%esi,%eax,4),%xmm4              ## jyO  -  -  -
        movss 8(%esi,%eax,4),%xmm5              ## jzO  -  -  -  

        movlps 12(%esi,%eax,4),%xmm6            ## xmm6 = jxH1 jyH1   -    -
        movss  20(%esi,%eax,4),%xmm7            ## xmm7 = jzH1   -    -    - 
        movhps 24(%esi,%eax,4),%xmm6            ## xmm6 = jxH1 jyH1 jxH2 jyH2
        movss  32(%esi,%eax,4),%xmm2            ## xmm2 = jzH2   -    -    -

        ## have all coords, time for some shuffling.

        shufps $216,%xmm6,%xmm6 ## constant 11011000     ;# xmm6 = jxH1 jxH2 jyH1 jyH2 
        unpcklps %xmm2,%xmm7                    ## xmm7 = jzH1 jzH2   -    -
        movaps  nb232_ixO(%esp),%xmm0
        movaps  nb232_iyO(%esp),%xmm1
        movaps  nb232_izO(%esp),%xmm2
        movlhps %xmm6,%xmm3                     ## xmm3 = jxO   0   jxH1 jxH2 
        shufps $228,%xmm6,%xmm4 ## constant 11100100    ;# xmm4 = jyO   0   jyH1 jyH2 
        shufps $68,%xmm7,%xmm5 ## constant 01000100    ;# xmm5 = jzO   0   jzH1 jzH2

        ## store all j coordinates in jO  
        movaps %xmm3,nb232_jxO(%esp)
        movaps %xmm4,nb232_jyO(%esp)
        movaps %xmm5,nb232_jzO(%esp)
        subps  %xmm3,%xmm0
        subps  %xmm4,%xmm1
        subps  %xmm5,%xmm2
        movaps %xmm0,nb232_dxOO(%esp)
        movaps %xmm1,nb232_dyOO(%esp)
        movaps %xmm2,nb232_dzOO(%esp)
        mulps %xmm0,%xmm0
        mulps %xmm1,%xmm1
        mulps %xmm2,%xmm2
        addps %xmm1,%xmm0
        addps %xmm2,%xmm0       ## have rsq in xmm0 
        movaps %xmm0,nb232_rsqOO(%esp)

        movaps %xmm0,%xmm6

        ## do invsqrt 
        rsqrtps %xmm0,%xmm1
        mulps   nb232_krf(%esp),%xmm6   ## xmm6=krsq 
        movaps  %xmm1,%xmm2
        movaps  %xmm6,%xmm7
        mulps   %xmm1,%xmm1
        movaps  nb232_three(%esp),%xmm3
        mulps   %xmm0,%xmm1
        subps   %xmm1,%xmm3
        mulps   %xmm2,%xmm3
        mulps   nb232_half(%esp),%xmm3   ## rinv iO - j water in xmm3
        movaps  %xmm3,nb232_rinvOO(%esp)

        addps   %xmm3,%xmm6     ## xmm6=rinv+ krsq 
        mulps   nb232_two(%esp),%xmm7
        subps  nb232_crf(%esp),%xmm6    ## xmm6=rinv+ krsq-crf 

        movaps  %xmm3,%xmm0 ## rinv
        subps   %xmm7,%xmm3     ## xmm3=rinv-2*krsq 
        xorps   %xmm4,%xmm4
        ## fetch charges to xmm4 (temporary) 
        movss   nb232_qqOO(%esp),%xmm4
        movhps  nb232_qqOH(%esp),%xmm4

        mulps %xmm4,%xmm6       ## vcoul  
        mulps %xmm4,%xmm3       ## coul part of fs  
        mulps %xmm0,%xmm3
        movaps %xmm3,nb232_fstmp(%esp)   ## save it
        addps  nb232_vctot(%esp),%xmm6
    movaps %xmm6,nb232_vctot(%esp)

        movaps nb232_rinvOO(%esp),%xmm0
        movss %xmm0,%xmm1
        mulss  nb232_rsqOO(%esp),%xmm1   ## xmm1=r 
        mulss  nb232_tsc(%esp),%xmm1

    cvttps2pi %xmm1,%mm6
    cvtpi2ps %mm6,%xmm3
        subss    %xmm3,%xmm1    ## xmm1=eps 
    movss %xmm1,%xmm2
    mulss  %xmm2,%xmm2      ## xmm2=eps2 
    pslld $3,%mm6

    movd %eax,%mm0

    movl nb232_VFtab(%ebp),%esi
    movd %mm6,%eax

    ## dispersion 
    movlps (%esi,%eax,4),%xmm5
    movaps %xmm5,%xmm4
    shufps $136,%xmm7,%xmm4 ## constant 10001000
    shufps $221,%xmm7,%xmm5 ## constant 11011101

    movlps 8(%esi,%eax,4),%xmm7
    movaps %xmm7,%xmm6
    shufps $136,%xmm3,%xmm6 ## constant 10001000
    shufps $221,%xmm3,%xmm7 ## constant 11011101
    ## dispersion table ready, in xmm4-xmm7 
    mulss  %xmm1,%xmm6      ## xmm6=Geps 
    mulss  %xmm2,%xmm7      ## xmm7=Heps2 
    addss  %xmm6,%xmm5
    addss  %xmm7,%xmm5      ## xmm5=Fp 
    mulss  nb232_two(%esp),%xmm7         ## two*Heps2 
    addss  %xmm6,%xmm7
    addss  %xmm5,%xmm7 ## xmm7=FF 
    mulss  %xmm1,%xmm5 ## xmm5=eps*Fp 
    addss  %xmm4,%xmm5 ## xmm5=VV 

    movss nb232_c6(%esp),%xmm4
    mulss  %xmm4,%xmm7   ## fijD 
    mulss  %xmm4,%xmm5   ## Vvdw6 
        movss  nb232_fstmp(%esp),%xmm3
        mulps  nb232_tsc(%esp),%xmm7
        subss  %xmm7,%xmm3
        movss  %xmm3,nb232_fstmp(%esp)

    addss  nb232_Vvdwtot(%esp),%xmm5
    movss %xmm5,nb232_Vvdwtot(%esp)

    ## repulsion 
    movlps 16(%esi,%eax,4),%xmm5
    movaps %xmm5,%xmm4
    shufps $136,%xmm7,%xmm4 ## constant 10001000
    shufps $221,%xmm7,%xmm5 ## constant 11011101

    movlps 24(%esi,%eax,4),%xmm7
    movaps %xmm7,%xmm6
    shufps $136,%xmm3,%xmm6 ## constant 10001000
    shufps $221,%xmm3,%xmm7 ## constant 11011101
    ## table ready, in xmm4-xmm7 
    mulss  %xmm1,%xmm6      ## xmm6=Geps 
    mulss  %xmm2,%xmm7      ## xmm7=Heps2 
    addss  %xmm6,%xmm5
    addss  %xmm7,%xmm5      ## xmm5=Fp 
    mulss  nb232_two(%esp),%xmm7         ## two*Heps2 
    addss  %xmm6,%xmm7
    addss  %xmm5,%xmm7 ## xmm7=FF 
    mulss  %xmm1,%xmm5 ## xmm5=eps*Fp 
    addss  %xmm4,%xmm5 ## xmm5=VV 

    movss nb232_c12(%esp),%xmm4
    mulss  %xmm4,%xmm7 ## fijR 
    mulss  %xmm4,%xmm5 ## Vvdw12 
        movaps nb232_fstmp(%esp),%xmm3
        mulss  nb232_tsc(%esp),%xmm7
        subss  %xmm7,%xmm3

    addss  nb232_Vvdwtot(%esp),%xmm5
    movss %xmm5,nb232_Vvdwtot(%esp)

        mulps  %xmm3,%xmm0
        movaps  %xmm0,%xmm1
        movaps  %xmm0,%xmm2

        mulps   nb232_dxOO(%esp),%xmm0
        mulps   nb232_dyOO(%esp),%xmm1
        mulps   nb232_dzOO(%esp),%xmm2

        movd %mm0,%eax

        ## initial update for j forces 
        xorps   %xmm3,%xmm3
        xorps   %xmm4,%xmm4
        xorps   %xmm5,%xmm5
        subps   %xmm0,%xmm3
        subps   %xmm1,%xmm4
        subps   %xmm2,%xmm5
        movaps  %xmm3,nb232_fjxO(%esp)
        movaps  %xmm4,nb232_fjyO(%esp)
        movaps  %xmm5,nb232_fjzO(%esp)
        addps   nb232_fixO(%esp),%xmm0
        addps   nb232_fiyO(%esp),%xmm1
        addps   nb232_fizO(%esp),%xmm2
        movaps  %xmm0,nb232_fixO(%esp)
        movaps  %xmm1,nb232_fiyO(%esp)
        movaps  %xmm2,nb232_fizO(%esp)


        ## done with i O Now do i H1 & H2 simultaneously first get i particle coords: 
        movaps  nb232_ixH1(%esp),%xmm0
        movaps  nb232_iyH1(%esp),%xmm1
        movaps  nb232_izH1(%esp),%xmm2
        movaps  nb232_ixH2(%esp),%xmm3
        movaps  nb232_iyH2(%esp),%xmm4
        movaps  nb232_izH2(%esp),%xmm5
        subps   nb232_jxO(%esp),%xmm0
        subps   nb232_jyO(%esp),%xmm1
        subps   nb232_jzO(%esp),%xmm2
        subps   nb232_jxO(%esp),%xmm3
        subps   nb232_jyO(%esp),%xmm4
        subps   nb232_jzO(%esp),%xmm5
        movaps %xmm0,nb232_dxH1O(%esp)
        movaps %xmm1,nb232_dyH1O(%esp)
        movaps %xmm2,nb232_dzH1O(%esp)
        movaps %xmm3,nb232_dxH2O(%esp)
        movaps %xmm4,nb232_dyH2O(%esp)
        movaps %xmm5,nb232_dzH2O(%esp)
        mulps %xmm0,%xmm0
        mulps %xmm1,%xmm1
        mulps %xmm2,%xmm2
        mulps %xmm3,%xmm3
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        addps %xmm1,%xmm0
        addps %xmm3,%xmm4
        addps %xmm2,%xmm0       ## have rsqH1 in xmm0 
        addps %xmm5,%xmm4       ## have rsqH2 in xmm4 

        ## do invsqrt 
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm4,%xmm5
        movaps  %xmm1,%xmm2
        movaps  %xmm5,%xmm6
        mulps   %xmm1,%xmm1
        mulps   %xmm5,%xmm5
        movaps  nb232_three(%esp),%xmm3
        movaps  %xmm3,%xmm7
        mulps   %xmm0,%xmm1
        mulps   %xmm4,%xmm5
        subps   %xmm1,%xmm3
        subps   %xmm5,%xmm7
        mulps   %xmm2,%xmm3
        mulps   %xmm6,%xmm7
        mulps   nb232_half(%esp),%xmm3   ## rinv H1 - j water 
        mulps   nb232_half(%esp),%xmm7   ## rinv H2 - j water  

        mulps nb232_krf(%esp),%xmm0   ## krsq 
        mulps nb232_krf(%esp),%xmm4   ## krsq  


        ## assemble charges in xmm6 
        xorps   %xmm6,%xmm6
        movss   nb232_qqOH(%esp),%xmm6
        movhps  nb232_qqHH(%esp),%xmm6
        movaps  %xmm0,%xmm1
        movaps  %xmm4,%xmm5
        addps   %xmm3,%xmm0     ## krsq+ rinv 
        addps   %xmm7,%xmm4     ## krsq+ rinv 
        subps nb232_crf(%esp),%xmm0
        subps nb232_crf(%esp),%xmm4
        mulps   nb232_two(%esp),%xmm1
        mulps   nb232_two(%esp),%xmm5
        mulps   %xmm6,%xmm0     ## vcoul 
        mulps   %xmm6,%xmm4     ## vcoul 
        addps   %xmm0,%xmm4
        addps   nb232_vctot(%esp),%xmm4
        movaps  %xmm4,nb232_vctot(%esp)
        movaps  %xmm3,%xmm0
        movaps  %xmm7,%xmm4
        mulps   %xmm3,%xmm3
        mulps   %xmm7,%xmm7
        subps   %xmm1,%xmm0
        subps   %xmm5,%xmm4
        mulps   %xmm6,%xmm0
        mulps   %xmm6,%xmm4
        mulps   %xmm3,%xmm0     ## fscal 
        mulps   %xmm4,%xmm7     ## fscal 

        movaps  %xmm0,%xmm1
        movaps  %xmm0,%xmm2
        mulps   nb232_dxH1O(%esp),%xmm0
        mulps   nb232_dyH1O(%esp),%xmm1
        mulps   nb232_dzH1O(%esp),%xmm2
        ## update forces H1 - j water 
        movaps  nb232_fjxO(%esp),%xmm3
        movaps  nb232_fjyO(%esp),%xmm4
        movaps  nb232_fjzO(%esp),%xmm5
        subps   %xmm0,%xmm3
        subps   %xmm1,%xmm4
        subps   %xmm2,%xmm5
        movaps  %xmm3,nb232_fjxO(%esp)
        movaps  %xmm4,nb232_fjyO(%esp)
        movaps  %xmm5,nb232_fjzO(%esp)
        addps   nb232_fixH1(%esp),%xmm0
        addps   nb232_fiyH1(%esp),%xmm1
        addps   nb232_fizH1(%esp),%xmm2
        movaps  %xmm0,nb232_fixH1(%esp)
        movaps  %xmm1,nb232_fiyH1(%esp)
        movaps  %xmm2,nb232_fizH1(%esp)
        ## do forces H2 - j water 
        movaps %xmm7,%xmm0
        movaps %xmm7,%xmm1
        movaps %xmm7,%xmm2
        mulps   nb232_dxH2O(%esp),%xmm0
        mulps   nb232_dyH2O(%esp),%xmm1
        mulps   nb232_dzH2O(%esp),%xmm2
        movaps  nb232_fjxO(%esp),%xmm3
        movaps  nb232_fjyO(%esp),%xmm4
        movaps  nb232_fjzO(%esp),%xmm5
        subps   %xmm0,%xmm3
        subps   %xmm1,%xmm4
        subps   %xmm2,%xmm5
        movl    nb232_faction(%ebp),%esi
        movaps  %xmm3,nb232_fjxO(%esp)
        movaps  %xmm4,nb232_fjyO(%esp)
        movaps  %xmm5,nb232_fjzO(%esp)
        addps   nb232_fixH2(%esp),%xmm0
        addps   nb232_fiyH2(%esp),%xmm1
        addps   nb232_fizH2(%esp),%xmm2
        movaps  %xmm0,nb232_fixH2(%esp)
        movaps  %xmm1,nb232_fiyH2(%esp)
        movaps  %xmm2,nb232_fizH2(%esp)

        ## update j water forces from local variables 
        movlps  (%esi,%eax,4),%xmm0
        movlps  12(%esi,%eax,4),%xmm1
        movhps  24(%esi,%eax,4),%xmm1
        movaps  nb232_fjxO(%esp),%xmm3
        movaps  nb232_fjyO(%esp),%xmm4
        movaps  nb232_fjzO(%esp),%xmm5
        movaps  %xmm5,%xmm6
        movaps  %xmm5,%xmm7
        shufps $2,%xmm6,%xmm6 ## constant 00000010
        shufps $3,%xmm7,%xmm7 ## constant 00000011
        addss   8(%esi,%eax,4),%xmm5
        addss   20(%esi,%eax,4),%xmm6
        addss   32(%esi,%eax,4),%xmm7
        movss   %xmm5,8(%esi,%eax,4)
        movss   %xmm6,20(%esi,%eax,4)
        movss   %xmm7,32(%esi,%eax,4)
        movaps   %xmm3,%xmm5