nb_kernel101_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,602 行 · 第 1/4 页

##
## $Id: nb_kernel101_x86_64_sse2.s,v 1.4.2.4 2007/09/13 05:30:46 lindahl Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##







.globl nb_kernel101_x86_64_sse2
.globl _nb_kernel101_x86_64_sse2
nb_kernel101_x86_64_sse2:       
_nb_kernel101_x86_64_sse2:      
##      Room for return address and rbp (16 bytes)
.set nb101_fshift, 16
.set nb101_gid, 24
.set nb101_pos, 32
.set nb101_faction, 40
.set nb101_charge, 48
.set nb101_p_facel, 56
.set nb101_argkrf, 64
.set nb101_argcrf, 72
.set nb101_Vc, 80
.set nb101_type, 88
.set nb101_p_ntype, 96
.set nb101_vdwparam, 104
.set nb101_Vvdw, 112
.set nb101_p_tabscale, 120
.set nb101_VFtab, 128
.set nb101_invsqrta, 136
.set nb101_dvda, 144
.set nb101_p_gbtabscale, 152
.set nb101_GBtab, 160
.set nb101_p_nthreads, 168
.set nb101_count, 176
.set nb101_mtx, 184
.set nb101_outeriter, 192
.set nb101_inneriter, 200
.set nb101_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb101_ixO, 0
.set nb101_iyO, 16
.set nb101_izO, 32
.set nb101_ixH1, 48
.set nb101_iyH1, 64
.set nb101_izH1, 80
.set nb101_ixH2, 96
.set nb101_iyH2, 112
.set nb101_izH2, 128
.set nb101_iqO, 144
.set nb101_iqH, 160
.set nb101_dxO, 176
.set nb101_dyO, 192
.set nb101_dzO, 208
.set nb101_dxH1, 224
.set nb101_dyH1, 240
.set nb101_dzH1, 256
.set nb101_dxH2, 272
.set nb101_dyH2, 288
.set nb101_dzH2, 304
.set nb101_qqO, 320
.set nb101_qqH, 336
.set nb101_vctot, 352
.set nb101_fixO, 368
.set nb101_fiyO, 384
.set nb101_fizO, 400
.set nb101_fixH1, 416
.set nb101_fiyH1, 432
.set nb101_fizH1, 448
.set nb101_fixH2, 464
.set nb101_fiyH2, 480
.set nb101_fizH2, 496
.set nb101_fjx, 512
.set nb101_fjy, 528
.set nb101_fjz, 544
.set nb101_half, 560
.set nb101_three, 576
.set nb101_nri, 592
.set nb101_innerjjnr, 600
.set nb101_iinr, 608
.set nb101_jindex, 616
.set nb101_jjnr, 624
.set nb101_shift, 632
.set nb101_shiftvec, 640
.set nb101_facel, 648
.set nb101_is3, 656
.set nb101_ii3, 660
.set nb101_innerk, 664
.set nb101_n, 668
.set nb101_nn1, 672
.set nb101_nouter, 676
.set nb101_ninner, 680
        push %rbp
        movq %rsp,%rbp
        push %rbx

        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $696,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb101_nouter(%rsp)
        movl %eax,nb101_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb101_nri(%rsp)
        movq %rsi,nb101_iinr(%rsp)
        movq %rdx,nb101_jindex(%rsp)
        movq %rcx,nb101_jjnr(%rsp)
        movq %r8,nb101_shift(%rsp)
        movq %r9,nb101_shiftvec(%rsp)
        movq nb101_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd %xmm0,nb101_facel(%rsp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double half IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb101_half(%rsp)
        movl %ebx,nb101_half+4(%rsp)
        movsd nb101_half(%rsp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## one
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## two
        addpd  %xmm2,%xmm3      ## three
        movapd %xmm1,nb101_half(%rsp)
        movapd %xmm3,nb101_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb101_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]        
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb101_charge(%rbp),%rdx
        movsd (%rdx,%rbx,8),%xmm3
        movsd 8(%rdx,%rbx,8),%xmm4
        movq nb101_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd nb101_facel(%rsp),%xmm5
        mulsd  %xmm5,%xmm3
        mulsd  %xmm5,%xmm4

        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        movapd %xmm3,nb101_iqO(%rsp)
        movapd %xmm4,nb101_iqH(%rsp)

_nb_kernel101_x86_64_sse2.nb101_threadloop: 
        movq  nb101_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel101_x86_64_sse2.nb101_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel101_x86_64_sse2.nb101_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb101_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb101_n(%rsp)
        movl %ebx,nb101_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel101_x86_64_sse2.nb101_outerstart
        jmp _nb_kernel101_x86_64_sse2.nb101_end

_nb_kernel101_x86_64_sse2.nb101_outerstart: 
        ## ebx contains number of outer iterations
        addl nb101_nouter(%rsp),%ebx
        movl %ebx,nb101_nouter(%rsp)

_nb_kernel101_x86_64_sse2.nb101_outer: 
        movq  nb101_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb101_is3(%rsp)      ## store is3 

        movq  nb101_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movsd (%rax,%rbx,8),%xmm0
        movsd 8(%rax,%rbx,8),%xmm1
        movsd 16(%rax,%rbx,8),%xmm2

        movq  nb101_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]        
        movl  (%rcx,%rsi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb101_pos(%rbp),%rax      ## rax = base of pos[]  
        movl  %ebx,nb101_ii3(%rsp)

        addsd (%rax,%rbx,8),%xmm3
        addsd 8(%rax,%rbx,8),%xmm4
        addsd 16(%rax,%rbx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb101_ixO(%rsp)
        movapd %xmm4,nb101_iyO(%rsp)
        movapd %xmm5,nb101_izO(%rsp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 24(%rax,%rbx,8),%xmm0
        addsd 32(%rax,%rbx,8),%xmm1
        addsd 40(%rax,%rbx,8),%xmm2
        addsd 48(%rax,%rbx,8),%xmm3
        addsd 56(%rax,%rbx,8),%xmm4
        addsd 64(%rax,%rbx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb101_ixH1(%rsp)
        movapd %xmm1,nb101_iyH1(%rsp)
        movapd %xmm2,nb101_izH1(%rsp)
        movapd %xmm3,nb101_ixH2(%rsp)
        movapd %xmm4,nb101_iyH2(%rsp)
        movapd %xmm5,nb101_izH2(%rsp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb101_vctot(%rsp)
        movapd %xmm4,nb101_fixO(%rsp)
        movapd %xmm4,nb101_fiyO(%rsp)
        movapd %xmm4,nb101_fizO(%rsp)
        movapd %xmm4,nb101_fixH1(%rsp)
        movapd %xmm4,nb101_fiyH1(%rsp)
        movapd %xmm4,nb101_fizH1(%rsp)
        movapd %xmm4,nb101_fixH2(%rsp)
        movapd %xmm4,nb101_fiyH2(%rsp)
        movapd %xmm4,nb101_fizH2(%rsp)

        movq  nb101_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx     ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb101_pos(%rbp),%rsi
        movq  nb101_faction(%rbp),%rdi
        movq  nb101_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb101_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb101_ninner(%rsp),%ecx
        movl  %ecx,nb101_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb101_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel101_x86_64_sse2.nb101_unroll_loop
        jmp   _nb_kernel101_x86_64_sse2.nb101_checksingle
_nb_kernel101_x86_64_sse2.nb101_unroll_loop: 
        ## twice unrolled innerloop here 
        movq  nb101_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx

        addq $8,nb101_innerjjnr(%rsp)             ## advance pointer (unrolled 2) 

        movq nb101_charge(%rbp),%rsi     ## base of charge[] 

        movlpd (%rsi,%rax,8),%xmm6      ## jq A 
        movhpd (%rsi,%rbx,8),%xmm6      ## jq B 
        movapd nb101_iqO(%rsp),%xmm3
        movapd nb101_iqH(%rsp),%xmm4
        mulpd %xmm6,%xmm3               ## qqO 
        mulpd %xmm6,%xmm4               ## qqH 

        movapd  %xmm3,nb101_qqO(%rsp)
        movapd  %xmm4,nb101_qqH(%rsp)

        movq nb101_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx

        ## move j coordinates to local temp variables 
    movlpd (%rsi,%rax,8),%xmm0
    movlpd 8(%rsi,%rax,8),%xmm1
    movlpd 16(%rsi,%rax,8),%xmm2
    movhpd (%rsi,%rbx,8),%xmm0
    movhpd 8(%rsi,%rbx,8),%xmm1
    movhpd 16(%rsi,%rbx,8),%xmm2

    ## xmm0 = jx
    ## xmm1 = jy
    ## xmm2 = jz

    movapd %xmm0,%xmm3
    movapd %xmm1,%xmm4
    movapd %xmm2,%xmm5
    movapd %xmm0,%xmm6
    movapd %xmm1,%xmm7
    movapd %xmm2,%xmm8

    subpd nb101_ixO(%rsp),%xmm0
    subpd nb101_iyO(%rsp),%xmm1
    subpd nb101_izO(%rsp),%xmm2
    subpd nb101_ixH1(%rsp),%xmm3
    subpd nb101_iyH1(%rsp),%xmm4
    subpd nb101_izH1(%rsp),%xmm5
    subpd nb101_ixH2(%rsp),%xmm6
    subpd nb101_iyH2(%rsp),%xmm7
    subpd nb101_izH2(%rsp),%xmm8

        movapd %xmm0,nb101_dxO(%rsp)
        movapd %xmm1,nb101_dyO(%rsp)
        movapd %xmm2,nb101_dzO(%rsp)
        mulpd  %xmm0,%xmm0
        mulpd  %xmm1,%xmm1
        mulpd  %xmm2,%xmm2
        movapd %xmm3,nb101_dxH1(%rsp)
        movapd %xmm4,nb101_dyH1(%rsp)
        movapd %xmm5,nb101_dzH1(%rsp)
        mulpd  %xmm3,%xmm3
        mulpd  %xmm4,%xmm4
        mulpd  %xmm5,%xmm5
        movapd %xmm6,nb101_dxH2(%rsp)
        movapd %xmm7,nb101_dyH2(%rsp)
        movapd %xmm8,nb101_dzH2(%rsp)
        mulpd  %xmm6,%xmm6
        mulpd  %xmm7,%xmm7
        mulpd  %xmm8,%xmm8
        addpd  %xmm1,%xmm0
        addpd  %xmm2,%xmm0
        addpd  %xmm4,%xmm3
        addpd  %xmm5,%xmm3
    addpd  %xmm7,%xmm6
    addpd  %xmm8,%xmm6

        ## start doing invsqrt for j atoms
    cvtpd2ps %xmm0,%xmm1
    cvtpd2ps %xmm3,%xmm4
    cvtpd2ps %xmm6,%xmm7
        rsqrtps %xmm1,%xmm1
        rsqrtps %xmm4,%xmm4
    rsqrtps %xmm7,%xmm7
    cvtps2pd %xmm1,%xmm1
    cvtps2pd %xmm4,%xmm4
    cvtps2pd %xmm7,%xmm7

        movapd  %xmm1,%xmm2
        movapd  %xmm4,%xmm5
    movapd  %xmm7,%xmm8

        mulpd   %xmm1,%xmm1 ## lu*lu
        mulpd   %xmm4,%xmm4 ## lu*lu
    mulpd   %xmm7,%xmm7 ## lu*lu

        movapd  nb101_three(%rsp),%xmm9
        movapd  %xmm9,%xmm10
    movapd  %xmm9,%xmm11

        mulpd   %xmm0,%xmm1 ## rsq*lu*lu
        mulpd   %xmm3,%xmm4 ## rsq*lu*lu 
    mulpd   %xmm6,%xmm7 ## rsq*lu*lu

        subpd   %xmm1,%xmm9
        subpd   %xmm4,%xmm10
    subpd   %xmm7,%xmm11 ## 3-rsq*lu*lu