nb_kernel233_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,127 行 · 第 1/5 页

##
## $Id: nb_kernel233_x86_64_sse2.s,v 1.4.2.3 2006/09/22 08:40:34 lindahl Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##





.globl nb_kernel233_x86_64_sse2
.globl _nb_kernel233_x86_64_sse2
nb_kernel233_x86_64_sse2:       
_nb_kernel233_x86_64_sse2:      
##      Room for return address and rbp (16 bytes)
.set nb233_fshift, 16
.set nb233_gid, 24
.set nb233_pos, 32
.set nb233_faction, 40
.set nb233_charge, 48
.set nb233_p_facel, 56
.set nb233_argkrf, 64
.set nb233_argcrf, 72
.set nb233_Vc, 80
.set nb233_type, 88
.set nb233_p_ntype, 96
.set nb233_vdwparam, 104
.set nb233_Vvdw, 112
.set nb233_p_tabscale, 120
.set nb233_VFtab, 128
.set nb233_invsqrta, 136
.set nb233_dvda, 144
.set nb233_p_gbtabscale, 152
.set nb233_GBtab, 160
.set nb233_p_nthreads, 168
.set nb233_count, 176
.set nb233_mtx, 184
.set nb233_outeriter, 192
.set nb233_inneriter, 200
.set nb233_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb233_ixO, 0
.set nb233_iyO, 16
.set nb233_izO, 32
.set nb233_ixH1, 48
.set nb233_iyH1, 64
.set nb233_izH1, 80
.set nb233_ixH2, 96
.set nb233_iyH2, 112
.set nb233_izH2, 128
.set nb233_ixM, 144
.set nb233_iyM, 160
.set nb233_izM, 176
.set nb233_iqH, 192
.set nb233_iqM, 208
.set nb233_dxO, 224
.set nb233_dyO, 240
.set nb233_dzO, 256
.set nb233_dxH1, 272
.set nb233_dyH1, 288
.set nb233_dzH1, 304
.set nb233_dxH2, 320
.set nb233_dyH2, 336
.set nb233_dzH2, 352
.set nb233_dxM, 368
.set nb233_dyM, 384
.set nb233_dzM, 400
.set nb233_qqH, 416
.set nb233_qqM, 432
.set nb233_c6, 448
.set nb233_c12, 464
.set nb233_tsc, 480
.set nb233_fstmp, 496
.set nb233_vctot, 512
.set nb233_Vvdwtot, 528
.set nb233_fixO, 544
.set nb233_fiyO, 560
.set nb233_fizO, 576
.set nb233_fixH1, 592
.set nb233_fiyH1, 608
.set nb233_fizH1, 624
.set nb233_fixH2, 640
.set nb233_fiyH2, 656
.set nb233_fizH2, 672
.set nb233_fixM, 688
.set nb233_fiyM, 704
.set nb233_fizM, 720
.set nb233_fjx, 736
.set nb233_fjy, 752
.set nb233_fjz, 768
.set nb233_half, 784
.set nb233_three, 800
.set nb233_two, 816
.set nb233_rinvH1, 832
.set nb233_rinvH2, 848
.set nb233_rinvM, 864
.set nb233_krsqH1, 880
.set nb233_krsqH2, 896
.set nb233_krsqM, 912
.set nb233_krf, 928
.set nb233_crf, 944
.set nb233_rsqO, 960
.set nb233_facel, 976
.set nb233_innerjjnr, 984
.set nb233_iinr, 992
.set nb233_jindex, 1000
.set nb233_jjnr, 1008
.set nb233_shift, 1016
.set nb233_shiftvec, 1024
.set nb233_is3, 1032
.set nb233_ii3, 1036
.set nb233_nri, 1040
.set nb233_ntia, 1044
.set nb233_innerk, 1048
.set nb233_n, 1052
.set nb233_nn1, 1056
.set nb233_nouter, 1060
.set nb233_ninner, 1064
        push %rbp
        movq %rsp,%rbp
        push %rbx
        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $1080,%rsp         ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb233_nouter(%rsp)
        movl %eax,nb233_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb233_nri(%rsp)
        movq %rsi,nb233_iinr(%rsp)
        movq %rdx,nb233_jindex(%rsp)
        movq %rcx,nb233_jjnr(%rsp)
        movq %r8,nb233_shift(%rsp)
        movq %r9,nb233_shiftvec(%rsp)
        movq nb233_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd %xmm0,nb233_facel(%rsp)

        movq nb233_p_tabscale(%rbp),%rax
        movsd (%rax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb233_tsc(%rsp)

        movq nb233_argkrf(%rbp),%rsi
        movq nb233_argcrf(%rbp),%rdi
        movsd (%rsi),%xmm1
        movsd (%rdi),%xmm2
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        movapd %xmm1,nb233_krf(%rsp)
        movapd %xmm2,nb233_crf(%rsp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double half IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb233_half(%rsp)
        movl %ebx,nb233_half+4(%rsp)
        movsd nb233_half(%rsp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## one
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## two
        addpd  %xmm2,%xmm3      ## three
        movapd %xmm1,nb233_half(%rsp)
        movapd %xmm2,nb233_two(%rsp)
        movapd %xmm3,nb233_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb233_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]        
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb233_charge(%rbp),%rdx
        movsd 8(%rdx,%rbx,8),%xmm3
        movsd 24(%rdx,%rbx,8),%xmm4

        movsd nb233_facel(%rsp),%xmm5
        mulsd  %xmm5,%xmm3
        mulsd  %xmm5,%xmm4

        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        movapd %xmm3,nb233_iqH(%rsp)
        movapd %xmm4,nb233_iqM(%rsp)

        movq  nb233_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%ecx
        shll  %ecx
        movq nb233_p_ntype(%rbp),%rdi
        imull (%rdi),%ecx     ## rcx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb233_ntia(%rsp)
_nb_kernel233_x86_64_sse2.nb233_threadloop: 
        movq  nb233_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel233_x86_64_sse2.nb233_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel233_x86_64_sse2.nb233_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb233_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb233_n(%rsp)
        movl %ebx,nb233_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel233_x86_64_sse2.nb233_outerstart
        jmp _nb_kernel233_x86_64_sse2.nb233_end

_nb_kernel233_x86_64_sse2.nb233_outerstart: 
        ## ebx contains number of outer iterations
        addl nb233_nouter(%rsp),%ebx
        movl %ebx,nb233_nouter(%rsp)

_nb_kernel233_x86_64_sse2.nb233_outer: 
        movq  nb233_shift(%rsp),%rax        ## eax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx        ## ebx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb233_is3(%rsp)      ## store is3 

        movq  nb233_shiftvec(%rsp),%rax     ## eax = base of shiftvec[] 

        movsd (%rax,%rbx,8),%xmm0
        movsd 8(%rax,%rbx,8),%xmm1
        movsd 16(%rax,%rbx,8),%xmm2

        movq  nb233_iinr(%rsp),%rcx         ## ecx = pointer into iinr[]        
        movl  (%rcx,%rsi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        movapd %xmm0,%xmm6
        movapd %xmm1,%xmm7

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb233_pos(%rbp),%rax      ## eax = base of pos[]  
        movl  %ebx,nb233_ii3(%rsp)

        addsd (%rax,%rbx,8),%xmm3       ## ox
        addsd 8(%rax,%rbx,8),%xmm4      ## oy
        addsd 16(%rax,%rbx,8),%xmm5     ## oz   
        addsd 24(%rax,%rbx,8),%xmm6     ## h1x
        addsd 32(%rax,%rbx,8),%xmm7     ## h1y
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm7,%xmm7
        movapd %xmm3,nb233_ixO(%rsp)
        movapd %xmm4,nb233_iyO(%rsp)
        movapd %xmm5,nb233_izO(%rsp)
        movapd %xmm6,nb233_ixH1(%rsp)
        movapd %xmm7,nb233_iyH1(%rsp)

        movsd %xmm2,%xmm6
        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 40(%rax,%rbx,8),%xmm6    ## h1z
        addsd 48(%rax,%rbx,8),%xmm0    ## h2x
        addsd 56(%rax,%rbx,8),%xmm1    ## h2y
        addsd 64(%rax,%rbx,8),%xmm2    ## h2z
        addsd 72(%rax,%rbx,8),%xmm3    ## mx
        addsd 80(%rax,%rbx,8),%xmm4    ## my
        addsd 88(%rax,%rbx,8),%xmm5    ## mz

        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm6,nb233_izH1(%rsp)
        movapd %xmm0,nb233_ixH2(%rsp)
        movapd %xmm1,nb233_iyH2(%rsp)
        movapd %xmm2,nb233_izH2(%rsp)
        movapd %xmm3,nb233_ixM(%rsp)
        movapd %xmm4,nb233_iyM(%rsp)
        movapd %xmm5,nb233_izM(%rsp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb233_vctot(%rsp)
        movapd %xmm4,nb233_Vvdwtot(%rsp)
        movapd %xmm4,nb233_fixO(%rsp)
        movapd %xmm4,nb233_fiyO(%rsp)
        movapd %xmm4,nb233_fizO(%rsp)
        movapd %xmm4,nb233_fixH1(%rsp)
        movapd %xmm4,nb233_fiyH1(%rsp)
        movapd %xmm4,nb233_fizH1(%rsp)
        movapd %xmm4,nb233_fixH2(%rsp)
        movapd %xmm4,nb233_fiyH2(%rsp)
        movapd %xmm4,nb233_fizH2(%rsp)
        movapd %xmm4,nb233_fixM(%rsp)
        movapd %xmm4,nb233_fiyM(%rsp)
        movapd %xmm4,nb233_fizM(%rsp)

        movq  nb233_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb233_pos(%rbp),%rsi
        movq  nb233_faction(%rbp),%rdi
        movq  nb233_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb233_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb233_ninner(%rsp),%ecx
        movl  %ecx,nb233_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb233_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel233_x86_64_sse2.nb233_unroll_loop
        jmp   _nb_kernel233_x86_64_sse2.nb233_checksingle
_nb_kernel233_x86_64_sse2.nb233_unroll_loop: 
        ## twice unrolled innerloop here 
        movq  nb233_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx

        addq $8,nb233_innerjjnr(%rsp)                   ## advance pointer (unrolled 2) 

        movq nb233_charge(%rbp),%rsi     ## base of charge[] 

        movlpd (%rsi,%rax,8),%xmm3
        movhpd (%rsi,%rbx,8),%xmm3
        movapd %xmm3,%xmm4
        mulpd  nb233_iqM(%rsp),%xmm3
        mulpd  nb233_iqH(%rsp),%xmm4

        movapd  %xmm3,nb233_qqM(%rsp)
        movapd  %xmm4,nb233_qqH(%rsp)

        movq nb233_type(%rbp),%rsi
        movl (%rsi,%rax,4),%r8d
        movl (%rsi,%rbx,4),%r9d
        movq nb233_vdwparam(%rbp),%rsi
        shll %r8d
        shll %r9d
        movl nb233_ntia(%rsp),%edi
        addl %edi,%r8d
        addl %edi,%r9d

        movlpd (%rsi,%r8,8),%xmm6       ## c6a
        movlpd (%rsi,%r9,8),%xmm7       ## c6b
        movhpd 8(%rsi,%r8,8),%xmm6      ## c6a c12a 
        movhpd 8(%rsi,%r9,8),%xmm7      ## c6b c12b 
        movapd %xmm6,%xmm4
        unpcklpd %xmm7,%xmm4
        unpckhpd %xmm7,%xmm6

        movapd %xmm4,nb233_c6(%rsp)
        movapd %xmm6,nb233_c12(%rsp)

        movq nb233_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx

        ## load j coordinates 
    movlpd (%rsi,%rax,8),%xmm0
    movlpd 8(%rsi,%rax,8),%xmm1
    movlpd 16(%rsi,%rax,8),%xmm2
    movhpd (%rsi,%rbx,8),%xmm0
    movhpd 8(%rsi,%rbx,8),%xmm1
    movhpd 16(%rsi,%rbx,8),%xmm2

    ## xmm0 = jx
    ## xmm1 = jy
    ## xmm2 = jz

    ## O interaction
    ## copy to xmm3-xmm5
    movapd %xmm0,%xmm3
    movapd %xmm1,%xmm4
    movapd %xmm2,%xmm5

    subpd nb233_ixO(%rsp),%xmm3
    subpd nb233_iyO(%rsp),%xmm4
    subpd nb233_izO(%rsp),%xmm5

    movapd %xmm3,nb233_dxO(%rsp)
    movapd %xmm4,nb233_dyO(%rsp)
    movapd %xmm5,nb233_dzO(%rsp)

        mulpd  %xmm3,%xmm3
        mulpd  %xmm4,%xmm4
        mulpd  %xmm5,%xmm5

        addpd  %xmm4,%xmm3
        addpd  %xmm5,%xmm3