nb_kernel114_x86_64_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,294 行 · 第 1/5 页

##
## $Id: nb_kernel114_x86_64_sse2.s,v 1.4.2.3 2006/09/22 08:40:32 lindahl Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##





.globl nb_kernel114_x86_64_sse2
.globl _nb_kernel114_x86_64_sse2
nb_kernel114_x86_64_sse2:       
_nb_kernel114_x86_64_sse2:      
.set nb114_fshift, 16
.set nb114_gid, 24
.set nb114_pos, 32
.set nb114_faction, 40
.set nb114_charge, 48
.set nb114_p_facel, 56
.set nb114_argkrf, 64
.set nb114_argcrf, 72
.set nb114_Vc, 80
.set nb114_type, 88
.set nb114_p_ntype, 96
.set nb114_vdwparam, 104
.set nb114_Vvdw, 112
.set nb114_p_tabscale, 120
.set nb114_VFtab, 128
.set nb114_invsqrta, 136
.set nb114_dvda, 144
.set nb114_p_gbtabscale, 152
.set nb114_GBtab, 160
.set nb114_p_nthreads, 168
.set nb114_count, 176
.set nb114_mtx, 184
.set nb114_outeriter, 192
.set nb114_inneriter, 200
.set nb114_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb114_ixO, 0
.set nb114_iyO, 16
.set nb114_izO, 32
.set nb114_ixH1, 48
.set nb114_iyH1, 64
.set nb114_izH1, 80
.set nb114_ixH2, 96
.set nb114_iyH2, 112
.set nb114_izH2, 128
.set nb114_ixM, 144
.set nb114_iyM, 160
.set nb114_izM, 176
.set nb114_jxO, 192
.set nb114_jyO, 208
.set nb114_jzO, 224
.set nb114_jxH1, 240
.set nb114_jyH1, 256
.set nb114_jzH1, 272
.set nb114_jxH2, 288
.set nb114_jyH2, 304
.set nb114_jzH2, 320
.set nb114_jxM, 336
.set nb114_jyM, 352
.set nb114_jzM, 368
.set nb114_dxOO, 384
.set nb114_dyOO, 400
.set nb114_dzOO, 416
.set nb114_dxH1H1, 432
.set nb114_dyH1H1, 448
.set nb114_dzH1H1, 464
.set nb114_dxH1H2, 480
.set nb114_dyH1H2, 496
.set nb114_dzH1H2, 512
.set nb114_dxH1M, 528
.set nb114_dyH1M, 544
.set nb114_dzH1M, 560
.set nb114_dxH2H1, 576
.set nb114_dyH2H1, 592
.set nb114_dzH2H1, 608
.set nb114_dxH2H2, 624
.set nb114_dyH2H2, 640
.set nb114_dzH2H2, 656
.set nb114_dxH2M, 672
.set nb114_dyH2M, 688
.set nb114_dzH2M, 704
.set nb114_dxMH1, 720
.set nb114_dyMH1, 736
.set nb114_dzMH1, 752
.set nb114_dxMH2, 768
.set nb114_dyMH2, 784
.set nb114_dzMH2, 800
.set nb114_dxMM, 816
.set nb114_dyMM, 832
.set nb114_dzMM, 848
.set nb114_qqMM, 864
.set nb114_qqMH, 880
.set nb114_qqHH, 896
.set nb114_two, 912
.set nb114_c6, 944
.set nb114_c12, 960
.set nb114_vctot, 976
.set nb114_Vvdwtot, 992
.set nb114_fixO, 1008
.set nb114_fiyO, 1024
.set nb114_fizO, 1040
.set nb114_fixH1, 1056
.set nb114_fiyH1, 1072
.set nb114_fizH1, 1088
.set nb114_fixH2, 1104
.set nb114_fiyH2, 1120
.set nb114_fizH2, 1136
.set nb114_fixM, 1152
.set nb114_fiyM, 1168
.set nb114_fizM, 1184
.set nb114_fjxO, 1200
.set nb114_fjyO, 1216
.set nb114_fjzO, 1232
.set nb114_fjxH1, 1248
.set nb114_fjyH1, 1264
.set nb114_fjzH1, 1280
.set nb114_fjxH2, 1296
.set nb114_fjyH2, 1312
.set nb114_fjzH2, 1328
.set nb114_fjxM, 1344
.set nb114_fjyM, 1360
.set nb114_fjzM, 1376
.set nb114_half, 1392
.set nb114_three, 1408
.set nb114_six, 1424
.set nb114_twelve, 1440
.set nb114_rsqOO, 1456
.set nb114_rsqH1H1, 1472
.set nb114_rsqH1H2, 1488
.set nb114_rsqH1M, 1504
.set nb114_rsqH2H1, 1520
.set nb114_rsqH2H2, 1536
.set nb114_rsqH2M, 1552
.set nb114_rsqMH1, 1568
.set nb114_rsqMH2, 1584
.set nb114_rsqMM, 1600
.set nb114_rinvsqOO, 1616
.set nb114_rinvH1H1, 1632
.set nb114_rinvH1H2, 1648
.set nb114_rinvH1M, 1664
.set nb114_rinvH2H1, 1680
.set nb114_rinvH2H2, 1696
.set nb114_rinvH2M, 1712
.set nb114_rinvMH1, 1728
.set nb114_rinvMH2, 1744
.set nb114_rinvMM, 1760
.set nb114_nri, 1776
.set nb114_iinr, 1784
.set nb114_jindex, 1792
.set nb114_jjnr, 1800
.set nb114_shift, 1808
.set nb114_shiftvec, 1816
.set nb114_facel, 1824
.set nb114_innerjjnr, 1832
.set nb114_is3, 1840
.set nb114_ii3, 1844
.set nb114_innerk, 1848
.set nb114_n, 1852
.set nb114_nn1, 1856
.set nb114_nouter, 1860
.set nb114_ninner, 1864
        push %rbp
        movq %rsp,%rbp
        push %rbx

        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $1880,%rsp         ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb114_nouter(%rsp)
        movl %eax,nb114_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb114_nri(%rsp)
        movq %rsi,nb114_iinr(%rsp)
        movq %rdx,nb114_jindex(%rsp)
        movq %rcx,nb114_jjnr(%rsp)
        movq %r8,nb114_shift(%rsp)
        movq %r9,nb114_shiftvec(%rsp)
        movq nb114_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd %xmm0,nb114_facel(%rsp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double half IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb114_half(%rsp)
        movl %ebx,nb114_half+4(%rsp)
        movsd nb114_half(%rsp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## one
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## two
        addpd  %xmm2,%xmm3      ## three
        movapd %xmm3,%xmm4
        addpd  %xmm4,%xmm4      ## six
        movapd %xmm4,%xmm5
        addpd  %xmm5,%xmm5      ## twelve
        movapd %xmm1,nb114_half(%rsp)
        movapd %xmm2,nb114_two(%rsp)
        movapd %xmm3,nb114_three(%rsp)
        movapd %xmm4,nb114_six(%rsp)
        movapd %xmm5,nb114_twelve(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb114_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]        
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb114_charge(%rbp),%rdx
        movsd 24(%rdx,%rbx,8),%xmm3
        movsd %xmm3,%xmm4
        movsd 8(%rdx,%rbx,8),%xmm5
        movq nb114_p_facel(%rbp),%rsi
        movsd (%rsi),%xmm0
        movsd nb114_facel(%rsp),%xmm6
        mulsd  %xmm3,%xmm3
        mulsd  %xmm5,%xmm4
        mulsd  %xmm5,%xmm5
        mulsd  %xmm6,%xmm3
        mulsd  %xmm6,%xmm4
        mulsd  %xmm6,%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb114_qqMM(%rsp)
        movapd %xmm4,nb114_qqMH(%rsp)
        movapd %xmm5,nb114_qqHH(%rsp)

        xorpd %xmm0,%xmm0
        movq  nb114_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movq nb114_p_ntype(%rbp),%rdi
        imull (%rdi),%ecx     ## rcx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movq  nb114_vdwparam(%rbp),%rax
        movlpd (%rax,%rdx,8),%xmm0
        movlpd 8(%rax,%rdx,8),%xmm1
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        movapd %xmm0,nb114_c6(%rsp)
        movapd %xmm1,nb114_c12(%rsp)

_nb_kernel114_x86_64_sse2.nb114_threadloop: 
        movq  nb114_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel114_x86_64_sse2.nb114_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel114_x86_64_sse2.nb114_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb114_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb114_n(%rsp)
        movl %ebx,nb114_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel114_x86_64_sse2.nb114_outerstart
        jmp _nb_kernel114_x86_64_sse2.nb114_end

_nb_kernel114_x86_64_sse2.nb114_outerstart: 
        ## ebx contains number of outer iterations
        addl nb114_nouter(%rsp),%ebx
        movl %ebx,nb114_nouter(%rsp)

_nb_kernel114_x86_64_sse2.nb114_outer: 
        movq  nb114_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx        ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb114_is3(%rsp)      ## store is3 

        movq  nb114_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movsd (%rax,%rbx,8),%xmm0
        movsd 8(%rax,%rbx,8),%xmm1
        movsd 16(%rax,%rbx,8),%xmm2

        movq  nb114_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]        
        movl  (%rcx,%rsi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        movapd %xmm0,%xmm6
        movapd %xmm1,%xmm7

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb114_pos(%rbp),%rax      ## rax = base of pos[]  
        movl  %ebx,nb114_ii3(%rsp)

        addsd (%rax,%rbx,8),%xmm3       ## ox
        addsd 8(%rax,%rbx,8),%xmm4      ## oy
        addsd 16(%rax,%rbx,8),%xmm5     ## oz   
        addsd 24(%rax,%rbx,8),%xmm6     ## h1x
        addsd 32(%rax,%rbx,8),%xmm7     ## h1y
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm7,%xmm7
        movapd %xmm3,nb114_ixO(%rsp)
        movapd %xmm4,nb114_iyO(%rsp)
        movapd %xmm5,nb114_izO(%rsp)
        movapd %xmm6,nb114_ixH1(%rsp)
        movapd %xmm7,nb114_iyH1(%rsp)

        movsd %xmm2,%xmm6
        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 40(%rax,%rbx,8),%xmm6    ## h1z
        addsd 48(%rax,%rbx,8),%xmm0    ## h2x
        addsd 56(%rax,%rbx,8),%xmm1    ## h2y
        addsd 64(%rax,%rbx,8),%xmm2    ## h2z
        addsd 72(%rax,%rbx,8),%xmm3    ## mx
        addsd 80(%rax,%rbx,8),%xmm4    ## my
        addsd 88(%rax,%rbx,8),%xmm5    ## mz

        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm6,nb114_izH1(%rsp)
        movapd %xmm0,nb114_ixH2(%rsp)
        movapd %xmm1,nb114_iyH2(%rsp)
        movapd %xmm2,nb114_izH2(%rsp)
        movapd %xmm3,nb114_ixM(%rsp)
        movapd %xmm4,nb114_iyM(%rsp)
        movapd %xmm5,nb114_izM(%rsp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb114_vctot(%rsp)
        movapd %xmm4,nb114_Vvdwtot(%rsp)
        movapd %xmm4,nb114_fixO(%rsp)
        movapd %xmm4,nb114_fiyO(%rsp)
        movapd %xmm4,nb114_fizO(%rsp)
        movapd %xmm4,nb114_fixH1(%rsp)
        movapd %xmm4,nb114_fiyH1(%rsp)
        movapd %xmm4,nb114_fizH1(%rsp)
        movapd %xmm4,nb114_fixH2(%rsp)
        movapd %xmm4,nb114_fiyH2(%rsp)
        movapd %xmm4,nb114_fizH2(%rsp)
        movapd %xmm4,nb114_fixM(%rsp)
        movapd %xmm4,nb114_fiyM(%rsp)
        movapd %xmm4,nb114_fizM(%rsp)

        movq  nb114_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb114_pos(%rbp),%rsi
        movq  nb114_faction(%rbp),%rdi
        movq  nb114_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb114_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb114_ninner(%rsp),%ecx
        movl  %ecx,nb114_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb114_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel114_x86_64_sse2.nb114_unroll_loop
        jmp   _nb_kernel114_x86_64_sse2.nb114_checksingle
_nb_kernel114_x86_64_sse2.nb114_unroll_loop: 
        ## twice unrolled innerloop here 
        movq  nb114_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx

        addq $8,nb114_innerjjnr(%rsp)            ## advance pointer (unrolled 2) 

        movq nb114_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx

        ## load j O coordinates
        movlpd (%rsi,%rax,8),%xmm4
        movlpd 8(%rsi,%rax,8),%xmm5
        movlpd 16(%rsi,%rax,8),%xmm6
        movhpd (%rsi,%rbx,8),%xmm4
        movhpd 8(%rsi,%rbx,8),%xmm5
        movhpd 16(%rsi,%rbx,8),%xmm6

    ## xmm4 = Ox
    ## xmm5 = Oy
    ## xmm6 = Oz

    subpd nb114_ixO(%rsp),%xmm4
    subpd nb114_iyO(%rsp),%xmm5
    subpd nb114_izO(%rsp),%xmm6

    ## store dx/dy/dz
    movapd %xmm4,%xmm9
    movapd %xmm5,%xmm10
    movapd %xmm6,%xmm11

        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm4
        addpd %xmm6,%xmm4       ## rsq in xmm4 

        cvtpd2ps %xmm4,%xmm6
        rcpps %xmm6,%xmm6
        cvtps2pd %xmm6,%xmm6    ## lu in low xmm6 

        ## 1/x lookup seed in xmm6 
        movapd nb114_two(%rsp),%xmm0
        movapd %xmm4,%xmm5
        mulpd %xmm6,%xmm4       ## lu*rsq 
        subpd %xmm4,%xmm0       ## 2-lu*rsq 
        mulpd %xmm0,%xmm6       ## (new lu) 

        movapd nb114_two(%rsp),%xmm0