nb_kernel110_x86_64_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,135 行 · 第 1/3 页

	movlpd xmm6, [rdi + rax*8]
	movlpd xmm7, [rdi + rax*8 + 8]
	movlpd xmm8, [rdi + rax*8 + 16]
	movhpd xmm6, [rdi + rbx*8]
	movhpd xmm7, [rdi + rbx*8 + 8]
	movhpd xmm8, [rdi + rbx*8 + 16]

	movapd [rsp + nb110_Vvdwtot], xmm5

	mulpd  xmm9, xmm4
	mulpd  xmm10, xmm4
	mulpd  xmm11, xmm4
    
	addpd xmm6, xmm9
	addpd xmm7, xmm10
	addpd xmm8, xmm11

	;# now update f_i 
	addpd  xmm13, xmm9
	addpd  xmm14, xmm10
	addpd  xmm15, xmm11

	movlpd [rdi + rax*8], xmm6
	movlpd [rdi + rax*8 + 8], xmm7
	movlpd [rdi + rax*8 + 16], xmm8
	movhpd [rdi + rbx*8], xmm6
	movhpd [rdi + rbx*8 + 8], xmm7
	movhpd [rdi + rbx*8 + 16], xmm8
	
	;# should we do one more iteration? 
	sub dword ptr [rsp + nb110_innerk],  2
	jl    .nb110_checksingle
	jmp   .nb110_unroll_loop	
.nb110_checksingle:
	mov   edx, [rsp + nb110_innerk]
	and   edx, 1
	jnz    .nb110_dosingle
	jmp    .nb110_updateouterdata
