nb_kernel300_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,119 行 · 第 1/3 页

	;# update vctot 
	addpd  xmm12, xmm5

	xorpd  xmm4, xmm4

	mulpd xmm3, [rsp + nb300_tsc]
	mulpd xmm3, xmm0
	subpd  xmm4, xmm3


	mulpd  xmm9, xmm4
	mulpd  xmm10, xmm4
	mulpd  xmm11, xmm4

	mov    rdi, [rbp + nb300_faction]
	;# the fj's - start by accumulating forces from memory 
	movlpd xmm3, [rdi + rax*8]
	movlpd xmm4, [rdi + rax*8 + 8]
	movlpd xmm5, [rdi + rax*8 + 16]
	movhpd xmm3, [rdi + rbx*8]
	movhpd xmm4, [rdi + rbx*8 + 8]
	movhpd xmm5, [rdi + rbx*8 + 16]

	;# now update f_i 
	addpd  xmm13, xmm9
	addpd  xmm14, xmm10
	addpd  xmm15, xmm11

	addpd xmm3, xmm9
	addpd xmm4, xmm10
	addpd xmm5, xmm11
	movlpd [rdi + rax*8], xmm3
	movlpd [rdi + rax*8 + 8], xmm4
	movlpd [rdi + rax*8 + 16], xmm5
	movhpd [rdi + rbx*8], xmm3
	movhpd [rdi + rbx*8 + 8], xmm4
	movhpd [rdi + rbx*8 + 16], xmm5
	
	;# should we do one more iteration? 
	sub dword ptr [rsp + nb300_innerk],  2
	jl    .nb300_checksingle
	jmp   .nb300_unroll_loop
.nb300_checksingle:
	mov   edx, [rsp + nb300_innerk]
	and   edx, 1
	jnz    .nb300_dosingle
	jmp    .nb300_updateouterdata
.nb300_dosingle:
	mov rsi, [rbp + nb300_charge]
	mov rdi, [rbp + nb300_pos]
	mov   rcx, [rsp + nb300_innerjjnr]
	mov   eax, [rcx]	

	mov rsi, [rbp + nb300_charge]    ;# base of charge[] 

	movsd xmm3, [rsi + rax*8]

	movapd xmm2, [rsp + nb300_iq]
	mulsd  xmm3, xmm2
	movapd [rsp + nb300_qq], xmm3	
	
	mov rsi, [rbp + nb300_pos]		;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 

	;# move two coordinates to xmm4-xmm6
	movsd xmm4, [rsi + rax*8]
	movsd xmm5, [rsi + rax*8 + 8]
	movsd xmm6, [rsi + rax*8 + 16]

	mov    rdi, [rbp + nb300_faction]
	
	;# calc dr 
	subsd xmm4, [rsp + nb300_ix]
	subsd xmm5, [rsp + nb300_iy]
	subsd xmm6, [rsp + nb300_iz]

	;# store dr 
	movapd xmm9, xmm4
	movapd xmm10, xmm5
	movapd xmm11, xmm6

	;# square it 
	mulsd xmm4,xmm4
	mulsd xmm5,xmm5
	mulsd xmm6,xmm6
	addsd xmm4, xmm5
	addsd xmm4, xmm6
	;# rsq in xmm4 

	cvtsd2ss xmm5, xmm4	
	rsqrtss xmm5, xmm5
	cvtss2sd xmm2, xmm5	;# lu in low xmm2 

	;# lookup seed in xmm2 
	movapd xmm5, xmm2	;# copy of lu 
	mulsd xmm2, xmm2	;# lu*lu 
	movapd xmm1, [rsp + nb300_three]
	mulsd xmm2, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [rsp + nb300_half]
	subsd xmm1, xmm2	;# 30-rsq*lu*lu 
	mulsd xmm1, xmm5	
	mulsd xmm1, xmm0	;# xmm0=iter1 of rinv (new lu) 

	movapd xmm5, xmm1	;# copy of lu 
	mulsd xmm1, xmm1	;# lu*lu 
	movapd xmm2, [rsp + nb300_three]
	mulsd xmm1, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [rsp + nb300_half]
	subsd xmm2, xmm1	;# 30-rsq*lu*lu 
	mulsd xmm2, xmm5	
	mulsd xmm0, xmm2	;# xmm0=iter2 of rinv (new lu) 
	mulsd xmm4, xmm0	;# xmm4=r 
	mulsd xmm4, [rsp + nb300_tsc]

	cvttsd2si r8d, xmm4	;# mm6 = lu idx 
	cvtsi2sd xmm5, r8d
	subsd xmm4, xmm5
	movapd xmm1, xmm4	;# xmm1=eps 
	movapd xmm2, xmm1	
	mulsd  xmm2, xmm2	;# xmm2=eps2 
	
	shl r8d, 2		;# idx *= 4 
	
	mov  rsi, [rbp + nb300_VFtab]

    movsd  xmm4, [rsi + r8*8]
    movsd  xmm5, [rsi + r8*8 + 8]
    movsd  xmm6, [rsi + r8*8 + 16]
    movsd  xmm7, [rsi + r8*8 + 24]
	;# coulomb table ready, in xmm4-xmm7  		

	mulsd  xmm6, xmm1	;# xmm6=Geps 
	mulsd  xmm7, xmm2	;# xmm7=Heps2 
	addsd  xmm5, xmm6
	addsd  xmm5, xmm7	;# xmm5=Fp 	
	addsd  xmm7, xmm7	;# two*Heps2 
	movapd xmm3, [rsp + nb300_qq]
	addsd  xmm7, xmm6
	addsd  xmm7, xmm5 ;# xmm7=FF 
	mulsd  xmm5, xmm1 ;# xmm5=eps*Fp 
	addsd  xmm5, xmm4 ;# xmm5=VV 
	mulsd  xmm5, xmm3 ;# vcoul=qq*VV  
	mulsd  xmm3, xmm7 ;# fijC=FF*qq 
	;# at this point mm5 contains vcoul and mm3 fijC 
	;# increment vcoul - then we can get rid of mm5 
	;# update vctot 
	addsd  xmm12, xmm5

	xorpd  xmm4, xmm4

	mulsd xmm3, [rsp + nb300_tsc]
	mulsd xmm3, xmm0
	subsd  xmm4, xmm3

	mov    rdi, [rbp + nb300_faction]
	mulsd  xmm9, xmm4
	mulsd  xmm10, xmm4
	mulsd  xmm11, xmm4

	;# now update f_i 
	addsd  xmm13, xmm9
	addsd  xmm14, xmm10
	addsd  xmm15, xmm11

	;# the fj's - start by accumulating forces from memory 
	addsd xmm9,  [rdi + rax*8]
	addsd xmm10, [rdi + rax*8 + 8]
	addsd xmm11, [rdi + rax*8 + 16]
	movsd [rdi + rax*8], xmm9
	movsd [rdi + rax*8 + 8], xmm10
	movsd [rdi + rax*8 + 16], xmm11
	
