nb_kernel304_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,976 行 · 第 1/5 页

##
## $Id: nb_kernel304_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:34 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##




.globl nb_kernel304_ia32_sse
.globl _nb_kernel304_ia32_sse
nb_kernel304_ia32_sse:  
_nb_kernel304_ia32_sse: 
.set nb304_p_nri, 8
.set nb304_iinr, 12
.set nb304_jindex, 16
.set nb304_jjnr, 20
.set nb304_shift, 24
.set nb304_shiftvec, 28
.set nb304_fshift, 32
.set nb304_gid, 36
.set nb304_pos, 40
.set nb304_faction, 44
.set nb304_charge, 48
.set nb304_p_facel, 52
.set nb304_argkrf, 56
.set nb304_argcrf, 60
.set nb304_Vc, 64
.set nb304_type, 68
.set nb304_p_ntype, 72
.set nb304_vdwparam, 76
.set nb304_Vvdw, 80
.set nb304_p_tabscale, 84
.set nb304_VFtab, 88
.set nb304_invsqrta, 92
.set nb304_dvda, 96
.set nb304_p_gbtabscale, 100
.set nb304_GBtab, 104
.set nb304_p_nthreads, 108
.set nb304_count, 112
.set nb304_mtx, 116
.set nb304_outeriter, 120
.set nb304_inneriter, 124
.set nb304_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb304_ixH1, 0
.set nb304_iyH1, 16
.set nb304_izH1, 32
.set nb304_ixH2, 48
.set nb304_iyH2, 64
.set nb304_izH2, 80
.set nb304_ixM, 96
.set nb304_iyM, 112
.set nb304_izM, 128
.set nb304_jxH1, 144
.set nb304_jyH1, 160
.set nb304_jzH1, 176
.set nb304_jxH2, 192
.set nb304_jyH2, 208
.set nb304_jzH2, 224
.set nb304_jxM, 240
.set nb304_jyM, 256
.set nb304_jzM, 272
.set nb304_dxH1H1, 288
.set nb304_dyH1H1, 304
.set nb304_dzH1H1, 320
.set nb304_dxH1H2, 336
.set nb304_dyH1H2, 352
.set nb304_dzH1H2, 368
.set nb304_dxH1M, 384
.set nb304_dyH1M, 400
.set nb304_dzH1M, 416
.set nb304_dxH2H1, 432
.set nb304_dyH2H1, 448
.set nb304_dzH2H1, 464
.set nb304_dxH2H2, 480
.set nb304_dyH2H2, 496
.set nb304_dzH2H2, 512
.set nb304_dxH2M, 528
.set nb304_dyH2M, 544
.set nb304_dzH2M, 560
.set nb304_dxMH1, 576
.set nb304_dyMH1, 592
.set nb304_dzMH1, 608
.set nb304_dxMH2, 624
.set nb304_dyMH2, 640
.set nb304_dzMH2, 656
.set nb304_dxMM, 672
.set nb304_dyMM, 688
.set nb304_dzMM, 704
.set nb304_qqHH, 720
.set nb304_qqMH, 736
.set nb304_qqMM, 752
.set nb304_two, 768
.set nb304_tsc, 784
.set nb304_vctot, 800
.set nb304_fixH1, 816
.set nb304_fiyH1, 832
.set nb304_fizH1, 848
.set nb304_fixH2, 864
.set nb304_fiyH2, 880
.set nb304_fizH2, 896
.set nb304_fixM, 912
.set nb304_fiyM, 928
.set nb304_fizM, 944
.set nb304_fjxH1, 960
.set nb304_fjyH1, 976
.set nb304_fjzH1, 992
.set nb304_fjxH2, 1008
.set nb304_fjyH2, 1024
.set nb304_fjzH2, 1040
.set nb304_fjxM, 1056
.set nb304_fjyM, 1072
.set nb304_fjzM, 1088
.set nb304_fjzMb, 1092
.set nb304_fjzMc, 1096
.set nb304_fjzMd, 1100
.set nb304_half, 1104
.set nb304_three, 1120
.set nb304_rsqH1H1, 1136
.set nb304_rsqH1H2, 1152
.set nb304_rsqH1M, 1168
.set nb304_rsqH2H1, 1184
.set nb304_rsqH2H2, 1200
.set nb304_rsqH2M, 1216
.set nb304_rsqMH1, 1232
.set nb304_rsqMH2, 1248
.set nb304_rsqMM, 1264
.set nb304_rinvH1H1, 1280
.set nb304_rinvH1H2, 1296
.set nb304_rinvH1M, 1312
.set nb304_rinvH2H1, 1328
.set nb304_rinvH2H2, 1344
.set nb304_rinvH2M, 1360
.set nb304_rinvMH1, 1376
.set nb304_rinvMH2, 1392
.set nb304_rinvMM, 1408
.set nb304_is3, 1424
.set nb304_ii3, 1428
.set nb304_innerjjnr, 1432
.set nb304_innerk, 1436
.set nb304_n, 1440
.set nb304_nn1, 1444
.set nb304_nri, 1448
.set nb304_nouter, 1452
.set nb304_ninner, 1456
.set nb304_salign, 1460
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $1464,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb304_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb304_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb304_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb304_nouter(%esp)
        movl %eax,nb304_ninner(%esp)


        movl nb304_p_tabscale(%ebp),%eax
        movss (%eax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb304_tsc(%esp)
        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb304_half(%esp)
        movss nb304_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb304_half(%esp)
        movaps %xmm2,nb304_two(%esp)
        movaps %xmm3,nb304_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb304_iinr(%ebp),%ecx             ## ecx = pointer into iinr[]    
        movl  (%ecx),%ebx               ## ebx =ii 

        movl  nb304_charge(%ebp),%edx
        movss 4(%edx,%ebx,4),%xmm3
        movss %xmm3,%xmm4
        movss 12(%edx,%ebx,4),%xmm5
        movl nb304_p_facel(%ebp),%esi
        movss (%esi),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb304_qqHH(%esp)
        movaps %xmm4,nb304_qqMH(%esp)
        movaps %xmm5,nb304_qqMM(%esp)

_nb_kernel304_ia32_sse.nb304_threadloop: 
        movl  nb304_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel304_ia32_sse.nb304_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel304_ia32_sse.nb304_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb304_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb304_n(%esp)
        movl %ebx,nb304_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel304_ia32_sse.nb304_outerstart
        jmp _nb_kernel304_ia32_sse.nb304_end

_nb_kernel304_ia32_sse.nb304_outerstart: 
        ## ebx contains number of outer iterations
        addl nb304_nouter(%esp),%ebx
        movl %ebx,nb304_nouter(%esp)

_nb_kernel304_ia32_sse.nb304_outer: 
        movl  nb304_shift(%ebp),%eax            ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx        ## ebx=3*is 
        movl  %ebx,nb304_is3(%esp)      ## store is3 

        movl  nb304_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb304_iinr(%ebp),%ecx             ## ecx = pointer into iinr[]    
        movl  (%ecx,%esi,4),%ebx                ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb304_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb304_ii3(%esp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        addss 12(%eax,%ebx,4),%xmm3
        addss 16(%eax,%ebx,4),%xmm4
        addss 20(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb304_ixH1(%esp)
        movaps %xmm4,nb304_iyH1(%esp)
        movaps %xmm5,nb304_izH1(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 24(%eax,%ebx,4),%xmm0
        addss 28(%eax,%ebx,4),%xmm1
        addss 32(%eax,%ebx,4),%xmm2
        addss 36(%eax,%ebx,4),%xmm3
        addss 40(%eax,%ebx,4),%xmm4
        addss 44(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb304_ixH2(%esp)
        movaps %xmm1,nb304_iyH2(%esp)
        movaps %xmm2,nb304_izH2(%esp)
        movaps %xmm3,nb304_ixM(%esp)
        movaps %xmm4,nb304_iyM(%esp)
        movaps %xmm5,nb304_izM(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb304_vctot(%esp)
        movaps %xmm4,nb304_fixH1(%esp)
        movaps %xmm4,nb304_fiyH1(%esp)
        movaps %xmm4,nb304_fizH1(%esp)
        movaps %xmm4,nb304_fixH2(%esp)
        movaps %xmm4,nb304_fiyH2(%esp)
        movaps %xmm4,nb304_fizH2(%esp)
        movaps %xmm4,nb304_fixM(%esp)
        movaps %xmm4,nb304_fiyM(%esp)
        movaps %xmm4,nb304_fizM(%esp)

        movl  nb304_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx                ## jindex[n] 
        movl  4(%eax,%esi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movl  nb304_pos(%ebp),%esi
        movl  nb304_faction(%ebp),%edi
        movl  nb304_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb304_innerjjnr(%esp)        ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb304_ninner(%esp),%ecx
        movl  %ecx,nb304_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb304_innerk(%esp)   ## number of innerloop atoms 
        jge   _nb_kernel304_ia32_sse.nb304_unroll_loop
        jmp   _nb_kernel304_ia32_sse.nb304_single_check
_nb_kernel304_ia32_sse.nb304_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb304_innerjjnr(%esp),%edx        ## pointer to jjnr[k] 

        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx             ## eax-edx=jnr1-4 

        addl $16,nb304_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb304_pos(%ebp),%esi       ## base of pos[] 

        leal  (%eax,%eax,2),%eax        ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx        ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move j coordinates to local temp variables 
        movlps 12(%esi,%eax,4),%xmm2
        movlps 24(%esi,%eax,4),%xmm3
        movlps 36(%esi,%eax,4),%xmm4

        movlps 12(%esi,%ebx,4),%xmm5
        movlps 24(%esi,%ebx,4),%xmm6
        movlps 36(%esi,%ebx,4),%xmm7

        movhps 12(%esi,%ecx,4),%xmm2
        movhps 24(%esi,%ecx,4),%xmm3
        movhps 36(%esi,%ecx,4),%xmm4

        movhps 12(%esi,%edx,4),%xmm5
        movhps 24(%esi,%edx,4),%xmm6
        movhps 36(%esi,%edx,4),%xmm7

        movaps %xmm2,%xmm0
        movaps %xmm3,%xmm1
        unpcklps %xmm5,%xmm0
        unpcklps %xmm6,%xmm1
        unpckhps %xmm5,%xmm2
        unpckhps %xmm6,%xmm3
        movaps %xmm4,%xmm5
        movaps   %xmm0,%xmm6
        unpcklps %xmm7,%xmm4
        unpckhps %xmm7,%xmm5
        movaps   %xmm1,%xmm7
        movlhps  %xmm2,%xmm0
        movaps %xmm0,nb304_jxH1(%esp)