nb_kernel111_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,816 行 · 第 1/4 页

;#
;# $Id: nb_kernel111_x86_64_sse2.intel_syntax.s,v 1.1.2.2 2006/09/22 08:40:32 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as



.globl nb_kernel111_x86_64_sse2
.globl _nb_kernel111_x86_64_sse2
nb_kernel111_x86_64_sse2:	
_nb_kernel111_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb111_fshift,           16
.equiv          nb111_gid,              24
.equiv          nb111_pos,              32
.equiv          nb111_faction,          40
.equiv          nb111_charge,           48
.equiv          nb111_p_facel,          56
.equiv          nb111_argkrf,           64
.equiv          nb111_argcrf,           72
.equiv          nb111_Vc,               80
.equiv          nb111_type,             88
.equiv          nb111_p_ntype,          96
.equiv          nb111_vdwparam,         104
.equiv          nb111_Vvdw,             112
.equiv          nb111_p_tabscale,       120
.equiv          nb111_VFtab,            128
.equiv          nb111_invsqrta,         136
.equiv          nb111_dvda,             144
.equiv          nb111_p_gbtabscale,     152
.equiv          nb111_GBtab,            160
.equiv          nb111_p_nthreads,       168
.equiv          nb111_count,            176
.equiv          nb111_mtx,              184
.equiv          nb111_outeriter,        192
.equiv          nb111_inneriter,        200
.equiv          nb111_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb111_ixO,              0
.equiv          nb111_iyO,              16
.equiv          nb111_izO,              32
.equiv          nb111_ixH1,             48
.equiv          nb111_iyH1,             64
.equiv          nb111_izH1,             80
.equiv          nb111_ixH2,             96
.equiv          nb111_iyH2,             112
.equiv          nb111_izH2,             128
.equiv          nb111_iqO,              144
.equiv          nb111_iqH,              160
.equiv          nb111_dxO,              176
.equiv          nb111_dyO,              192
.equiv          nb111_dzO,              208
.equiv          nb111_dxH1,             224
.equiv          nb111_dyH1,             240
.equiv          nb111_dzH1,             256
.equiv          nb111_dxH2,             272
.equiv          nb111_dyH2,             288
.equiv          nb111_dzH2,             304
.equiv          nb111_qqO,              320
.equiv          nb111_qqH,              336
.equiv          nb111_c6,               352
.equiv          nb111_c12,              368
.equiv          nb111_six,              384
.equiv          nb111_twelve,           400
.equiv          nb111_vctot,            416
.equiv          nb111_Vvdwtot,          432
.equiv          nb111_fixO,             448
.equiv          nb111_fiyO,             464
.equiv          nb111_fizO,             480
.equiv          nb111_fixH1,            496
.equiv          nb111_fiyH1,            512
.equiv          nb111_fizH1,            528
.equiv          nb111_fixH2,            544
.equiv          nb111_fiyH2,            560
.equiv          nb111_fizH2,            576
.equiv          nb111_fjx,              592
.equiv          nb111_fjy,              608
.equiv          nb111_fjz,              624
.equiv          nb111_half,             640
.equiv          nb111_three,            656
.equiv          nb111_is3,              672
.equiv          nb111_ii3,              676
.equiv          nb111_nri,              692
.equiv          nb111_iinr,             700
.equiv          nb111_jindex,           708
.equiv          nb111_jjnr,             716
.equiv          nb111_shift,            724
.equiv          nb111_shiftvec,         732
.equiv          nb111_facel,            740
.equiv          nb111_innerjjnr,        748
.equiv          nb111_ntia,             756
.equiv          nb111_innerk,           760
.equiv          nb111_n,                764
.equiv          nb111_nn1,              768
.equiv          nb111_nouter,           772
.equiv          nb111_ninner,           776
	push rbp
	mov  rbp, rsp
	push rbx
	
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 792		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb111_nouter], eax
	mov [rsp + nb111_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb111_nri], edi
	mov [rsp + nb111_iinr], rsi
	mov [rsp + nb111_jindex], rdx
	mov [rsp + nb111_jjnr], rcx
	mov [rsp + nb111_shift], r8
	mov [rsp + nb111_shiftvec], r9
	mov rsi, [rbp + nb111_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb111_facel], xmm0

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000
	mov [rsp + nb111_half], eax
	mov [rsp + nb111_half+4], ebx
	movsd xmm1, [rsp + nb111_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd xmm4, xmm3
	addpd  xmm4, xmm4       ;# six
	movapd xmm5, xmm4
	addpd  xmm5, xmm5       ;# twelve
	movapd [rsp + nb111_half], xmm1
	movapd [rsp + nb111_three], xmm3
	movapd [rsp + nb111_six], xmm4
	movapd [rsp + nb111_twelve], xmm5

	;# assume we have at least one i particle - start directly 
	mov   rcx, [rsp + nb111_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx]	    ;# ebx =ii 

	mov   rdx, [rbp + nb111_charge]
	movsd xmm3, [rdx + rbx*8]	
	movsd xmm4, [rdx + rbx*8 + 8]	
	mov rsi, [rbp + nb111_p_facel]
	movsd xmm0, [rsi]
	movsd xmm5, [rsp + nb111_facel]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [rsp + nb111_iqO], xmm3
	movapd [rsp + nb111_iqH], xmm4
	
	mov   rdx, [rbp + nb111_type]
	mov   ecx, [rdx + rbx*4]
	shl   ecx, 1
	mov rdi, [rbp + nb111_p_ntype]
	imul  ecx, [rdi]      ;# rcx = ntia = 2*ntype*type[ii0] 
	mov   [rsp + nb111_ntia], ecx		
.nb111_threadloop:
        mov   rsi, [rbp + nb111_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb111_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb111_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb111_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb111_n], eax
        mov [rsp + nb111_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb111_outerstart
        jmp .nb111_end

.nb111_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb111_nouter]
	mov [rsp + nb111_nouter], ebx

.nb111_outer:
	mov   rax, [rsp + nb111_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax+rsi*4]		;# rbx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb111_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb111_shiftvec]   ;# rax = base of shiftvec[] 

	movsd xmm0, [rax + rbx*8]
	movsd xmm1, [rax + rbx*8 + 8]
	movsd xmm2, [rax + rbx*8 + 16] 

	mov   rcx, [rsp + nb111_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb111_pos]    ;# rax = base of pos[]  
	mov   [rsp + nb111_ii3], ebx

	addsd xmm3, [rax + rbx*8]
	addsd xmm4, [rax + rbx*8 + 8]
	addsd xmm5, [rax + rbx*8 + 16]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb111_ixO], xmm3
	movapd [rsp + nb111_iyO], xmm4
	movapd [rsp + nb111_izO], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [rax + rbx*8 + 24]
	addsd xmm1, [rax + rbx*8 + 32]
	addsd xmm2, [rax + rbx*8 + 40]		
	addsd xmm3, [rax + rbx*8 + 48]
	addsd xmm4, [rax + rbx*8 + 56]
	addsd xmm5, [rax + rbx*8 + 64]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [rsp + nb111_ixH1], xmm0
	movapd [rsp + nb111_iyH1], xmm1
	movapd [rsp + nb111_izH1], xmm2
	movapd [rsp + nb111_ixH2], xmm3
	movapd [rsp + nb111_iyH2], xmm4
	movapd [rsp + nb111_izH2], xmm5
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [rsp + nb111_vctot], xmm4
	movapd [rsp + nb111_Vvdwtot], xmm4
	movapd [rsp + nb111_fixO], xmm4
	movapd [rsp + nb111_fiyO], xmm4
	movapd [rsp + nb111_fizO], xmm4
	movapd [rsp + nb111_fixH1], xmm4
	movapd [rsp + nb111_fiyH1], xmm4
	movapd [rsp + nb111_fizH1], xmm4
	movapd [rsp + nb111_fixH2], xmm4
	movapd [rsp + nb111_fiyH2], xmm4
	movapd [rsp + nb111_fizH2], xmm4
	
	mov   rax, [rsp + nb111_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb111_pos]
	mov   rdi, [rbp + nb111_faction]	
	mov   rax, [rsp + nb111_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb111_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [rsp + nb111_ninner]
	mov   [rsp + nb111_ninner], ecx
	add   edx, 0
	mov   [rsp + nb111_innerk], edx    ;# number of innerloop atoms 
	jge   .nb111_unroll_loop
	jmp   .nb111_checksingle
.nb111_unroll_loop:
	;# twice unrolled innerloop here 
	mov   rdx, [rsp + nb111_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]

	add qword ptr [rsp + nb111_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov rsi, [rbp + nb111_charge]    ;# base of charge[] 
	
	movlpd xmm3, [rsi + rax*8]
	movhpd xmm3, [rsi + rbx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [rsp + nb111_iqO]
	mulpd  xmm4, [rsp + nb111_iqH]

	movapd  [rsp + nb111_qqO], xmm3
	movapd  [rsp + nb111_qqH], xmm4
	
	mov rsi, [rbp + nb111_type]
	mov r8d, [rsi + rax*4]
	mov r9d, [rsi + rbx*4]
	mov rsi, [rbp + nb111_vdwparam]
	shl r8d, 1	
	shl r9d, 1	
	mov edi, [rsp + nb111_ntia]
	add r8d, edi
	add r9d, edi

	movlpd xmm6, [rsi + r8*8]	;# c6a
	movlpd xmm7, [rsi + r9*8]	;# c6b
	movhpd xmm6, [rsi + r8*8 + 8]	;# c6a c12a 
	movhpd xmm7, [rsi + r9*8 + 8]	;# c6b c12b 
	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7
	
	movapd [rsp + nb111_c6], xmm4
	movapd [rsp + nb111_c12], xmm6
	
	mov rsi, [rbp + nb111_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	

	;# move j coordinates to local temp variables 
    movlpd xmm0, [rsi + rax*8] 
    movlpd xmm1, [rsi + rax*8 + 8] 
    movlpd xmm2, [rsi + rax*8 + 16] 
    movhpd xmm0, [rsi + rbx*8] 
    movhpd xmm1, [rsi + rbx*8 + 8] 
    movhpd xmm2, [rsi + rbx*8 + 16] 

    ;# xmm0 = jx
    ;# xmm1 = jy
    ;# xmm2 = jz
        
    movapd xmm3, xmm0
    movapd xmm4, xmm1
    movapd xmm5, xmm2
    movapd xmm6, xmm0
    movapd xmm7, xmm1
    movapd xmm8, xmm2
    
    subpd xmm0, [rsp + nb111_ixO]
    subpd xmm1, [rsp + nb111_iyO]
    subpd xmm2, [rsp + nb111_izO]
    subpd xmm3, [rsp + nb111_ixH1]
    subpd xmm4, [rsp + nb111_iyH1]
    subpd xmm5, [rsp + nb111_izH1]
    subpd xmm6, [rsp + nb111_ixH2]
    subpd xmm7, [rsp + nb111_iyH2]
    subpd xmm8, [rsp + nb111_izH2]
    
	movapd [rsp + nb111_dxO], xmm0
	movapd [rsp + nb111_dyO], xmm1
	movapd [rsp + nb111_dzO], xmm2
	mulpd  xmm0, xmm0
	mulpd  xmm1, xmm1
	mulpd  xmm2, xmm2
	movapd [rsp + nb111_dxH1], xmm3
	movapd [rsp + nb111_dyH1], xmm4
	movapd [rsp + nb111_dzH1], xmm5
	mulpd  xmm3, xmm3
	mulpd  xmm4, xmm4
	mulpd  xmm5, xmm5
	movapd [rsp + nb111_dxH2], xmm6
	movapd [rsp + nb111_dyH2], xmm7
	movapd [rsp + nb111_dzH2], xmm8
	mulpd  xmm6, xmm6
	mulpd  xmm7, xmm7
	mulpd  xmm8, xmm8
	addpd  xmm0, xmm1
	addpd  xmm0, xmm2
	addpd  xmm3, xmm4
	addpd  xmm3, xmm5
    addpd  xmm6, xmm7
    addpd  xmm6, xmm8

	;# start doing invsqrt for j atoms
    cvtpd2ps xmm1, xmm0
    cvtpd2ps xmm4, xmm3
    cvtpd2ps xmm7, xmm6
	rsqrtps xmm1, xmm1
	rsqrtps xmm4, xmm4
    rsqrtps xmm7, xmm7
    cvtps2pd xmm1, xmm1
    cvtps2pd xmm4, xmm4
    cvtps2pd xmm7, xmm7
	
	movapd  xmm2, xmm1
	movapd  xmm5, xmm4
    movapd  xmm8, xmm7
    
	mulpd   xmm1, xmm1 ;# lu*lu
	mulpd   xmm4, xmm4 ;# lu*lu
    mulpd   xmm7, xmm7 ;# lu*lu
		
	movapd  xmm9, [rsp + nb111_three]
	movapd  xmm10, xmm9
    movapd  xmm11, xmm9