nb_kernel430_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,138 行 · 第 1/5 页

        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%edi,%ecx,4),%xmm3
        movss  4(%edi,%ecx,4),%xmm4
        movss  8(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,(%edi,%ecx,4)
        movss  %xmm4,4(%edi,%ecx,4)
        movss  %xmm5,8(%edi,%ecx,4)

        ## increment fshift force  
        movss  (%esi,%edx,4),%xmm3
        movss  4(%esi,%edx,4),%xmm4
        movss  8(%esi,%edx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,(%esi,%edx,4)
        movss  %xmm4,4(%esi,%edx,4)
        movss  %xmm5,8(%esi,%edx,4)

        ## get n from stack
        movl nb430_n(%esp),%esi
        ## get group index for i particle 
        movl  nb430_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb430_vctot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb430_Vc(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## accumulate total lj energy and update it 
        movaps nb430_Vvdwtot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb430_Vvdw(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## accumulate dVda and update it 
        movaps nb430_dvdasum(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        movl nb430_ii(%esp),%edx
        movl nb430_dvda(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        movss %xmm7,(%eax,%edx,4)

        ## finish if last 
        movl nb430_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel430_ia32_sse.nb430_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb430_n(%esp)
        jmp _nb_kernel430_ia32_sse.nb430_outer
_nb_kernel430_ia32_sse.nb430_outerend: 
        ## check if more outer neighborlists remain
        movl  nb430_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel430_ia32_sse.nb430_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel430_ia32_sse.nb430_threadloop
_nb_kernel430_ia32_sse.nb430_end: 
        emms

        movl nb430_nouter(%esp),%eax
        movl nb430_ninner(%esp),%ebx
        movl nb430_outeriter(%ebp),%ecx
        movl nb430_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        movl nb430_salign(%esp),%eax
        addl %eax,%esp
        addl $488,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret







.globl nb_kernel430nf_ia32_sse
.globl _nb_kernel430nf_ia32_sse
nb_kernel430nf_ia32_sse:        
_nb_kernel430nf_ia32_sse:       
.set nb430nf_p_nri, 8
.set nb430nf_iinr, 12
.set nb430nf_jindex, 16
.set nb430nf_jjnr, 20
.set nb430nf_shift, 24
.set nb430nf_shiftvec, 28
.set nb430nf_fshift, 32
.set nb430nf_gid, 36
.set nb430nf_pos, 40
.set nb430nf_faction, 44
.set nb430nf_charge, 48
.set nb430nf_p_facel, 52
.set nb430nf_argkrf, 56
.set nb430nf_argcrf, 60
.set nb430nf_Vc, 64
.set nb430nf_type, 68
.set nb430nf_p_ntype, 72
.set nb430nf_vdwparam, 76
.set nb430nf_Vvdw, 80
.set nb430nf_p_tabscale, 84
.set nb430nf_VFtab, 88
.set nb430nf_invsqrta, 92
.set nb430nf_dvda, 96
.set nb430nf_p_gbtabscale, 100
.set nb430nf_GBtab, 104
.set nb430nf_p_nthreads, 108
.set nb430nf_count, 112
.set nb430nf_mtx, 116
.set nb430nf_outeriter, 120
.set nb430nf_inneriter, 124
.set nb430nf_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb430nf_ix, 0
.set nb430nf_iy, 16
.set nb430nf_iz, 32
.set nb430nf_iq, 48
.set nb430nf_gbtsc, 64
.set nb430nf_tsc, 80
.set nb430nf_qq, 96
.set nb430nf_c6, 112
.set nb430nf_c12, 128
.set nb430nf_vctot, 144
.set nb430nf_Vvdwtot, 160
.set nb430nf_half, 176
.set nb430nf_three, 192
.set nb430nf_isai, 208
.set nb430nf_isaprod, 224
.set nb430nf_gbscale, 240
.set nb430nf_r, 256
.set nb430nf_is3, 272
.set nb430nf_ii3, 276
.set nb430nf_ntia, 280
.set nb430nf_innerjjnr, 284
.set nb430nf_innerk, 288
.set nb430nf_n, 292
.set nb430nf_nn1, 296
.set nb430nf_nri, 300
.set nb430nf_facel, 304
.set nb430nf_ntype, 308
.set nb430nf_nouter, 312
.set nb430nf_ninner, 316
.set nb430nf_salign, 320
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $324,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb430nf_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb430nf_p_nri(%ebp),%ecx
        movl nb430nf_p_facel(%ebp),%esi
        movl nb430nf_p_ntype(%ebp),%edi
        movl (%ecx),%ecx
        movl (%esi),%esi
        movl (%edi),%edi
        movl %ecx,nb430nf_nri(%esp)
        movl %esi,nb430nf_facel(%esp)
        movl %edi,nb430nf_ntype(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb430nf_nouter(%esp)
        movl %eax,nb430nf_ninner(%esp)


        movl nb430nf_p_gbtabscale(%ebp),%eax
        movss (%eax),%xmm3
        movl nb430nf_p_tabscale(%ebp),%eax
        movss (%eax),%xmm4
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb430nf_gbtsc(%esp)
        movaps %xmm4,nb430nf_tsc(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb430nf_half(%esp)
        movss nb430nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb430nf_half(%esp)
        movaps %xmm3,nb430nf_three(%esp)

_nb_kernel430nf_ia32_sse.nb430nf_threadloop: 
        movl  nb430nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel430nf_ia32_sse.nb430nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel430nf_ia32_sse.nb430nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb430nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb430nf_n(%esp)
        movl %ebx,nb430nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel430nf_ia32_sse.nb430nf_outerstart
        jmp _nb_kernel430nf_ia32_sse.nb430nf_end

_nb_kernel430nf_ia32_sse.nb430nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb430nf_nouter(%esp),%ebx
        movl %ebx,nb430nf_nouter(%esp)

_nb_kernel430nf_ia32_sse.nb430nf_outer: 
        movl  nb430nf_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb430nf_is3(%esp)            ## store is3 

        movl  nb430nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb430nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        movl  nb430nf_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        mulss nb430nf_facel(%esp),%xmm3
        shufps $0,%xmm3,%xmm3

        movl  nb430nf_invsqrta(%ebp),%edx       ## load invsqrta[ii]
        movss (%edx,%ebx,4),%xmm4
        shufps $0,%xmm4,%xmm4

        movl  nb430nf_type(%ebp),%edx
        movl  (%edx,%ebx,4),%edx
        imull nb430nf_ntype(%esp),%edx
        shll  %edx
        movl  %edx,nb430nf_ntia(%esp)

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb430nf_pos(%ebp),%eax      ## eax = base of pos[]  

        addss (%eax,%ebx,4),%xmm0
        addss 4(%eax,%ebx,4),%xmm1
        addss 8(%eax,%ebx,4),%xmm2

        movaps %xmm3,nb430nf_iq(%esp)
        movaps %xmm4,nb430nf_isai(%esp)

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2

        movaps %xmm0,nb430nf_ix(%esp)
        movaps %xmm1,nb430nf_iy(%esp)
        movaps %xmm2,nb430nf_iz(%esp)

        movl  %ebx,nb430nf_ii3(%esp)

        ## clear vctot 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb430nf_vctot(%esp)
        movaps %xmm4,nb430nf_Vvdwtot(%esp)

        movl  nb430nf_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb430nf_pos(%ebp),%esi
        movl  nb430nf_faction(%ebp),%edi
        movl  nb430nf_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb430nf_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb430nf_ninner(%esp),%ecx
        movl  %ecx,nb430nf_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb430nf_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel430nf_ia32_sse.nb430nf_unroll_loop
        jmp   _nb_kernel430nf_ia32_sse.nb430nf_finish_inner
_nb_kernel430nf_ia32_sse.nb430nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb430nf_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 
        addl $16,nb430nf_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        ## load isa2
        movl nb430nf_invsqrta(%ebp),%esi
        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7
        movaps nb430nf_isai(%esp),%xmm2
        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        mulps  %xmm3,%xmm2

        movaps %xmm2,nb430nf_isaprod(%esp)
        movaps %xmm2,%xmm1
        mulps nb430nf_gbtsc(%esp),%xmm1
        movaps %xmm1,nb430nf_gbscale(%esp)

        movl nb430nf_charge(%ebp),%esi     ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        mulps nb430nf_iq(%esp),%xmm2
        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        mulps  %xmm2,%xmm3
        movaps %xmm3,nb430nf_qq(%esp)

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movl nb430nf_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl (%esi,%ecx,4),%ecx
        movl (%esi,%edx,4),%edx
        movl nb430nf_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb430nf_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%esi,%eax,4),%xmm6
        movlps (%esi,%ecx,4),%xmm7
        movhps (%esi,%ebx,4),%xmm6
        movhps (%esi,%edx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## constant 10001000