.nb110_dosingle:
	mov rsi, [rbp + nb110_charge]
	mov rdi, [rbp + nb110_pos]
	mov rcx, [rsp + nb110_innerjjnr]
	mov   eax, [rcx]
	
	mov rsi, [rbp + nb110_charge]    ;# base of charge[] 
	
	movsd xmm3, [rsi + rax*8]
    mulsd xmm3, [rsp + nb110_iq] ;# qq

	mov rsi, [rbp + nb110_type]
	mov r8d, [rsi + rax*4]
	mov rsi, [rbp + nb110_vdwparam]
	shl r8d, 1
	mov edi, [rsp + nb110_ntia]
	add r8d, edi

	movsd xmm4, [rsi + r8*8]	    ;# c6
	movsd xmm6, [rsi + r8*8 + 8]	;# c12
	movapd [rsp + nb110_c6], xmm4
	movapd [rsp + nb110_c12], xmm6
	
	mov rsi, [rbp + nb110_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 

	;# move two coordinates to xmm4-xmm6
	movsd xmm4, [rsi + rax*8]
	movsd xmm5, [rsi + rax*8 + 8]
	movsd xmm6, [rsi + rax*8 + 16]
	
	;# calc dr 
	subsd xmm4, [rsp + nb110_ix]
	subsd xmm5, [rsp + nb110_iy]
	subsd xmm6, [rsp + nb110_iz]

	;# store dr 
	movapd xmm9, xmm4
	movapd xmm10, xmm5
	movapd xmm11, xmm6

	;# square it 
	mulsd xmm4,xmm4
	mulsd xmm5,xmm5
	mulsd xmm6,xmm6
	addsd xmm4, xmm5
	addsd xmm4, xmm6
	;# rsq in xmm4 

	cvtsd2ss xmm5, xmm4	
	rsqrtss xmm5, xmm5
	cvtss2sd xmm2, xmm5	;# lu in low xmm2 

	;# lookup seed in xmm2 
	movapd xmm5, xmm2	;# copy of lu 
	mulsd xmm2, xmm2	;# lu*lu 
	movapd xmm1, [rsp + nb110_three]
	mulsd xmm2, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [rsp + nb110_half]
	subsd xmm1, xmm2	;# 30-rsq*lu*lu 
	mulsd xmm1, xmm5	
	mulsd xmm1, xmm0	;# xmm0=iter1 of rinv (new lu) 

	movapd xmm5, xmm1	;# copy of lu 
	mulsd xmm1, xmm1	;# lu*lu 
	movapd xmm2, [rsp + nb110_three]
	mulsd xmm1, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [rsp + nb110_half]
	subsd xmm2, xmm1	;# 30-rsq*lu*lu 
	mulsd xmm2, xmm5	
	mulsd xmm0, xmm2	;# xmm0=rinv 
	
	movapd xmm4, xmm0
	mulsd  xmm4, xmm4	;# xmm4=rinvsq 
	movapd xmm1, xmm4
	mulsd  xmm1, xmm4
	mulsd  xmm1, xmm4	;# xmm1=rinvsix 
	movapd xmm2, xmm1
	mulsd  xmm2, xmm2	;# xmm2=rinvtwelve 
	mulsd  xmm3, xmm0	;# xmm3=vcoul 
	mulsd  xmm1, [rsp + nb110_c6]
	mulsd  xmm2, [rsp + nb110_c12]
	movapd xmm5, xmm2
	subsd  xmm5, xmm1	;# Vvdw=Vvdw12-Vvdw6 
	addsd  xmm5, [rsp + nb110_Vvdwtot]
	mulsd  xmm1, [rsp + nb110_six]
	mulsd  xmm2, [rsp + nb110_twelve]
	subsd  xmm2, xmm1
	addsd  xmm2, xmm3
	mulsd  xmm4, xmm2	;# xmm4=total fscal 
	addsd  xmm12, xmm3   ;# add to vctot

	movsd [rsp + nb110_Vvdwtot], xmm5

	mov    rdi, [rbp + nb110_faction]
	mulsd  xmm9, xmm4
	mulsd  xmm10, xmm4
	mulsd  xmm11, xmm4
    
	;# now update f_i 
	addsd  xmm13, xmm9
	addsd  xmm14, xmm10
	addsd  xmm15, xmm11
	;# the fj's - start by accumulating forces from memory 
	addsd xmm9,  [rdi + rax*8]
	addsd xmm10, [rdi + rax*8 + 8]
	addsd xmm11, [rdi + rax*8 + 16]
	movsd [rdi + rax*8], xmm9
	movsd [rdi + rax*8 + 8], xmm10
	movsd [rdi + rax*8 + 16], xmm11
	
.nb110_updateouterdata:
	mov   ecx, [rsp + nb110_ii3]
	mov   rdi, [rbp + nb110_faction]
	mov   rsi, [rbp + nb110_fshift]
	mov   edx, [rsp + nb110_is3]

	;# accumulate i forces in xmm13, xmm14, xmm15
	movhlps xmm3, xmm13
	movhlps xmm4, xmm14
	movhlps xmm5, xmm15
	addsd  xmm13, xmm3
	addsd  xmm14, xmm4
	addsd  xmm15, xmm5 ;# sum is in low xmm13-xmm15

	;# increment i force 
	movsd  xmm3, [rdi + rcx*8]
	movsd  xmm4, [rdi + rcx*8 + 8]
	movsd  xmm5, [rdi + rcx*8 + 16]
	subsd  xmm3, xmm13
	subsd  xmm4, xmm14
	subsd  xmm5, xmm15
	movsd  [rdi + rcx*8],     xmm3
	movsd  [rdi + rcx*8 + 8], xmm4
	movsd  [rdi + rcx*8 + 16], xmm5

	;# increment fshift force  
	movsd  xmm3, [rsi + rdx*8]
	movsd  xmm4, [rsi + rdx*8 + 8]
	movsd  xmm5, [rsi + rdx*8 + 16]
	subsd  xmm3, xmm13
	subsd  xmm4, xmm14
	subsd  xmm5, xmm15
	movsd  [rsi + rdx*8],     xmm3
	movsd  [rsi + rdx*8 + 8], xmm4
	movsd  [rsi + rdx*8 + 16], xmm5

	;# get n from stack
	mov esi, [rsp + nb110_n]
        ;# get group index for i particle 
        mov   rdx, [rbp + nb110_gid]      	;# base of gid[]
        mov   edx, [rdx + rsi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movhlps xmm6, xmm12
	addsd  xmm12, xmm6	;# low xmm12 has the sum now 

	;# add earlier value from mem 
	mov   rax, [rbp + nb110_Vc]
	addsd xmm12, [rax + rdx*8] 
	;# move back to mem 
	movsd [rax + rdx*8], xmm12
	
	;# accumulate total lj energy and update it 
	movapd xmm7, [rsp + nb110_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 
	
	;# add earlier value from mem 
	mov   rax, [rbp + nb110_Vvdw]
	addsd xmm7, [rax + rdx*8] 
	;# move back to mem 
	movsd [rax + rdx*8], xmm7 
	
       ;# finish if last 
        mov ecx, [rsp + nb110_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb110_outerend

        ;# not last, iterate outer loop once more!  
        mov [rsp + nb110_n], esi
        jmp .nb110_outer
.nb110_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [rsp + nb110_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb110_end
        ;# non-zero, do one more workunit
        jmp   .nb110_threadloop
.nb110_end:
	mov eax, [rsp + nb110_nouter]
	mov ebx, [rsp + nb110_ninner]
	mov rcx, [rbp + nb110_outeriter]
	mov rdx, [rbp + nb110_inneriter]
	mov [rcx], eax
	mov [rdx], ebx

	add rsp, 408
	emms


        pop r15
        pop r14
        pop r13
        pop r12

	pop rbx
	pop	rbp
	ret






.globl nb_kernel110nf_x86_64_sse2
.globl _nb_kernel110nf_x86_64_sse2
nb_kernel110nf_x86_64_sse2:	
_nb_kernel110nf_x86_64_sse2:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb110nf_fshift,         16
.equiv          nb110nf_gid,            24
.equiv          nb110nf_pos,            32
.equiv          nb110nf_faction,        40
.equiv          nb110nf_charge,         48
.equiv          nb110nf_p_facel,        56
.equiv          nb110nf_argkrf,         64
.equiv          nb110nf_argcrf,         72
.equiv          nb110nf_Vc,             80
.equiv          nb110nf_type,           88
.equiv          nb110nf_p_ntype,        96
.equiv          nb110nf_vdwparam,       104
.equiv          nb110nf_Vvdw,           112
.equiv          nb110nf_p_tabscale,     120
.equiv          nb110nf_VFtab,          128
.equiv          nb110nf_invsqrta,       136
.equiv          nb110nf_dvda,           144
.equiv          nb110nf_p_gbtabscale,   152
.equiv          nb110nf_GBtab,          160
.equiv          nb110nf_p_nthreads,     168
.equiv          nb110nf_count,          176
.equiv          nb110nf_mtx,            184
.equiv          nb110nf_outeriter,      192
.equiv          nb110nf_inneriter,      200
.equiv          nb110nf_work,           208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb110nf_ix,             0
.equiv          nb110nf_iy,             16
.equiv          nb110nf_iz,             32
.equiv          nb110nf_iq,             48
.equiv          nb110nf_c6,             64
.equiv          nb110nf_c12,            80
.equiv          nb110nf_vctot,          96
.equiv          nb110nf_Vvdwtot,        112
.equiv          nb110nf_half,           128
.equiv          nb110nf_three,          144
.equiv          nb110nf_is3,            160
.equiv          nb110nf_ii3,            164
.equiv          nb110nf_nri,            168
.equiv          nb110nf_iinr,           176
.equiv          nb110nf_jindex,         184
.equiv          nb110nf_jjnr,           192
.equiv          nb110nf_shift,          200
.equiv          nb110nf_shiftvec,       208
.equiv          nb110nf_facel,          216
.equiv          nb110nf_innerjjnr,      224
.equiv          nb110nf_ntia,           232
.equiv          nb110nf_innerk,         236
.equiv          nb110nf_n,              240
.equiv          nb110nf_nn1,            244
.equiv          nb110nf_ntype,          248
.equiv          nb110nf_nouter,         252
.equiv          nb110nf_ninner,         256
	push rbp
	mov  rbp, rsp
	push rbx
	
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 280		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb110nf_nouter], eax
	mov [rsp + nb110nf_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb110nf_nri], edi
	mov [rsp + nb110nf_iinr], rsi
	mov [rsp + nb110nf_jindex], rdx
	mov [rsp + nb110nf_jjnr], rcx
	mov [rsp + nb110nf_shift], r8
	mov [rsp + nb110nf_shiftvec], r9
	mov rdi, [rbp + nb110nf_p_ntype]
	mov edi, [rdi]
	mov [rsp + nb110nf_ntype], edi
	mov rsi, [rbp + nb110nf_p_facel]
	movsd xmm0, [rsi]
	movsd [rsp + nb110nf_facel], xmm0

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double half IEEE (hex)
	mov ebx, 0x3fe00000
	mov [rsp + nb110nf_half], eax
	mov [rsp + nb110nf_half+4], ebx
	movsd xmm1, [rsp + nb110nf_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# one
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# two
	addpd  xmm3, xmm2	;# three
	movapd [rsp + nb110nf_half], xmm1
	movapd [rsp + nb110nf_three], xmm3

.nb110nf_threadloop:
        mov   rsi, [rbp + nb110nf_count]        ;# pointer to sync counter
        mov   eax, [rsi]
.nb110nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           	;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb110nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb110nf_nri]