.nb300_updateouterdata:
	mov   ecx, [rsp + nb300_ii3]
	mov   rdi, [rbp + nb300_faction]
	mov   rsi, [rbp + nb300_fshift]
	mov   edx, [rsp + nb300_is3]

	;# accumulate i forces in xmm13, xmm14, xmm15
	movhlps xmm3, xmm13
	movhlps xmm4, xmm14
	movhlps xmm5, xmm15
	addsd  xmm13, xmm3
	addsd  xmm14, xmm4
	addsd  xmm15, xmm5 ;# sum is in low xmm13-xmm15

	;# increment i force 
	movsd  xmm3, [rdi + rcx*8]
	movsd  xmm4, [rdi + rcx*8 + 8]
	movsd  xmm5, [rdi + rcx*8 + 16]
	subsd  xmm3, xmm13
	subsd  xmm4, xmm14
	subsd  xmm5, xmm15
	movsd  [rdi + rcx*8],     xmm3
	movsd  [rdi + rcx*8 + 8], xmm4
	movsd  [rdi + rcx*8 + 16], xmm5

	;# increment fshift force  
	movsd  xmm3, [rsi + rdx*8]
	movsd  xmm4, [rsi + rdx*8 + 8]
	movsd  xmm5, [rsi + rdx*8 + 16]
	subsd  xmm3, xmm13
	subsd  xmm4, xmm14
	subsd  xmm5, xmm15
	movsd  [rsi + rdx*8],     xmm3
	movsd  [rsi + rdx*8 + 8], xmm4
	movsd  [rsi + rdx*8 + 16], xmm5

	;# get n from stack
	mov esi, [rsp + nb300_n]
        ;# get group index for i particle 
        mov   rdx, [rbp + nb300_gid]      	;# base of gid[]
        mov   edx, [rdx + rsi*4]		;# ggid=gid[n]

	;# accumulate total coulomb energy and update it 
	movhlps xmm6, xmm12
	addsd  xmm12, xmm6	;# low xmm12 have the sum now 

	;# add earlier value from mem 
	mov   rax, [rbp + nb300_Vc]
	addsd xmm12, [rax + rdx*8] 
	;# move back to mem 
	movsd [rax + rdx*8], xmm12
	
        ;# finish if last 
        mov ecx, [rsp + nb300_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb300_outerend

        ;# not last, iterate outer loop once more!  
        mov [rsp + nb300_n], esi
        jmp .nb300_outer
.nb300_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [rsp + nb300_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb300_end
        ;# non-zero, do one more workunit
        jmp   .nb300_threadloop
.nb300_end:
	mov eax, [rsp + nb300_nouter]
	mov ebx, [rsp + nb300_ninner]
	mov rcx, [rbp + nb300_outeriter]
	mov rdx, [rbp + nb300_inneriter]
	mov [rcx], eax
	mov [rdx], ebx

	add rsp, 376
	emms


        pop r15
        pop r14
        pop r13
        pop r12

	pop rbx
	pop	rbp
	ret




	

.globl nb_kernel300nf_x86_64_sse2
.globl _nb_kernel300nf_x86_64_sse2
nb_kernel300nf_x86_64_sse2:	
_nb_kernel300nf_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb300nf_fshift,         16
.equiv          nb300nf_gid,            24
.equiv          nb300nf_pos,            32
.equiv          nb300nf_faction,        40
.equiv          nb300nf_charge,         48
.equiv          nb300nf_p_facel,        56
.equiv          nb300nf_argkrf,         64
.equiv          nb300nf_argcrf,         72
.equiv          nb300nf_Vc,             80
.equiv          nb300nf_type,           88
.equiv          nb300nf_p_ntype,        96
.equiv          nb300nf_vdwparam,       104
.equiv          nb300nf_Vvdw,           112
.equiv          nb300nf_p_tabscale,     120
.equiv          nb300nf_VFtab,          128
.equiv          nb300nf_invsqrta,       136
.equiv          nb300nf_dvda,           144
.equiv          nb300nf_p_gbtabscale,   152
.equiv          nb300nf_GBtab,          160
.equiv          nb300nf_p_nthreads,     168
.equiv          nb300nf_count,          176
.equiv          nb300nf_mtx,            184
.equiv          nb300nf_outeriter,      192
.equiv          nb300nf_inneriter,      200
.equiv          nb300nf_work,           208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb300nf_ix,             0
.equiv          nb300nf_iy,             16
.equiv          nb300nf_iz,             32
.equiv          nb300nf_iq,             48
.equiv          nb300nf_tsc,            64
.equiv          nb300nf_qq,             80
.equiv          nb300nf_vctot,          96
.equiv          nb300nf_half,           112
.equiv          nb300nf_three,          128
.equiv          nb300nf_is3,            144
.equiv          nb300nf_ii3,            148
.equiv          nb300nf_nri,            152
.equiv          nb300nf_iinr,           160
.equiv          nb300nf_jindex,         168
.equiv          nb300nf_jjnr,           176
.equiv          nb300nf_shift,          184
.equiv          nb300nf_shiftvec,       192
.equiv          nb300nf_facel,          200
.equiv          nb300nf_innerjjnr,      208
.equiv          nb300nf_innerk,         216
.equiv          nb300nf_n,              220
.equiv          nb300nf_nn1,            224
.equiv          nb300nf_nouter,         228
.equiv          nb300nf_ninner,         232
	push rbp
	mov  rbp, rsp
	push rbx
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 248		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb300nf_nouter], eax
	mov [rsp + nb300nf_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb300nf_nri], edi
	mov [rsp + nb300nf_iinr], rsi
	mov [rsp + nb300nf_jindex], rdx
	mov [rsp + nb300nf_jjnr], rcx
	mov [rsp + nb300nf_shift], r8
	mov [rsp + nb300nf_shiftvec], r9
	mov rsi, [rbp + nb300nf_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb300nf_facel], xmm0

	mov rax, [rbp + nb300nf_p_tabscale]
	movsd xmm3, [rax]
	shufpd xmm3, xmm3, 0
	movapd [rsp + nb300nf_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000
	mov [rsp + nb300nf_half], eax
	mov [rsp + nb300nf_half+4], ebx
	movsd xmm1, [rsp + nb300nf_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd [rsp + nb300nf_half], xmm1
	movapd [rsp + nb300nf_three], xmm3