nb_kernel203_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,708 行 · 第 1/4 页

        addsd  nb203_fjy(%rsp),%xmm1
        addsd  nb203_fjz(%rsp),%xmm2
        movlpd (%rdi,%rax,8),%xmm3
        movlpd 8(%rdi,%rax,8),%xmm4
        movlpd 16(%rdi,%rax,8),%xmm5
        addsd %xmm0,%xmm3
        addsd %xmm1,%xmm4
        addsd %xmm2,%xmm5
        movlpd %xmm3,(%rdi,%rax,8)
        movlpd %xmm4,8(%rdi,%rax,8)
        movlpd %xmm5,16(%rdi,%rax,8)

_nb_kernel203_x86_64_sse2.nb203_updateouterdata: 
        movl  nb203_ii3(%rsp),%ecx
        movq  nb203_faction(%rbp),%rdi
        movq  nb203_fshift(%rbp),%rsi
        movl  nb203_is3(%rsp),%edx

        ## accumulate H1i forces in xmm0, xmm1, xmm2 
        movapd nb203_fixH1(%rsp),%xmm0
        movapd nb203_fiyH1(%rsp),%xmm1
        movapd nb203_fizH1(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addsd  %xmm3,%xmm0
        addsd  %xmm4,%xmm1
        addsd  %xmm5,%xmm2 ## sum is in low xmm0-xmm2 

        ## increment i force 
        movsd  24(%rdi,%rcx,8),%xmm3
        movsd  32(%rdi,%rcx,8),%xmm4
        movsd  40(%rdi,%rcx,8),%xmm5
        subsd  %xmm0,%xmm3
        subsd  %xmm1,%xmm4
        subsd  %xmm2,%xmm5
        movsd  %xmm3,24(%rdi,%rcx,8)
        movsd  %xmm4,32(%rdi,%rcx,8)
        movsd  %xmm5,40(%rdi,%rcx,8)

        ## accumulate force in xmm6/xmm7 for fshift 
        movapd %xmm0,%xmm6
        movsd %xmm2,%xmm7
        unpcklpd %xmm1,%xmm6

        ## accumulate H2i forces in xmm0, xmm1, xmm2 
        movapd nb203_fixH2(%rsp),%xmm0
        movapd nb203_fiyH2(%rsp),%xmm1
        movapd nb203_fizH2(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addsd  %xmm3,%xmm0
        addsd  %xmm4,%xmm1
        addsd  %xmm5,%xmm2 ## sum is in low xmm0-xmm2 

        ## increment i force 
        movsd  48(%rdi,%rcx,8),%xmm3
        movsd  56(%rdi,%rcx,8),%xmm4
        movsd  64(%rdi,%rcx,8),%xmm5
        subsd  %xmm0,%xmm3
        subsd  %xmm1,%xmm4
        subsd  %xmm2,%xmm5
        movsd  %xmm3,48(%rdi,%rcx,8)
        movsd  %xmm4,56(%rdi,%rcx,8)
        movsd  %xmm5,64(%rdi,%rcx,8)

        ## accumulate force in xmm6/xmm7 for fshift 
        addsd %xmm2,%xmm7
        unpcklpd %xmm1,%xmm0
        addpd %xmm0,%xmm6

        ## accumulate H2i forces in xmm0, xmm1, xmm2 
        movapd nb203_fixM(%rsp),%xmm0
        movapd nb203_fiyM(%rsp),%xmm1
        movapd nb203_fizM(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addsd  %xmm3,%xmm0
        addsd  %xmm4,%xmm1
        addsd  %xmm5,%xmm2 ## sum is in low xmm0-xmm2 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5

        ## increment i force 
        movsd  72(%rdi,%rcx,8),%xmm3
        movsd  80(%rdi,%rcx,8),%xmm4
        movsd  88(%rdi,%rcx,8),%xmm5
        subsd  %xmm0,%xmm3
        subsd  %xmm1,%xmm4
        subsd  %xmm2,%xmm5
        movsd  %xmm3,72(%rdi,%rcx,8)
        movsd  %xmm4,80(%rdi,%rcx,8)
        movsd  %xmm5,88(%rdi,%rcx,8)

        ## accumulate force in xmm6/xmm7 for fshift 
        addsd %xmm2,%xmm7
        unpcklpd %xmm1,%xmm0
        addpd %xmm0,%xmm6

        ## increment fshift force 
        movlpd (%rsi,%rdx,8),%xmm3
        movhpd 8(%rsi,%rdx,8),%xmm3
        movsd  16(%rsi,%rdx,8),%xmm4
        subpd  %xmm6,%xmm3
        subsd  %xmm7,%xmm4
        movlpd %xmm3,(%rsi,%rdx,8)
        movhpd %xmm3,8(%rsi,%rdx,8)
        movsd  %xmm4,16(%rsi,%rdx,8)

        ## get n from stack
        movl nb203_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb203_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movapd nb203_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addsd  %xmm6,%xmm7      ## low xmm7 has the sum now 

        ## add earlier value from mem 
        movq  nb203_Vc(%rbp),%rax
        addsd (%rax,%rdx,8),%xmm7
        ## move back to mem 
        movsd %xmm7,(%rax,%rdx,8)

        ## finish if last 
        movl nb203_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel203_x86_64_sse2.nb203_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb203_n(%rsp)
        jmp _nb_kernel203_x86_64_sse2.nb203_outer
_nb_kernel203_x86_64_sse2.nb203_outerend: 
        ## check if more outer neighborlists remain
        movl  nb203_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel203_x86_64_sse2.nb203_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel203_x86_64_sse2.nb203_threadloop
_nb_kernel203_x86_64_sse2.nb203_end: 
        movl nb203_nouter(%rsp),%eax
        movl nb203_ninner(%rsp),%ebx
        movq nb203_outeriter(%rbp),%rcx
        movq nb203_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $808,%rsp
        emms


        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret




.globl nb_kernel203nf_x86_64_sse2
.globl _nb_kernel203nf_x86_64_sse2
nb_kernel203nf_x86_64_sse2:     
_nb_kernel203nf_x86_64_sse2:    
##      Room for return address and rbp (16 bytes)
.set nb203nf_fshift, 16
.set nb203nf_gid, 24
.set nb203nf_pos, 32
.set nb203nf_faction, 40
.set nb203nf_charge, 48
.set nb203nf_p_facel, 56
.set nb203nf_argkrf, 64
.set nb203nf_argcrf, 72
.set nb203nf_Vc, 80
.set nb203nf_type, 88
.set nb203nf_p_ntype, 96
.set nb203nf_vdwparam, 104
.set nb203nf_Vvdw, 112
.set nb203nf_p_tabscale, 120
.set nb203nf_VFtab, 128
.set nb203nf_invsqrta, 136
.set nb203nf_dvda, 144
.set nb203nf_p_gbtabscale, 152
.set nb203nf_GBtab, 160
.set nb203nf_p_nthreads, 168
.set nb203nf_count, 176
.set nb203nf_mtx, 184
.set nb203nf_outeriter, 192
.set nb203nf_inneriter, 200
.set nb203nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb203nf_ixM, 0
.set nb203nf_iyM, 16
.set nb203nf_izM, 32
.set nb203nf_ixH1, 48
.set nb203nf_iyH1, 64
.set nb203nf_izH1, 80
.set nb203nf_ixH2, 96
.set nb203nf_iyH2, 112
.set nb203nf_izH2, 128
.set nb203nf_iqM, 144
.set nb203nf_iqH, 160
.set nb203nf_qqM, 176
.set nb203nf_qqH, 192
.set nb203nf_vctot, 208
.set nb203nf_half, 224
.set nb203nf_three, 240
.set nb203nf_krf, 256
.set nb203nf_crf, 272
.set nb203nf_krsqM, 288
.set nb203nf_krsqH1, 304
.set nb203nf_krsqH2, 320
.set nb203nf_is3, 336
.set nb203nf_ii3, 340
.set nb203nf_nri, 344
.set nb203nf_iinr, 352
.set nb203nf_jindex, 360
.set nb203nf_jjnr, 368
.set nb203nf_shift, 376
.set nb203nf_shiftvec, 384
.set nb203nf_facel, 392
.set nb203nf_innerjjnr, 400
.set nb203nf_innerk, 408
.set nb203nf_n, 412
.set nb203nf_nn1, 416
.set nb203nf_nouter, 420
.set nb203nf_ninner, 424
        push %rbp
        movq %rsp,%rbp
        push %rbx
        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $440,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb203nf_nouter(%rsp)
        movl %eax,nb203nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb203nf_nri(%rsp)
        movq %rsi,nb203nf_iinr(%rsp)
        movq %rdx,nb203nf_jindex(%rsp)
        movq %rcx,nb203nf_jjnr(%rsp)
        movq %r8,nb203nf_shift(%rsp)
        movq %r9,nb203nf_shiftvec(%rsp)
        movq nb203nf_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd %xmm0,nb203nf_facel(%rsp)

        movq nb203nf_argkrf(%rbp),%rsi
        movq nb203nf_argcrf(%rbp),%rdi
        movsd (%rsi),%xmm1
        movsd (%rdi),%xmm2
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        movapd %xmm1,nb203nf_krf(%rsp)
        movapd %xmm2,nb203nf_crf(%rsp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double half IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb203nf_half(%rsp)
        movl %ebx,nb203nf_half+4(%rsp)
        movsd nb203nf_half(%rsp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## one
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## two
        addpd  %xmm2,%xmm3      ## three
        movapd %xmm1,nb203nf_half(%rsp)
        movapd %xmm3,nb203nf_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb203nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb203nf_charge(%rbp),%rdx
        movsd 8(%rdx,%rbx,8),%xmm3
        movsd 24(%rdx,%rbx,8),%xmm4

        movsd nb203nf_facel(%rsp),%xmm5
        mulsd  %xmm5,%xmm3
        mulsd  %xmm5,%xmm4

        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        movapd %xmm3,nb203nf_iqH(%rsp)
        movapd %xmm4,nb203nf_iqM(%rsp)

_nb_kernel203nf_x86_64_sse2.nb203nf_threadloop: 
        movq  nb203nf_count(%rbp),%rsi          ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel203nf_x86_64_sse2.nb203nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                           ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel203nf_x86_64_sse2.nb203nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb203nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb203nf_n(%rsp)
        movl %ebx,nb203nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel203nf_x86_64_sse2.nb203nf_outerstart
        jmp _nb_kernel203nf_x86_64_sse2.nb203nf_end

_nb_kernel203nf_x86_64_sse2.nb203nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb203nf_nouter(%rsp),%ebx
        movl %ebx,nb203nf_nouter(%rsp)

_nb_kernel203nf_x86_64_sse2.nb203nf_outer: 
        movq  nb203nf_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx        ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 

        movq  nb203nf_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movsd (%rax,%rbx,8),%xmm0
        movsd 8(%rax,%rbx,8),%xmm1
        movsd 16(%rax,%rbx,8),%xmm2

        movq  nb203nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx,%rsi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb203nf_pos(%rbp),%rax      ## rax = base of pos[]  
        movl  %ebx,nb203nf_ii3(%rsp)

        addsd 24(%rax,%rbx,8),%xmm3
        addsd 32(%rax,%rbx,8),%xmm4
        addsd 40(%rax,%rbx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb203nf_ixH1(%rsp)
        movapd %xmm4,nb203nf_iyH1(%rsp)
        movapd %xmm5,nb203nf_izH1(%rsp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 48(%rax,%rbx,8),%xmm0
        addsd 56(%rax,%rbx,8),%xmm1
        addsd 64(%rax,%rbx,8),%xmm2
        addsd 72(%rax,%rbx,8),%xmm3
        addsd 80(%rax,%rbx,8),%xmm4
        addsd 88(%rax,%rbx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb203nf_ixH2(%rsp)
        movapd %xmm1,nb203nf_iyH2(%rsp)
        movapd %xmm2,nb203nf_izH2(%rsp)
        movapd %xmm3,nb203nf_ixM(%rsp)
        movapd %xmm4,nb203nf_iyM(%rsp)
        movapd %xmm5,nb203nf_izM(%rsp)

        ## clear vctot 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb203nf_vctot(%rsp)

        movq  nb203nf_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx     ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb203nf_pos(%rbp),%rsi
        movq  nb203nf_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb203nf_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb203nf_ninner(%rsp),%ecx
        movl  %ecx,nb203nf_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb203nf_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel203nf_x86_64_sse2.nb203nf_unroll_loop
        jmp   _nb_kernel203nf_x86_64_sse2.nb203nf_checksingle
_nb_kernel203nf_x86_64_sse2.nb203nf_unroll_loop: 
        ## twice unrolled innerloop here 
        movq  nb203nf_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax