nb_kernel110_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,111 行 · 第 1/3 页

##
## $Id: nb_kernel110_x86_64_sse2.s,v 1.4.2.3 2006/09/22 08:40:32 lindahl Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##








.globl nb_kernel110_x86_64_sse2
.globl _nb_kernel110_x86_64_sse2
nb_kernel110_x86_64_sse2:       
_nb_kernel110_x86_64_sse2:      
##      Room for return address and rbp (16 bytes)
.set nb110_fshift, 16
.set nb110_gid, 24
.set nb110_pos, 32
.set nb110_faction, 40
.set nb110_charge, 48
.set nb110_p_facel, 56
.set nb110_argkrf, 64
.set nb110_argcrf, 72
.set nb110_Vc, 80
.set nb110_type, 88
.set nb110_p_ntype, 96
.set nb110_vdwparam, 104
.set nb110_Vvdw, 112
.set nb110_p_tabscale, 120
.set nb110_VFtab, 128
.set nb110_invsqrta, 136
.set nb110_dvda, 144
.set nb110_p_gbtabscale, 152
.set nb110_GBtab, 160
.set nb110_p_nthreads, 168
.set nb110_count, 176
.set nb110_mtx, 184
.set nb110_outeriter, 192
.set nb110_inneriter, 200
.set nb110_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb110_ix, 0
.set nb110_iy, 16
.set nb110_iz, 32
.set nb110_iq, 48
.set nb110_dx, 64
.set nb110_dy, 80
.set nb110_dz, 96
.set nb110_c6, 112
.set nb110_c12, 128
.set nb110_six, 144
.set nb110_twelve, 160
.set nb110_vctot, 176
.set nb110_Vvdwtot, 192
.set nb110_fix, 208
.set nb110_fiy, 224
.set nb110_fiz, 240
.set nb110_half, 256
.set nb110_three, 272
.set nb110_is3, 288
.set nb110_ii3, 292
.set nb110_nri, 296
.set nb110_iinr, 304
.set nb110_jindex, 312
.set nb110_jjnr, 320
.set nb110_shift, 328
.set nb110_shiftvec, 336
.set nb110_facel, 344
.set nb110_innerjjnr, 352
.set nb110_ntia, 360
.set nb110_innerk, 364
.set nb110_n, 368
.set nb110_nn1, 372
.set nb110_ntype, 376
.set nb110_nouter, 380
.set nb110_ninner, 384
        push %rbp
        movq %rsp,%rbp
        push %rbx

        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $408,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb110_nouter(%rsp)
        movl %eax,nb110_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb110_nri(%rsp)
        movq %rsi,nb110_iinr(%rsp)
        movq %rdx,nb110_jindex(%rsp)
        movq %rcx,nb110_jjnr(%rsp)
        movq %r8,nb110_shift(%rsp)
        movq %r9,nb110_shiftvec(%rsp)
        movq nb110_p_ntype(%rbp),%rdi
        movl (%rdi),%edi
        movl %edi,nb110_ntype(%rsp)
        movq nb110_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd %xmm0,nb110_facel(%rsp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double half IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb110_half(%rsp)
        movl %ebx,nb110_half+4(%rsp)
        movsd nb110_half(%rsp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## one
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## two
        addpd  %xmm2,%xmm3      ## three
        movapd %xmm3,%xmm4
        addpd  %xmm4,%xmm4      ## six
        movapd %xmm4,%xmm5
        addpd  %xmm5,%xmm5      ## twelve
        movapd %xmm1,nb110_half(%rsp)
        movapd %xmm3,nb110_three(%rsp)
        movapd %xmm4,nb110_six(%rsp)
        movapd %xmm5,nb110_twelve(%rsp)

_nb_kernel110_x86_64_sse2.nb110_threadloop: 
        movq  nb110_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel110_x86_64_sse2.nb110_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel110_x86_64_sse2.nb110_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb110_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb110_n(%rsp)
        movl %ebx,nb110_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel110_x86_64_sse2.nb110_outerstart
        jmp _nb_kernel110_x86_64_sse2.nb110_end

_nb_kernel110_x86_64_sse2.nb110_outerstart: 
        ## ebx contains number of outer iterations
        addl nb110_nouter(%rsp),%ebx
        movl %ebx,nb110_nouter(%rsp)

_nb_kernel110_x86_64_sse2.nb110_outer: 
        movq  nb110_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx        ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb110_is3(%rsp)      ## store is3 

        movq  nb110_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movsd (%rax,%rbx,8),%xmm0
        movsd 8(%rax,%rbx,8),%xmm1
        movsd 16(%rax,%rbx,8),%xmm2

        movq  nb110_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]        
        movl  (%rcx,%rsi,4),%ebx    ## ebx =ii 

        movq  nb110_charge(%rbp),%rdx
        movsd (%rdx,%rbx,8),%xmm3
        mulsd nb110_facel(%rsp),%xmm3
        shufpd $0,%xmm3,%xmm3

        movq  nb110_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%edx
        imull nb110_ntype(%rsp),%edx
        shll  %edx
        movl  %edx,nb110_ntia(%rsp)

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb110_pos(%rbp),%rax      ## rax = base of pos[]  

        addsd (%rax,%rbx,8),%xmm0
        addsd 8(%rax,%rbx,8),%xmm1
        addsd 16(%rax,%rbx,8),%xmm2

        movapd %xmm3,nb110_iq(%rsp)

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2

        movapd %xmm0,nb110_ix(%rsp)
        movapd %xmm1,nb110_iy(%rsp)
        movapd %xmm2,nb110_iz(%rsp)

        movl  %ebx,nb110_ii3(%rsp)

        ## clear vctot and i forces 
        xorpd %xmm12,%xmm12
        movapd %xmm12,nb110_Vvdwtot(%rsp)
        movapd %xmm12,%xmm13
        movapd %xmm12,%xmm14
        movapd %xmm12,%xmm15

        movq  nb110_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb110_pos(%rbp),%rsi
        movq  nb110_faction(%rbp),%rdi
        movq  nb110_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb110_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb110_ninner(%rsp),%ecx
        movl  %ecx,nb110_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb110_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel110_x86_64_sse2.nb110_unroll_loop
        jmp   _nb_kernel110_x86_64_sse2.nb110_checksingle
_nb_kernel110_x86_64_sse2.nb110_unroll_loop: 
        ## twice unrolled innerloop here 
        movq  nb110_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%r8d
        movl  4(%rdx),%r9d
        addq $8,nb110_innerjjnr(%rsp)                   ## advance pointer (unrolled 2) 

        movq nb110_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%r8,%r8,2),%rax     ## replace jnr with j3 
        lea  (%r9,%r9,2),%rbx

        ## move two coordinates to xmm4-xmm6
        movlpd (%rsi,%rax,8),%xmm4
        movlpd 8(%rsi,%rax,8),%xmm5
        movlpd 16(%rsi,%rax,8),%xmm6
        movhpd (%rsi,%rbx,8),%xmm4
        movhpd 8(%rsi,%rbx,8),%xmm5
        movhpd 16(%rsi,%rbx,8),%xmm6

        ## calc dr 
        subpd nb110_ix(%rsp),%xmm4
        subpd nb110_iy(%rsp),%xmm5
        subpd nb110_iz(%rsp),%xmm6

        ## store dr 
        movapd %xmm4,%xmm9
        movapd %xmm5,%xmm10
        movapd %xmm6,%xmm11

        movq nb110_charge(%rbp),%rsi     ## base of charge[] 

        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        movq nb110_type(%rbp),%rdi
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm4
        addpd %xmm6,%xmm4
        ## rsq in xmm4 

        movlpd (%rsi,%r8,8),%xmm3
        movhpd (%rsi,%r9,8),%xmm3

        cvtpd2ps %xmm4,%xmm5
        movl (%rdi,%r8,4),%r8d
        movl (%rdi,%r9,4),%r9d
        rsqrtps %xmm5,%xmm5
        cvtps2pd %xmm5,%xmm2    ## lu in low xmm2 

        shll %r8d
        shll %r9d

        ## lookup seed in xmm2 
        movapd %xmm2,%xmm5      ## copy of lu 
        mulpd %xmm2,%xmm2       ## lu*lu 
        movl nb110_ntia(%rsp),%edi
        addl %edi,%r8d
        addl %edi,%r9d
        movapd nb110_three(%rsp),%xmm1
        mulpd %xmm4,%xmm2       ## rsq*lu*lu                    
        movq nb110_vdwparam(%rbp),%rdi
        movapd nb110_half(%rsp),%xmm0
        subpd %xmm2,%xmm1       ## 30-rsq*lu*lu 
        mulpd %xmm5,%xmm1
        mulpd %xmm0,%xmm1       ## xmm0=iter1 of rinv (new lu) 
        mulpd nb110_iq(%rsp),%xmm3              ## qq 

    movlpd (%rdi,%r8,8),%xmm6
    movlpd 8(%rdi,%r8,8),%xmm7

        movapd %xmm1,%xmm5      ## copy of lu 
        mulpd %xmm1,%xmm1       ## lu*lu 
        movapd nb110_three(%rsp),%xmm2
        mulpd %xmm4,%xmm1       ## rsq*lu*lu                    
        movapd nb110_half(%rsp),%xmm0
        subpd %xmm1,%xmm2       ## 30-rsq*lu*lu 
        mulpd %xmm5,%xmm2
        mulpd %xmm2,%xmm0       ## xmm0=rinv 

    movhpd (%rdi,%r9,8),%xmm6
    movhpd 8(%rdi,%r9,8),%xmm7

        movapd %xmm0,%xmm4
        mulpd  %xmm4,%xmm4      ## xmm4=rinvsq 
        movapd %xmm4,%xmm1
        mulpd  %xmm4,%xmm1
        mulpd  %xmm4,%xmm1      ## xmm1=rinvsix 
        movapd %xmm1,%xmm2
        mulpd  %xmm2,%xmm2      ## xmm2=rinvtwelve 
        mulpd  %xmm0,%xmm3      ## xmm3=vcoul 
        mulpd  %xmm6,%xmm1
        mulpd  %xmm7,%xmm2
        movapd %xmm2,%xmm5
        subpd  %xmm1,%xmm5      ## Vvdw=Vvdw12-Vvdw6 
        addpd  nb110_Vvdwtot(%rsp),%xmm5
        mulpd  nb110_six(%rsp),%xmm1
        mulpd  nb110_twelve(%rsp),%xmm2
        subpd  %xmm1,%xmm2
        addpd  %xmm3,%xmm2
        mulpd  %xmm2,%xmm4      ## xmm4=total fscal 
        addpd  %xmm3,%xmm12 ## add to vctot
        movq   nb110_faction(%rbp),%rdi

        ## the fj's - start by accumulating forces from memory 
        movlpd (%rdi,%rax,8),%xmm6
        movlpd 8(%rdi,%rax,8),%xmm7
        movlpd 16(%rdi,%rax,8),%xmm8
        movhpd (%rdi,%rbx,8),%xmm6
        movhpd 8(%rdi,%rbx,8),%xmm7
        movhpd 16(%rdi,%rbx,8),%xmm8

        movapd %xmm5,nb110_Vvdwtot(%rsp)

        mulpd  %xmm4,%xmm9
        mulpd  %xmm4,%xmm10
        mulpd  %xmm4,%xmm11

        addpd %xmm9,%xmm6
        addpd %xmm10,%xmm7
        addpd %xmm11,%xmm8